how to refer generated object in another pkl file

[Rasool-Ansari-Shaik]

I have created below pkl file to dynamically generate schema configuration for each token.

module template_schemas

class JsonSchemaConfig {
  type: String = "template"
  templateId: String
  config: Map
}

class StConfig { // Service Token Config
    token: String
    config: Map
}

jsonSchema {
    for (_tid, _stcl in tempIdConfigMap) { 
        for (_stc in _stcl) {  
            ["\(_stc.token)"] = new JsonSchemaConfig {
                templateId = _tid
                config = _stc.config
            }
        }
    }
}

tempIdConfigMap = Map(
    "schemaStr", List(new StConfig {token="token1" config=Map("param_1", "scc")},
                                    new StConfig {token="token2" config=Map("param_1", "mcc")}),
    "schemaArrays", List(new StConfig {token="token3" config=Map("param_1", "pl", "param_2", "pnp","minItems",1, "maxItems",10)}),
    "schemaArray", List(new StConfig {token="token4" config=Map("param_1", "scc")},
                                    new StConfig {token="token5" config=Map("param_1", "pl")},
                                    new StConfig {token="token6" config=Map("param_1", "pn")})
)

When run the pkl command "pkl eval q11.pkl, the output contain all token detais as "JsonSchemaConfig" objects inside "jsonSchema" property of the module "template_schemas".

jsonSchema {
  ["token1"] {
    type = "template"
    templateId = "schemaStr"
    config = Map("param_1", "scc")
  }
  ["token2"] {
    type = "template"
    templateId = "schemaStr"
    config = Map("param_1", "mcc")
  }
  ....
}

My requirement is to refer the generated token (token1, token2, ..) in another pkl file. Like below -

module another_module
import "template_schemas.pkl"

class TokenConfig {
    token: String // token id
    users: List<String>
    jsonSchema: String // value from previous pkl file for the token
}
mainConfig {
    for (_tok in tokenList) {}
        ["c1"] = new TokenConfig {
            ...
            jsonSchema = template_schemas.jsonSchema._tok  // how???
        }
    }
}

tokenList = List("token1", "token2")

How can I refer the token generated in a pkl file into another pkl file?

[HT154]

The core issue is that you're attempting property access when you want to be subscripting. There are a couple more design/style things you may want to consider:

• In several places you're not typing your properties, which will affect type checking fidelity and IDE editing experiences
• It's generally best practice to use Listing/Mapping over List/Map when defining values. The latter are intended for "internal" data manipulation, not for use in module schemas.
• "inline" object definition members should be ;-separated

Here's how I might write this accounting for this (and following the style guide):

module template_schemas

class JsonSchemaConfig {
  type: String = "template"
  templateId: String
  config: Map
}

class StConfig { // Service Token Config
    token: String
    config: Mapping
}

jsonSchema: Mapping<String, JsonSchemaConfig> = new {
    for (_tid, _stcl in tempIdConfigMap) { 
        for (_stc in _stcl) {  
            ["\(_stc.token)"] {
                templateId = _tid
                config = _stc.config
            }
        }
    }
}

tempIdConfigMap: Mapping<String, Listing<StConfig>> = new {
    ["schemaStr"] {
        new { token = "token1"; config { ["param_1"] = "scc" } }
        new { token = "token2"; config { ["param_1"] = "mcc" } }
    }
    ["schemaArrays"] {
        new { token = "token3"; config { ["param_1"] = "pl"; ["param_2"] = "pnp"; ["minItems"] = 1; ["maxItems"] = 10 } }
    }
    ["schemaArray"] {
        new { token = "token4"; config { ["param_1"] = "scc" } }
        new { token = "token5"; config { ["param_1"] = "pl" } }
        new { token = "token6"; config { ["param_1"] = "pn" } }
    }
)

Then in your other module:

module another_module
import "template_schemas.pkl"

class TokenConfig {
    token: String // token id
    users: Listing<String>
    jsonSchema: String // value from previous pkl file for the token
}
mainConfig: Mapping<String, TokenConfig> {
    for (_tok in tokenList) {
        ["c1"] { // not sure this makes sense as it'll result in duplicate mapping entries
            ...
            jsonSchema = template_schemas.jsonSchema[_tok]
        }
    }
}

tokenList: Listing<String> = new { "token1"; "token2" }