/
layout.xsl
1525 lines (1358 loc) · 81 KB
/
layout.xsl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE xsl:stylesheet [
<!ENTITY lapp "https://w3id.org/atomgraph/linkeddatahub/apps#">
<!ENTITY adm "https://w3id.org/atomgraph/linkeddatahub/admin#">
<!ENTITY lacl "https://w3id.org/atomgraph/linkeddatahub/admin/acl#">
<!ENTITY def "https://w3id.org/atomgraph/linkeddatahub/default#">
<!ENTITY ldh "https://w3id.org/atomgraph/linkeddatahub#">
<!ENTITY ldht "https://w3id.org/atomgraph/linkeddatahub/templates#">
<!ENTITY ldhc "https://w3id.org/atomgraph/linkeddatahub/config#">
<!ENTITY google "https://w3id.org/atomgraph/linkeddatahub/services/google#">
<!ENTITY ac "https://w3id.org/atomgraph/client#">
<!ENTITY a "https://w3id.org/atomgraph/core#">
<!ENTITY rdf "http://www.w3.org/1999/02/22-rdf-syntax-ns#">
<!ENTITY xhv "http://www.w3.org/1999/xhtml/vocab#">
<!ENTITY rdfs "http://www.w3.org/2000/01/rdf-schema#">
<!ENTITY xsd "http://www.w3.org/2001/XMLSchema#">
<!ENTITY owl "http://www.w3.org/2002/07/owl#">
<!ENTITY geo "http://www.w3.org/2003/01/geo/wgs84_pos#">
<!ENTITY srx "http://www.w3.org/2005/sparql-results#">
<!ENTITY http "http://www.w3.org/2011/http#">
<!ENTITY sc "http://www.w3.org/2011/http-statusCodes#">
<!ENTITY acl "http://www.w3.org/ns/auth/acl#">
<!ENTITY cert "http://www.w3.org/ns/auth/cert#">
<!ENTITY sd "http://www.w3.org/ns/sparql-service-description#">
<!ENTITY sh "http://www.w3.org/ns/shacl#">
<!ENTITY ldt "https://www.w3.org/ns/ldt#">
<!ENTITY c "https://www.w3.org/ns/ldt/core/domain#">
<!ENTITY ct "https://www.w3.org/ns/ldt/core/templates#">
<!ENTITY dh "https://www.w3.org/ns/ldt/document-hierarchy#">
<!ENTITY dct "http://purl.org/dc/terms/">
<!ENTITY foaf "http://xmlns.com/foaf/0.1/">
<!ENTITY sioc "http://rdfs.org/sioc/ns#">
<!ENTITY sp "http://spinrdf.org/sp#">
<!ENTITY spin "http://spinrdf.org/spin#">
<!ENTITY spl "http://spinrdf.org/spl#">
<!ENTITY void "http://rdfs.org/ns/void#">
<!ENTITY nfo "http://www.semanticdesktop.org/ontologies/2007/03/22/nfo#">
<!ENTITY schema "https://schema.org/">
]>
<xsl:stylesheet version="3.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xhtml="http://www.w3.org/1999/xhtml"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:map="http://www.w3.org/2005/xpath-functions/map"
xmlns:ac="∾"
xmlns:a="&a;"
xmlns:lapp="&lapp;"
xmlns:lacl="&lacl;"
xmlns:ldh="&ldh;"
xmlns:ldhc="&ldhc;"
xmlns:ldht="&ldht;"
xmlns:rdf="&rdf;"
xmlns:xhv="&xhv;"
xmlns:rdfs="&rdfs;"
xmlns:owl="&owl;"
xmlns:http="&http;"
xmlns:acl="&acl;"
xmlns:cert="&cert;"
xmlns:sd="&sd;"
xmlns:sh="&sh;"
xmlns:ldt="&ldt;"
xmlns:core="&c;"
xmlns:dh="&dh;"
xmlns:dct="&dct;"
xmlns:foaf="&foaf;"
xmlns:sioc="&sioc;"
xmlns:spin="&spin;"
xmlns:sp="&sp;"
xmlns:spl="&spl;"
xmlns:void="&void;"
xmlns:nfo="&nfo;"
xmlns:geo="&geo;"
xmlns:srx="&srx;"
xmlns:google="&google;"
xmlns:schema="&schema;"
xmlns:bs2="http://graphity.org/xsl/bootstrap/2.3.2"
exclude-result-prefixes="#all">
<xsl:import href="imports/xml-to-string.xsl"/>
<xsl:import href="../../../../client/xsl/converters/RDFXML2JSON-LD.xsl"/>
<xsl:import href="../../../../client/xsl/bootstrap/2.3.2/internal-layout.xsl"/>
<xsl:import href="imports/default.xsl"/>
<xsl:import href="imports/ac.xsl"/>
<xsl:import href="imports/ldh.xsl"/>
<xsl:import href="imports/dct.xsl"/>
<xsl:import href="imports/nfo.xsl"/>
<xsl:import href="imports/rdf.xsl"/>
<xsl:import href="imports/sioc.xsl"/>
<xsl:import href="imports/sp.xsl"/>
<xsl:import href="resource.xsl"/>
<xsl:import href="document.xsl"/>
<!-- To use xsl:import-schema, you need the schema-aware version of Saxon -->
<!-- <xsl:import-schema namespace="http://www.w3.org/1999/xhtml" schema-location="http://www.w3.org/2002/08/xhtml/xhtml1-transitional.xsd"/> -->
<xsl:output method="xhtml" encoding="UTF-8" indent="yes" omit-xml-declaration="yes" doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd" doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN" media-type="application/xhtml+xml"/>
<xsl:param name="ldh:base" as="xs:anyURI" static="yes"/>
<xsl:param name="ldh:absolutePath" as="xs:anyURI"/>
<xsl:param name="ldh:requestUri" as="xs:anyURI"/>
<xsl:param name="ac:endpoint" select="resolve-uri('sparql', $ldt:base)" as="xs:anyURI"/>
<xsl:param name="a:graphStore" select="resolve-uri('service', $ldt:base)" as="xs:anyURI"/> <!-- TO-DO: rename to ac:graphStore? -->
<xsl:param name="sd:endpoint" as="xs:anyURI?"/>
<xsl:param name="acl:agent" as="xs:anyURI?"/>
<xsl:param name="lapp:Application" as="document-node()?"/>
<xsl:param name="foaf:Agent" select="if ($acl:agent) then document(ac:document-uri($acl:agent)) else ()" as="document-node()?"/>
<xsl:param name="force-exclude-all-namespaces" select="true()"/>
<xsl:param name="ac:httpHeaders" as="xs:string"/>
<xsl:param name="ac:method" as="xs:string"/>
<xsl:param name="ac:uri" as="xs:anyURI"/>
<xsl:param name="ac:mode" as="xs:anyURI*"/> <!-- select="xs:anyURI('∾ReadMode')" -->
<xsl:param name="acl:mode" as="xs:anyURI*"/>
<xsl:param name="ldh:forShape" as="xs:anyURI?"/>
<xsl:param name="ldh:createGraph" select="false()" as="xs:boolean"/>
<xsl:param name="ldh:ajaxRendering" select="true()" as="xs:boolean"/> <!-- TO-DO: rename to ldhc:ajaxRendering? -->
<xsl:param name="ldhc:enableWebIDSignUp" as="xs:boolean"/>
<xsl:param name="google:clientID" as="xs:string?"/>
<xsl:param name="default-classes" as="map(xs:string, xs:anyURI)">
<xsl:map>
<xsl:map-entry key="'&lapp;Application'" select="resolve-uri('apps/', $ldt:base)"/>
<xsl:map-entry key="'&sd;Service'" select="resolve-uri('services/', $ldt:base)"/>
<xsl:map-entry key="'&nfo;FileDataObject'" select="resolve-uri('files/', $ldt:base)"/>
<xsl:map-entry key="'&sp;Construct'" select="resolve-uri('queries/', $ldt:base)"/>
<xsl:map-entry key="'&sp;Describe'" select="resolve-uri('queries/', $ldt:base)"/>
<xsl:map-entry key="'&sp;Select'" select="resolve-uri('queries/', $ldt:base)"/>
<xsl:map-entry key="'&sp;Ask'" select="resolve-uri('queries/', $ldt:base)"/>
<xsl:map-entry key="'&ldh;RDFImport'" select="resolve-uri('imports/', $ldt:base)"/>
<xsl:map-entry key="'&ldh;CSVImport'" select="resolve-uri('imports/', $ldt:base)"/>
<xsl:map-entry key="'&ldh;GraphChart'" select="resolve-uri('charts/', $ldt:base)"/>
<xsl:map-entry key="'&ldh;ResultSetChart'" select="resolve-uri('charts/', $ldt:base)"/>
</xsl:map>
</xsl:param>
<xsl:param name="location-mapping" as="map(xs:anyURI, xs:anyURI)">
<xsl:map>
<xsl:map-entry key="resolve-uri('static/com/atomgraph/linkeddatahub/xsl/bootstrap/2.3.2/translations.rdf', $ac:contextUri)" select="resolve-uri('static/com/atomgraph/linkeddatahub/xsl/bootstrap/2.3.2/translations.rdf', $ac:contextUri)"/>
<xsl:map-entry key="resolve-uri('static/com/atomgraph/linkeddatahub/xsl/bootstrap/2.3.2/http-statusCodes.rdf', $ac:contextUri)" select="resolve-uri('static/com/atomgraph/linkeddatahub/xsl/bootstrap/2.3.2/http-statusCodes.rdf', $ac:contextUri)"/>
<xsl:map-entry key="resolve-uri(ac:document-uri(xs:anyURI('∾')), $ac:contextUri)" select="ac:build-uri($ldt:base, map{ 'uri': string(ac:document-uri(xs:anyURI('∾'))), 'accept': 'application/rdf+xml' })"/>
<xsl:map-entry key="resolve-uri(ac:document-uri(xs:anyURI('&adm;')), $ac:contextUri)" select="ac:build-uri($ldt:base, map{ 'uri': string(ac:document-uri(xs:anyURI('&adm;'))), 'accept': 'application/rdf+xml' })"/>
<xsl:map-entry key="resolve-uri(ac:document-uri(xs:anyURI('&ldh;')), $ac:contextUri)" select="ac:build-uri($ldt:base, map{ 'uri': string(ac:document-uri(xs:anyURI('&ldh;'))), 'accept': 'application/rdf+xml' })"/>
<xsl:map-entry key="resolve-uri(ac:document-uri(xs:anyURI('&def;')), $ac:contextUri)" select="ac:build-uri($ldt:base, map{ 'uri': string(ac:document-uri(xs:anyURI('&def;'))), 'accept': 'application/rdf+xml' })"/>
<xsl:map-entry key="resolve-uri(ac:document-uri(xs:anyURI('&dh;')), $ac:contextUri)" select="ac:build-uri($ldt:base, map{ 'uri': string(ac:document-uri(xs:anyURI('&dh;'))), 'accept': 'application/rdf+xml' })"/>
<xsl:map-entry key="resolve-uri(ac:document-uri(xs:anyURI('&sp;')), $ac:contextUri)" select="ac:build-uri($ldt:base, map{ 'uri': string(ac:document-uri(xs:anyURI('&sp;'))), 'accept': 'application/rdf+xml' })"/>
<xsl:map-entry key="resolve-uri(ac:document-uri(xs:anyURI('&rdf;')), $ac:contextUri)" select="ac:build-uri($ldt:base, map{ 'uri': string(ac:document-uri(xs:anyURI('&rdf;'))), 'accept': 'application/rdf+xml' })"/>
</xsl:map>
</xsl:param>
<xsl:param name="explore-service-query" as="xs:string">
<![CDATA[SELECT DISTINCT ?type (COUNT(?s) AS ?count) (SAMPLE(?s) AS ?sample)
WHERE
{ { ?s a ?type }
UNION
{ GRAPH ?g
{ ?s a ?type }
}
}
GROUP BY ?type
ORDER BY DESC(COUNT(?s))
LIMIT 100
]]></xsl:param>
<!-- the query has to support services that do not belong to any app. Use type URIs because that is what triggers Varnish invalidation. -->
<xsl:variable name="app-query" as="xs:string">
DESCRIBE ?resource
WHERE
{ GRAPH ?graph
{
{ ?resource a <&lapp;Application> ;
<&ldt;base> ?base
}
UNION
{ ?resource a <&sd;Service> ;
<&sd;endpoint> ?endpoint
}
}
}
</xsl:variable>
<xsl:variable name="app-request-uri" select="ac:build-uri(resolve-uri('sparql', $ldt:base), map{ 'query': $app-query })" as="xs:anyURI"/>
<xsl:variable name="template-query" as="xs:string">
<![CDATA[
PREFIX ldh: <https://w3id.org/atomgraph/linkeddatahub#>
SELECT *
WHERE
{
$Type ldh:template ?content
}
]]>
<!-- VALUES $Type goes here -->
</xsl:variable>
<xsl:variable name="constraint-query" as="xs:string">
<![CDATA[
PREFIX ldh: <https://w3id.org/atomgraph/linkeddatahub#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sp: <http://spinrdf.org/sp#>
PREFIX spin: <http://spinrdf.org/spin#>
SELECT ?property
WHERE
{ $Type (rdfs:subClassOf)*/spin:constraint ?constraint .
?constraint a ldh:MissingPropertyValue ;
sp:arg1 ?property
}
]]>
<!-- VALUES $Type goes here -->
</xsl:variable>
<xsl:variable name="constructor-query" as="xs:string">
<![CDATA[
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sp: <http://spinrdf.org/sp#>
PREFIX spin: <http://spinrdf.org/spin#>
SELECT $Type ?constructor ?construct
WHERE
{ $Type (rdfs:subClassOf)*/spin:constructor ?constructor .
?constructor sp:text ?construct .
}
]]>
<!-- VALUES $Type goes here -->
</xsl:variable>
<xsl:variable name="shape-query" as="xs:string">
<![CDATA[
PREFIX sh: <http://www.w3.org/ns/shacl#>
DESCRIBE $Shape ?property
WHERE
{ $Shape sh:targetClass $Type
OPTIONAL
{ $Shape sh:property ?property }
}
]]>
<!-- VALUES $Type goes here -->
</xsl:variable>
<xsl:key name="resources-by-primary-topic" match="*[@rdf:about] | *[@rdf:nodeID]" use="foaf:primaryTopic/@rdf:resource"/>
<xsl:key name="violations-by-root" match="*[@rdf:about] | *[@rdf:nodeID]" use="spin:violationRoot/@rdf:resource | spin:violationRoot/@rdf:nodeID"/>
<xsl:key name="violations-by-value" match="*" use="ldh:violationValue/text()"/>
<xsl:key name="violations-by-focus-node" match="*" use="sh:focusNode/@rdf:resource | sh:focusNode/@rdf:nodeID"/>
<xsl:key name="resources-by-container" match="*[@rdf:about] | *[@rdf:nodeID]" use="sioc:has_parent/@rdf:resource | sioc:has_container/@rdf:resource"/>
<rdf:Description rdf:about="">
</rdf:Description>
<xsl:function name="ac:uri" as="xs:anyURI">
<xsl:sequence select="$ac:uri"/>
</xsl:function>
<xsl:function name="ldh:href" as="xs:anyURI">
<xsl:sequence select="$ldh:requestUri"/>
</xsl:function>
<!-- TITLE -->
<xsl:template match="rdf:RDF" mode="xhtml:Title">
<title>
<xsl:if test="$lapp:Application">
<xsl:value-of>
<xsl:apply-templates select="$lapp:Application//*[ldt:base/@rdf:resource = $ldt:base]" mode="ac:label"/>
</xsl:value-of>
<xsl:text> - </xsl:text>
</xsl:if>
<xsl:apply-templates mode="#current"/>
</title>
</xsl:template>
<xsl:template match="*[rdf:type/@rdf:resource = '&http;Response'][not(key('resources', ac:uri()))]" mode="xhtml:Title" priority="1">
<xsl:value-of>
<xsl:apply-templates select="." mode="ac:label"/>
</xsl:value-of>
</xsl:template>
<xsl:template match="*[@rdf:about = ac:uri()]" mode="xhtml:Title" priority="1">
<xsl:value-of>
<xsl:apply-templates select="." mode="ac:label"/>
</xsl:value-of>
</xsl:template>
<xsl:template match="*[*][@rdf:about] | *[*][@rdf:nodeID]" mode="xhtml:Title"/>
<!-- META -->
<xsl:template match="rdf:RDF | srx:sparql" mode="xhtml:Meta">
<meta name="viewport" content="width=device-width, initial-scale=1.0"/>
<meta name="og:url" content="{ac:uri()}"/>
<meta name="twitter:url" content="{ac:uri()}"/>
<xsl:for-each select="key('resources', ac:uri())">
<meta name="og:title" content="{ac:label(.)}"/>
<meta name="twitter:title" content="{ac:label(.)}"/>
<meta name="twitter:card" content="summary_large_image"/>
<xsl:if test="ac:description(.)">
<meta name="description" content="{ac:description(.)}"/>
<meta property="og:description" content="{ac:description(.)}"/>
<meta name="twitter:description" content="{ac:description(.)}"/>
</xsl:if>
<xsl:if test="ac:image(.)">
<meta property="og:image" content="{ac:image(.)}"/>
<meta name="twitter:image" content="{ac:image(.)}"/>
</xsl:if>
<xsl:for-each select="foaf:maker/@rdf:resource">
<xsl:if test="doc-available(ac:document-uri(.))">
<xsl:for-each select="key('resources', ., document(ac:document-uri(.)))">
<meta name="author" content="{ac:label(.)}"/>
</xsl:for-each>
</xsl:if>
</xsl:for-each>
</xsl:for-each>
<xsl:if test="$lapp:Application//*[ldt:base/@rdf:resource = $ldt:base]">
<meta property="og:site_name" content="{ac:label($lapp:Application//*[ldt:base/@rdf:resource = $ldt:base])}"/>
</xsl:if>
</xsl:template>
<!-- STYLE -->
<xsl:template match="rdf:RDF | srx:sparql" mode="xhtml:Style">
<xsl:param name="load-wymeditor" select="exists($foaf:Agent//@rdf:about)" as="xs:boolean"/>
<xsl:param name="load-yasqe" select="true()" as="xs:boolean"/>
<xsl:apply-imports/>
<link href="{resolve-uri('static/com/atomgraph/linkeddatahub/css/bootstrap.css', $ac:contextUri)}" rel="stylesheet" type="text/css"/>
<xsl:if test="$load-wymeditor">
<link href="{resolve-uri('static/com/atomgraph/linkeddatahub/js/wymeditor/skins/default/skin.css', $ac:contextUri)}" rel="stylesheet" type="text/css"/>
</xsl:if>
<xsl:if test="$load-yasqe">
<link href="{resolve-uri('static/css/yasqe.css', $ac:contextUri)}" rel="stylesheet" type="text/css"/>
</xsl:if>
</xsl:template>
<!-- SCRIPT -->
<xsl:template match="rdf:RDF | srx:sparql" mode="xhtml:Script">
<xsl:param name="client-stylesheet" select="resolve-uri('static/com/atomgraph/linkeddatahub/xsl/client.xsl.sef.json', $ac:contextUri)" as="xs:anyURI"/>
<xsl:param name="saxon-js-log-level" select="10" as="xs:integer"/>
<xsl:param name="load-wymeditor" select="not($ac:mode = ('∾ModalMode', '&ldht;InfoWindowMode'))" as="xs:boolean"/>
<xsl:param name="load-yasqe" select="not($ac:mode = ('∾ModalMode', '&ldht;InfoWindowMode'))" as="xs:boolean"/>
<xsl:param name="load-saxon-js" select="$ldh:ajaxRendering and not($ac:mode = ('∾ModalMode', '&ldht;InfoWindowMode'))" as="xs:boolean"/>
<xsl:param name="load-sparql-builder" select="not($ac:mode = ('∾ModalMode', '&ldht;InfoWindowMode'))" as="xs:boolean"/>
<xsl:param name="load-sparql-map" select="not($ac:mode = ('∾ModalMode', '&ldht;InfoWindowMode'))" as="xs:boolean"/>
<xsl:param name="load-google-charts" select="not($ac:mode = ('∾ModalMode', '&ldht;InfoWindowMode'))" as="xs:boolean"/>
<xsl:param name="output-schema-org" select="true()" as="xs:boolean"/>
<xsl:param name="location-mapping" select="$location-mapping" as="map(xs:anyURI, xs:anyURI)"/>
<!-- Web-Client scripts -->
<script type="text/javascript" src="{resolve-uri('static/js/jquery.min.js', $ac:contextUri)}" defer="defer"></script>
<script type="text/javascript" src="{resolve-uri('static/js/bootstrap.js', $ac:contextUri)}" defer="defer"></script>
<script type="text/javascript" src="{resolve-uri('static/com/atomgraph/client/js/UUID.js', $ac:contextUri)}" defer="defer"></script>
<!-- LinkedDataHub scripts -->
<script type="text/javascript" src="{resolve-uri('static/com/atomgraph/linkeddatahub/js/jquery.js', $ac:contextUri)}" defer="defer"></script>
<script type="text/javascript">
<![CDATA[
var baseUri = ]]><xsl:value-of select="'"' || $ldt:base || '"'"/><![CDATA[;
var absolutePath = ]]><xsl:value-of select="'"' || $ldh:absolutePath || '"'"/><![CDATA[;
var ontologyUri = ]]><xsl:value-of select="'"' || $ldt:ontology || '"'"/><![CDATA[;
var endpointUri = ]]><xsl:value-of select="if ($sd:endpoint) then '"' || $sd:endpoint || '"' else 'null'"/><![CDATA[;
var contextUri = ]]><xsl:value-of select="if ($ac:contextUri) then '"' || $ac:contextUri || '"' else 'null'"/><![CDATA[;
var agentUri = []]><xsl:value-of select="if ($acl:agent) then '"' || $acl:agent || '"' else 'null'"/><![CDATA[];
var accessModeUri = []]><xsl:value-of select="string-join(for $mode in $acl:mode return '"' || $mode || '"', ', ')"/><![CDATA[];
]]>
</script>
<xsl:if test="$load-wymeditor">
<script type="text/javascript" src="{resolve-uri('static/com/atomgraph/linkeddatahub/js/wymeditor/jquery.wymeditor.js', $ac:contextUri)}" defer="defer"></script>
</xsl:if>
<xsl:if test="$load-yasqe">
<script src="{resolve-uri('static/js/yasqe.js', $ac:contextUri)}" type="text/javascript"></script>
</xsl:if>
<xsl:if test="$load-saxon-js">
<script type="text/javascript" src="{resolve-uri('static/com/atomgraph/linkeddatahub/js/saxon-js/SaxonJS2.rt.js', $ac:contextUri)}" defer="defer"></script>
<script type="text/javascript">
<![CDATA[
window.onload = function() {
const locationMapping = [
]]>
<xsl:for-each select="map:keys($location-mapping)">
<xsl:text>{ name: "</xsl:text>
<xsl:value-of select="."/>
<xsl:text>", altName: "</xsl:text>
<xsl:value-of select="map:get($location-mapping, .)"/>
<xsl:text>" }</xsl:text>
<xsl:if test="position() != last()">
<xsl:text>,
</xsl:text>
</xsl:if>
</xsl:for-each>
<!--<xsl:variable name="ontology-imports" select="for $value in distinct-values(ldh:ontologyImports($ldt:ontology)) return xs:anyURI($value)" as="xs:anyURI*"/>
<xsl:if test="exists($ontology-imports)">
<xsl:text>,</xsl:text>
<xsl:for-each select="$ontology-imports">
<xsl:text>{ name: "</xsl:text>
<xsl:value-of select="ac:document-uri(.)"/>
<xsl:text>", altName: baseUri + "?uri=" + encodeURIComponent("</xsl:text>
<xsl:value-of select="ac:document-uri(.)"/>
<xsl:text>") + "&accept=" + encodeURIComponent("application/rdf+xml") }</xsl:text>
<xsl:if test="position() != last()">
<xsl:text>,
</xsl:text>
</xsl:if>
</xsl:for-each>
</xsl:if> -->
<![CDATA[
];
const docPromises = locationMapping.map(mapping => SaxonJS.getResource({location: mapping.altName, type: "xml"}));
const servicesRequestUri = "]]><xsl:value-of select="$app-request-uri"/><![CDATA[";
const stylesheetParams = {
"Q{https://w3id.org/atomgraph/client#}contextUri": contextUri, // servlet context URI
"Q{https://www.w3.org/ns/ldt#}base": baseUri,
"Q{https://www.w3.org/ns/ldt#}ontology": ontologyUri,
"Q{http://www.w3.org/ns/sparql-service-description#}endpoint": endpointUri,
"Q{https://w3id.org/atomgraph/linkeddatahub#}absolutePath": absolutePath,
"Q{http://www.w3.org/ns/auth/acl#}agent": agentUri,
"Q{http://www.w3.org/ns/auth/acl#}mode": accessModeUri,
"Q{}app-request-uri": servicesRequestUri
};
SaxonJS.getResource({location: servicesRequestUri, type: "xml", headers: { "Accept": "application/rdf+xml" } }).
then(resource => {
stylesheetParams["Q{https://w3id.org/atomgraph/linkeddatahub#}apps"] = resource;
return Promise.all(docPromises);
}, error => {
return Promise.all(docPromises);
}).
then(resources => {
const cache = {};
for (var i = 0; i < resources.length; i++) {
cache[locationMapping[i].name] = resources[i]
};
return SaxonJS.transform({
documentPool: cache,
stylesheetLocation: "]]><xsl:value-of select="$client-stylesheet"/><![CDATA[",
initialTemplate: "main",
logLevel: ]]><xsl:value-of select="$saxon-js-log-level"/><![CDATA[,
stylesheetParams: stylesheetParams
}, "async");
}).
catch(err => console.log("Transformation failed: " + err));
}
]]>
</script>
</xsl:if>
<xsl:if test="$load-sparql-builder">
<script type="text/javascript" src="{resolve-uri('static/com/atomgraph/linkeddatahub/js/SPARQLBuilder.js', $ac:contextUri)}" defer="defer"></script>
</xsl:if>
<xsl:if test="$load-sparql-map">
<link href="{resolve-uri('static/com/atomgraph/linkeddatahub/css/ol.css', $ac:contextUri)}" rel="stylesheet" type="text/css"></link>
<script type="text/javascript" src="{resolve-uri('static/com/atomgraph/linkeddatahub/js/ol.js', $ac:contextUri)}"></script>
</xsl:if>
<xsl:if test="$load-google-charts">
<script type="text/javascript" src="https://www.gstatic.com/charts/loader.js"></script>
<script type="text/javascript">
<![CDATA[
google.charts.load('current', {packages: ['corechart', 'table', 'timeline', 'map']});
]]>
</script>
</xsl:if>
<xsl:if test="$output-schema-org">
<xsl:variable name="rdf" as="element()?">
<xsl:apply-templates select="." mode="schema:BreadCrumbList"/>
</xsl:variable>
<xsl:if test="exists($rdf)">
<!-- output structured data: https://developers.google.com/search/docs/guides/intro-structured-data -->
<script type="application/ld+json">
<xsl:variable name="json-xml" as="element()">
<xsl:apply-templates select="$rdf" mode="ac:JSON-LD"/>
</xsl:variable>
<xsl:sequence select="xml-to-json($json-xml)"/>
</script>
</xsl:if>
</xsl:if>
</xsl:template>
<!-- NAVBAR -->
<xsl:template match="rdf:RDF | srx:sparql" mode="bs2:NavBar">
<div class="navbar navbar-fixed-top">
<div class="navbar-inner">
<div class="container-fluid">
<button class="btn btn-navbar">
<span class="icon-bar"></span>
<span class="icon-bar"></span>
<span class="icon-bar"></span>
</button>
<xsl:if test="$ldt:base">
<xsl:if test="not($ldt:base = $ac:contextUri)">
<a class="brand context" href="{resolve-uri('..', $ldt:base)}"/>
</xsl:if>
</xsl:if>
<xsl:apply-templates select="." mode="bs2:Brand"/>
<div id="collapsing-top-navbar" class="nav-collapse collapse" style="margin-left: 17%;">
<xsl:if test="$ldh:ajaxRendering">
<xsl:apply-templates select="." mode="bs2:SearchBar"/>
</xsl:if>
<xsl:apply-templates select="." mode="bs2:NavBarNavList"/>
</div>
</div>
</div>
<xsl:apply-templates select="." mode="bs2:ActionBar"/>
</div>
</xsl:template>
<xsl:template match="rdf:RDF | srx:sparql" mode="bs2:Brand">
<a class="brand" href="{$ldt:base}">
<xsl:if test="$lapp:Application//*[ldt:base/@rdf:resource = $ldt:base]/rdf:type/@rdf:resource = '&lapp;AdminApplication'">
<xsl:attribute name="class" select="'brand admin'"/>
</xsl:if>
<xsl:value-of>
<xsl:apply-templates select="$lapp:Application//*[ldt:base/@rdf:resource = $ldt:base]" mode="ac:label"/>
</xsl:value-of>
</a>
</xsl:template>
<!-- check if agent has access to the user endpoint by executing a dummy query ASK {} -->
<xsl:template match="rdf:RDF[doc-available(resolve-uri('sparql?query=ASK%20%7B%7D', $ldt:base))] | srx:sparql[doc-available(resolve-uri('sparql?query=ASK%20%7B%7D', $ldt:base))]" mode="bs2:SearchBar" priority="1">
<form action="" method="get" class="navbar-form pull-left" accept-charset="UTF-8" title="{ac:label(key('resources', 'search-title', document('translations.rdf')))}">
<div class="input-append">
<select id="search-service" name="service">
<option value="">
<xsl:value-of>
<xsl:text>[</xsl:text>
<xsl:apply-templates select="key('resources', 'sparql-service', document('translations.rdf'))" mode="ac:label"/>
<xsl:text>]</xsl:text>
</xsl:value-of>
</option>
</select>
<input type="text" id="uri" name="uri" class="input-xxlarge typeahead">
<xsl:if test="not(starts-with(ac:uri(), $ldt:base))">
<xsl:attribute name="value" select="ac:uri()"/>
</xsl:if>
</input>
<!-- placeholder used by the client-side typeahead -->
<ul id="ul-{generate-id()}" class="search-typeahead typeahead dropdown-menu" style="display: none"/>
<button type="submit">
<xsl:apply-templates select="key('resources', 'search', document('translations.rdf'))" mode="ldh:logo">
<xsl:with-param name="class" select="'btn btn-primary'"/>
</xsl:apply-templates>
</button>
</div>
</form>
</xsl:template>
<xsl:template match="*" mode="bs2:SearchBar"/>
<xsl:template match="rdf:RDF | srx:sparql" mode="bs2:ActionBarLeft">
<xsl:param name="id" as="xs:string?"/>
<xsl:param name="class" select="'span2'" as="xs:string?"/>
<xsl:param name="classes" select="for $class-uri in map:keys($default-classes) return key('resources', $class-uri, document(ac:document-uri($class-uri)))" as="element()*"/>
<div>
<xsl:if test="$id">
<xsl:attribute name="id" select="$id"/>
</xsl:if>
<xsl:if test="$class">
<xsl:attribute name="class" select="$class"/>
</xsl:if>
<xsl:apply-templates select="." mode="bs2:Create">
<xsl:with-param name="class" select="'btn-group pull-left'"/>
<xsl:with-param name="classes" select="$classes"/>
<xsl:with-param name="create-graph" select="true()"/>
</xsl:apply-templates>
<xsl:if test="$ldh:ajaxRendering">
<xsl:apply-templates select="." mode="bs2:AddData"/>
</xsl:if>
</div>
</xsl:template>
<xsl:template match="rdf:RDF | srx:sparql" mode="bs2:ActionBarMain">
<xsl:param name="id" as="xs:string?"/>
<xsl:param name="class" select="'span7'" as="xs:string?"/>
<div>
<xsl:if test="$id">
<xsl:attribute name="id" select="$id"/>
</xsl:if>
<xsl:if test="$class">
<xsl:attribute name="class" select="$class"/>
</xsl:if>
<div class="row-fluid">
<xsl:apply-templates select="." mode="bs2:BreadCrumbBar"/>
<div id="created-modified-date" class="span3">
<!-- placeholder for client.xsl callbacks -->
</div>
</div>
</div>
</xsl:template>
<xsl:template match="rdf:RDF | srx:sparql" mode="bs2:ActionBarRight">
<xsl:param name="id" as="xs:string?"/>
<xsl:param name="class" select="'span3'" as="xs:string?"/>
<div>
<xsl:if test="$id">
<xsl:attribute name="id" select="$id"/>
</xsl:if>
<xsl:if test="$class">
<xsl:attribute name="class" select="$class"/>
</xsl:if>
<xsl:apply-templates select="." mode="bs2:MediaTypeList"/>
<xsl:apply-templates select="." mode="bs2:NavBarActions"/>
</div>
</xsl:template>
<xsl:template match="rdf:RDF" mode="bs2:BreadCrumbBar">
<xsl:param name="id" select="'breadcrumb-nav'" as="xs:string?"/>
<xsl:param name="class" select="'span9'" as="xs:string?"/>
<div>
<xsl:if test="$id">
<xsl:attribute name="id" select="$id"/>
</xsl:if>
<xsl:if test="$class">
<xsl:attribute name="class" select="$class"/>
</xsl:if>
<!-- placeholder for client.xsl callbacks -->
<xsl:if test="not($ldh:ajaxRendering)">
<ul class="breadcrumb pull-left">
<!-- render breadcrumbs server-side -->
<xsl:apply-templates select="key('resources', ac:uri())" mode="bs2:BreadCrumbListItem"/>
</ul>
</xsl:if>
</div>
</xsl:template>
<xsl:template match="srx:sparql" mode="bs2:BreadCrumbBar"/>
<xsl:template match="rdf:RDF | srx:sparql" mode="bs2:NavBarNavList">
<xsl:if test="$foaf:Agent//@rdf:about">
<ul class="nav pull-right">
<li>
<xsl:if test="$ac:mode = '∾QueryEditorMode'">
<xsl:attribute name="class" select="'active'"/>
</xsl:if>
<a href="{ac:build-uri((), map{ 'mode': '∾QueryEditorMode' })}" class="query-editor">
<xsl:value-of>
<xsl:apply-templates select="key('resources', 'sparql-editor', document('translations.rdf'))" mode="ac:label"/>
</xsl:value-of>
</a>
</li>
<xsl:if test="doc-available($app-request-uri)">
<li>
<div class="btn-group">
<button class="btn dropdown-toggle" title="{ac:label(key('resources', 'application-list-title', document('translations.rdf')))}">
<xsl:apply-templates select="key('resources', 'applications', document('translations.rdf'))" mode="ldh:logo">
<xsl:with-param name="class" select="'btn dropdown-toggle'"/>
</xsl:apply-templates>
</button>
<ul class="dropdown-menu pull-right">
<xsl:variable name="apps" select="document($app-request-uri)" as="document-node()"/>
<xsl:for-each select="$apps//*[ldt:base/@rdf:resource]">
<xsl:sort select="ac:label(.)" order="ascending" lang="{$ldt:lang}"/>
<li>
<!-- <xsl:if test="$active">
<xsl:attribute name="class" select="'active'"/>
</xsl:if>-->
<a href="{ldt:base/@rdf:resource}" title="{ldt:base/@rdf:resource}">
<xsl:apply-templates select="." mode="ac:label"/>
</a>
</li>
</xsl:for-each>
</ul>
</div>
</li>
</xsl:if>
<li>
<xsl:apply-templates select="." mode="bs2:Settings"/>
</li>
<!-- overridden in acl/layout.xsl! TO-DO: extract into separate template -->
<li>
<div class="btn-group">
<button type="button" title="{ac:label($foaf:Agent//*[@rdf:about][1])}">
<xsl:apply-templates select="key('resources', '&foaf;Agent', document(ac:document-uri('&foaf;')))" mode="ldh:logo">
<xsl:with-param name="class" select="'btn dropdown-toggle'"/>
</xsl:apply-templates>
</button>
<ul class="dropdown-menu pull-right">
<li>
<xsl:for-each select="key('resources-by-type', '&foaf;Agent', $foaf:Agent)">
<xsl:apply-templates select="@rdf:about" mode="xhtml:Anchor"/>
</xsl:for-each>
</li>
</ul>
</div>
</li>
</ul>
</xsl:if>
<xsl:apply-templates select="." mode="bs2:SignUp"/>
</xsl:template>
<xsl:template match="rdf:RDF[not($foaf:Agent//@rdf:about)][$lapp:Application//rdf:type/@rdf:resource = '&lapp;EndUserApplication'] | srx:sparql[not($foaf:Agent//@rdf:about)][$lapp:Application//rdf:type/@rdf:resource = '&lapp;EndUserApplication']" mode="bs2:SignUp" priority="1">
<!-- resolve links against the base URI of LinkedDataHub and not of the current app, as we want signups to always go the root app -->
<xsl:param name="google-signup-uri" select="ac:build-uri(resolve-uri('admin/oauth2/authorize/google', $ldh:base), map{ 'referer': string(ac:uri()) })" as="xs:anyURI"/>
<xsl:param name="webid-signup-uri" select="resolve-uri('admin/sign%20up', $ldh:base)" as="xs:anyURI"/>
<xsl:param name="google-signup" select="exists($google:clientID)" as="xs:boolean"/>
<xsl:param name="webid-signup" select="$ldhc:enableWebIDSignUp" as="xs:boolean"/>
<xsl:if test="$google-signup or $webid-signup">
<p class="pull-right">
<xsl:if test="$google-signup">
<a class="btn btn-primary" href="{$google-signup-uri}">
<xsl:value-of>
<xsl:apply-templates select="key('resources', 'login-google', document('translations.rdf'))" mode="ac:label"/>
</xsl:value-of>
</a>
</xsl:if>
<xsl:if test="$webid-signup">
<a class="btn btn-primary" href="{if (not(starts-with($ldt:base, $ldh:base))) then ac:build-uri((), map{ 'uri': string($webid-signup-uri) }) else $webid-signup-uri}">
<xsl:value-of>
<xsl:apply-templates select="key('resources', 'sign-up', document('translations.rdf'))" mode="ac:label"/>
</xsl:value-of>
</a>
</xsl:if>
</p>
</xsl:if>
</xsl:template>
<xsl:template match="*" mode="bs2:SignUp"/>
<xsl:template match="*[ldt:base/@rdf:resource]" mode="bs2:AppListItem">
<xsl:param name="active" as="xs:boolean?"/>
<li>
<xsl:if test="$active">
<xsl:attribute name="class" select="'active'"/>
</xsl:if>
<a href="{ldt:base/@rdf:resource[starts-with(., $ac:contextUri)]}" title="{ldt:base/@rdf:resource[starts-with(., $ac:contextUri)]}">
<xsl:value-of>
<xsl:apply-templates select="." mode="ac:label"/>
</xsl:value-of>
</a>
</li>
</xsl:template>
<!-- BODY -->
<xsl:template match="rdf:RDF[key('resources', ac:uri())][$ac:mode = '&ldht;InfoWindowMode']" mode="xhtml:Body" priority="1">
<body>
<div> <!-- SPARQLMap renders the first child of <body> as InfoWindow -->
<xsl:apply-templates select="." mode="bs2:Block">
<xsl:with-param name="display" select="true()" tunnel="yes"/>
</xsl:apply-templates>
</div>
</body>
</xsl:template>
<xsl:template match="rdf:RDF[key('resources', ac:uri())][$ac:mode = '&ldht;ObjectMode']" mode="xhtml:Body" priority="2">
<body class="embed">
<div>
<xsl:apply-templates select="." mode="bs2:Object">
<xsl:with-param name="show-controls" select="false()" tunnel="yes"/>
</xsl:apply-templates>
</div>
</body>
</xsl:template>
<xsl:template match="rdf:RDF | srx:sparql" mode="xhtml:Body">
<body>
<div id="visible-body">
<xsl:apply-templates select="." mode="bs2:NavBar"/>
<xsl:apply-templates select="." mode="bs2:ContentBody"/>
<xsl:apply-templates select="." mode="bs2:Footer"/>
</div>
<xsl:apply-templates select="." mode="bs2:DocumentTree"/>
</body>
</xsl:template>
<xsl:template match="rdf:RDF" mode="bs2:ContentBody">
<xsl:param name="id" select="'content-body'" as="xs:string?"/>
<xsl:param name="class" select="'container-fluid'" as="xs:string?"/>
<xsl:param name="about" select="ac:uri()" as="xs:anyURI?"/>
<xsl:param name="classes" select="for $class-uri in map:keys($default-classes) return key('resources', $class-uri, document(ac:document-uri($class-uri)))" as="element()*"/>
<xsl:param name="doc-types" select="key('resources', ac:uri())/rdf:type/@rdf:resource[ . = ('&def;Root', '&dh;Container', '&dh;Item')]" as="xs:anyURI*"/>
<xsl:param name="content-values" select="if (exists($doc-types) and doc-available(resolve-uri('ns?query=ASK%20%7B%7D', $ldt:base))) then (ldh:query-result(map{}, resolve-uri('ns', $ldt:base), $template-query || ' VALUES $Type { ' || string-join(for $type in $doc-types return '<' || $type || '>', ' ') || ' }')//srx:binding[@name = 'content']/srx:uri/xs:anyURI(.)) else ()" as="xs:anyURI*"/>
<xsl:param name="has-content" select="key('resources', key('resources', ac:uri())/rdf:*[starts-with(local-name(), '_')]/@rdf:resource) or exists($content-values)" as="xs:boolean"/>
<div>
<xsl:if test="$id">
<xsl:attribute name="id" select="$id"/>
</xsl:if>
<xsl:if test="$class">
<xsl:attribute name="class" select="$class"/>
</xsl:if>
<xsl:if test="$about">
<xsl:attribute name="about" select="$about"/>
</xsl:if>
<xsl:apply-templates select="." mode="bs2:ModeTabs">
<xsl:with-param name="has-content" select="$has-content"/>
<xsl:with-param name="active-mode" select="$ac:mode"/>
<xsl:with-param name="forClass" select="$ac:forClass"/>
<xsl:with-param name="ajax-rendering" select="$ldh:ajaxRendering"/>
</xsl:apply-templates>
<xsl:choose>
<!-- error responses always rendered in bs2:Row mode, no matter what $ac:mode specifies -->
<xsl:when test="key('resources-by-type', '&http;Response') and not(key('resources-by-type', '&spin;ConstraintViolation')) and not(key('resources-by-type', '&sh;ValidationResult'))">
<xsl:apply-templates select="." mode="bs2:Row">
<xsl:with-param name="template-query" select="$template-query" tunnel="yes"/>
<xsl:sort select="ac:label(.)"/>
</xsl:apply-templates>
</xsl:when>
<xsl:when test="$ac:forClass and $ac:method = 'GET'">
<xsl:variable name="constructor" as="document-node()">
<xsl:apply-templates select="." mode="ldh:Constructor">
<xsl:with-param name="forClass" select="$ac:forClass"/>
<xsl:with-param name="createGraph" select="$ldh:createGraph"/>
<xsl:with-param name="constructor-query" select="$constructor-query"/>
</xsl:apply-templates>
</xsl:variable>
<xsl:choose>
<xsl:when test="$ac:mode = '∾ModalMode'">
<xsl:apply-templates select="$constructor" mode="bs2:ModalForm">
<xsl:with-param name="constructor-query" select="$constructor-query" tunnel="yes"/>
<xsl:with-param name="constraint-query" select="$constraint-query" tunnel="yes"/>
<xsl:with-param name="shape-query" select="$shape-query" tunnel="yes"/>
<xsl:sort select="ac:label(.)"/>
</xsl:apply-templates>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates select="$constructor" mode="bs2:RowForm">
<xsl:with-param name="classes" select="$classes"/>
<xsl:with-param name="constructor-query" select="$constructor-query" tunnel="yes"/>
<xsl:with-param name="constraint-query" select="$constraint-query" tunnel="yes"/>
<xsl:with-param name="shape-query" select="$shape-query" tunnel="yes"/>
<xsl:sort select="ac:label(.)"/>
</xsl:apply-templates>
</xsl:otherwise>
</xsl:choose>
</xsl:when>
<xsl:when test="$ldh:forShape and $ac:method = 'GET'">
<xsl:variable name="shapes" select="ldh:query-result(map{ '$Shape': $ldh:forShape }, resolve-uri('ns', $ldt:base), $shape-query)" as="document-node()"/>
<xsl:variable name="constructor" as="document-node()">
<xsl:apply-templates select="$shapes" mode="ldh:Shape"/>
</xsl:variable>
<xsl:choose>
<xsl:when test="$ac:mode = '∾ModalMode'">
<xsl:apply-templates select="ldh:reserialize($constructor)" mode="bs2:ModalForm">
<xsl:with-param name="constructor-query" select="$constructor-query" tunnel="yes"/>
<xsl:with-param name="constraint-query" select="$constraint-query" tunnel="yes"/>
<xsl:with-param name="shape-query" select="$shape-query" tunnel="yes"/>
<xsl:sort select="ac:label(.)"/>
</xsl:apply-templates>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates select="ldh:reserialize($constructor)" mode="bs2:RowForm">
<xsl:with-param name="classes" select="$classes"/>
<xsl:with-param name="constructor-query" select="$constructor-query" tunnel="yes"/>
<xsl:with-param name="constraint-query" select="$constraint-query" tunnel="yes"/>
<xsl:with-param name="shape-query" select="$shape-query" tunnel="yes"/>
<xsl:sort select="ac:label(.)"/>
</xsl:apply-templates>
</xsl:otherwise>
</xsl:choose>
</xsl:when>
<!-- check if the current document has content or its class has content -->
<xsl:when test="(empty($ac:mode) and $has-content) or $ac:mode = '&ldh;ContentMode'">
<xsl:apply-templates select="." mode="ldh:ContentList"/>
<xsl:for-each select="$content-values">
<xsl:if test="doc-available(ac:document-uri(.))">
<xsl:apply-templates select="key('resources', ., document(ac:document-uri(.)))" mode="bs2:RowContent"/>
</xsl:if>
</xsl:for-each>
</xsl:when>
<xsl:when test="$ac:mode = '∾MapMode'">
<xsl:apply-templates select="." mode="bs2:Map">
<xsl:with-param name="id" select="generate-id() || '-map-canvas'"/>
<xsl:sort select="ac:label(.)"/>
</xsl:apply-templates>
</xsl:when>
<xsl:when test="$ac:mode = '∾ChartMode'">
<xsl:apply-templates select="." mode="bs2:Chart">
<xsl:with-param name="id" select="generate-id() || '-chart-canvas'"/>
<xsl:with-param name="show-save" select="false()"/>
<xsl:sort select="ac:label(.)"/>
</xsl:apply-templates>
</xsl:when>
<xsl:when test="$ac:mode = '∾GraphMode'">
<xsl:apply-templates select="." mode="bs2:Graph">
<xsl:sort select="ac:label(.)"/>
</xsl:apply-templates>
</xsl:when>
<xsl:when test="$ac:mode = '∾EditMode' and $ac:mode = '∾ModalMode'">
<xsl:apply-templates select="." mode="bs2:ModalForm">
<xsl:with-param name="constructor-query" select="$constructor-query" tunnel="yes"/>
<xsl:with-param name="constraint-query" select="$constraint-query" tunnel="yes"/>
<xsl:with-param name="shape-query" select="$shape-query" tunnel="yes"/>
<xsl:sort select="ac:label(.)"/>
</xsl:apply-templates>
</xsl:when>
<xsl:when test="$ac:mode = '∾EditMode'">
<xsl:apply-templates select="." mode="bs2:RowForm">
<xsl:with-param name="classes" select="$classes"/>
<xsl:with-param name="constructor-query" select="$constructor-query" tunnel="yes"/>
<xsl:with-param name="constraint-query" select="$constraint-query" tunnel="yes"/>
<xsl:with-param name="shape-query" select="$shape-query" tunnel="yes"/>
<xsl:sort select="ac:label(.)"/>
</xsl:apply-templates>
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates select="." mode="bs2:Row">
<xsl:sort select="ac:label(.)"/>
</xsl:apply-templates>
</xsl:otherwise>
</xsl:choose>
</div>
</xsl:template>
<!-- don't show document-level tabs if the response returned an error or if we're in EditMode -->
<xsl:template match="rdf:RDF[key('resources-by-type', '&http;Response')] | rdf:RDF[$ac:forClass or $ac:mode = '∾EditMode']" mode="bs2:ModeTabs" priority="1"/>
<xsl:template match="srx:sparql" mode="bs2:ContentBody">
<xsl:param name="id" select="'content-body'" as="xs:string?"/>
<xsl:param name="class" select="'container-fluid'" as="xs:string?"/>
<xsl:param name="about" select="ac:uri()" as="xs:anyURI?"/>
<div>
<xsl:if test="$id">
<xsl:attribute name="id" select="$id"/>
</xsl:if>
<xsl:if test="$class">
<xsl:attribute name="class" select="$class"/>
</xsl:if>
<xsl:if test="$about">
<xsl:attribute name="about" select="$about"/>
</xsl:if>
<xsl:apply-templates select="." mode="xhtml:Table"/>
</div>
</xsl:template>
<!-- only lookup resource locally using DESCRIBE if it's external (not relative to the app's base URI) and the agent is authenticated -->
<xsl:template match="*[*][@rdf:about = ac:uri()][not(starts-with(@rdf:about, $ldt:base))][$foaf:Agent//@rdf:about]" mode="bs2:PropertyList">
<xsl:param name="endpoint" select="($sd:endpoint, $ac:endpoint)[1]" as="xs:anyURI"/>
<xsl:param name="property-uris" select="distinct-values(*/concat(namespace-uri(), local-name()))" as="xs:anyURI*"/>
<xsl:param name="property-metadata" select="ldh:send-request(resolve-uri('ns', $ldt:base), 'POST', 'application/sparql-query', 'DESCRIBE ' || string-join(for $uri in distinct-values(/rdf:RDF/*/*/concat(namespace-uri(), local-name())) return '<' || $uri || '>', ' '), map{ 'Accept': 'application/rdf+xml' })" as="document-node()"/>
<xsl:variable name="local-doc" select="ldh:query-result(map{}, $endpoint, 'DESCRIBE <' || @rdf:about || '>')" as="document-node()"/>
<xsl:variable name="original-doc" as="document-node()">
<xsl:try>
<!-- try loading resource by deferencing its URI -->
<xsl:variable name="full-doc" select="document(ac:build-uri($ldt:base, map{ 'uri': string(ac:document-uri(@rdf:about)), 'accept': 'application/rdf+xml' }))" as="document-node()"/>
<xsl:document>
<rdf:RDF>
<xsl:copy-of select="key('resources', @rdf:about, $full-doc)"/>
</rdf:RDF>
</xsl:document>
<!-- fallback to the $local-doc -->
<xsl:catch>
<xsl:sequence select="$local-doc"/>
</xsl:catch>
</xsl:try>
</xsl:variable>
<xsl:variable name="triples-original" as="map(xs:string, element())">
<xsl:map>
<xsl:for-each select="$original-doc/rdf:RDF/rdf:Description/*">
<xsl:map-entry key="concat(../@rdf:about, '|', ../@rdf:nodeID, '|', namespace-uri(), local-name(), '|', @rdf:resource, @rdf:nodeID, if (text() castable as xs:float) then xs:float(text()) else text(), '|', @rdf:datatype, @xml:lang)" select="."/>
</xsl:for-each>
</xsl:map>
</xsl:variable>
<xsl:variable name="triples-local" as="map(xs:string, element())">
<xsl:map>
<xsl:for-each select="$local-doc/rdf:RDF/rdf:Description/*">
<xsl:map-entry key="concat(../@rdf:about, '|', ../@rdf:nodeID, '|', namespace-uri(), local-name(), '|', @rdf:resource, @rdf:nodeID, if (text() castable as xs:float) then xs:float(text()) else text(), '|', @rdf:datatype, @xml:lang)" select="."/>
</xsl:for-each>
</xsl:map>
</xsl:variable>
<xsl:variable name="properties-original" select="for $triple-key in ac:value-except(map:keys($triples-original), map:keys($triples-local)) return map:get($triples-original, $triple-key)" as="element()*"/>
<xsl:if test="exists($properties-original)">
<div>
<h2 class="nav-header btn">
<xsl:value-of>
<xsl:apply-templates select="key('resources', 'from-origin', document('translations.rdf'))" mode="ac:label"/>