-
-
Notifications
You must be signed in to change notification settings - Fork 31
/
engine.pro
642 lines (589 loc) · 18.6 KB
/
engine.pro
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
# The Doomsday Engine Project
# Copyright (c) 2011 Jaakko Keränen <jaakko.keranen@iki.fi>
# Copyright (c) 2011 Daniel Swanson <danij@dengine.net>
TEMPLATE = app
TARGET = doomsday
# Build Configuration --------------------------------------------------------
include(../config.pri)
VERSION = $$DENG_VERSION
echo(Doomsday version $${DENG_VERSION}.)
# External Dependencies ------------------------------------------------------
include(../dep_sdl.pri)
include(../dep_opengl.pri)
include(../dep_zlib.pri)
include(../dep_libpng.pri)
include(../dep_curses.pri)
include(../dep_curl.pri)
include(../dep_lzss.pri)
win32 {
include(../dep_directx.pri)
}
# Common Definitions ---------------------------------------------------------
DEFINES += __DOOMSDAY__
!isEmpty(DENG_BUILD) {
echo(Build number: $$DENG_BUILD)
DEFINES += DOOMSDAY_BUILD_TEXT=\\\"$$DENG_BUILD\\\"
} else {
echo(DENG_BUILD is not defined.)
}
unix:!macx {
DEFINES += DENG_BASE_DIR=\\\"$${DENG_BASE_DIR}/\\\"
DEFINES += DENG_LIBRARY_DIR=\\\"$${DENG_LIB_DIR}/\\\"
QMAKE_LFLAGS += -rdynamic
}
macx {
useFramework(Cocoa)
useFramework(QTKit)
}
win32 {
DEFINES += WIN32_GAMMA
RC_FILE = win32/res/doomsday.rc
OTHER_FILES += api/doomsday.def
QMAKE_LFLAGS += \
/NODEFAULTLIB:libcmt \
/DEF:\"$$DENG_API_DIR/doomsday.def\" \
/IMPLIB:\"$$DENG_EXPORT_LIB\"
LIBS += -lkernel32 -lgdi32 -lole32 -luser32 -lwsock32 -lwinmm \
-lopengl32 -lglu32
}
# Engine Configuration -------------------------------------------------------
deng_writertypecheck {
DEFINES += DENG_WRITER_TYPECHECK
}
deng_sdlnetdummy {
HEADERS += portable/include/sdlnet_dummy.h
}
# Source Files ---------------------------------------------------------------
DENG_API_HEADERS = \
api/dd_animator.h \
api/dd_api.h \
api/dd_fontrenderer.h \
api/dd_gl.h \
api/dd_infine.h \
api/dd_maptypes.h \
api/dd_plugin.h \
api/dd_share.h \
api/dd_string.h \
api/dd_types.h \
api/dd_ui.h \
api/dd_vectorgraphic.h \
api/dd_wad.h \
api/dd_world.h \
api/dengproject.h \
api/dfile.h \
api/doomsday.h \
api/point.h \
api/reader.h \
api/rect.h \
api/size.h \
api/smoother.h \
api/sys_audiod.h \
api/sys_audiod_mus.h \
api/sys_audiod_sfx.h \
api/uri.h \
api/writer.h
DENG_HEADERS = \
portable/include/abstractfile.h \
portable/include/bitmapfont.h \
portable/include/blockset.h \
portable/include/bsp_edge.h \
portable/include/bsp_intersection.h \
portable/include/bsp_main.h \
portable/include/bsp_map.h \
portable/include/bsp_node.h \
portable/include/bsp_superblock.h \
portable/include/b_command.h \
portable/include/b_context.h \
portable/include/b_device.h \
portable/include/b_main.h \
portable/include/b_util.h \
portable/include/cbuffer.h \
portable/include/cl_def.h \
portable/include/cl_frame.h \
portable/include/cl_infine.h \
portable/include/cl_mobj.h \
portable/include/cl_player.h \
portable/include/cl_sound.h \
portable/include/cl_world.h \
portable/include/colorpalette.h \
portable/include/con_bar.h \
portable/include/con_bind.h \
portable/include/con_busy.h \
portable/include/con_config.h \
portable/include/con_main.h \
portable/include/dam_file.h \
portable/include/dam_main.h \
portable/include/dd_def.h \
portable/include/dd_help.h \
portable/include/dd_input.h \
portable/include/dd_loop.h \
portable/include/dd_main.h \
portable/include/dd_pinit.h \
portable/include/dd_version.h \
portable/include/dd_zone.h \
portable/include/def_data.h \
portable/include/def_main.h \
portable/include/def_share.h \
portable/include/de_audio.h \
portable/include/de_base.h \
portable/include/de_bsp.h \
portable/include/de_console.h \
portable/include/de_dam.h \
portable/include/de_defs.h \
portable/include/de_edit.h \
portable/include/de_filesys.h \
portable/include/de_graphics.h \
portable/include/de_infine.h \
portable/include/de_misc.h \
portable/include/de_network.h \
portable/include/de_platform.h \
portable/include/de_play.h \
portable/include/de_refresh.h \
portable/include/de_render.h \
portable/include/de_system.h \
portable/include/de_ui.h \
portable/include/edit_bias.h \
portable/include/edit_map.h \
portable/include/filedirectory.h \
portable/include/filelist.h \
portable/include/finaleinterpreter.h \
portable/include/fi_main.h \
portable/include/font.h \
portable/include/fonts.h \
portable/include/fs_main.h \
portable/include/fs_util.h \
portable/include/game.h \
portable/include/gl_defer.h \
portable/include/gl_draw.h \
portable/include/gl_hq2x.h \
portable/include/gl_main.h \
portable/include/gl_model.h \
portable/include/gl_pcx.h \
portable/include/gl_png.h \
portable/include/gl_tex.h \
portable/include/gl_texmanager.h \
portable/include/gl_tga.h \
portable/include/image.h \
portable/include/library.h \
portable/include/lumpdirectory.h \
portable/include/lumpfile.h \
portable/include/lumpinfo.h \
portable/include/material.h \
portable/include/materials.h \
portable/include/materialvariant.h \
portable/include/m_args.h \
portable/include/m_bams.h \
portable/include/m_binarytree.h \
portable/include/m_decomp64.h \
portable/include/m_gridmap.h \
portable/include/m_huffman.h \
portable/include/m_linkedlist.h \
portable/include/m_md5.h \
portable/include/m_misc.h \
portable/include/m_mus2midi.h \
portable/include/m_nodepile.h \
portable/include/m_profiler.h \
portable/include/m_stack.h \
portable/include/m_vector.h \
portable/include/net_buf.h \
portable/include/net_demo.h \
portable/include/net_event.h \
portable/include/net_main.h \
portable/include/net_msg.h \
portable/include/pathdirectory.h \
portable/include/p_bmap.h \
portable/include/p_cmd.h \
portable/include/p_control.h \
portable/include/p_dmu.h \
portable/include/p_intercept.h \
portable/include/p_linedef.h \
portable/include/p_mapdata.h \
portable/include/p_maptypes.h \
portable/include/p_maputil.h \
portable/include/p_object.h \
portable/include/p_objlink.h \
portable/include/p_particle.h \
portable/include/p_plane.h \
portable/include/p_players.h \
portable/include/p_polyob.h \
portable/include/p_polyobj.h \
portable/include/p_sector.h \
portable/include/p_seg.h \
portable/include/p_sidedef.h \
portable/include/p_sight.h \
portable/include/p_subsector.h \
portable/include/p_surface.h \
portable/include/p_think.h \
portable/include/p_ticker.h \
portable/include/p_vertex.h \
portable/include/rend_bias.h \
portable/include/rend_clip.h \
portable/include/rend_console.h \
portable/include/rend_decor.h \
portable/include/rend_dynlight.h \
portable/include/rend_fakeradio.h \
portable/include/rend_font.h \
portable/include/rend_halo.h \
portable/include/rend_list.h \
portable/include/rend_main.h \
portable/include/rend_model.h \
portable/include/rend_particle.h \
portable/include/rend_shadow.h \
portable/include/rend_sky.h \
portable/include/rend_sprite.h \
portable/include/resourcenamespace.h \
portable/include/abstractresource.h \
portable/include/r_data.h \
portable/include/r_draw.h \
portable/include/r_fakeradio.h \
portable/include/r_lgrid.h \
portable/include/r_lumobjs.h \
portable/include/r_main.h \
portable/include/r_model.h \
portable/include/r_shadow.h \
portable/include/r_sky.h \
portable/include/r_things.h \
portable/include/r_util.h \
portable/include/r_world.h \
portable/include/sv_def.h \
portable/include/sv_frame.h \
portable/include/sv_infine.h \
portable/include/sv_missile.h \
portable/include/sv_pool.h \
portable/include/sv_sound.h \
portable/include/svg.h \
portable/include/sys_audio.h \
portable/include/sys_audiod_dummy.h \
portable/include/sys_audiod_loader.h \
portable/include/sys_console.h \
portable/include/sys_direc.h \
portable/include/sys_findfile.h \
portable/include/sys_input.h \
portable/include/sys_master.h \
portable/include/sys_network.h \
portable/include/sys_opengl.h \
portable/include/sys_reslocator.h \
portable/include/sys_sock.h \
portable/include/sys_system.h \
portable/include/sys_timer.h \
portable/include/sys_window.h \
portable/include/s_cache.h \
portable/include/s_environ.h \
portable/include/s_logic.h \
portable/include/s_main.h \
portable/include/s_mus.h \
portable/include/s_sfx.h \
portable/include/s_wav.h \
portable/include/tab_anorms.h \
portable/include/texture.h \
portable/include/textures.h \
portable/include/texturecontent.h \
portable/include/texturevariant.h \
portable/include/texturevariantspecification.h \
portable/include/ui2_main.h \
portable/include/ui_main.h \
portable/include/ui_mpi.h \
portable/include/ui_panel.h \
portable/include/wadfile.h \
portable/include/zipfile.h
# Platform-specific configuration.
unix:!win32 {
DENG_PLATFORM_HEADERS += \
$$DENG_UNIX_INCLUDE_DIR/dd_uinit.h \
$$DENG_UNIX_INCLUDE_DIR/sys_path.h
INCLUDEPATH += $$DENG_UNIX_INCLUDE_DIR
}
macx {
DENG_PLATFORM_HEADERS += \
$$DENG_MAC_INCLUDE_DIR/DoomsdayRunner.h \
$$DENG_MAC_INCLUDE_DIR/MusicPlayer.h \
$$DENG_MAC_INCLUDE_DIR/SDLMain.h \
$$DENG_MAC_INCLUDE_DIR/StartupWindowController.h
OBJECTIVE_SOURCES += \
mac/src/DoomsdayRunner.m \
mac/src/MusicPlayer.m \
mac/src/SDLMain.m \
mac/src/StartupWindowController.m
INCLUDEPATH += $$DENG_MAC_INCLUDE_DIR
}
win32 {
DENG_PLATFORM_HEADERS += \
$$DENG_WIN_INCLUDE_DIR/dd_winit.h \
$$DENG_WIN_INCLUDE_DIR/resource.h
INCLUDEPATH += $$DENG_WIN_INCLUDE_DIR
}
INCLUDEPATH += \
$$DENG_INCLUDE_DIR \
$$DENG_API_DIR
HEADERS += \
$$DENG_API_HEADERS \
$$DENG_PLATFORM_HEADERS \
$$DENG_HEADERS
DENG_UNIX_SOURCES += \
portable/src/sys_sdl_window.c \
unix/src/dd_uinit.c \
unix/src/sys_audiod_loader.c \
unix/src/sys_console.c \
unix/src/sys_findfile.c \
unix/src/sys_input.c \
unix/src/sys_path.c
DENG_WIN32_SOURCES += \
win32/src/dd_winit.c \
win32/src/sys_audiod_loader.c \
win32/src/sys_console.c \
win32/src/sys_findfile.c \
win32/src/sys_input.c \
win32/src/sys_window.c
SOURCES += \
portable/src/abstractfile.c \
portable/src/animator.c \
portable/src/bitmapfont.c \
portable/src/blockset.c \
portable/src/b_command.c \
portable/src/b_context.c \
portable/src/b_device.c \
portable/src/b_main.c \
portable/src/b_util.c \
portable/src/bsp_edge.c \
portable/src/bsp_intersection.c \
portable/src/bsp_main.c \
portable/src/bsp_map.c \
portable/src/bsp_node.c \
portable/src/bsp_superblock.c \
portable/src/cbuffer.c \
portable/src/cl_frame.c \
portable/src/cl_infine.c \
portable/src/cl_main.c \
portable/src/cl_mobj.c \
portable/src/cl_player.c \
portable/src/cl_sound.c \
portable/src/cl_world.c \
portable/src/colorpalette.c \
portable/src/con_bar.c \
portable/src/con_busy.c \
portable/src/con_config.c \
portable/src/con_data.c \
portable/src/con_main.c \
portable/src/dam_file.c \
portable/src/dam_main.c \
portable/src/dd_help.c \
portable/src/dd_input.c \
portable/src/dd_loop.c \
portable/src/dd_main.c \
portable/src/dd_pinit.c \
portable/src/dd_plugin.c \
portable/src/dd_wad.c \
portable/src/dd_zone.c \
portable/src/def_data.c \
portable/src/def_main.c \
portable/src/def_read.c \
portable/src/dfile.c \
portable/src/dgl_common.c \
portable/src/dgl_draw.c \
portable/src/edit_bias.c \
portable/src/edit_map.c \
portable/src/filedirectory.c \
portable/src/filelist.c \
portable/src/finaleinterpreter.c \
portable/src/fi_main.c \
portable/src/fonts.c \
portable/src/fs_main.c \
portable/src/fs_util.c \
portable/src/game.c \
portable/src/gl_defer.c \
portable/src/gl_draw.c \
portable/src/gl_drawvectorgraphic.c \
portable/src/gl_hq2x.c \
portable/src/gl_main.c \
portable/src/gl_pcx.c \
portable/src/gl_png.c \
portable/src/gl_tex.c \
portable/src/gl_texmanager.c \
portable/src/gl_tga.c \
portable/src/image.c \
portable/src/library.c \
portable/src/lumpdirectory.c \
portable/src/lumpfile.c \
portable/src/material.c \
portable/src/materials.c \
portable/src/materialvariant.c \
portable/src/m_args.c \
portable/src/m_bams.c \
portable/src/m_binarytree.c \
portable/src/m_decomp64.c \
portable/src/m_gridmap.c \
portable/src/m_huffman.c \
portable/src/m_linkedlist.c \
portable/src/m_md5.c \
portable/src/m_misc.c \
portable/src/m_mus2midi.c \
portable/src/m_nodepile.c \
portable/src/m_stack.c \
portable/src/m_string.c \
portable/src/m_vector.c \
portable/src/net_buf.c \
portable/src/net_demo.c \
portable/src/net_event.c \
portable/src/net_main.c \
portable/src/net_msg.c \
portable/src/net_ping.c \
portable/src/pathdirectory.c \
portable/src/p_bmap.c \
portable/src/p_cmd.c \
portable/src/p_control.c \
portable/src/p_data.c \
portable/src/p_dmu.c \
portable/src/p_intercept.c \
portable/src/p_linedef.c \
portable/src/p_maputil.c \
portable/src/p_mobj.c \
portable/src/p_objlink.c \
portable/src/p_particle.c \
portable/src/p_plane.c \
portable/src/p_players.c \
portable/src/p_polyob.c \
portable/src/p_sector.c \
portable/src/p_seg.c \
portable/src/p_sidedef.c \
portable/src/p_sight.c \
portable/src/p_subsector.c \
portable/src/p_surface.c \
portable/src/p_think.c \
portable/src/p_ticker.c \
portable/src/p_vertex.c \
portable/src/point.c \
portable/src/r_data.c \
portable/src/r_draw.c \
portable/src/r_fakeradio.c \
portable/src/r_lgrid.c \
portable/src/r_lumobjs.c \
portable/src/r_main.c \
portable/src/r_model.c \
portable/src/r_shadow.c \
portable/src/r_sky.c \
portable/src/r_things.c \
portable/src/r_util.c \
portable/src/r_world.c \
portable/src/reader.c \
portable/src/rect.c \
portable/src/rend_bias.c \
portable/src/rend_clip.c \
portable/src/rend_console.c \
portable/src/rend_decor.c \
portable/src/rend_dynlight.c \
portable/src/rend_fakeradio.c \
portable/src/rend_font.c \
portable/src/rend_halo.c \
portable/src/rend_list.c \
portable/src/rend_main.c \
portable/src/rend_model.c \
portable/src/rend_particle.c \
portable/src/rend_shadow.c \
portable/src/rend_sky.c \
portable/src/rend_sprite.c \
portable/src/resourcenamespace.c \
portable/src/abstractresource.c \
portable/src/smoother.c \
portable/src/stringpool.c \
portable/src/s_cache.c \
portable/src/s_environ.c \
portable/src/s_logic.c \
portable/src/s_main.c \
portable/src/s_mus.c \
portable/src/s_sfx.c \
portable/src/s_wav.c \
portable/src/size.c \
portable/src/sv_frame.c \
portable/src/sv_infine.c \
portable/src/sv_main.c \
portable/src/sv_missile.c \
portable/src/sv_pool.c \
portable/src/sv_sound.c \
portable/src/svg.c \
portable/src/sys_audiod_dummy.c \
portable/src/sys_direc.c \
portable/src/sys_master.c \
portable/src/sys_network.c \
portable/src/sys_opengl.c \
portable/src/sys_reslocator.c \
portable/src/sys_sock.c \
portable/src/sys_system.c \
portable/src/sys_timer.c \
portable/src/tab_tables.c \
portable/src/texture.c \
portable/src/textures.c \
portable/src/texturevariant.c \
portable/src/ui_main.c \
portable/src/ui2_main.c \
portable/src/ui_mpi.c \
portable/src/ui_panel.c \
portable/src/uri.c \
portable/src/wadfile.c \
portable/src/writer.c \
portable/src/zipfile.c
unix {
SOURCES += $$DENG_UNIX_SOURCES
}
win32 {
SOURCES += $$DENG_WIN32_SOURCES
}
!deng_nosdlmixer {
HEADERS += portable/include/sys_audiod_sdlmixer.h
SOURCES += portable/src/sys_audiod_sdlmixer.c
}
# Use the fixed-point math from libcommon.
# TODO: Move it to the engine.
SOURCES += ../plugins/common/src/m_fixed.c
OTHER_FILES += data/cphelp.txt
# Resources ------------------------------------------------------------------
data.files = $$OUT_PWD/../doomsday.pk3
startupfonts.files = \
data/fonts/normal12.dfn \
data/fonts/normal18.dfn
startupgfx.files = \
data/graphics/background.pcx \
data/graphics/loading1.png \
data/graphics/loading2.png \
data/graphics/logo.png
macx {
# Since qmake is unable to copy directories as bundle data, let's copy
# the frameworks manually.
doPostLink("rm -rf \"$${OUT_PWD}/doomsday.app/Contents/Frameworks\"")
doPostLink("mkdir \"$${OUT_PWD}/doomsday.app/Contents/Frameworks\"")
doPostLink("cp -fRp \"$${SDL_FRAMEWORK_DIR}/SDL.framework\" \"$${OUT_PWD}/doomsday.app/Contents/Frameworks/\"")
!deng_nosdlmixer {
doPostLink("cp -fRp \"$${SDL_FRAMEWORK_DIR}/SDL_mixer.framework\" \"$${OUT_PWD}/doomsday.app/Contents/Frameworks/\"")
}
doPostLink("cp -fRp \"$${SDL_FRAMEWORK_DIR}/SDL_net.framework\" \"$${OUT_PWD}/doomsday.app/Contents/Frameworks/\"")
res.path = Contents/Resources
res.files = \
mac/res/English.lproj \
mac/res/Startup.nib \
mac/res/deng.icns
data.path = $$res.path
startupfonts.path = $${res.path}/Data/Fonts
startupgfx.path = $${res.path}/Data/Graphics
QMAKE_BUNDLE_DATA += res data startupfonts startupgfx
QMAKE_INFO_PLIST = ../build/mac/Info.plist
}
# Installation ---------------------------------------------------------------
win32 {
# Windows installation.
INSTALLS += target data startupgfx startupfonts license
target.path = $$DENG_LIB_DIR
data.path = $$DENG_DATA_DIR
startupfonts.path = $$DENG_DATA_DIR/fonts
startupgfx.path = $$DENG_DATA_DIR/graphics
license.files = doc/LICENSE
license.path = $$DENG_DOCS_DIR
}
else:unix:!macx {
# Generic Unix installation.
INSTALLS += target data startupgfx desktop
target.path = $$DENG_BIN_DIR
data.path = $$DENG_DATA_DIR
startupfonts.path = $$DENG_DATA_DIR/fonts
startupgfx.path = $$DENG_DATA_DIR/graphics
desktop.files = ../../distrib/linux/doomsday-engine.desktop
desktop.path = /usr/share/applications
}