chapter01.gradle

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "org.junit.platform:junit-platform-gradle-plugin:$junit5PluginVersion"
    }

}

plugins {
    id 'java-library'
}

group 'com.apress.bgn.ch1'
ext.moduleName = 'chapter.one'

apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'org.junit.platform.gradle.plugin'

dependencies {
    compile project(':chapter00')
    testImplementation testing.junit
}

jar {
    manifest {
        attributes(
                "Created-By": System.getProperty('java.version'),
                "Specification-Title": "Java for Absolute Beginners",
                "Implementation-Version": version,
                "Class-Path": configurations.compile.collect { it.getName() }.join(' ')
        )
    }
}

afterEvaluate {
    repositories {
        jcenter()
    }

    compileJava {
        inputs.property("moduleName", moduleName)
        doFirst {
            options.compilerArgs = [
                    '-proc:none',
                    '--module-path', classpath.asPath,
            ]
            classpath = files()
        }
    }

    compileTestJava {
        inputs.property("moduleName", moduleName)
        doFirst {
            options.compilerArgs = [
                    '-proc:none',
                    '--module-path', classpath.asPath,
                    '--add-modules', 'org.junit.jupiter.engine',
                    '--add-reads', "$moduleName=org.junit.jupiter.engine",
                    '--patch-module', "$moduleName=" + files(sourceSets.test.java.srcDirs).asPath,
            ]
            classpath = files()
        }
    }

    test {
        inputs.property("moduleName", moduleName)
        doFirst {
            jvmArgs = [
                    '--module-path', classpath.asPath,
                    '--add-modules', 'ALL-MODULE-PATH',
                    '--add-reads', "$moduleName=junit",
                    '--patch-module', "$moduleName=" + files(sourceSets.test.java.outputDir).asPath,
            ]
            classpath = files()
        }
    }
}