-
Notifications
You must be signed in to change notification settings - Fork 5
/
util.clj
406 lines (298 loc) · 10.8 KB
/
util.clj
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
(ns com.brunobonacci.oneconfig.util
(:require [cheshire.core :as json]
[clojure.edn :as edn]
[clojure.java.io :as io]
[safely.core :refer [safely]]
[schema.core :as s]
[where.core :refer [where]]
[clojure.string :as str]
[clojure.tools.logging :as log])
(:import [java.io ByteArrayInputStream ByteArrayOutputStream InputStream]
java.util.zip.GZIPInputStream
java.util.Properties java.util.Map))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ;;
;; ----==| U S E F U L F U N C T I O N S |==---- ;;
;; ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defn sem-ver
"Returns a vector of the numerical components of a 3-leg version number.
eg:
(sem-ver \"1.2.3\") ;;=> [1 2 3]
(sem-ver \"1.2-alpha\") ;;=> nil
"
[ver]
(when ver
(when-let [components (re-find #"(\d{1,5})\.(\d{1,5})\.(\d{1,5})" ver)]
(mapv (fn [^String n] (Long/parseLong n)) (rest components)))))
(defn comparable-version
"takes a 3-leg version number and returns a version string
which it can be compared lexicographically and maintain it's semantic
version ordering."
[ver]
(apply format "%05d%05d%05d" (sem-ver ver)))
(defn entry-record
"Given an internal entry, it returns only the keys which are public"
[entry]
(when entry
(select-keys entry [:env :key :version :content-type :value :change-num
:user :master-key-alias :master-key])))
(defn- filter-entries [{:keys [key env version]} entries]
(->> entries
(filter
(where [:and
[:env :starts-with? (or env "")]
[:key :starts-with? (or key "")]
[:version :starts-with? (or version "")]]))))
(defn list-entries
[filters entries]
(let [;; add default ordering to given order
order (concat (get filters :order-by []) [:key :env (comp comparable-version :version) :change-num])
;; use semantic versioning order
order (map (fn [k] (if (= k :version) (comp comparable-version :version) k)) order)
;; compose order function
order-fn (apply juxt order)]
(->> entries
(filter-entries filters)
(map #(select-keys % [:key :env :version :change-num :content-type
:master-key :master-key-alias :user
:backend]))
(sort-by order-fn))))
;; mapcat is not lazy so defining one
(defn lazy-mapcat
"maps a function over a collection and
lazily concatenate all the results."
[f coll]
(lazy-seq
(if (not-empty coll)
(concat
(f (first coll))
(lazy-mapcat f (rest coll))))))
(defn clean-map
"remove keys with nils"
[map]
(->> map
(remove (where second :is? nil))
(into {})))
(defmacro show-stacktrace!!
[show & body]
{:style/indent 1}
`(try ~@body
(catch Throwable x#
(if ~show
(.printStackTrace x#)
(do
(.println System/err (str "ERROR: " (.getMessage x#)))
(.println System/err (str "CAUSE: " (loop [e# x#]
(if (.getCause e#)
(recur (.getCause e#))
(.getMessage e#)))))))
(System/exit 1))))
(defmacro log-configure-request
"logs the what was requested to configure and it was returned"
[in & body]
{:style/indent 1}
`(let [in# ~in]
(try
(let [out# (do ~@body)]
(log/infof "1config> requested config for: %s received: %s"
(pr-str in#)
(pr-str (and out#
(select-keys out#
[:key :env :version :change-num]))))
out#)
(catch Exception x#
(log/infof "1config> requested config for: %s received: %s"
(pr-str in#)
(str "ERROR: " (pr-str (.getMessage x#))))
(throw x#)))))
(defn println-err [& args]
(binding [*out* *err*]
(apply println args)))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ;;
;; ----==| E N V & P R O P E R T I E S |==---- ;;
;; ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defn env
"Returns the value of a environment variable or a map with the all variables."
([]
(into {} (System/getenv)))
([var]
(System/getenv var))
([var default]
(or (System/getenv var) default)))
(defn system-property
"Returns the value of a system property or a map with all properties."
([]
(into {} (System/getProperties)))
([property]
(System/getProperty property)))
(defn oneconfig-version
[]
(some->
(io/resource "1config.version")
slurp
(str/trim)))
(defn config-property
[prop-name env-name default]
(or
(system-property prop-name)
(env env-name)
default))
(defn default-backend-name
[]
(keyword
(config-property "1config.default.backend"
"ONECONFIG_DEFAULT_BACKEND"
"hierarchical")))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ;;
;; ----==| F I L E U I L I T I E S |==---- ;;
;; ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defn read-file
"reads a file and returns its content as a string or nil if not found or can't be read"
[file]
(safely
(slurp file :encoding "utf-8")
:on-error
:default nil))
(defn homedir
"returns the current home dir or nil if not found"
[]
(env "HOME"))
(defn home-1config
"returns ~/.1config/"
[]
(some-> (homedir) (str "/.1config/")))
(defn list-files
"Returns a lazy list of files and directories for a given path and reg-ex"
([pattern dir & {:keys [as-string]
:or {as-string false}}]
(let [matches? (if pattern
(fn [^java.io.File f] (re-find pattern (.getCanonicalPath f)))
(constantly true))
mapper (if as-string (fn [^java.io.File f] (.getCanonicalPath f)) identity)]
(->> (list-files dir)
(filter matches?)
(map mapper))))
([dir]
(if-let [^java.io.File path (and dir (.exists (io/file dir)) (io/file dir))]
(if (.isDirectory path)
(lazy-seq
(cons path
(mapcat list-files
(.listFiles path))))
[path])
[])))
(defn file-exists?
[f]
(when f
(and (.exists (io/file f))
f)))
(defn configuration-file-search
"It searches configuration files in a number of different locations.
it returns a list of entries or nil if no configuration files are found."
[]
(some file-exists?
[(system-property "1config.file")
(env "ONECONFIG_FILE")
(io/resource "1config.edn")
(io/resource "1config.json")
(io/resource "1config.txt")
(io/resource "1config.properties")
"./1config.edn"
"./1config.json"
"./1config.txt"
"./1config.properties"]))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ;;
;; ----==| F I L E F O R M A T S |==---- ;;
;; ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defn read-edn-file
"reads a EDN file and returns its content or nil if invalid"
[file]
(safely
(some-> file slurp edn/read-string)
:on-error :default nil))
(defn read-config-file
[file]
(safely
(some-> file slurp)
:on-error :default nil))
(defn filename->content-type
[^String file]
(->> file
(re-find #"(?i).*\.(edn|json|txt|properties)$")
second
(#(some-> % str/lower-case))))
(defn parse-properties [^String properties]
(doto (Properties.)
(.load (ByteArrayInputStream. (.getBytes properties "ISO-8859-1")))))
(defn properties->str [^Properties properties]
(let [out (java.io.StringWriter.)]
(.store properties (java.io.PrintWriter. out) nil)
(-> out (.getBuffer) (.toString))))
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; ;;
;; ----==| E N C O D E / D E C O D E |==---- ;;
;; ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defmulti decode (fn [form value] form))
(defmethod decode "edn"
[_ value]
(edn/read-string value))
(defmethod decode "json"
[_ value]
(json/parse-string value true))
(defmethod decode "txt"
[_ value]
value)
(defmethod decode "properties"
[_ value]
(parse-properties value))
(defmethod decode "props"
[_ value]
(decode "properties" value))
(defmulti encode (fn [form value] form))
(defmethod encode "edn"
[_ value]
(pr-str value))
(defmethod encode "json"
[_ value]
(json/generate-string value))
(defmethod encode "txt"
[_ value]
(cond
(string? value) value
(number? value) (str value)
:else
(throw (ex-info "Illegal value, a string expected" {:value value}))))
(defmethod encode "properties"
[_ value]
(cond
(instance? Properties value) (properties->str value)
(instance? Map value) (properties->str (doto (Properties.)
(.putAll value)))
:else
(throw (ex-info "Illegal value, a Properties expected" {:value value}))))
(defmethod encode "props"
[_ value]
(encode "properties" value))
(comment
(defmethod decode "gzip"
[_ value]
(let [bout (ByteArrayOutputStream.)
in (GZIPInputStream. value)]
(io/copy in bout)
(if (instance? InputStream value)
(.close value))
(ByteArrayInputStream. (.toByteArray bout)))))
(defn unmarshall-value
[{:keys [content-type] :as config-entry}]
(update config-entry :value (partial decode content-type)))
(defn marshall-value
[{:keys [content-type] :as config-entry}]
(update config-entry :value (partial encode content-type)))