Provision multiple VM's with multiple interfaces

[akhoscode]

Hi Team,

I'm trying to provision multiple VM's with multiple NIC's but struggling to nail it down till now .I have created a sample code but it needs some tweaking in order to work properly.I'm not sure how do we pass the multiple interfaces provisioned at runtime to VM.

    @description('Username for the Virtual Machine.')
    param adminUsername string
    
    @description('Password for the Virtual Machine.')
    @secure()
    param adminPassword string
    
    @description('The Windows version for the VM. This will pick a fully patched image of this given Windows version.')
    @allowed([  
      '2019-datacenter'
      '2019-datacenter-core-smalldisk-g2'
      '2019-datacenter-core-with-containers-g2'
      '2019-datacenter-core-with-containers-smalldisk-g2'
      '2019-datacenter-gensecond'
      '2019-datacenter-smalldisk-g2'
      '2019-datacenter-with-containers-g2'
      '2019-datacenter-with-containers-smalldisk-g2'
      '2019-datacenter-zhcn-g2'
    ])
    param OSVersion string = '2019-datacenter'
    
    @description('Size of the virtual machine.')
    param vmSize string = 'Standard_B2ms'
    
    @description('Size of the DataDisk in GB.')
    param dataDiskSize string = '128'
    
    @description('Size of the DataDisk in GB.')
    param osDiskSize string = '128'
    
    @description('Location for all resources.')
    param location string = resourceGroup().location
    
    @description('Name of the virtual machine.')
    param vmName string = 'simple-vm'
    
    @description('Number of NICs for VM.')
    param nicCount int = 2
    
    @description('Security Type of the Virtual Machine.')
    @allowed([
      'Standard'
      'TrustedLaunch'
    ])
    param securityType string = 'TrustedLaunch'
    
    var subnetName = 'Subnet'
    
    var virtualNetworkName = 'MyVNET'
    
    var securityProfileJson = {
      uefiSettings: {
        secureBootEnabled: true
        vTpmEnabled: true
      }
      securityType: securityType
    }
    var extensionName = 'GuestAttestation'
    var extensionPublisher = 'Microsoft.Azure.Security.WindowsAttestation'
    var extensionVersion = '1.0'
    var maaTenantName = 'GuestAttestation'
    var maaEndpoint = substring('emptyString', 0, 0)
    
    resource nic 'Microsoft.Network/networkInterfaces@2022-05-01' = [for i in range(0, nicCount): {
      name: '@vmName-nic-${i+1}' // multipe NIC's based on the nicCount
      location: location
      properties: {
        ipConfigurations: [
          {
            name: 'ipconfig1'
            properties: {
              privateIPAllocationMethod: 'Dynamic'
              subnet: {
                id: resourceId('Microsoft.Network/virtualNetworks/subnets', virtualNetworkName, subnetName)
              }
            }
          }
        ]
      }
    }]
    
    output nicIds array = [for i in range(0, 2): {
      id: nic[i].id
    }]
    
    resource vm 'Microsoft.Compute/virtualMachines@2022-03-01' = {
      name: vmName
      location: location
      properties: {
        hardwareProfile: {
          vmSize: vmSize
        }
        osProfile: {
          computerName: vmName
          adminUsername: adminUsername
          adminPassword: adminPassword
        }
        storageProfile: {
          imageReference: {
            publisher: 'MicrosoftWindowsServer'
            offer: 'WindowsServer'
            sku: OSVersion
            version: 'latest'
          }
          osDisk: {
            createOption: 'FromImage'
            managedDisk: {
              storageAccountType: 'StandardSSD_LRS'
            }
            diskSizeGB: osDiskSize
            
          }
          dataDisks: [
            {
              diskSizeGB: dataDiskSize
              lun: 0
              createOption: 'Empty'
            }
          ]
        }
        networkProfile: {
          networkInterfaces: [for interface in nicCount: {
            {
              id: ???
            }
          }]
        }    
        securityProfile: ((securityType == 'TrustedLaunch') ? securityProfileJson : null)
      }
    }

[brwilkinson]

@akhoscode did you try this?

    networkProfile: {
      networkInterfaces: [for (interface, index) in range(0, nicCount): {
        id: nic[index].id
      }]
    }

[akhoscode]

Yes provisioning worked but the output of nic ipaddress is not working. I'm basically trying to provision two VM's

1st VM with 1 NIC and 2nd VM with 2 NIC's

output vmIPs array = [for (interface, index) in range(0, nicCount): {
ipAddress: nic[interface].properties.ipConfigurations[interface].properties.privateIPAddress
}]

it is throwing out of index "The template output 'vmIPs' is not valid: The language expression property array index '1' is out of bounds.. (Code: DeploymentOutputEvaluationFailed, Target: vmIPs)"

[akhoscode]

never mind I solved it

output vmIPs array = [for i in range(0, nicCount): {
//id: nic[i].id
ipAddress: nic[i].properties.ipConfigurations[0].properties.privateIPAddress
}]