/
acdc_agent_fsm.erl
1337 lines (1120 loc) · 53.8 KB
/
acdc_agent_fsm.erl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
%%%-------------------------------------------------------------------
%%% @copyright (C) 2012, VoIP INC
%%% @doc
%%% Tracks the agent's state, responds to messages from the corresponding
%%% acdc_agent gen_listener process.
%%% @end
%%% @contributors
%%% James Aimonetti
%%%-------------------------------------------------------------------
-module(acdc_agent_fsm).
-behaviour(gen_fsm).
%% API
-export([start_link/2, start_link/3, start_link/4
,call_event/4
,member_connect_req/2
,member_connect_win/2
,originate_ready/2
,originate_resp/2
,originate_failed/2
,route_req/2
,sync_req/2, sync_resp/2
,pause/2
,resume/1
,refresh/2
,current_call/1
,status/1
]).
-export([wait_for_listener/4]).
%% gen_fsm callbacks
-export([init/1
,handle_event/3
,handle_sync_event/4
,handle_info/3
,terminate/3
,code_change/4
]).
%% Agent states
-export([wait/2
,sync/2
,ready/2
,ringing/2
,answered/2
,wrapup/2
,paused/2
,outbound/2
,wait/3
,sync/3
,ready/3
,ringing/3
,answered/3
,wrapup/3
,paused/3
,outbound/3
]).
-include("acdc.hrl").
%% When an agent starts up, how long do we wait for other agents to respond with their status?
-define(SYNC_RESPONSE_TIMEOUT, 5000).
-define(SYNC_RESPONSE_MESSAGE, sync_response_timeout).
%% We weren't able to join our brethern, how long to wait to check again
-define(RESYNC_RESPONSE_TIMEOUT, 15000).
-define(RESYNC_RESPONSE_MESSAGE, resync_response_timeout).
-define(PAUSE_MESSAGE, pause_expired).
-define(WRAPUP_FINISHED, wrapup_finished).
-define(CALL_STATUS_TIMEOUT, 10000).
-define(CALL_STATUS_MESSAGE, call_status_timeout).
-record(state, {
acct_id :: ne_binary()
,acct_db :: ne_binary()
,agent_id :: ne_binary()
,agent_proc :: pid()
,agent_proc_id :: ne_binary()
,wrapup_timeout = 0 :: integer() % optionally set on win
,wrapup_ref :: reference()
,sync_ref :: reference()
,call_status_ref :: reference()
,call_status_failures = 0 :: integer()
,member_call :: whapps_call:call()
,member_call_id :: ne_binary()
,member_call_queue_id :: ne_binary()
,member_call_start :: wh_now()
,caller_exit_key = <<"#">> :: ne_binary()
,agent_call_id :: ne_binary()
,next_status :: ne_binary()
,fsm_call_id :: ne_binary() % used when no call-ids are available
,endpoints = [] :: wh_json:objects()
,outbound_call_id :: api_binary()
}).
%%%===================================================================
%%% API
%%%===================================================================
%%--------------------------------------------------------------------
%% @doc
%% When a queue receives a call and needs an agent, it will send a
%% member_connect_req. The agent will respond (if possible) with a
%% member_connect_resp payload or ignore the request
%% @end
%%--------------------------------------------------------------------
-spec member_connect_req/2 :: (pid(), wh_json:object()) -> 'ok'.
member_connect_req(FSM, JObj) ->
gen_fsm:send_event(FSM, {member_connect_req, JObj}).
%%--------------------------------------------------------------------
%% @doc
%% When a queue receives a call and needs an agent, it will send a
%% member_connect_req. The agent will respond (if possible) with a
%% member_connect_resp payload or ignore the request
%% @end
%%--------------------------------------------------------------------
-spec member_connect_win/2 :: (pid(), wh_json:object()) -> 'ok'.
member_connect_win(FSM, JObj) ->
gen_fsm:send_event(FSM, {member_connect_win, JObj}).
%%--------------------------------------------------------------------
%% @doc
%% When an agent is involved in a call, it will receive call events.
%% Pass the call event to the FSM to see if action is needed (usually
%% for bridge and hangup events).
%% @end
%%--------------------------------------------------------------------
-spec call_event/4 :: (pid(), ne_binary(), ne_binary(), wh_json:object()) -> 'ok'.
call_event(FSM, <<"call_event">>, <<"CHANNEL_BRIDGE">>, JObj) ->
gen_fsm:send_event(FSM, {channel_bridged, callid(JObj)});
call_event(FSM, <<"call_event">>, <<"CHANNEL_UNBRIDGE">>, JObj) ->
gen_fsm:send_event(FSM, {channel_unbridged, callid(JObj)});
call_event(FSM, <<"call_event">>, <<"CHANNEL_DESTROY">>, JObj) ->
gen_fsm:send_event(FSM, {channel_hungup, callid(JObj)});
call_event(FSM, <<"call_event">>, <<"LEG_CREATED">>, JObj) ->
gen_fsm:send_event(FSM, {leg_created, callid(JObj)});
call_event(FSM, <<"call_event">>, <<"LEG_DESTROYED">>, JObj) ->
gen_fsm:send_event(FSM, {leg_destroyed, callid(JObj)});
call_event(FSM, <<"call_event">>, <<"CHANNEL_ANSWER">>, JObj) ->
gen_fsm:send_event(FSM, {channel_answered, callid(JObj)});
call_event(FSM, <<"call_event">>, <<"DTMF">>, EvtJObj) ->
gen_fsm:send_event(FSM, {dtmf_pressed, wh_json:get_value(<<"DTMF-Digit">>, EvtJObj)});
call_event(FSM, <<"call_event">>, <<"CHANNEL_EXECUTE_COMPLETE">>, JObj) ->
maybe_send_execute_complete(FSM, wh_json:get_value(<<"Application-Name">>, JObj), JObj);
call_event(FSM, <<"call_event">>, <<"call_status_resp">>, JObj) ->
gen_fsm:send_event(FSM, {call_status, JObj});
call_event(FSM, <<"error">>, <<"dialplan">>, JObj) ->
_ = wh_util:put_callid(JObj),
lager:debug("error event: ~s", [wh_json:get_value(<<"Error-Message">>, JObj)]),
Req = wh_json:get_value(<<"Request">>, JObj),
gen_fsm:send_event(FSM, {dialplan_error, wh_json:get_value(<<"Application-Name">>, Req)});
call_event(_, _C, _E, _) ->
lager:debug("unhandled call event: ~s: ~s", [_C, _E]).
%%--------------------------------------------------------------------
%% @doc
%% @end
%%--------------------------------------------------------------------
-spec maybe_send_execute_complete/3 :: (pid(), ne_binary(), wh_json:object()) -> 'ok'.
maybe_send_execute_complete(FSM, <<"bridge">>, JObj) ->
gen_fsm:send_event(FSM, {channel_unbridged, callid(JObj)});
maybe_send_execute_complete(FSM, <<"call_pickup">>, JObj) ->
gen_fsm:send_event(FSM, {channel_bridged, callid(JObj)});
maybe_send_execute_complete(_, _, _) -> ok.
%%--------------------------------------------------------------------
%% @doc
%% @end
%%--------------------------------------------------------------------
originate_ready(FSM, JObj) ->
gen_fsm:send_event(FSM, {originate_ready, JObj}).
originate_resp(FSM, JObj) ->
gen_fsm:send_event(FSM, {originate_resp, wh_json:get_value(<<"Call-ID">>, JObj)}).
%%--------------------------------------------------------------------
%% @doc
%% @end
%%--------------------------------------------------------------------
originate_failed(FSM, JObj) ->
gen_fsm:send_event(FSM, {originate_failed, JObj}).
route_req(FSM, Call) ->
gen_fsm:send_event(FSM, {route_req, Call}).
%%--------------------------------------------------------------------
%% @doc
%% @end
%%--------------------------------------------------------------------
sync_req(FSM, JObj) ->
gen_fsm:send_event(FSM, {sync_req, JObj}).
%%--------------------------------------------------------------------
%% @doc
%% @end
%%--------------------------------------------------------------------
sync_resp(FSM, JObj) ->
gen_fsm:send_event(FSM, {sync_resp, JObj}).
%%--------------------------------------------------------------------
%% @doc
%% @end
%%--------------------------------------------------------------------
pause(FSM, Timeout) ->
gen_fsm:send_event(FSM, {pause, Timeout}).
%%--------------------------------------------------------------------
%% @doc
%% @end
%%--------------------------------------------------------------------
resume(FSM) ->
gen_fsm:send_event(FSM, {resume}).
%%--------------------------------------------------------------------
%% @doc
%% @end
%%--------------------------------------------------------------------
refresh(FSM, AgentJObj) ->
gen_fsm:send_all_state_event(FSM, {refresh, AgentJObj}).
-spec current_call/1 :: (pid()) -> 'undefined' | wh_json:object().
current_call(FSM) ->
gen_fsm:sync_send_event(FSM, current_call).
status(FSM) ->
gen_fsm:sync_send_event(FSM, status).
%%--------------------------------------------------------------------
%% @doc
%% Creates a gen_fsm process which calls Module:init/1 to
%% initialize. To ensure a synchronized start-up procedure, this
%% function does not return until Module:init/1 has returned.
%%
%% @spec start_link() -> {ok, Pid} | ignore | {error, Error}
%% @end
%%--------------------------------------------------------------------
-spec start_link/2 :: (pid(), wh_json:object()) -> startlink_ret().
-spec start_link/3 :: (pid(), whapps_call:call(), ne_binary()) -> startlink_ret().
-spec start_link/4 :: (ne_binary(), ne_binary(), pid(), wh_proplist()) -> startlink_ret().
start_link(Supervisor, AgentJObj) when is_pid(Supervisor) ->
start_link(wh_json:get_value(<<"pvt_account_id">>, AgentJObj)
,wh_json:get_value(<<"_id">>, AgentJObj)
,Supervisor
,[]
,false
).
start_link(Supervisor, ThiefCall, _QueueId) ->
start_link(whapps_call:account_id(ThiefCall)
,whapps_call:owner_id(ThiefCall)
,Supervisor
,[]
,true
).
start_link(AcctId, AgentId, Supervisor, Props) ->
start_link(AcctId, AgentId, Supervisor, Props, false).
start_link(AcctId, AgentId, Supervisor, Props, IsThief) ->
gen_fsm:start_link(?MODULE, [AcctId, AgentId, Supervisor, Props, IsThief], []).
%%%===================================================================
%%% gen_fsm callbacks
%%%===================================================================
%%--------------------------------------------------------------------
%% @private
%% @doc
%% Whenever a gen_fsm is started using gen_fsm:start/[3,4] or
%% gen_fsm:start_link/[3,4], this function is called by the new
%% process to initialize.
%%
%% @spec init(Args) -> {ok, StateName, State} |
%% {ok, StateName, State, Timeout} |
%% ignore |
%% {stop, StopReason}
%% @end
%%--------------------------------------------------------------------
init([AcctId, AgentId, Supervisor, Props, IsThief]) ->
FSMCallId = <<"fsm_", AcctId/binary, "_", AgentId/binary>>,
put(callid, FSMCallId),
lager:debug("started acdc agent fsm"),
acdc_stats:agent_active(AcctId, AgentId),
webseq:reg_who(self(), iolist_to_binary([<<"aFSM">>, pid_to_list(self())])),
Self = self(),
_P = spawn(?MODULE, wait_for_listener, [Supervisor, Self, Props, IsThief]),
lager:debug("waiting for listener in ~p", [_P]),
{ok, wait, #state{acct_id=AcctId
,acct_db=wh_util:format_account_id(AcctId, encoded)
,agent_id=AgentId
,fsm_call_id=FSMCallId
}}.
wait_for_listener(Supervisor, FSM, Props, IsThief) ->
case acdc_agent_sup:agent(Supervisor) of
undefined ->
lager:debug("listener not ready yet, waiting"),
timer:sleep(100),
wait_for_listener(Supervisor, FSM, Props, IsThief);
P when is_pid(P) ->
lager:debug("listener retrieved: ~p", [P]),
{NextState, SyncRef} = case props:get_value(skip_sync, Props) =:= 'true' orelse IsThief of
true -> {ready, undefined};
_ ->
gen_fsm:send_event(FSM, send_sync_event),
gen_fsm:send_all_state_event(FSM, load_endpoints),
{sync, start_sync_timer(FSM)}
end,
gen_fsm:send_event(FSM, {listener, P, NextState, SyncRef})
end.
%%--------------------------------------------------------------------
%% @private
%% @doc
%% @end
%%--------------------------------------------------------------------
wait({listener, AgentProc, NextState, SyncRef}, State) ->
lager:debug("setting agent proc to ~p", [AgentProc]),
acdc_agent:fsm_started(AgentProc, self()),
{next_state, NextState, State#state{
agent_proc=AgentProc
,sync_ref=SyncRef
,agent_proc_id=acdc_util:proc_id()
}};
wait(send_sync_event, State) ->
gen_fsm:send_event(self(), send_sync_event),
{next_state, wait, State};
wait({route_req, _Call}=Req, State) ->
gen_fsm:send_event(self(), Req),
{next_state, wait, State};
wait(_Msg, State) ->
lager:debug("unhandled event in wait: ~p", [_Msg]),
{next_state, wait, State}.
wait(status, _, State) ->
{reply, undefined, wait, State};
wait(current_call, _, State) ->
{reply, undefined, wait, State}.
%%--------------------------------------------------------------------
%% @private
%% @doc
%% @end
%%--------------------------------------------------------------------
sync({timeout, Ref, ?SYNC_RESPONSE_MESSAGE}, #state{sync_ref=Ref
,acct_id=AcctId
,agent_id=AgentId
}=State) when is_reference(Ref) ->
lager:debug("done waiting for sync responses"),
acdc_util:presence_update(AcctId, AgentId, ?PRESENCE_GREEN),
acdc_stats:agent_ready(AcctId, AgentId),
{next_state, ready, State#state{sync_ref=Ref}};
sync({timeout, Ref, ?RESYNC_RESPONSE_MESSAGE}, #state{sync_ref=Ref}=State) when is_reference(Ref) ->
lager:debug("resync timer expired, lets check with the others again"),
SyncRef = start_sync_timer(),
gen_fsm:send_event(self(), send_sync_event),
{next_state, sync, State#state{sync_ref=SyncRef}};
sync(send_sync_event, #state{agent_proc=Srv, agent_proc_id=_AProcId}=State) ->
lager:debug("sending sync_req event to other agent processes: ~s", [_AProcId]),
acdc_agent:send_sync_req(Srv),
{next_state, sync, State};
sync({sync_req, JObj}, #state{agent_proc=Srv
,agent_proc_id=AProcId
}=State) ->
case wh_json:get_value(<<"Process-ID">>, JObj) of
AProcId ->
lager:debug("recv sync req from ourself"),
{next_state, sync, State};
_OtherProcId ->
lager:debug("recv sync_req from ~s (we are ~s)", [_OtherProcId, AProcId]),
acdc_agent:send_sync_resp(Srv, sync, JObj),
{next_state, sync, State}
end;
sync({sync_resp, JObj}, #state{sync_ref=Ref
,acct_id=AcctId
,agent_id=AgentId
}=State) ->
case catch wh_util:to_atom(wh_json:get_value(<<"Status">>, JObj)) of
sync ->
lager:debug("other agent is in sync too"),
{next_state, sync, State};
ready ->
lager:debug("other agent is in ready state, joining"),
_ = erlang:cancel_timer(Ref),
acdc_util:presence_update(AcctId, AgentId, ?PRESENCE_GREEN),
acdc_stats:agent_ready(AcctId, AgentId),
{next_state, ready, State#state{sync_ref=undefined}};
{'EXIT', _} ->
lager:debug("other agent sent unusable state, ignoring"),
{next_state, sync, State};
Status ->
lager:debug("other agent is in ~s, delaying", [Status]),
_ = erlang:cancel_timer(Ref),
{next_state, sync, State#state{sync_ref=start_resync_timer()}}
end;
sync({member_connect_req, _}, State) ->
lager:debug("member_connect_req recv, not ready"),
{next_state, sync, State};
sync({pause, Timeout}, #state{acct_id=AcctId
,agent_id=AgentId
}=State) ->
lager:debug("recv status update:, pausing for up to ~b s", [Timeout]),
Ref = start_pause_timer(Timeout),
acdc_stats:agent_paused(AcctId, AgentId, Timeout),
acdc_util:presence_update(AcctId, AgentId, ?PRESENCE_RED_FLASH),
{next_state, paused, State#state{sync_ref=Ref}};
sync({route_req, _Call}=Req, State) ->
gen_fsm:send_event(self(), Req),
{next_state, sync, State};
sync(_Evt, State) ->
lager:debug("unhandled event while syncing: ~p", [_Evt]),
{next_state, sync, State}.
sync(status, _, State) ->
{reply, undefined, sync, State};
sync(current_call, _, State) ->
{reply, undefined, sync, State}.
%%--------------------------------------------------------------------
%% @private
%% @doc
%% @end
%%--------------------------------------------------------------------
ready({pause, Timeout}, #state{acct_id=AcctId
,agent_id=AgentId
}=State) ->
lager:debug("recv status update: pausing for up to ~b s", [Timeout]),
Ref = start_pause_timer(Timeout),
acdc_stats:agent_paused(AcctId, AgentId, Timeout),
acdc_util:presence_update(AcctId, AgentId, ?PRESENCE_RED_FLASH),
webseq:note(self(), right, [<<"pausing for ">>, wh_util:to_binary(Timeout)]),
{next_state, paused, State#state{sync_ref=Ref}};
ready({sync_req, JObj}, #state{agent_proc=Srv}=State) ->
lager:debug("recv sync_req from ~s", [wh_json:get_value(<<"Server-ID">>, JObj)]),
acdc_agent:send_sync_resp(Srv, ready, JObj),
{next_state, ready, State};
ready({member_connect_win, JObj}, #state{agent_proc=Srv
,endpoints=EPs
,agent_proc_id=MyId
,agent_id=AgentId
}=State) ->
Call = whapps_call:from_json(wh_json:get_value(<<"Call">>, JObj)),
CallId = whapps_call:call_id(Call),
put(callid, CallId),
WrapupTimer = wh_json:get_integer_value(<<"Wrapup-Timeout">>, JObj, 0),
CallerExitKey = wh_json:get_value(<<"Caller-Exit-Key">>, JObj, <<"#">>),
QueueId = wh_json:get_value(<<"Queue-ID">>, JObj),
case wh_json:get_value(<<"Agent-Process-ID">>, JObj) of
MyId ->
lager:debug("trying to ring agent ~s to connect to caller", [AgentId]),
acdc_agent:bridge_to_member(Srv, Call, JObj, EPs),
webseq:note(self(), right, [<<"recv win for ">>, CallId, <<", ringing">>]),
{next_state, ringing, State#state{wrapup_timeout=WrapupTimer
,member_call=Call
,member_call_id=CallId
,member_call_start=erlang:now()
,member_call_queue_id=QueueId
,caller_exit_key=CallerExitKey
}};
_OtherId ->
lager:debug("monitoring agent ~s connecting to caller: ~s(~s)", [AgentId, _OtherId, MyId]),
acdc_agent:monitor_call(Srv, Call),
webseq:note(self(), right, [<<"recv monitor for ">>, CallId, <<", ringing">>]),
{next_state, ringing, State#state{
wrapup_timeout=WrapupTimer
,member_call_id=CallId
,member_call_start=erlang:now()
,member_call_queue_id=QueueId
,caller_exit_key=CallerExitKey
}}
end;
ready({member_connect_req, JObj}, #state{agent_proc=Srv}=State) ->
acdc_agent:member_connect_resp(Srv, JObj),
webseq:evt(self(), webseq:process_pid(JObj), <<"member connect resp">>),
{next_state, ready, State};
ready({channel_hungup, CallId}, #state{agent_proc=Srv}=State) ->
lager:debug("channel hungup for ~s", [CallId]),
acdc_agent:channel_hungup(Srv, CallId),
{next_state, ready, State};
ready({channel_unbridged, CallId}, #state{agent_proc=_Srv}=State) ->
lager:debug("channel unbridged: ~s", [CallId]),
{next_state, ready, State};
ready({leg_destroyed, CallId}, #state{agent_proc=_Srv}=State) ->
lager:debug("channel unbridged: ~s", [CallId]),
{next_state, ready, State};
ready({resume}, State) ->
{next_state, ready, State};
ready({dtmf_pressed, _}, State) ->
{next_state, ready, State};
ready({originate_failed, _E}, State) ->
{next_state, ready, State};
ready({route_req, Call}, #state{agent_proc=Srv
,acct_id=AcctId
,agent_id=AgentId
}=State) ->
CallId = whapps_call:call_id(Call),
put(callid, CallId),
lager:debug("agent making outbound call, not receiving calls"),
acdc_agent:outbound_call(Srv, Call),
acdc_stats:agent_oncall(AcctId, AgentId, CallId),
webseq:evt(CallId, self(), <<"outbound call started">>),
webseq:note(self(), right, <<"outbound">>),
{next_state
,outbound
,State#state{outbound_call_id=CallId
,call_status_ref=start_call_status_timer()
,call_status_failures=0
}
,hibernate
};
ready(_Evt, State) ->
lager:debug("unhandled event while ready: ~p", [_Evt]),
{next_state, ready, State}.
ready(status, _, State) ->
{reply, <<"ready">>, ready, State};
ready(current_call, _, State) ->
{reply, undefined, ready, State}.
%%--------------------------------------------------------------------
%% @private
%% @doc
%% @end
%%--------------------------------------------------------------------
ringing({member_connect_req, _}, State) ->
{next_state, ringing, State};
ringing({member_connect_win, JObj}, #state{agent_proc=Srv}=State) ->
lager:debug("agent won, but can't process this right now (already ringing)"),
acdc_agent:member_connect_retry(Srv, JObj),
webseq:evt(self(), webseq:process_pid(JObj), <<"agent busy, retry member call">>),
{next_state, ringing, State};
ringing({originate_ready, JObj}, #state{agent_proc=Srv}=State) ->
CallId = wh_json:get_value(<<"Call-ID">>, JObj),
lager:debug("ringing agent's phone with call-id ~s", [CallId]),
acdc_agent:originate_execute(Srv, JObj),
{next_state, ringing, State#state{agent_call_id=CallId}};
ringing({originate_resp, ACallId}, #state{agent_proc=Srv
,member_call_id=MCallId
}=State) ->
lager:debug("originate resp on ~s, connecting to caller", [ACallId]),
acdc_agent:agent_call_id(Srv, ACallId),
acdc_agent:member_connect_accepted(Srv),
webseq:evt(self(), MCallId, <<"bridged to member">>),
{next_state, answered, State#state{call_status_ref=start_call_status_timer()
,call_status_failures=0
,agent_call_id=ACallId
}};
ringing({originate_failed, _E}, #state{agent_proc=Srv
,acct_id=AcctId
,agent_id=AgentId
,member_call_queue_id=QueueId
,member_call_id=CallId
}=State) ->
lager:debug("ringing agent failed: ~s", [wh_json:get_value(<<"Error-Message">>, _E)]),
acdc_agent:member_connect_retry(Srv, CallId),
webseq:note(self(), right, [<<"ringing failed: ">>, wh_json:get_value(<<"Error-Message">>, _E)]),
acdc_stats:call_missed(AcctId, QueueId, AgentId, CallId),
acdc_stats:agent_ready(AcctId, AgentId),
acdc_util:presence_update(AcctId, AgentId, ?PRESENCE_GREEN),
{next_state, ready, clear_call(State)};
ringing({channel_bridged, CallId}, #state{member_call_id=CallId
,agent_proc=Srv
}=State) ->
lager:debug("agent phone has been connected to caller"),
acdc_agent:member_connect_accepted(Srv),
webseq:evt(self(), CallId, <<"bridged to member">>),
{next_state, answered, State#state{call_status_ref=start_call_status_timer()
,call_status_failures=0
}};
ringing({channel_hungup, CallId}, #state{agent_proc=Srv
,agent_call_id=CallId
,acct_id=AcctId
,agent_id=AgentId
,member_call_queue_id=QueueId
,member_call_id=MCallId
}=State) ->
lager:debug("agent did not answer their phone in time: ~s", [CallId]),
acdc_agent:member_connect_retry(Srv, MCallId),
acdc_agent:channel_hungup(Srv, CallId),
acdc_stats:call_missed(AcctId, QueueId, AgentId, MCallId),
acdc_stats:agent_ready(AcctId, AgentId),
webseq:note(self(), right, <<"failed to answer phone in time">>),
acdc_util:presence_update(AcctId, AgentId, ?PRESENCE_GREEN),
{next_state, ready, clear_call(State)};
ringing({channel_hungup, CallId}, #state{agent_proc=Srv
,acct_id=AcctId
,agent_id=AgentId
,member_call_id=CallId
,member_call_queue_id=QueueId
,agent_call_id=AgentCallId
}=State) ->
lager:debug("caller's channel (~s) has gone down, stop agent's call", [CallId]),
acdc_agent:channel_hungup(Srv, AgentCallId),
acdc_stats:call_abandoned(AcctId, QueueId, CallId, ?ABANDON_HANGUP),
acdc_stats:agent_ready(AcctId, AgentId),
webseq:note(self(), right, <<"caller hungup">>),
acdc_util:presence_update(AcctId, AgentId, ?PRESENCE_GREEN),
{next_state, ready, clear_call(State)};
ringing({dtmf_pressed, DTMF}, #state{caller_exit_key=DTMF
,agent_proc=Srv
,agent_call_id=AgentCallId
,acct_id=AcctId
,agent_id=AgentId
,member_call_queue_id=QueueId
,member_call_id=CallId
}=State) when is_binary(DTMF) ->
lager:debug("caller exit key pressed: ~s", [DTMF]),
acdc_agent:channel_hungup(Srv, AgentCallId),
acdc_stats:call_abandoned(AcctId, QueueId, CallId, ?ABANDON_EXIT),
acdc_stats:agent_ready(AcctId, AgentId),
acdc_util:presence_update(AcctId, AgentId, ?PRESENCE_GREEN),
webseq:note(self(), right, <<"member call hungup - DTMF">>),
{next_state, ready, clear_call(State)};
ringing({dtmf_pressed, DTMF}, #state{caller_exit_key=_ExitKey}=State) ->
lager:debug("caller pressed ~s, exit key is ~s", [DTMF, _ExitKey]),
{next_state, ringing, State};
ringing({channel_answered, ACallId}, #state{agent_call_id=ACallId
,agent_proc=Srv
,member_call_id=MCallId
}=State) ->
lager:debug("agent answered phone on ~s, connecting to caller", [ACallId]),
acdc_agent:join_agent(Srv, ACallId),
webseq:evt(self(), MCallId, <<"agent answered line, bridging to member">>),
{next_state, answered, State#state{call_status_ref=start_call_status_timer()
,call_status_failures=0
}};
ringing({channel_answered, MCallId}, #state{member_call_id=MCallId}=State) ->
lager:debug("caller's channel answered"),
{next_state, ringing, State};
ringing({sync_req, JObj}, #state{agent_proc=Srv}=State) ->
lager:debug("recv sync_req from ~s", [wh_json:get_value(<<"Process-ID">>, JObj)]),
acdc_agent:send_sync_resp(Srv, ringing, JObj),
{next_state, ringing, State};
ringing(_Evt, State) ->
lager:debug("unhandled event while ringing: ~p", [_Evt]),
{next_state, ringing, State}.
ringing(status, _, State) ->
{reply, <<"ringing">>, ringing, State};
ringing(current_call, _, #state{member_call=Call
,member_call_queue_id=QueueId
}=State) ->
{reply, current_call(Call, ringing, QueueId, undefined), ringing, State}.
%%--------------------------------------------------------------------
%% @private
%% @doc
%% @end
%%--------------------------------------------------------------------
answered({member_connect_req, _}, State) ->
{next_state, answered, State};
answered({member_connect_win, JObj}, #state{agent_proc=Srv}=State) ->
lager:debug("agent won, but can't process this right now (on the phone with someone)"),
acdc_agent:member_connect_retry(Srv, JObj),
webseq:evt(self(), webseq:process_pid(JObj), <<"agent busy, retry member call">>),
{next_state, answered, State};
answered({dialplan_error, _App}, #state{agent_proc=Srv
,acct_id=AcctId
,agent_id=AgentId
,member_call_queue_id=QueueId
,member_call_id=CallId
,agent_call_id=ACallId
}=State) ->
lager:debug("connecting agent to caller failed, clearing call"),
acdc_agent:channel_hungup(Srv, ACallId),
acdc_agent:member_connect_retry(Srv, CallId),
acdc_stats:call_missed(AcctId, QueueId, AgentId, CallId),
acdc_stats:agent_ready(AcctId, AgentId),
webseq:note(self(), right, <<"connecting to member failed">>),
acdc_util:presence_update(AcctId, AgentId, ?PRESENCE_GREEN),
{next_state, ready, clear_call(State)};
answered({channel_bridged, CallId}, #state{member_call_id=CallId
,agent_proc=Srv
}=State) ->
lager:debug("agent has connected to member"),
acdc_agent:member_connect_accepted(Srv),
{next_state, answered, State};
answered({channel_bridged, CallId}, #state{agent_call_id=CallId
,agent_proc=Srv
}=State) ->
lager:debug("agent has connected (~s) to caller", [CallId]),
acdc_agent:member_connect_accepted(Srv),
{next_state, answered, State};
answered({channel_hungup, CallId}, #state{member_call_id=CallId}=State) ->
lager:debug("caller's channel hung up"),
webseq:evt(CallId, self(), <<"member hangup">>),
{next_state, wrapup, State#state{wrapup_timeout=0, wrapup_ref=hangup_call(State)}};
answered({channel_hungup, CallId}, #state{agent_call_id=CallId}=State) ->
lager:debug("agent's channel has hung up"),
webseq:evt(CallId, self(), <<"agent hangup">>),
{next_state, wrapup, State#state{wrapup_timeout=0, wrapup_ref=hangup_call(State)}};
answered({channel_hungup, CallId}, #state{agent_proc=Srv}=State) ->
lager:debug("someone(~s) hungup, ignoring", [CallId]),
acdc_agent:channel_hungup(Srv, CallId),
{next_state, answered, State};
answered({sync_req, JObj}, #state{agent_proc=Srv
,member_call_id=CallId
}=State) ->
lager:debug("recv sync_req from ~s", [wh_json:get_value(<<"Process-ID">>, JObj)]),
acdc_agent:send_sync_resp(Srv, answered, JObj, [{<<"Call-ID">>, CallId}]),
{next_state, answered, State};
answered({channel_unbridged, CallId}, #state{member_call_id=CallId}=State) ->
lager:debug("caller channel unbridged"),
{next_state, wrapup, State#state{wrapup_timeout=0
,wrapup_ref=hangup_call(State)
}};
answered({channel_unbridged, CallId}, #state{agent_call_id=CallId}=State) ->
lager:debug("agent channel unbridged"),
{next_state, wrapup, State#state{wrapup_timeout=0
,wrapup_ref=hangup_call(State)
}};
answered({timeout, CRef, ?CALL_STATUS_MESSAGE}, #state{call_status_ref=CRef
,call_status_failures=Failures
}=State) when Failures > 3 ->
lager:debug("call status failed ~b times, call is probably down", [Failures]),
{next_state, wrapup, State#state{wrapup_timeout=0
,wrapup_ref=hangup_call(State)
}};
answered({timeout, CRef, ?CALL_STATUS_MESSAGE}, #state{call_status_ref=CRef
,call_status_failures=Failures
,agent_proc=Srv
}=State) ->
acdc_agent:call_status_req(Srv),
{next_state, answered, State#state{call_status_ref=start_call_status_timer()
,call_status_failures=Failures+1
}};
answered({call_status, JObj}, #state{call_status_failures=Failures}=State) ->
case wh_json:get_value(<<"Status">>, JObj) of
<<"active">> -> {next_state, answered, State#state{call_status_failures=0}};
_S ->
{next_state, answered, State#state{call_status_failures=Failures+1}}
end;
answered(_Evt, State) ->
lager:debug("unhandled event while answered: ~p", [_Evt]),
{next_state, answered, State}.
answered(status, _, State) ->
{reply, <<"answered">>, answered, State};
answered(current_call, _, #state{member_call=Call
,member_call_start=Start
,member_call_queue_id=QueueId
}=State) ->
{reply, current_call(Call, answered, QueueId, Start), answered, State}.
%%--------------------------------------------------------------------
%% @private
%% @doc
%% @end
%%--------------------------------------------------------------------
wrapup({member_connect_req, _}, State) ->
{next_state, wrapup, State#state{wrapup_timeout=0}};
wrapup({member_connect_win, JObj}, #state{agent_proc=Srv}=State) ->
lager:debug("agent won, but can't process this right now (in wrapup)"),
acdc_agent:member_connect_retry(Srv, JObj),
webseq:evt(self(), webseq:process_pid(JObj), <<"agent busy, retry member call">>),
{next_state, wrapup, State#state{wrapup_timeout=0}};
wrapup({timeout, Ref, ?WRAPUP_FINISHED}, #state{wrapup_ref=Ref
,acct_id=AcctId
,agent_id=AgentId
}=State) ->
lager:debug("wrapup timer expired, ready for action!"),
acdc_stats:agent_ready(AcctId, AgentId),
acdc_util:presence_update(AcctId, AgentId, ?PRESENCE_GREEN),
webseq:note(self(), right, <<"wrapup finished">>),
{next_state, ready, clear_call(State)};
wrapup({sync_req, JObj}, #state{agent_proc=Srv
,wrapup_ref=Ref
}=State) ->
lager:debug("recv sync_req from ~s", [wh_json:get_value(<<"Process-ID">>, JObj)]),
acdc_agent:send_sync_resp(Srv, wrapup, JObj, [{<<"Time-Left">>, time_left(Ref)}]),
{next_state, wrapup, State};
wrapup({channel_hungup, CallId}, #state{agent_proc=Srv}=State) ->
lager:debug("channel ~s hungup", [CallId]),
acdc_agent:channel_hungup(Srv, CallId),
{next_state, wrapup, State};
wrapup({leg_destroyed, CallId}, #state{agent_proc=Srv}=State) ->
lager:debug("leg ~s destroyed", [CallId]),
acdc_agent:channel_hungup(Srv, CallId),
{next_state, wrapup, State};
wrapup({route_req, Call}, #state{agent_proc=Srv
,acct_id=AcctId
,agent_id=AgentId
}=State) ->
CallId = whapps_call:call_id(Call),
put(callid, CallId),
lager:debug("agent on outbound call, not receiving calls"),
acdc_agent:outbound_call(Srv, Call),
acdc_stats:agent_oncall(AcctId, AgentId, CallId),
webseq:evt(CallId, self(), <<"outbound call started while wrapping up">>),
{next_state
,outbound
,State#state{outbound_call_id=CallId
,call_status_ref=start_call_status_timer()
,call_status_failures=0
}
,hibernate
};
wrapup(_Evt, State) ->
lager:debug("unhandled event while in wrapup: ~p", [_Evt]),
{next_state, wrapup, State#state{wrapup_timeout=0}}.
wrapup(status, _, State) ->
{reply, <<"wrapup">>, wrapup, State};
wrapup(current_call, _, #state{member_call=Call
,member_call_start=Start
,member_call_queue_id=QueueId
}=State) ->
{reply, current_call(Call, wrapup, QueueId, Start), wrapup, State}.
%%--------------------------------------------------------------------
%% @private
%% @doc
%% @end
%%--------------------------------------------------------------------
paused({timeout, Ref, ?PAUSE_MESSAGE}, #state{sync_ref=Ref
,acct_id=AcctId
,agent_id=AgentId
,agent_proc=Srv
}=State) when is_reference(Ref) ->
lager:debug("pause timer expired, putting agent back into action"),
_ = update_agent_status_to_resume(AcctId, AgentId),
acdc_agent:send_status_resume(Srv),
acdc_stats:agent_ready(AcctId, AgentId),
acdc_util:presence_update(AcctId, AgentId, ?PRESENCE_GREEN),
webseq:note(self(), right, <<"wrapup timer finished - timeout">>),
{next_state, ready, clear_call(State#state{sync_ref=undefined})};
paused({resume}, #state{acct_id=AcctId
,agent_id=AgentId
,agent_proc=Srv
,sync_ref=Ref
}=State) ->
lager:debug("resume received, putting agent back into action"),
_ = erlang:cancel_timer(Ref),
_ = update_agent_status_to_resume(AcctId, AgentId),
acdc_agent:send_status_resume(Srv),
acdc_stats:agent_ready(AcctId, AgentId),
acdc_util:presence_update(AcctId, AgentId, ?PRESENCE_GREEN),
webseq:note(self(), right, <<"wrapup timer finished - resumed">>),
{next_state, ready, clear_call(State)};
paused({sync_req, JObj}, #state{agent_proc=Srv
,wrapup_ref=Ref
}=State) ->
lager:debug("recv sync_req from ~s", [wh_json:get_value(<<"Process-ID">>, JObj)]),
acdc_agent:send_sync_resp(Srv, paused, JObj, [{<<"Time-Left">>, time_left(Ref)}]),
{next_state, paused, State};
paused({member_connect_req, _}, State) ->
{next_state, paused, State};
paused({member_connect_win, JObj}, #state{agent_proc=Srv}=State) ->
lager:debug("agent won, but can't process this right now"),
acdc_agent:member_connect_retry(Srv, JObj),
webseq:evt(self(), webseq:process_pid(JObj), <<"agent busy, retry member call">>),
{next_state, paused, State};
paused({route_req, Call}, #state{agent_proc=Srv
,acct_id=AcctId
,agent_id=AgentId
}=State) ->
CallId = whapps_call:call_id(Call),
put(callid, CallId),
lager:debug("agent on outbound call, not receiving calls"),
acdc_agent:outbound_call(Srv, Call),
acdc_stats:agent_oncall(AcctId, AgentId, CallId),
webseq:evt(CallId, self(), <<"outbound call started while paused">>),
{next_state