:RecentNotes command to list (matching) notes by modification date

Author: xolox

README.md

@@ -11,6 +11,7 @@ The notes.vim plug-in for the [Vim text editor] [vim] makes it easy to manage yo
    * **Smart defaults:** Without an argument `:SearchNotes` searches for the word under the cursor (if the word starts with `@` that character will be included in the search, this means you can easily search for *@tagged* notes)
    * **Back-references:** The `:RelatedNotes` command find all notes referencing the current file
    * A [Python 2] [python] script is included that accelerates keyword searches using an [SQLite] [sqlite] database
+   * The `:RecentNotes` command lists your notes by modification date, starting with the most recently edited note
  * **Navigating between notes:** The included file type plug-in redefines [gf] [gf] to jump between notes and the syntax script highlights note names as hyper links
  * **Writing aids:** The included file type plug-in contains mappings for automatic curly quotes, arrows and list bullets and supports completion of note titles using Control-X Control-U
  * **Embedded file types:** The included syntax script supports embedded highlighting using blocks marked with `{{{type … }}}` which allows you to embed highlighted code and configuration snippets in your notes

autoload/xolox/notes.vim

@@ -1,6 +1,6 @@
 " Vim auto-load script
 " Author: Peter Odding <peter@peterodding.com>
-" Last Change: June 8, 2011
+" Last Change: June 11, 2011
 " URL: http://peterodding.com/code/vim/notes/
 
 " Note: This file is encoded in UTF-8 including a byte order mark so
@@ -309,6 +309,78 @@ function! xolox#notes#related(bang) " {{{1
   endif
 endfunction
 
+function! xolox#notes#recent(bang, title_filter) " {{{1
+  let start = xolox#misc#timer#start()
+  let bufname = '[All Notes]'
+  " Open buffer that holds list of notes.
+  if !bufexists(bufname)
+    execute 'hide edit' fnameescape(bufname)
+    setlocal buftype=nofile nospell
+  else
+    execute 'hide buffer' fnameescape(bufname)
+    setlocal noreadonly modifiable
+    silent %delete
+  endif
+  " Filter notes by pattern (argument)?
+  let notes = []
+  let title_filter = '\v' . a:title_filter
+  for [fname, title] in items(xolox#notes#get_fnames_and_titles())
+    if title =~? title_filter
+      call add(notes, [getftime(fname), title])
+    endif
+  endfor
+  " Start note with title and short description.
+  let readme = "You have "
+  if empty(notes)
+    let readme .= "no notes"
+  elseif len(notes) == 1
+    let readme .= "one note"
+  else
+    let readme .= len(notes) . " notes"
+  endif
+  if a:title_filter != ''
+    let quote_format = xolox#notes#unicode_enabled() ? '‘%s’' : "`%s'"
+    let readme .= " matching " . printf(quote_format, a:title_filter)
+  endif
+  if empty(notes)
+    let readme .= "."
+  elseif len(notes) == 1
+    let readme .= ", it's listed below."
+  else
+    let readme .= ". They're listed below grouped by the day they were edited, starting with your most recently edited note."
+  endif
+  call setline(1, ["All notes", "", readme])
+  normal Ggqq
+  " Sort, group and format list of (matching) notes.
+  let last_date = ''
+  let list_item_format = xolox#notes#unicode_enabled() ? ' • %s' : ' * %s'
+  let date_format = '%A, %B %d:'
+  let today = strftime(date_format, localtime())
+  let yesterday = strftime(date_format, localtime() - 60*60*24)
+  call sort(notes)
+  call reverse(notes)
+  let lines = []
+  for [ftime, title] in notes
+    let date = strftime(date_format, ftime)
+    " Add date heading because date changed?
+    if date != last_date
+      call add(lines, '')
+      if date == today
+        call add(lines, "Today:")
+      elseif date == yesterday
+        call add(lines, "Yesterday:")
+      else
+        call add(lines, date)
+      endif
+      let last_date = date
+    endif
+    call add(lines, printf(list_item_format, title))
+  endfor
+  call setline(line('$') + 1, lines)
+  setlocal readonly nomodifiable nomodified filetype=notes
+  call xolox#misc#timer#stop("%s: Created list of notes in %s.", s:script, start)
+endfunction
+
 " Miscellaneous functions. {{{1
 
 function! s:is_empty_buffer() " {{{2

doc/notes.txt

@@ -34,6 +34,9 @@ notes in Vim:
  - A Python 2 [1] script is included that accelerates keyword searches using an
    SQLite [2] database
 
+ - The ':RecentNotes' command lists your notes by modification date, starting
+   with the most recently edited note
+
  - Navigating between notes: The included file type plug-in redefines |gf| to
    jump between notes and the syntax script highlights note names as hyper
    links

misc/notes/shadow/Note taking commands

@@ -84,3 +84,11 @@ updates and searches should be more or less instantaneous.
 This command makes it easy to find all notes related to the current file: If
 you are currently editing a note then a search for the note’s title is done,
 otherwise this searches for the absolute path of the current file.
+
+# :RecentNotes lists notes by modification date
+
+If you execute the :RecentNotes command it will open a Vim buffer that lists
+all your notes grouped by the day they were edited, starting with your most
+recently edited note. If you pass an argument to :RecentNotes it will filter
+the list of notes by matching the title of each note against the argument which
+is interpreted as a Vim pattern.

plugin/notes.vim

@@ -1,9 +1,9 @@
 " Vim plug-in
 " Author: Peter Odding <peter@peterodding.com>
-" Last Change: June 8, 2011
+" Last Change: June 11, 2011
 " URL: http://peterodding.com/code/vim/notes/
 " License: MIT
-" Version: 0.8.11
+" Version: 0.8.12
 
 " Support for automatic update using the GLVS plug-in.
 " GetLatestVimScripts: 3375 1 :AutoInstall: notes.zip
@@ -42,6 +42,7 @@ command! -bar -bang -range NoteFromSelectedText call xolox#notes#from_selection(
 command! -bar -bang DeleteNote call xolox#notes#delete(<q-bang>)
 command! -bar -bang -nargs=? SearchNotes call xolox#notes#search(<q-bang>, <q-args>)
 command! -bar -bang RelatedNotes call xolox#notes#related(<q-bang>)
+command! -bar -bang -nargs=? RecentNotes call xolox#notes#recent(<q-bang>, <q-args>)
 
 " Automatic commands to enable the :edit note:… shortcut and load the notes file type.