-
Notifications
You must be signed in to change notification settings - Fork 9
/
starfield.asm
1420 lines (1150 loc) · 24 KB
/
starfield.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
FIELD_NUMFRAMES = 1800
include "../framework/hardware.i"
include "../framework/framework.i"
include "../launcher/timings.asm"
ifnd _DEMO
include "../framework/parttester.asm"
endc // _DEMO
section "field_code",code
entrypoint:
move.l a6,fw_jumptable
bsr.w field_init
bsr.w field_page
move.w #TIME_STARFIELD_START,d0
move.l fw_jumptable,a6
jsr WAITFORFRAME(a6)
move.l #field_copperlist,a0
move.l #field_irq,a1
move.l fw_jumptable,a6
jsr SETCOPPER(a6)
jsr GETFRAME(a6)
addi.w #FIELD_NUMFRAMES,d0
move.w d0,field_endframe
field_main:
;move.w #$0008,$dff180
bsr.w field_clear
bsr.w field_plot
bsr.w field_fadecol
bsr.w field_page
bsr.w field_movesprites
bsr.w field_updatefadespr
bsr.w field_updateline
;move.w #$000,$dff180
;bsr.w vsync
.sync:
tst.w field_sync
beq.b .sync
clr.w field_sync
btst #$06,$bfe001
beq.b field_end
move.w field_endframe,d0
move.l fw_jumptable(pc),a6
jsr ISFRAMEOVER(a6)
bpl.b field_main
field_end:
move.l fw_jumptable,a6
jsr SETBASECOPPER(a6)
move.w #$0020,$dff096 ;turn off sprite dma
rts
cnop 0,4
fw_jumptable:
dc.l 0
field_endframe:
dc.w 0
;--------------------------------------------------------------------
field_init:
bsr.w field_initpal
bsr.w field_initrnd
bsr.w field_initfield
bsr.w field_initfade
bsr.w field_gencode
bsr.w field_convexptab
bsr.w field_convlogtab
bsr.w field_inittexts
moveq #0,d0
bsr.w field_settext
lea field_sintab,a0
lea $800(a0),a1
move.l a1,a2
lea $1000(a0),a3
move.l a3,a4
move.w #$1ff,d7
.sl0:
move.w (a0)+,d0
move.w d0,-(a1)
move.w d0,(a4)+
neg.w d0
move.w d0,(a2)+
move.w d0,-(a3)
dbra d7,.sl0
lea $dff1a0,a2
moveq #16-1,d7
.sl1:
clr.w (a2)+
dbra d7,.sl1
bsr.w initsprites
rts
;--------------------------------------------------------------------
initsprites:
lea field_satellite,a0
lea field_sprites,a1
moveq #8-1,d7
.l1:
move.l (a1)+,a2
addq #4,a2
moveq #64*2-1,d6
.l2:
move.w (a0)+,(a2)+
dbra d6,.l2
dbra d7,.l1
rts
;--------------------------------------------------------------------
field_convexptab:
lea field_exptabcomp,a0
lea field_exptabcompend-2,a6
lea field_exptabx,a1
lea field_exptaby,a2
move.l #$1fffc,d5
.l0:
move.w (a0)+,d0 ;x1
move.w (a0)+,d1 ;y1
move.l (a0)+,d3 ;ystep
move.w (a0),d2 ;x2
subq #1,d2
sub.w d0,d2 ;dx=x2-x1
swap d1
move.w #$8000,d1
.l1:
move.l d1,d0
swap d0
move.w d0,d4
addi.w #128,d4
bpl.b .cliptop
moveq #0,d4
.cliptop:
cmpi.w #256,d4
blt.b .clipbottom
moveq #0,d4
.clipbottom:
addi.w #160,d0
bpl.b .clipleft
moveq #0,d0
.clipleft:
cmpi.w #320,d0
blt.b .clipright
moveq #0,d0
.clipright:
move.w d0,d6
not.w d0
lsr.w #3,d6
lsl.w #6,d4
move.l d5,d7
lsr.l #1,d7
andi.w #$fffc,d7
addq #2,d7
move.w d0,(a1,d7.w)
move.w d4,(a2,d7.w)
subq #2,d7
move.w d6,(a1,d7.w)
move.w d4,(a2,d7.w)
subq.l #4,d5
add.l d3,d1
dbra d2,.l1
cmp.l a0,a6
bne.b .l0
.end:
rts
;--------------------------------------------------------------------
field_convlogtab:
lea field_logtabcomp,a0
lea field_logtab,a1
lea field_logtabcompend-2,a6
moveq #$0,d5
.l0:
move.w (a0)+,d0 ;x1
move.w (a0)+,d1 ;y1
move.l (a0)+,d3 ;ystep
move.w (a0),d2 ;x2
subq #1,d2
sub.w d0,d2 ;dx=x2-x1
swap d1
move.w #$8000,d1
.l1:
move.l d1,d0
swap d0
add.w d0,d0
andi.w #$fffc,d0
move.w d0,(a1,d5.w)
addq #2,d5
add.l d3,d1
dbra d2,.l1
cmp.l a0,a6
bne.b .l0
.end:
rts
;--------------------------------------------------------------------
field_initpal:
lea $dff180,a1
clr.w d0
moveq #8-1,d7
.l0:
move.w d0,(a1)+
dbra d7,.l0
rts
;--------------------------------------------------------------------
field_initrnd:
lea field_rndtab,a0
move.l #12345678,d0
move.w #NUMPLOTS*3-1,d7
.l0:
divu.w #4433,d0
move.w d0,(a0)+
dbra d7,.l0
rts
;--------------------------------------------------------------------
field_initfield:
lea field_rndtab,a0
lea field_points,a1
move.w #NUMPLOTS-1,d7
.l0:
move.w (a0)+,d0
andi.w #$3f,d0
cmpi.w #$20,d0
bne.b .nocenter ;if the plot in x is directly in the center, move it 1 to the right. otherwise we only get a blinking dot in the first phase.
addq #1,d0
.nocenter:
add.w d0,d0
move.w (a0)+,d1
andi.w #$3f,d1
add.w d1,d1
move.w (a0)+,d2
andi.w #$3f,d2
add.w d2,d2
move.w d0,(a1)+
move.w d1,(a1)+
move.w d2,(a1)+
dbra d7,.l0
rts
;--------------------------------------------------------------------
field_gencode:
lea field_plotcode,a0
lea field_points,a3
move.w #NUMPLOTS-1,d7
.l0:
move.l a0,a2
lea .template,a1
moveq #(.templateend-.template)/2-1,d6
.l1:
move.w (a1)+,(a0)+
dbra d6,.l1
movem.w (a3)+,d0-d2
move.w d0,d3
move.w d1,d4
move.w d2,d5
add.w d3,d3
add.w d4,d4
add.w d5,d5
addi.w #256*0,d3
addi.w #256*3,d4
addi.w #256*6,d5
move.w d3,(.off1-.template)+2(a2)
move.w d4,(.off2-.template)+2(a2)
move.w d5,(.off3-.template)+2(a2)
move.w d0,d3
move.w d1,d4
move.w d2,d5
addi.w #256*2,d3
addi.w #256*5,d4
addi.w #256*8,d5
move.w d3,(.off4-.template)+2(a2)
move.w d4,(.off5-.template)+2(a2)
move.w d5,(.off6-.template)+2(a2)
dbra d7,.l0
move.w #$4e75,(a0)+ ;rts
rts
FIELD_PLOTCODESIZE = .templateend-.template
.template:
.off1:
move.l 1234(a1),d0
.off2:
add.l 1234(a1),d0
.off3:
add.l 1234(a1),d0
.off4:
move.w 1234(a1),d2
.off5:
add.w 1234(a1),d2
.off6:
add.w 1234(a1),d2
move.w (a2,d2.w),d5 ; -log(z)
move.w d5,d3 ; -log(z)
sub.w (a2,d0.w),d5 ; +=log(x)
swap d0
and.w d1,d0
sub.w (a2,d0.w),d3 ; +=log(y)
movem.w (a5,d5.w),d0/d5
add.w (a3,d3.w),d0
and.w d7,d2
add.w d2,d0
bset.b d5,(a6,d0.l)
.templateend:
;--------------------------------------------------------------------
cnop 0,4
field_coppermuxs:
dc.l field_coppermux1
dc.l field_coppermux2
dc.l field_coppermux3
dc.l field_coppermux4
dc.l field_coppermux5
dc.l field_coppermux6
dc.l field_coppermux7
dc.l field_coppermux7
field_text:
dc.b 0," axis "
dc.b 8," faker "
dc.b 8," yazoo "
dc.b 8," alien "
dc.b 0," nytrik "
dc.b 8," fanta "
dc.b 0," "
cnop 0,2
field_settext:
lea field_copperjmp+2,a0
lea field_coppermuxs(pc),a1
move.l (a1,d0.w),d0
cmp.l field_coppermux7,d0
move.w d0,4(a0)
swap d0
move.w d0,(a0)
rts
;--------------------------------------------------------------------
cnop 0,4
texpoi:
dc.l field_text
field_inittexts:
lea field_coppermux1,a0
bsr.w field_inittext
lea field_coppermux2,a0
bsr.w field_inittext
lea field_coppermux3,a0
bsr.w field_inittext
lea field_coppermux4,a0
bsr.w field_inittext
lea field_coppermux5,a0
bsr.w field_inittext
lea field_coppermux6,a0
bsr.w field_inittext
lea field_coppermux7,a0
lea field_sprites,a1
lea field_satpal,a2
move.w #$0120,d0
moveq #8-1,d7
.l0:
move.l (a1)+,d1
move.w d0,(a0)+
addq #2,d0
swap d1
move.w d1,(a0)+
move.w d0,(a0)+
addq #2,d0
swap d1
move.w d1,(a0)+
dbra d7,.l0
move.w #$01a0,d0
moveq #16-1,d7
.l1:
move.w d0,(a0)+
move.w (a2)+,(a0)+
addq #2,d0
dbra d7,.l1
move.w #$0096,(a0)+
move.w #$8020,(a0)+ ;turn on sprite dma
move.l #$ffdffffe,(a0)+ ; wait line 256
move.l #$280ffffe,(a0)+ ; wait line 296
move.l #$009c8010,(a0)+ ; start irq
move.l #$fffffffe,(a0)+ ; end coplist
rts
;--------------------------------------------------------------------
sprcenter = $9d8c
sprstep = 16
field_inittext:
lea field_font-12,a1 ;correctpointer by 2 lines, because we dont display the first 2 lines
move.l #$990ffffe,(a0)+
move.l #$010a0000,(a0)+
move.l #$9cd7fffe,d0
moveq #35-1,d7
.l0:
move.l d0,(a0)+
move.l texpoi(pc),a2
moveq #0,d2
move.b (a2)+,d2
move.w #$0140,d1
add.w #sprcenter-sprstep*4+sprstep/2,d2
moveq #sprstep,d5
cmpi.w #32,d7
blt.b .fix ;hide the first 2 lines of the sprites, because the display only dma-trash
move.w #$9dfc,d2
moveq #0,d5
.fix:
moveq #0,d4
moveq #8-1,d6
.l1:
move.b (a2),d4
andi.w #$1f,d4
mulu.w #34*8,d4
add.w d3,d4
move.w d1,(a0)+
addq #4,d1
move.w d2,(a0)+
move.w d1,(a0)+
addq #2,d1
move.w (a1,d4.w),(a0)+
move.w d1,(a0)+
addq #2,d1
move.w 2(a1,d4.w),(a0)+
eori.w #$88,d3
btst #0,d6
bne.b .l2
add.w d5,d2
addq #1,a2
.l2:
dbra d6,.l1
addq #4,a1
move.w #$0140,d1
moveq #0,d3
moveq #8-1,d6
.l3:
move.b (a2),d4
andi.w #$1f,d4
mulu.w #34*8,d4
add.w d3,d4
move.w d1,(a0)+
addq #4,d1
move.w d2,(a0)+
move.w d1,(a0)+
addq #2,d1
move.w (a1,d4.w),(a0)+
move.w d1,(a0)+
addq #2,d1
move.w 2(a1,d4.w),(a0)+
eori.w #$88,d3
btst #0,d6
bne.b .l4
add.w d5,d2
addq #1,a2
.l4:
dbra d6,.l3
addi.l #$01000000,d0
dbra d7,.l0
move.l #$c50ffffe,(a0)+
move.l #$010affd8,(a0)+
move.l #$ffdffffe,(a0)+ ; wait line 256
move.l #$280ffffe,(a0)+ ; wait line 296
move.l #$009c8010,(a0)+ ; start irq
move.l #$fffffffe,(a0)+ ; end coplist
add.l #9,texpoi
rts
;--------------------------------------------------------------------
field_initfade:
lea field_fadedat,a1
moveq #1,d7
.l0:
lea field_sprpal,a0
moveq #16-1,d6
.l1:
move.w (a0)+,d0
move.w d0,d1
move.w d0,d2
andi.w #$f00,d0
andi.w #$0f0,d1
andi.w #$00f,d2
mulu.w d7,d0
mulu.w d7,d1
mulu.w d7,d2
lsr.w #4,d0
lsr.w #4,d1
lsr.w #4,d2
andi.w #$f00,d0
andi.w #$0f0,d1
andi.w #$00f,d2
or.w d1,d0
or.w d2,d0
move.w d0,(a1)+
dbra d6,.l1
addq #1,d7
cmpi.w #17,d7
bne.b .l0
rts
;--------------------------------------------------------------------
field_clear:
move.l field_screens+0,a0
move.l fw_jumptable,a6
jsr BLTWAIT(a6)
lea BLTBASE,a6
move.w #$ffff,BLTAFWM(a6)
move.w #$ffff,BLTAFWM(a6)
clr.w BLTADAT(a6)
move.w #24,BLTDMOD(a6)
move.l a0,BLTDPTR(a6)
move.l #$01f00000,BLTCON0(a6)
move.w #$8014,BLTSIZE(a6)
;bsr.w bltwait
rts
;--------------------------------------------------------------------
NUMPLOTS = 470
tf = 8000
cnop 0,2
field_frame:dc.w 0
field_rx: dc.w $00
field_ry: dc.w $00
field_rz: dc.w $00
field_stepx:dc.w 0
field_stepy:dc.w 0
field_stepz:dc.w 0
field_z: dc.w 0
field_tmps: ds.w 3
field_mat: ds.w 9
field_plot:
addq.w #1,field_frame
move.w field_frame,d0
cmpi.w #256,d0
bne.b .noevent1
move.w #$8,field_stepz
.noevent1:
cmpi.w #512,d0
bne.b .noevent2
move.w #$2,field_stepx
move.w #$4,field_stepy
.noevent2:
cmpi.w #1365,d0
bne.b .noevent3
clr.w field_stepx
clr.w field_stepy
clr.w field_stepz
.noevent3:
move.w field_z(pc),d0
subq #2,d0
andi.w #$7e,d0
move.w d0,field_z
move.w field_rx(pc),d0
add.w field_stepx(pc),d0
andi.w #$ffe,d0
move.w d0,field_rx
move.w field_ry(pc),d1
add.w field_stepy(pc),d1
andi.w #$ffe,d1
move.w d1,field_ry
move.w field_rz(pc),d2
add.w field_stepz(pc),d2
andi.w #$ffe,d2
move.w d2,field_rz
lea field_sintab,a0
lea field_sintab+$400,a1
lea field_tmps,a2
lea field_mat,a3
move.w (a0,d0.w),d3 ;sx
move.w (a1,d0.w),d0 ;cx
move.w (a0,d1.w),d4 ;sy
move.w (a1,d1.w),d1 ;cy
move.w (a0,d2.w),d5 ;sz
move.w (a1,d2.w),d2 ;cz
move.w d4,d6
muls.w d3,d6
lsl.l #2,d6
swap d6
move.w d6,0(a2) ;sx*sy
move.w d0,d6
muls.w d5,d6
lsl.l #2,d6
swap d6
move.w d6,2(a2) ;cx*sz
move.w d0,d6
muls.w d2,d6
lsl.l #2,d6
swap d6
move.w d6,4(a2) ;cx*cz
move.w d1,d6
muls.w d2,d6
lsl.l #1,d6
swap d6
move.w d6,0(a3) ;cy*cz
move.w d1,d6
muls.w d5,d6
lsl.l #1,d6
swap d6
move.w d6,2(a3) ;cy*sz
move.w d4,d6
asr.w #1,d6
move.w d6,4(a3) ;sy
move.w 0(a2),d6
muls.w d2,d6
lsl.l #2,d6
swap d6
neg.w d6
sub.w 2(a2),d6
asr.w #1,d6
move.w d6,6(a3) ;-a*cz-b
move.w 0(a2),d6
muls.w d5,d6
lsl.l #2,d6
swap d6
neg.w d6
add.w 4(a2),d6
asr.w #1,d6
move.w d6,8(a3) ;-a*sz+c
move.w d3,d6
muls.w d1,d6
lsl.l #1,d6
swap d6
move.w d6,10(a3) ;sx*cy
move.w 4(a2),d6
muls.w d4,d6
move.w d3,d7
muls.w d5,d7
sub.l d7,d6
lsl.l #1,d6
swap d6
move.w d6,12(a3) ;c*sy-sx*sz
move.w 2(a2),d6
muls.w d4,d6
move.w d3,d7
muls.w d2,d7
add.l d7,d6
lsl.l #1,d6
swap d6
move.w d6,14(a3) ;b*sy+sx*cz
move.w d0,d6
muls.w d1,d6
lsl.l #1,d6
swap d6
neg.w d6
move.w d6,16(a3) ;-cx*cy
lea field_mat,a1
lea field_lerptab,a2
bsr.w dolerpxy
moveq #0,d2
bsr.w dolerpz
bsr.w dolerpxy
moveq #0,d2
bsr.w dolerpz
adda.w field_z(pc),a2
adda.w field_z(pc),a2
bsr.w dolerpxy
suba.w field_z(pc),a2
move.w #tf*2,d2
bsr.w dolerpz
lea field_lerptab+256*6,a0
lea 256(a0),a1
lea 256(a1),a2
lea 128(a2),a3
move.w field_z(pc),d7
lsr.w #1,d7
subq #1,d7
bmi.b .skip
.l2:
move.l (a1)+,(a0)+
move.w (a3)+,(a2)+
dbra d7,.l2
.skip:
lea field_lerptab,a1
move.l field_screens+4,a6
lea field_logtab,a2
lea field_exptabx,a5
lea field_exptaby,a3
moveq #0,d0
move.w #$c000,d7
move.w #$fffe,d1
jmp field_plotcode
dolerpxy:
move.l #$80000000,d0
move.l #$80000000,d4
move.w (a1)+,d0
move.w (a1)+,d4
move.w d0,d1
move.w d4,d5
neg.w d0
neg.w d5
sub.w d0,d1
sub.w d4,d5
swap d1
swap d5
clr.w d1
clr.w d5
asr.l #6,d1
asr.l #6,d5
swap d1
swap d4
move.l d4,a4
add.w #0,d0
move.l #$fffefffe,d2
REPT 64
move.l a4,d3
move.w d0,d3
and.l d2,d3
move.l d3,(a2)+
addx.l d1,d0
add.l d5,a4
ENDR
lea 256(a2),a2
rts
dolerpz:
move.l #$80000000,d0
move.w (a1)+,d0
move.w d0,d1
neg.w d0
sub.w d0,d1
swap d1
clr.w d1
asr.l #6,d1
swap d1
add.w d2,d0
.bla2:
add.w #0,d0
moveq #$fffffffe,d2
REPT 64
move.w d0,d3
and.w d2,d3
move.w d3,(a2)+
addx.l d1,d0
ENDR
lea 128(a2),a2
rts
;--------------------------------------------------------------------
field_screens:
dc.l field_screen1,field_screen2,field_screen3
field_page:
lea field_screens,a0
move.l $00(a0),d0
move.l $04(a0),d1
move.l $08(a0),d2
move.l d0,$04(a0)
move.l d1,$08(a0)
move.l d2,$00(a0)
move.l #field_lineplane,d2
lea field_copperbpl,a6
move.l d1,d0
addi.l #64,d0
move.l d0,d1
addi.l #$4000,d0
move.w d0,$06(a6)
swap d0
move.w d0,$02(a6)
move.w d2,$0e(a6)
swap d2
move.w d2,$0a(a6)
move.w d1,$16(a6)
swap d1
move.w d1,$12(a6)
rts
;--------------------------------------------------------------------
MACRO<FADECOL>
move.w (a0)+,d0
sub.w d6,d0
bpl.b .clamp\@
moveq #0,d0
.clamp\@:
add.w d0,d0
move.w (a1,d0.w),\1*2(a2)
ENDM
cnop 0,2
field_fadeframe:
dc.w 0
field_fadetab:
dc.w $0000,$0111,$0222,$0333,$0444,$0555,$0666,$0777
dc.w $0888,$0999,$0aaa,$0bbb,$0ccc,$0ddd,$0eee,$0fff
field_pal:
dc.w $00,$08,$0f,$0f
field_fadecol:
addq.w #1,field_fadeframe
move.w field_fadeframe(pc),d6
cmpi.w #32,d6
bgt.b .fadeout
sub.w #32,d6
neg.w d6
bpl.b .clipfront
moveq #0,d6
.clipfront:
lsr.w #1,d6
bsr.w .dofade
rts
.fadeout:
sub.w #FIELD_NUMFRAMES-32,d6
bpl.b .clipback
moveq #0,d6
.clipback:
bsr.w .dofade
rts
.dofade:
lea field_pal,a0
lea field_fadetab,a1
lea $dff180,a2
FADECOL 0
FADECOL 1
FADECOL 4
FADECOL 5
rts
;--------------------------------------------------------------------
cnop 0,4
field_spritex:
dc.l 160*65536
field_spritey:
dc.l 0*65536
field_spritexspeed:
dc.l 300*256*2
field_spriteyspeed:
dc.l 250*256*2
field_movesprites:
move.w field_fadeframe(pc),d0
subi.w #FIELD_NUMFRAMES-200,d0
blt.w .skip
move.w #$0038,field_copperprio+2
move.l field_spritex(pc),d0
move.l field_spritexspeed(pc),d1
move.l field_spritey(pc),d2
move.l field_spriteyspeed(pc),d3
sub.l d1,d0
add.l d3,d2
sub.l #1300,d1
bpl.b .noright
moveq #0,d1
.noright: