forked from MethodicalAcceleratorDesign/MAD-X
-
Notifications
You must be signed in to change notification settings - Fork 0
/
twiss.f90
9278 lines (7956 loc) · 327 KB
/
twiss.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
SUBROUTINE twiss(rt,disp0,tab_name,sector_tab_name)
use twiss0fi
use twissafi
use twisslfi
use twisscfi
use twissotmfi
use twissbeamfi
use twissdqmin
use trackfi, only : fsecarb
use fasterror
use matrices, only : EYE
use math_constfi, only : zero, one, two
implicit none
!----------------------------------------------------------------------*
! Purpose: *
! TWISS command: Track linear lattice parameters. *
!----------------------------------------------------------------------*
double precision :: rt(6,6), disp0(6), cp_thrd=1d-12 ! coupling limit
integer :: tab_name(*)
integer :: sector_tab_name(*) ! holds sectormap data
integer :: i, j, ithr_on
integer :: chrom, eflag, chrom_warn
double precision :: orbit0(6), orbit(6), tt(6,6,6), ddisp0(6), r0mat(2,2)
double precision :: s0mat(6,6), eig_tol ! initial sigma matrix
character(len=48) :: charconv
character(len=150) :: warnstr
logical :: fast_error_func
double precision, external :: get_value
integer, external :: get_option
integer, parameter :: izero=0, ione=1
!---- Initialization
table_name = charconv(tab_name)
sectorTableName = charconv(sector_tab_name)
chrom=0
chrom_warn=1
eflag=0
ithr_on=0
fsecarb=.false.
ORBIT0 = zero
exact_expansion = get_value('twiss ','exact ') .ne. zero
call get_node_vector('orbit0 ', 6, orbit0)
RT = EYE
RW = EYE
TT = zero
call get_disp0(disp0)
DDISP0 = zero
R0MAT = zero
S0MAT = zero
OPT_FUN0 = zero
OPT_FUN = zero
DISP = zero
DDISP = zero
RMAT = zero
SIGMAT = zero
betx=zero; alfx=zero; amux=zero; bxmax=zero; dxmax=zero; xcomax=zero
sigxco=zero; sigdx=zero; cosmux=zero; wx=zero; phix=zero; dmux=zero
qx=zero; sinmux=zero; xix=zero
bety=zero; alfy=zero; amuy=zero; bymax=zero; dymax=zero; ycomax=zero
sigyco=zero; sigdy=zero; cosmuy=zero; wy=zero; phiy=zero; dmuy=zero
qy=zero; sinmuy=zero; xiy=zero
gammacp=one
nmode_flip = 0
mode_flip =.false.
synch_1=zero; synch_2=zero; synch_3=zero; synch_4=zero; synch_5=zero
synch_6=zero; synch_8=zero
suml=zero; circ=zero; eta=zero; alfa=zero; gamtr=zero; wgt=zero
!---- Track chromatic functions
chrom = get_option('twiss_chrom ')
!---- flag if called from match process
!---- get match flag for storing variables in nodes
match_is_on = get_option('match_is_on ') .ne. 0
if (match_is_on) chrom_warn = get_option('chrom_match ')
!---- flags for writing cumulative or lumped matrices
rmatrix = get_value('twiss ','rmatrix ').ne.zero
sectormap = get_option('twiss_sector ').ne.zero
!---- Get circumference
circ = get_value('probe ','circ ')
if (circ .eq. zero) call fort_fail('TWISS: ', 'Zero length sequence.')
!---- Get beam parameters
radiate = get_value('probe ','radiate ') .ne. zero
energy = get_value('probe ','energy ')
deltap = get_value('probe ','deltap ')
beta = get_value('probe ','beta ')
gamma = get_value('probe ','gamma ')
pc = get_value('probe ','pc ')
arad = get_value('probe ','arad ')
dtbyds = get_value('probe ','dtbyds ')
charge = get_value('probe ','charge ')
npart = get_value('probe ','npart ')
eig_tol = get_value('twiss ','clorb_tol ' )
!---- Set fast_error_func flag to use faster error function
!---- including tables. Thanks to late G. Erskine
fast_error_func = get_option('fast_error_func ') .ne. 0
if (fast_error_func .and. .not.fasterror_on) then
call wzset
fasterror_on = .true.
endif
if (get_option('twiss_inval ') .ne. 0) then
!---- Initial values from command attributes.
call twinifun(opt_fun0, rt)
if (get_option('twiss_print ') .ne. 0) then
print *, ' '
print '(''open line - error with deltap: '',1p,e14.6)', deltap
print '(''initial orbit vector: '', 1p,6e14.6)', orbit0
endif
call tmfrst(orbit0,orbit,.true.,.true.,rt,tt,eflag,0,0,ithr_on); if (eflag.ne.0) go to 900
if (get_option('twiss_print ') .ne. 0) &
print '(''final orbit vector: '', 1p,6e14.6)', orbit
call tmsigma(s0mat) !-- from initial conditions in opt_fun0
else
!---- Initial values from periodic solution.
call tmclor(orbit0,.true.,.true.,eig_tol,opt_fun0,rt,tt,eflag); if (eflag.ne.0) go to 900
! LD: useless, identical to last call to tmfrst in tmclor...
! call tmfrst(orbit0,orbit,.true.,.true.,rt,tt,eflag,0,0,ithr_on); if (eflag.ne.0) go to 900
call twcpin(rt,disp0,r0mat,eflag); if (eflag.ne.0) go to 900
!----IrinaTecker: For Sagan-Rubin and Talman versions of coupling
! call twcpin_sagan(rt,disp0,r0mat,eflag); if (eflag.ne.0) go to 900
! call twcpin_talman(rt,disp0,r0mat,eflag); if (eflag.ne.0) go to 900
!---- Initialize opt_fun0
call twinifun(opt_fun0,rt)
call tmsigma_emit(rt,s0mat)
endif
if (sectormap) then
SORB = ORBIT0
SRMAT = EYE
STMAT = zero
endif
! save sigma matrix
do i= 1,6
do j= 1,6
opt_fun0(74 + (i-1)*6 + j) = s0mat(i,j)
enddo
enddo
sigmat = s0mat
!---- Build table of lattice functions, coupled.
call twcpgo(rt,orbit0)
!---- List chromatic functions.
if (chrom .ne. 0) then
if ( any(rt(1:2,3:4) .gt. cp_thrd) .or. any(rt(3:4,1:2) .gt. cp_thrd) ) then
if (chrom_warn .eq. 1) then
write (warnstr, '(a)') 'Calculation of Wx, Wy etc. could be inaccurate due to coupling!'
call fort_warn('TWISS: ', warnstr)
endif
endif
call twbtin(rt,tt)
call twchgo
endif
!---- Print summary
call double_to_table_curr('summ ','nflips ' , dble(nmode_flip))
if (MOD(nmode_flip, 2).ne.0) then
write (warnstr, '(a,i5)') 'Total number of modes flips is not even! Nflips = ', nmode_flip
print*, 'Total number of modes flips is not even! Nflips = ', nmode_flip
endif
if (get_option('twiss_summ ') .ne. 0) call tw_summ(rt,tt)
if (get_option('keeporbit ') .ne. 0) then
call store_node_vector('orbit0 ', 6, opt_fun0(9))
endif
call set_option('twiss_success ', ione)
return
900 call set_option('twiss_success ', izero)
end SUBROUTINE twiss
SUBROUTINE tmrefe(rt)
use twissbeamfi
use math_constfi, only : zero
implicit none
!----------------------------------------------------------------------*
! Purpose: *
! Transfer matrix w.r.t. ideal orbit for one period. *
! Ignores cavities, radiation, and imperfections. *
! entry point for mad_twiss, mad_emit and mad_beam *
! Output: *
! rt(6,6) (double) transfer matrix. *
!----------------------------------------------------------------------*
double precision :: rt(6,6)
integer :: eflag, ithr_on
double precision :: orbit0(6), orbit(6), tt(6,6,6)
double precision, external :: get_value
!---- Get beam parameters
radiate = get_value('probe ','radiate ') .ne. zero
energy = get_value('probe ','energy ')
deltap = get_value('probe ','deltap ')
beta = get_value('probe ','beta ')
gamma = get_value('probe ','gamma ')
pc = get_value('probe ','pc ')
arad = get_value('probe ','arad ')
dtbyds = get_value('probe ','dtbyds ')
charge = get_value('probe ','charge ')
npart = get_value('probe ','npart ')
ithr_on = 0
ORBIT0 = zero ; ORBIT = zero ; TT = zero
!---- Get transfer matrix.
call tmfrst(orbit0,orbit,.false.,.false.,rt,tt,eflag,0,0,ithr_on)
end SUBROUTINE tmrefe
SUBROUTINE tmrefo(kobs,orbit0,orbit,rt)
use twiss0fi
use twissbeamfi
use math_constfi, only : zero
implicit none
!----------------------------------------------------------------------*
! Purpose: *
! Transfer matrix w.r.t. ideal orbit for one period. *
! entry point for mad_dynap and mad_track *
! Input: *
! kobs if > 0, track until node with this obs. point number *
! Output: *
! orbit0(6) (double) closed orbit at start=end *
! orbit(6) (double) closed orbit at obs. point kobs, or at end *
! rt(6,6) (double) transfer matrix. *
!----------------------------------------------------------------------*
integer :: kobs
double precision :: orbit0(6), orbit(6), rt(6,6)
integer :: eflag, ithr_on
double precision :: opt_fun0(fundim), tt(6,6,6), eig_tol
double precision, external :: get_value
integer, parameter :: izero=0, ione=1
!---- Get beam parameters
radiate = get_value('probe ','radiate ') .ne. zero
energy = get_value('probe ','energy ')
deltap = get_value('probe ','deltap ')
beta = get_value('probe ','beta ')
gamma = get_value('probe ','gamma ')
pc = get_value('probe ','pc ')
arad = get_value('probe ','arad ')
dtbyds = get_value('probe ','dtbyds ')
charge = get_value('probe ','charge ')
npart = get_value('probe ','npart ')
eig_tol = 1d-6
ithr_on = izero
ORBIT0 = zero
!---- Get closed orbit and coupled transfer matrix.
call tmclor(orbit0,.true.,.true.,eig_tol, opt_fun0,rt,tt,eflag)
call tmfrst(orbit0,orbit,.true.,.true.,rt,tt,eflag,kobs,0,ithr_on) ! useless?
end SUBROUTINE tmrefo
SUBROUTINE twinifun(opt_fun0,rt)
use twiss0fi
use twisslfi
use twissbeamfi, only : energy
use math_constfi, only : zero, twopi
implicit none
!----------------------------------------------------------------------*
! Purpose: *
! Initial twiss parameters put to opt_fun0. *
! Input/output: *
! opt_fun0(fundim) (double) initial optical values: *
! betx0,alfx0,amux0,bety0,alfy0,amuy0, etc. *
!----------------------------------------------------------------------*
double precision :: opt_fun0(*), rt(6,6)
integer :: i, j
double precision :: betx, alfx, mux, bety, alfy, muy, dx, dpx, dy, dpy
double precision :: x, px, y, py, t, pt
double precision :: wx, phix, dmux, wy, phiy, dmuy, ddx, ddpx, ddy, ddpy
double precision :: r(2,2)
double precision, external :: get_value
!---- Initialize
betx = get_value('twiss ','betx ')
bety = get_value('twiss ','bety ')
if (betx.gt.zero) opt_fun0(3) = betx
if (bety.gt.zero) opt_fun0(6) = bety
if (opt_fun0(3).le.zero .or. opt_fun0(6).le.zero) &
call fort_fail('TWINIFUN: ', 'BETX and BETY must be both larger than zero.')
alfx= get_value('twiss ','alfx ')
mux= get_value('twiss ','mux ')
alfy= get_value('twiss ','alfy ')
muy= get_value('twiss ','muy ')
x= get_value('twiss ','x ')
px= get_value('twiss ','px ')
y= get_value('twiss ','y ')
py= get_value('twiss ','py ')
t= get_value('twiss ','t ')
pt= get_value('twiss ','pt ')
dx= get_value('twiss ','dx ')
dpx= get_value('twiss ','dpx ')
dy= get_value('twiss ','dy ')
dpy= get_value('twiss ','dpy ')
wx= get_value('twiss ','wx ')
phix= get_value('twiss ','phix ')
dmux= get_value('twiss ','dmux ')
wy= get_value('twiss ','wy ')
phiy= get_value('twiss ','phiy ')
dmuy= get_value('twiss ','dmuy ')
ddx= get_value('twiss ','ddx ')
ddpx= get_value('twiss ','ddpx ')
ddy= get_value('twiss ','ddy ')
ddpy= get_value('twiss ','ddpy ')
r(1,1) = get_value('twiss ','r11 ')
r(1,2) = get_value('twiss ','r12 ')
r(2,1) = get_value('twiss ','r21 ')
r(2,2) = get_value('twiss ','r22 ')
if (alfx .ne.zero) opt_fun0(4 ) = alfx
if (mux .ne.zero) opt_fun0(5 ) = mux * twopi
if (alfy .ne.zero) opt_fun0(7 ) = alfy
if (muy .ne.zero) opt_fun0(8 ) = muy * twopi
if (x .ne.zero) opt_fun0(9 ) = x
if (px .ne.zero) opt_fun0(10) = px
if (y .ne.zero) opt_fun0(11) = y
if (py .ne.zero) opt_fun0(12) = py
if (t .ne.zero) opt_fun0(13) = t
if (pt .ne.zero) opt_fun0(14) = pt
if (dx .ne.zero) opt_fun0(15) = dx
if (dpx .ne.zero) opt_fun0(16) = dpx
if (dy .ne.zero) opt_fun0(17) = dy
if (dpy .ne.zero) opt_fun0(18) = dpy
if (wx .ne.zero) opt_fun0(19) = wx
if (phix .ne.zero) opt_fun0(20) = phix * twopi
if (dmux .ne.zero) opt_fun0(21) = dmux * twopi
if (wy .ne.zero) opt_fun0(22) = wy
if (phiy .ne.zero) opt_fun0(23) = phiy * twopi
if (dmuy .ne.zero) opt_fun0(24) = dmuy * twopi
if (ddx .ne.zero) opt_fun0(25) = ddx
if (ddpx .ne.zero) opt_fun0(26) = ddpx
if (ddy .ne.zero) opt_fun0(27) = ddy
if (ddpy .ne.zero) opt_fun0(28) = ddpy
if (r(1,1).ne.zero) opt_fun0(29) = r(1,1)
if (r(1,2).ne.zero) opt_fun0(30) = r(1,2)
if (r(2,1).ne.zero) opt_fun0(31) = r(2,1)
if (r(2,2).ne.zero) opt_fun0(32) = r(2,2)
if (energy.ne.zero) opt_fun0(33) = energy
if (rmatrix) then
do i= 1,6
do j= 1,6
opt_fun0(33 + (i-1)*6 + j) = rt(i,j)
enddo
enddo
endif
end SUBROUTINE twinifun
SUBROUTINE twprep(save,case,opt_fun,position,ii)
use twissafi
use twisslfi
use twissotmfi
use math_constfi, only : zero, twopi
implicit none
!----------------------------------------------------------------------*
! Purpose: *
! Finalize twiss parameters, if save flag fill *
! table with twiss parameters. *
! Input: *
! case (integer) =1 fill from twcpgo; =2 fill from twchgo *
! position (double) end position of element *
! ii (integer) index of interpolated segment
! Input/output: *
! opt_fun(fundim) (double) optical values: *
! betx,alfx,amux,bety,alfy,amuy, etc. *
!----------------------------------------------------------------------*
integer :: save, case, ii
double precision :: opt_fun(*), position
integer :: i
double precision :: opt5, opt8, opt20, opt21, opt23, opt24
if (case .eq. 1) then
!--- fill with data from twcpgo (Twiss Couple)
opt_fun(2) = position
opt5 = opt_fun(5) ; opt_fun(5) = opt_fun(5) / twopi
opt8 = opt_fun(8) ; opt_fun(8) = opt_fun(8) / twopi
if (save .ne. 0) call twfill(case,opt_fun,position)
if (match_is_on) call copy_twiss_data(opt_fun, 0, 110, ii)
opt_fun(5) = opt5
opt_fun(8) = opt8
elseif (case.eq.2) then
!--- fill with data from twchgo (Twiss Chrom)
opt20 = opt_fun(20) ; opt_fun(20) = opt_fun(20) / twopi
opt21 = opt_fun(21) ; opt_fun(21) = opt_fun(21) / twopi
opt23 = opt_fun(23) ; opt_fun(23) = opt_fun(23) / twopi
opt24 = opt_fun(24) ; opt_fun(24) = opt_fun(24) / twopi
if (save .ne. 0) call twfill(case,opt_fun,position)
if (match_is_on) call copy_twiss_data(opt_fun, 18, 10, ii)! fill 10 values starting with wx
opt_fun(20) = opt20
opt_fun(21) = opt21
opt_fun(23) = opt23
opt_fun(24) = opt24
endif
end SUBROUTINE twprep
SUBROUTINE twfill(case,opt_fun,position)
use twissafi
use twisslfi
use twissotmfi
use math_constfi, only : zero
implicit none
!----------------------------------------------------------------------*
! Purpose: *
! Fill twiss table with twiss parameters. *
! Input: *
! case (integer) =1 fill from twcpgo; =2 fill from twchgo *
! position (double) end position of element *
! Input/output: *
! opt_fun(fundim) (double) optical values: *
! betx,alfx,amux,bety,alfy,amuy, etc. *
!----------------------------------------------------------------------*
integer :: case
double precision :: opt_fun(*), position
double precision, external :: get_value
ripken = get_value('twiss ','ripken ') .ne. zero
if (case .eq. 1) then
call vector_to_table_curr(table_name, 's ' , opt_fun( 2), 17) ! fill 17 values starting with s
call vector_to_table_curr(table_name, 'r11 ' , opt_fun(29), 5 ) ! fill 5 values starting with r11
call vector_to_table_curr(table_name, 'sig11 ', opt_fun(75), 36) ! fill 36 values starting with sigmat11
call vector_to_table_curr(table_name, 'kmax ' , opt_fun(70), 5 ) ! fill 5 values starting with kmax
if (rmatrix) call vector_to_table_curr(table_name, 're11 ', opt_fun(34), 36) ! fill Rmatrix
if (ripken) call twfill_ripken(opt_fun)
elseif (case .eq. 2) then
call vector_to_table_curr(table_name, 'wx ', opt_fun(19), 10) ! fill 10 values starting with wx
endif
!---- Augment table twiss
call augment_count(table_name)
end SUBROUTINE twfill
SUBROUTINE twfill_ripken(opt_fun)
use math_constfi, only : zero, one, two
implicit none
!----------------------------------------------------------------------*
! Purpose: *
! Fill twiss table with Ripken-Mais twiss parameters. *
! beta11, beta12, beta21, beta22, *
! alfa11, alfa12, alfa21, alfa22, *
! gama11, gama12, gama21, gama22, *
!----------------------------------------------------------------------*
double precision :: opt_fun(*)
double precision :: kappa, betx, bety, alfx, alfy, gamx, gamy, r11, r12, r21, r22
double precision :: beta11, beta12, beta21, beta22, &
alfa11, alfa12, alfa21, alfa22, &
gama11, gama12, gama21, gama22
betx = opt_fun(3); bety = opt_fun(6); alfx = opt_fun(4); alfy = opt_fun(7)
r11 = opt_fun(29); r12 = opt_fun(30); r21 = opt_fun(31); r22 = opt_fun(32)
kappa = one/(one + (r11*r22 - r12*r21))
gamx = (one + alfx**2) / betx; gamy = (one + alfy**2) / bety
beta11 = kappa * betx
beta22 = kappa * bety
beta12 = kappa * ( r22**2*bety + two*r12*r22*alfy + r12**2*gamy )
beta21 = kappa * ( r11**2*betx - two*r12*r11*alfx + r12**2*gamx )
alfa11 = kappa * alfx
alfa22 = kappa * alfy
alfa12 = kappa * ( r21*r22*bety + (r12*r21 + r11*r22)*alfy + r11*r12*gamy )
alfa21 = -kappa * ( r21*r11*betx - (r12*r21 + r11*r22)*alfx + r12*r22*gamx )
gama11 = kappa * gamx
gama22 = kappa * gamy
gama12 = zero; if (beta12 .ne. zero) gama12 = ((one-kappa)**2 + alfa12**2) / beta12
gama21 = zero; if (beta21 .ne. zero) gama21 = ((one-kappa)**2 + alfa21**2) / beta21
call double_to_table_curr('twiss ','beta11 ' ,beta11)
call double_to_table_curr('twiss ','beta12 ' ,beta12)
call double_to_table_curr('twiss ','beta21 ' ,beta21)
call double_to_table_curr('twiss ','beta22 ' ,beta22)
call double_to_table_curr('twiss ','alfa11 ' ,alfa11)
call double_to_table_curr('twiss ','alfa12 ' ,alfa12)
call double_to_table_curr('twiss ','alfa21 ' ,alfa21)
call double_to_table_curr('twiss ','alfa22 ' ,alfa22)
call double_to_table_curr('twiss ','gama11 ' ,gama11)
call double_to_table_curr('twiss ','gama12 ' ,gama12)
call double_to_table_curr('twiss ','gama21 ' ,gama21)
call double_to_table_curr('twiss ','gama22 ' ,gama22)
end SUBROUTINE twfill_ripken
SUBROUTINE tmclor(guess,fsec,ftrk, eig_tol, opt_fun0,rt,tt,eflag)
use twissbeamfi, only : deltap
use matrices, only : EYE
use math_constfi, only : zero, one
! watch out iterate is defined in taperfi and as loop label here in tmclor
use taperfi, only : taperout, stepsize
use io_units, only : tapout
implicit none
!----------------------------------------------------------------------*
! Purpose: *
! Find closed orbit for a beam line sequence. *
! Called also directly from emit and taper *
! Input: *
! guess(6) (double) first guess for orbit start *
! fsec (logical) if true, return second order terms. *
! ftrk (logical) if true, track orbit. *
! Output: *
! guess(6) (double) final orbit *
! opt_fun0(fundim) (double) initial optical values: *
! betx0,alfx0,amux0,bety0,alfy0,amuy0, etc. *
! rt(6,6) (double) transfer matrix. *
! tt(6,6,6) (double) second order terms. *
! eflag (integer) error flag (0: OK, else != 0) *
!----------------------------------------------------------------------*
double precision :: guess(6), opt_fun0(*), rt(6,6), tt(6,6,6)
logical :: fsec, ftrk
integer :: eflag
logical :: pflag
integer :: i, k, irank, itra, thr_on, ithr_on, save_opt, debug
double precision :: cotol, err, eig_tol
double precision :: orbit0(6), orbit(6), a(6,7), b(4,5)
integer, external :: get_option
double precision, external :: get_variable, get_value
logical, external :: m66sta
integer, parameter :: itmax=20
logical :: taperoutsave
! double precision :: stepsizesave
deltap = get_value('probe ','deltap ')
!---- Initialize.
ithr_on = 0
thr_on = get_option('threader ')
debug = get_option('debug ')
pflag = get_option('twiss_print ') .ne. 0
cotol = get_variable('twiss_tol ')
eflag = 0
!---- Initialize guess.
ORBIT0 = GUESS
!---- Need tapering output on last iteration only
taperoutsave = taperout
taperout = .false.
!---- use the stepsize on last iteration also
! stepsizesave = stepsize
! stepsize = zero
!---- Iteration for closed orbit.
iterate: do itra = 1, itmax
!---- Track orbit and transfer matrix.
call tmfrst(orbit0,orbit,fsec,ftrk,rt,tt,eflag,0,0,thr_on)
if (eflag.ne.0) return
! turn off threader immediately after first iteration, ie after first turn
thr_on = 0
if (.not.m66sta(rt)) then
!---- Solve for dynamic case.
err = zero
A(:,:6) = RT(:,:6) - EYE
A(1:6,7) = ORBIT(1:6) - ORBIT0(1:6)
err = maxval(abs(A(1:6,7)))
call solver(A,6,1,irank)
if (irank.lt.6) then
print *, 'Singular matrix occurred during closed orbit search.'
eflag = 1
return
endif
ORBIT0(1:6) = ORBIT0(1:6) - A(1:6,7)
else
!---- Solve for static case.
err = zero
B(:4,:4) = RT(:4,:4) - EYE(:4,:4)
B(1:4,5) = ORBIT(1:4) - ORBIT0(1:4)
err = maxval(abs(B(1:4,5)))
call solver(b,4,1,irank)
if (irank.lt.4) then
print *, 'Singular matrix occurred during closed orbit search.'
eflag = 1
return
endif
ORBIT0(1:4) = ORBIT0(1:4) - B(1:4,5)
endif
!---- Message and convergence test.
if (pflag) then
print *, ' '
print '(''iteration: '',i3,'' error: '',1p,e14.6,'' deltap: '',1p,e14.6)',itra,err,deltap
print '(''orbit: '', 1p,6e14.6)', orbit0
endif
if (err.lt.cotol) then
save_opt = get_option('keeporbit ')
taperout = taperoutsave ! restore output flag for tapering
! stepsize = stepsizesave ! restore stepsize
call tmfrst(orbit0,orbit,.true.,.true.,rt,tt,eflag,0,save_opt,ithr_on)
OPT_FUN0(9:14) = ORBIT0(1:6)
GUESS = ORBIT0
call tmcheckstab(rt,eig_tol, debug)
return ! normal exit
endif
enddo iterate
!---- No convergence.
call tmcheckstab(rt, eig_tol,debug)
print '(''Closed orbit did not converge in '', i3, '' iterations'')', itmax
OPT_FUN0(9:14) = zero
taperout = taperoutsave ! restore output flag for tapering
if (taperout) &
write(tapout,'(a,i3,a)') "! Orbit did not converge in ",itmax," iterations. No ouput for tapering."
return
end SUBROUTINE tmclor
SUBROUTINE tmcheckstab(rt,tol, debug)
use math_constfi, only : one, zero
!----------------------------------------------------------------------*
! Purpose: *
! Check the stability of the one turn matrix *
! *
! Input: *
! rt(6,6) (double) transfer matrix. *
!----------------------------------------------------------------------*
double precision :: rt(6,6) , tmp1, tmp2
double precision :: em(6,6), tol
double precision :: reval(6), aival(6) ! re and im parts for damping and tune
logical :: stabx, staby, stabt
integer :: debug
logical, external :: m66sta
character(len=250) :: warnstr
double precision, external :: get_value, get_variable
if(tol .eq. zero) tol = 1e-6
if (m66sta(rt)) then
call laseig(rt, reval, aival, em)
stabt = .false.
else
call ladeig(rt, reval, aival, em)
stabt = abs(reval(5)**2 + aival(5)**2-one) .ge. tol .or. &
abs(reval(6)**2 + aival(6)**2-one) .ge. tol
endif
stabx = abs(reval(1)**2 + aival(1)**2 - one) .ge. tol .or. &
abs(reval(2)**2 + aival(2)**2 - one) .ge. tol
staby = abs(reval(3)**2 + aival(3)**2 - one) .ge. tol .or. &
abs(reval(4)**2 + aival(4)**2 - one) .ge. tol
if (stabx) then
tmp1 = reval(1)**2 + aival(1)**2
tmp2 = reval(2)**2 + aival(2)**2
write (warnstr,'(a)') 'Horizontal plane might be unstable' // &
' More information with the debug flag on.'
call fort_warn('TWCLORB: ',warnstr)
if(debug .ne. zero) print *, 'Eigenvalue(1)**2 ', tmp1, " Eigenvalue(2)**2", tmp2
endif
if (staby) then
tmp1 = reval(1)**2 + aival(1)**2
tmp2 = reval(2)**2 + aival(2)**2
write (warnstr,'(a)') 'Vertical plane might be unstable' // &
' More information with the debug flag on.'
call fort_warn('TWCLORB: ',warnstr)
if(debug .ne. zero) print *, 'Eigenvalue(3)**2 ', tmp1, " Eigenvalue(4)**2", tmp2
endif
if (stabt) then
tmp1 = reval(5)**2 + aival(5)**2
tmp2 = reval(6)**2 + aival(6)**2
write (warnstr,'(a)') 'Longitudinal plane might be unstable.' // &
' Try change lag with 0.5. More information with the debug flag on.'
call fort_warn('TWCLORB: ',warnstr)
if(debug .ne. zero) print *, 'Eigenvalue(5)**2 ', tmp1, " Eigenvalue(6)**2", tmp2
endif
end SUBROUTINE tmcheckstab
SUBROUTINE tmfrst(orbit0,orbit,fsec,ftrk,rt,tt,eflag,kobs,save,thr_on)
use bbfi
use twiss0fi
use twissbeamfi, only : beta, gamma, arad, charge, npart, pc, energy, radiate
use name_lenfi
use twisscfi
use spch_bbfi
use matrices, only : EYE, symp_thrd ! , symp_thrd_orbit
use math_constfi, only : zero, one, two
use code_constfi
use taperfi
use io_units
implicit none
!----------------------------------------------------------------------*
! Purpose: *
! Transfer matrix w.r.t. actual orbit for one (half) superperiod. *
! Misalignment and field errors are considered. *
! Input: *
! orbit0(6) (double) first guess for orbit start *
! fsec (logical) if true, return second order terms. *
! ftrk (logical) if true, track orbit. *
! Output: *
! orbit(6) (double) orbit after one turn starting from orbit0 *
! rt(6,6) (double) transfer matrix. *
! tt(6,6,6) (double) second order terms. *
! eflag (integer) error flag. *
! kobs (integer) if > 0, stop at node with this obs. point # *
! save (integer) if > 0, save orbit at all BPMs *
! thr_on (integer) if > 0, use threader *
!----------------------------------------------------------------------*
double precision :: orbit0(6), orbit(6)
logical :: fsec, ftrk
double precision :: rt(6,6), tt(6,6,6)
integer :: eflag, kobs, save, thr_on
integer :: i
logical :: fmap, twisstaper
character(len=28) :: tmptxt1, tmptxt2, tmptxt3
character(len=150) :: warnstr
character(len=name_len) :: c_name(2), p_name, el_name, name
character(len=2) :: ptxt(2)=(/'x-','y-'/)
integer :: j, code, n_align, nobs, node, old, poc_cnt, debug, n_perm_align
integer :: kpro, corr_pick(2), enable, coc_cnt(2), lastnb, rep_cnt(2)
double precision :: orbit2(6), ek(6), re(6,6), te(6,6,6), orbittap(6)
double precision :: al_errors(align_max)
double precision :: el, cick, err, nrm, nrm0, angle
double precision :: parvec(26), vector(10), reforb(6)
double precision :: restsum(2), restorb(6,2), restm(6,6,2), restt(6,6,6,2)
double precision :: cmatr(6,6,2), pmatr(6,6), dorb(6)
integer, external :: restart_sequ, advance_node, node_al_errors, get_vector, get_option, is_permalign
double precision, external :: node_value, get_value
double precision, parameter :: orb_limit=1d1
integer, parameter :: max_rep=100
double precision :: dpt ! for tapering
integer :: step_prev
debug = get_option('debug ')
radiate = get_value('probe ','radiate ') .ne. zero
beta = get_value('probe ','beta ')
gamma = get_value('probe ','gamma ')
!---- Initialize
!---- corr_pick stores for both projection the last pickup used by the
! threader in order to avoid corrections in front of it when
! restarting.
CORR_PICK = 0
REP_CNT = 0
RESTSUM = zero
nrm0 = zero
if (thr_on .gt. 0) then
VECTOR = zero
j = get_vector('threader ', 'vector ', vector)
if (j .lt. 3) thr_on = 0
endif
TT = zero
RT = EYE
eflag = 0
suml = zero
ORBIT = ORBIT0
parvec(5) = arad
parvec(6) = charge * npart
parvec(7) = gamma
bbd_cnt = 0
bbd_flag = 1
i_spch = 0 !!!!!!!!!!
! initialise first tapering value to initial momentum offset
step_prev = int((orbit0(6)/beta)/stepsize)
!---- Initiate the tapering output for command TAPER with RELATIVE option
if (taperflag .and. (stepsize .ne. zero)) then
print '(''initial orbit vector: '', 1p,6e14.6)', orbit
print '(''first taper value: '',1p,e14.6,1p,'' nsteps: '',1p,i8)', step_prev*stepsize, step_prev
print '('' '')'
endif
!--- start
node = restart_sequ()
!--- loop over nodes
10 continue
bbd_pos = node !--- for space charge
code = node_value('mad8_type ')
! if (code .eq. code_tkicker) code = code_kicker ! TKICKER treated as KICKER
if (code .eq. code_placeholder) code = code_instrument ! PLACEHOLDER treated as INSTRUMENT
if (thr_on .gt. 0) then
!--- threader is on - keep position,orbit,matrix,and tensor for restart
select case (code)
case (code_hkicker)
restsum(1) = suml
RESTORB(:,1) = ORBIT(:)
RESTM(:,:,1) = RT(:,:)
RESTT(:,:,:,1) = TT(:,:,:)
case (code_kicker)
restsum(1) = suml
RESTORB(:,1) = ORBIT(:)
RESTM(:,:,1) = RT(:,:)
RESTT(:,:,:,1) = TT(:,:,:)
restsum(2) = suml
RESTORB(:,2) = ORBIT(:)
RESTM(:,:,2) = RT(:,:)
RESTT(:,:,:,2) = TT(:,:,:)
case (code_vkicker)
restsum(2) = suml
RESTORB(:,2) = ORBIT(:)
RESTM(:,:,2) = RT(:,:)
RESTT(:,:,:,2) = TT(:,:,:)
end select
endif
!---- Element length.t
el = node_value('l ')
nobs = node_value('obs_point ')
al_errors = 0
n_align = node_al_errors(al_errors)
n_perm_align = is_permalign()
if (n_perm_align .ne. 0) then
al_errors(1) = al_errors(1) + node_value('dx ')
al_errors(2) = al_errors(2) + node_value('dy ')
al_errors(3) = al_errors(3) + node_value('ds ')
al_errors(4) = al_errors(4) + node_value('dphi ')
al_errors(5) = al_errors(5) + node_value('dtheta ')
al_errors(6) = al_errors(6) + node_value('dpsi ')
n_align = 1
endif
if (n_align .ne. 0) then
ORBIT2 = ORBIT
call tmali1(orbit2,al_errors,beta,gamma,orbit,re)
RT = matmul(RE,RT)
!--- IT check if RT is symplectic
if (thr_on .eq. 0 .and. debug .ne. 0) then
call m66symp(rt,nrm)
if ((nrm-nrm0) .gt. symp_thrd) then
call element_name(el_name,len(el_name))
write (warnstr,'(a,e13.6,a,a)') "Symplectic deviation: ", nrm, " in element ", el_name
call fort_warn('THREADER-1: ', warnstr)
endif
nrm0 = nrm
endif
endif
!---- Tapering adjustment for dipoles, quadrupoles and sextupoles
! can be initiated from TWISS or MATCH command (tapering = true) or TAPER command
if (taperflag) then
select case (code)
case (code_rbend, code_sbend)
! first take only account of momentum deviation at entrance of element
dpt = orbit(6)/beta
! then maybe loop track through element to take energy loss in element into account
do i = 1, iterate
ORBITTAP = ORBIT ! work on a temporary orbit vector
call store_node_value('ktap ', dpt) ! initial guess
call tmmap(code,fsec,ftrk,orbittap,fmap,ek,re,te,.false.,el)
dpt = (orbittap(6)+orbit(6))/(two*beta)
enddo
if (stepsize .ne. zero) then
! count and add # of steps of size stepsize means adding integers which is more precise
! than adding # of steps * stepsize which means adding small real values
step_prev = step_prev + int((dpt/stepsize-step_prev)*two)
call store_node_value('ktap ', step_prev*stepsize)
else
call store_node_value('ktap ', dpt)
endif
if (taperout) then
call element_name(el_name,len(el_name))
write(tapout,'(a,t15,a,e20.12,a)') trim(el_name),", KTAP = ",node_value('ktap ')," ;"
endif
case (code_quadrupole, code_sextupole)
dpt = orbit(6)/beta
if (iterate .ge. 1) then ! loop is only one pass
ORBITTAP = ORBIT
call store_node_value('ktap ', dpt)
call tmmap(code,fsec,ftrk,orbittap,fmap,ek,re,te,.false.,el)
dpt = (orbittap(6)+orbit(6))/(two*beta)
endif
if (stepsize .ne. zero) then
step_prev = step_prev + int((dpt/stepsize-step_prev)*two)
call store_node_value('ktap ', step_prev*stepsize)
else
call store_node_value('ktap ', dpt)
endif
if (taperout) then
call element_name(el_name,len(el_name))
write(tapout,'(a,t15,a,e20.12,a)') trim(el_name),", KTAP = ",node_value('ktap ')," ;"
endif
end select
endif ! End of tapering section.
!---- Element matrix
call tmmap(code,fsec,ftrk,orbit,fmap,ek,re,te,.false.,el)
!--- if element has a map, concatenate
if (fmap) then
call tmcat(.true.,re,te,rt,tt,rt,tt)
suml = suml + el
!--- IT check if RT is symplectic
if (thr_on .eq. zero .and. debug .ne. 0) then
call m66symp(rt,nrm)
if ((nrm-nrm0) .gt. symp_thrd) then
call element_name(el_name,len(el_name))
write (warnstr,'(a,e13.6,a,a)') "Symplectic deviation: ", nrm, " in element ", el_name
call fort_warn('THREADER-M: ', warnstr)
endif
nrm0 = nrm
endif
endif
if (n_align .ne. 0) then
ORBIT2 = ORBIT
call tmali2(el,orbit2,al_errors,beta,gamma,orbit,re)
RT = matmul(RE,RT)
!--- IT check if RT is symplectic
if (thr_on .eq. 0 .and. debug .ne. 0) then
call m66symp(rt,nrm)
if ((nrm-nrm0) .gt. symp_thrd) then
call element_name(el_name,len(el_name))
write (warnstr,'(a,e13.6,a,a)') "Symplectic deviation: ", nrm, " in element ", el_name
call fort_warn('THREADER-2: ', warnstr)
endif
nrm0 = nrm
endif
endif
if (kobs.gt.0 .and. kobs.eq.nobs) return
if (thr_on .gt. 0) then !--- threader is on; keep matrix
select case (code)
case (code_hkicker)
CMATR(1:6,1:6,1) = RT(1:6,1:6)
j = name_len
call element_name(c_name(1),j)
coc_cnt(1) = node_value('occ_cnt ')
case (code_kicker)
CMATR(1:6,1:6,1) = RT(1:6,1:6)
CMATR(1:6,1:6,2) = RT(1:6,1:6)