-
Notifications
You must be signed in to change notification settings - Fork 0
/
ui.ur
224 lines (201 loc) · 7.57 KB
/
ui.ur
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
open Bootstrap3
type context = {
ModalId : id,
ModalSpot : source xbody
}
type t a = {
Create : transaction a,
Onload : a -> transaction unit,
Render : context -> a -> xbody
}
signature S0 = sig
type a
val ui : t a
end
signature S = sig
type input
type a
val ui : input -> t a
end
type seq ts = $ts
fun seq [ts] (fl : folder ts) (ts : $(map t ts)) = {
Create = @Monad.mapR _ [t] [ident] (fn [nm ::_] [t ::_] r => r.Create) fl ts,
Onload = @Monad.appR2 _ [t] [ident] (fn [nm ::_] [t ::_] r => r.Onload) fl ts,
Render = fn ctx =>
@mapX2 [t] [ident] [body] (fn [nm ::_] [t ::_] [r ::_] [[nm] ~ r] r =>
r.Render ctx) fl ts
}
datatype moded a1 a2 = First of a1 | Second of a2
fun moded [a1] [a2] (t1 : t a1) (t2 : t a2) (which : bool) = {
Create = if which then
x <- t1.Create;
return (First x)
else
x <- t2.Create;
return (Second x),
Onload = fn st => case st of
First x => t1.Onload x
| Second x => t2.Onload x,
Render = fn ctx st => case st of
First x => t1.Render ctx x
| Second x => t2.Render ctx x
}
type const = unit
fun const bod = {
Create = return (),
Onload = fn () => return (),
Render = fn _ () => bod
}
fun constM bod = {
Create = return (),
Onload = fn () => return (),
Render = fn ctx () => bod ctx
}
fun simple [a] titl (t : t a) =
nid <- fresh;
mid <- fresh;
ms <- source <xml/>;
state <- t.Create;
return <xml>
<head>
<title>{[titl]}</title>
<link rel="stylesheet" href="https://maxcdn.bootstrapcdn.com/bootstrap/3.3.2/css/bootstrap.min.css"/>
<link rel="stylesheet" href="/style.css"/>
</head>
<body onload={t.Onload state}>
<div class="modal" id={mid}>
<dyn signal={signal ms}/>
</div>
<nav class="navbar navbar-inverse navbar-fixed-top">
<div class="container">
<div class="navbar-header">
<button class="navbar-toggle collapsed" data-toggle="collapse" data-target={"#" ^ show nid} aria-expanded="false" aria-controls="navbar">
<span class="sr-only">Toggle navigation</span>
<span class="icon-bar"></span>
<span class="icon-bar"></span>
<span class="icon-bar"></span>
</button>
<a class="navbar-brand">{[titl]}</a>
</div>
<div id={nid} class="collapse navbar-collapse">
<ul class="bs3-nav navbar-nav"/>
</div>
</div>
</nav>
<div class="container-fluid">
{t.Render {ModalId = mid, ModalSpot = ms} state}
</div>
</body>
</xml>
fun tabbed [ts] (fl : folder ts) titl (ts : $(map (fn a => option string * t a) ts)) =
nid <- fresh;
mid <- fresh;
ms <- source <xml/>;
state <- @Monad.mapR _ [fn a => option string * t a] [ident]
(fn [nm ::_] [t ::_] (_, r) => r.Create) fl ts;
size <- return (@fold [fn _ => int]
(fn [nm ::_] [v ::_] [r ::_] [[nm] ~ r] n => n + 1)
0 fl);
(curTab : source int) <- source (@foldR [fn a => option string * t a] [fn _ => int * int]
(fn [nm ::_] [v ::_] [r ::_] [[nm] ~ r] (opt, _) (cur, chosen) =>
(cur - 1,
case opt of
None => chosen
| Some _ => cur))
(size-1, size) fl ts).2;
return <xml>
<head>
<title>{[titl]}</title>
<link rel="stylesheet" href="https://maxcdn.bootstrapcdn.com/bootstrap/3.3.2/css/bootstrap.min.css"/>
<link rel="stylesheet" href="/style.css"/>
</head>
<body onload={@Monad.appR2 _ [fn a => option string * t a] [ident]
(fn [nm ::_] [t ::_] (_, r) => r.Onload)
fl ts state}>
<div class="modal" id={mid}>
<dyn signal={signal ms}/>
</div>
<nav class="navbar navbar-inverse navbar-fixed-top">
<div class="container">
<div class="navbar-header">
<button class="navbar-toggle collapsed" data-toggle="collapse" data-target={"#" ^ show nid} aria-expanded="false" aria-controls="navbar">
<span class="sr-only">Toggle navigation</span>
<span class="icon-bar"></span>
<span class="icon-bar"></span>
<span class="icon-bar"></span>
</button>
<a class="navbar-brand">{[titl]}</a>
</div>
<div id={nid} class="collapse navbar-collapse">
<ul class="bs3-nav navbar-nav">
{(@foldR2 [fn a => option string * t a] [ident]
[fn _ => xbody * int]
(fn [nm ::_] [t ::_] [r ::_] [[nm] ~ r] (labl : option string, r) st (bod, n) =>
(case labl of
None => bod
| Some labl => <xml>
<li dynClass={ct <- signal curTab;
return (if ct = n then
bs3_active
else
null)}
onclick={fn _ => set curTab n}><a>{[labl]}</a></li>
{bod}
</xml>,
n-1))
(<xml/>, size-1)
fl ts state).1}
</ul>
</div>
</div>
</nav>
<div class="container-fluid">
<dyn signal={ct <- signal curTab;
return (@foldR2 [fn a => option string * t a] [ident] [fn _ => xbody * int]
(fn [nm ::_] [t ::_] [r ::_] [[nm] ~ r] (_, t) st (acc, n) =>
(if ct = n then
t.Render {ModalId = mid, ModalSpot = ms} st
else
acc, n-1))
(<xml/>, size-1) fl ts state).1}/>
</div>
</body>
</xml>
fun modalButton ctx cls bod onclick = <xml>
<button class={cls}
data-toggle="modal"
data-target={"#" ^ show ctx.ModalId}
onclick={fn _ =>
ms <- onclick;
set ctx.ModalSpot ms}>
{bod}
</button>
</xml>
fun modal bcode titl bod blab = <xml>
<div class="modal-dialog">
<div class="modal-content">
<div class="modal-header">
<h4 class="modal-title">{titl}</h4>
</div>
<div class="modal-body">
{bod}
</div>
<div class="modal-footer">
<button class="btn btn-primary"
data-dismiss="modal"
onclick={fn _ => bcode}>
{blab}
</button>
<button class="btn btn-default"
data-dismiss="modal"
value="Cancel"/>
</div>
</div>
</div>
</xml>
val p bod = const <xml><p>{bod}</p></xml>
val h1 bod = const <xml><h1>{bod}</h1></xml>
val h2 bod = const <xml><h2>{bod}</h2></xml>
val h3 bod = const <xml><h3>{bod}</h3></xml>
val h4 bod = const <xml><h4>{bod}</h4></xml>
val hr = const <xml><hr/></xml>