/
browse.pl
2391 lines (2064 loc) · 63.5 KB
/
browse.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/* Part of ClioPatria SeRQL and SPARQL server
Author: Jan Wielemaker
E-mail: J.Wielemaker@cs.vu.nl
WWW: http://www.swi-prolog.org
Copyright (C): 2009-2015, VU University Amsterdam
This program is free software; you can redistribute it and/or
modify it under the terms of the GNU General Public License
as published by the Free Software Foundation; either version 2
of the License, or (at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public
License along with this library; if not, write to the Free Software
Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
As a special exception, if you link this library with other files,
compiled with a Free Software compiler, to produce an executable, this
library does not by itself cause the resulting executable to be covered
by the GNU General Public License. This exception does not however
invalidate any other reasons why the executable file might be covered by
the GNU General Public License.
*/
:- module(cpa_browse,
[ graph_info//1, % +Graph
graph_as_resource//2, % +Graph, +Options
graph_actions//1, % +Graph
list_resource//2, % +URI, +Options
context_graph//2 % +URI, +Options
]).
:- use_module(library(http/http_dispatch)).
:- use_module(library(http/http_parameters)).
:- use_module(library(http/html_write)).
:- use_module(library(http/js_write)).
:- use_module(library(http/html_head)).
:- use_module(library(http/http_wrapper)).
:- use_module(library(http/yui_resources)).
:- use_module(library(http/http_path)).
:- use_module(library(http/jquery)).
:- use_module(library(semweb/rdf_db)).
:- use_module(library(semweb/rdfs)).
:- use_module(library(semweb/rdf_litindex)).
:- use_module(library(semweb/rdf_persistency)).
:- use_module(library(aggregate)).
:- use_module(library(lists)).
:- use_module(library(pairs)).
:- use_module(library(debug)).
:- use_module(library(option)).
:- use_module(library(apply)).
:- use_module(components(label)).
:- use_module(components(simple_search)).
:- use_module(components(graphviz)).
:- use_module(components(basics)).
:- use_module(api(lod_crawler)).
:- use_module(api(sesame)).
:- use_module(library(semweb/rdf_abstract)).
:- use_module(library(semweb/rdf_label)).
:- use_module(user(user_db)).
/** <module> ClioPatria RDF data browser
This module implements basic browsing of an RDF repository. This is not
intended to be used as an end-user application, but for the developer to
gain insight in the data in the RDF store. That said, the distinction
between end-user and developer can be rather vague if we consider
`back-office' applications. To a certain extend, back-office
applications are considered within the scope of this module and
therefore it provides several hooks and defines several `components'
that allow back-office applications to reuse this infrastructure.
@see cliopatria(hooks) for available hooks.
*/
/*******************************
* PATHS *
*******************************/
:- http_handler(rdf_browser(.),
http_404([index(list_graphs)]),
[spawn(cliopatria), prefix]).
:- http_handler(rdf_browser(list_graphs), list_graphs, []).
:- http_handler(rdf_browser(list_graph), list_graph, []).
:- http_handler(rdf_browser(list_classes), list_classes, []).
:- http_handler(rdf_browser(list_instances), list_instances, []).
:- http_handler(rdf_browser(list_predicates), list_predicates, []).
:- http_handler(rdf_browser(list_predicate_resources),
list_predicate_resources, []).
:- http_handler(rdf_browser(list_resource), list_resource, []).
:- http_handler(rdf_browser(list_triples), list_triples, []).
:- http_handler(rdf_browser(list_triples_with_object),
list_triples_with_object, []).
:- http_handler(rdf_browser(list_triples_with_literal),
list_triples_with_literal, []).
:- http_handler(rdf_browser(list_prefixes), list_prefixes, []).
:- http_handler(rdf_browser(search), search, []).
:- http_handler(rdf_browser(multigraph_action), multigraph_action,
[ time_limit(infinite) ]).
:- meta_predicate
table_rows(3, +, ?, ?),
table_rows_top_bottom(3, +, +, +, ?, ?),
html_property_table(?, 0, ?, ?).
%% list_graphs(+Request)
%
% Display a page holding a table with all RDF graphs. The graphs
% are sorted to the number of triples.
list_graphs(_Request) :-
findall(Count-Graph,
( rdf_graph(Graph),
graph_triples(Graph, Count)
),
Pairs),
keysort(Pairs, Sorted),
pairs_values(Sorted, UpCount),
reverse(UpCount, DownCount),
append(DownCount, [virtual(total)], Rows),
reply_html_page(cliopatria(default),
title('RDF Graphs'),
[ h1('Named graphs in the RDF store'),
\graph_table(Rows, [])
]).
:- if((rdf_version(V),V>=30000)).
graph_triples(Graph, Count) :-
rdf_statistics(triples_by_graph(Graph, Count)).
:- else.
graph_triples(Graph, Count) :- % RDF-DB < 3.0
rdf_statistics(triples_by_file(Graph, Count)).
:- endif.
graph_table(Graphs, Options) -->
{ option(top_max(TopMax), Options, 500),
option(top_max(BottomMax), Options, 500),
http_link_to_id(multigraph_action, [], Action),
graph_actions(Options, ActionOptions)
},
html_requires(css('rdf.css')),
html(form([ action(Action),
class('graph-table')
],
[ table(class(block),
[ \graph_table_header
| \table_rows_top_bottom(
graph_row(ActionOptions), Graphs,
TopMax, BottomMax)
]),
\multigraph_actions(ActionOptions)
])),
mgraph_action_script.
graph_table_header -->
html(tr([ th('RDF Graph'),
th('Triples'),
th('Persistency')
])).
graph_row(_, virtual(total)) --> !,
{ rdf_statistics(triples(Count))
},
html([ th(class(total), 'Total #triples:'),
\nc('~D', Count, [class(total)])
]).
graph_row(Options, Graph) -->
{ graph_triples(Graph, Count)
},
html([ td(\graph_link(Graph)),
\nc('~D', Count),
td(style('text-align:center'), \persistency(Graph)),
\graph_checkbox(Graph, Options)
]).
graph_link(Graph) -->
{ http_link_to_id(list_graph, [graph=Graph], URI)
},
html(a(href(URI), Graph)).
persistency(Graph) -->
{ rdf_graph_property(Graph, persistent(true)) }, !,
snapshot(Graph),
journal(Graph).
persistency(_) -->
{ http_absolute_location(icons('volatile.png'), Img, [])
},
html(img([ class('in-text'),
title('Graph is not persistent'),
src(Img)
])).
snapshot(Graph) -->
{ rdf_snapshot_file(Graph, _),
http_absolute_location(icons('snapshot.png'), Img, [])
},
html(img([ class('in-text'),
title('Graph has persistent snapshot'),
src(Img)
])).
snapshot(_) --> [].
journal(Graph) -->
{ rdf_journal_file(Graph, _),
http_absolute_location(icons('journal.png'), Img, [])
},
html(img([ class('in-text'),
title('Graph has a journal'),
src(Img)
])).
journal(_) --> [].
%% graph_actions(+Options0, -Options).
%% multigraph_actions(+Options)
%
% Deal with actions on multiple graphs.
graph_actions(Options, [show_actions(true)|Options]) :-
logged_on(User), !,
catch(check_permission(User, write(_, unload(user))), _, fail), !.
graph_actions(Options, Options).
graph_checkbox(Graph, Options) -->
{ option(show_actions(true), Options) }, !,
html(td(class('no-border'),
input([type(checkbox),name(graph),value(Graph),
class('graph-select')]))).
graph_checkbox(_, _) --> [].
multigraph_actions(Options) -->
{ option(show_actions(true), Options), !,
findall(Action-Format,
clause(graph_action(Action,Format,_), _),
Pairs)
},
html([ ul([ class('multi-graph-actions')
],
\li_graph_actions(Pairs))
]).
multigraph_actions(_) --> [].
li_graph_actions([]) --> [].
li_graph_actions([H|T]) --> li_graph_action(H), li_graph_actions(T).
li_graph_action(Action-Format) -->
{ atomic_list_concat([Pre,Post], '~w', Format) },
html(li([ Pre,
input([ type(submit), name(action), value(Action) ]),
Post
])).
mgraph_action_script -->
html_requires(jquery),
js_script({|javascript||
function showActions(time) {
if ( time === undefined ) time = 400;
var val = [];
$('.graph-table :checkbox:checked').each(function(i) {
val[i] = $(this).val();
});
if ( val.length == 0 )
$(".multi-graph-actions").hide(time);
else
$(".multi-graph-actions").show(time);
}
$(function() {
showActions(0);
$(".graph-table .graph-select").on('click', showActions);
});
|}).
%% multigraph_action(Request)
%
% HTTP Handler for user actions on multiple graphs.
multigraph_action(Request) :-
findall(Action, clause(graph_action(Action,_,_), _), Actions),
http_parameters(Request,
[ graph(Graphs, [list(atom)]),
action(Action, [oneof(Actions)])
]),
clause(graph_action(Action,Format,_), _),
api_action(Request, multigraph_action(Action, Graphs), html,
Format-[Action]).
multigraph_action(Action, Graphs) :-
forall(member(Graph, Graphs),
( print_message(informational,
format('Processing ~w ...', [Graph])),
graph_action(Action, _, Graph))).
graph_action('Delete', '~w selected graphs', Graph) :-
rdf_unload_graph(Graph).
graph_action(volatile, 'Make selected graphs ~w', Graph) :-
rdf_persistency(Graph, false).
graph_action(persistent, 'Make selected graphs ~w', Graph) :-
rdf_persistency(Graph, true).
graph_action('Merge journals', '~w for selected graphs', Graph) :-
rdf_flush_journals([graph(Graph)]).
%% list_graph(+Request)
%
% HTTP handler that provides information about an individual RDF
% graph. The output is an HTML table.
list_graph(Request) :-
http_parameters(Request,
[ graph(Graph,
[description('Name of the graph to describe')])
]),
( rdf_graph(Graph)
-> true
; http_404([], Request)
),
reply_html_page(cliopatria(default),
title('RDF Graph ~w'-[Graph]),
[ h1('Summary information for graph "~w"'-[Graph]),
\simple_search_form([ id(ac_find_in_graph),
filter(graph(Graph)),
label('Search this graph')
]),
\graph_info(Graph),
\graph_as_resource(Graph, []),
\graph_persistency(Graph),
\graph_actions(Graph)
]).
%% graph_info(+Graph)//
%
% HTML component that shows -statistical- properties about the
% given named graph.
graph_info(Graph) -->
html_property_table(row(P,V),
graph_property(Graph,P,V)).
:- dynamic
graph_property_cache/3.
graph_property(Graph, P, V) :-
graph_property_cache(Graph, MD5, Pairs),
rdf_md5(Graph, MD5), !,
member(P0-V, Pairs),
P =.. [P0,Graph].
graph_property(Graph, P, V) :-
retractall(graph_property_cache(Graph, _, _)),
findall(P-V, graph_property_nc(Graph, P, V), Pairs),
rdf_md5(Graph, MD5),
assert(graph_property_cache(Graph, MD5, Pairs)),
member(P0-V, Pairs),
P =.. [P0,Graph].
graph_property_nc(Graph, source, Source) :-
rdf_source(Graph, Source).
graph_property_nc(Graph, triples, int(Triples)) :-
graph_triples(Graph, Triples).
graph_property_nc(Graph, predicate_count, int(Count)) :-
aggregate_all(count, predicate_in_graph(Graph, _P), Count).
graph_property_nc(Graph, subject_count, int(Count)) :-
aggregate_all(count, subject_in_graph(Graph, _P), Count).
graph_property_nc(Graph, bnode_count, int(Count)) :-
aggregate_all(count, bnode_in_graph(Graph, _P), Count).
graph_property_nc(Graph, type_count, int(Count)) :-
aggregate_all(count, type_in_graph(Graph, _P), Count).
predicate_in_graph(Graph, P) :-
rdf_current_predicate(P),
once(rdf(_,P,_,Graph)).
%% subject_in_graph(+Graph, -Subject)
%
% Generate the distinct subjects in a graph. There are two ways to
% do this: first the subjects and then whether they appear in the
% graph or the other way around. At least this has the advantage
% that we get distinct subjects for free.
subject_in_graph(Graph, S) :-
graph_triples(Graph, Count),
rdf_statistics(triples(Total)),
Count * 10 > Total, !, % Graph has more than 10% of triples
rdf_subject(S),
once(rdf(S, _, _, Graph)).
subject_in_graph(Graph, S) :-
findall(S, rdf(S,_,_,Graph), List),
sort(List, Subjects),
member(S, Subjects).
bnode_in_graph(Graph, S) :-
graph_triples(Graph, Count),
rdf_statistics(triples(Total)),
Count * 10 > Total, !,
rdf_subject(S),
rdf_is_bnode(S),
once(rdf(S, _, _, Graph)).
bnode_in_graph(Graph, S) :-
findall(S, (rdf(S,_,_,Graph), rdf_is_bnode(S)), List),
sort(List, Subjects),
member(S, Subjects).
%% type_in_graph(+Graph, -Class)
%
% Generate the unique types in Graph
:- thread_local
type_seen/1.
type_in_graph(Graph, Class) :-
call_cleanup(type_in_graph2(Graph, Class),
retractall(type_seen(_))).
type_in_graph2(Graph, Class) :-
subject_in_graph(Graph, S),
( rdf_has(S, rdf:type, Class)
*-> true
; rdf_equal(Class, rdfs:'Resource')
),
( type_seen(Class)
-> fail
; assert(type_seen(Class))
).
%% graph_persistency(+Graph)//
%
% Show information about the persistency of the graph
graph_persistency(Graph) -->
{ rdf_graph_property(Graph, persistent(true)),
( rdf_journal_file(Graph, _)
; rdf_snapshot_file(Graph, _)
)
}, !,
html([ h1('Persistency information'),
table(class(block),
[ tr([ td(class('no-border'),[]),
th('File'), th('Size'),th('Modified'),
td(class('no-border'),[])
]),
\graph_shapshot(Graph),
\graph_journal(Graph)
])
]).
graph_persistency(Graph) -->
{ rdf_graph_property(Graph, persistent(true))
}, !,
html([ h1('Persistency information'),
p('The graph has no associated persistency files')
]).
graph_persistency(_Graph) -->
[].
graph_shapshot(Graph) -->
{ rdf_snapshot_file(Graph, File)
},
html(tr([ th(class('file-role'), 'Snapshot'),
\file_info(File)
])).
graph_shapshot(_) --> [].
graph_journal(Graph) -->
{ rdf_journal_file(Graph, File)
},
html(tr([ th(class('file-role'), 'Journal'),
\file_info(File),
\flush_journal_button(Graph)
])).
graph_journal(_) --> [].
flush_journal_button(Graph) -->
{ http_link_to_id(flush_journal, [], HREF)
},
html(td(class('no-border'),
form(action(HREF),
[ input([type(hidden), name(graph), value(Graph)]),
input([type(hidden), name(resultFormat), value(html)]),
input([type(submit), value('Merge journal')])
]))).
file_info(File) -->
{ size_file(File, Size),
time_file(File, Time),
format_time(string(Modified), '%+', Time)
},
html([ td(class('file-name'), File),
td(class('int'), \n(human, Size)),
td(class('file-time'), Modified)
]).
%% graph_actions(+Graph)// is det.
%
% Provide a form for basic actions on the graph
graph_actions(Graph) -->
html([ h2('Actions'),
ul(class(graph_actions),
[ \li_export_graph(Graph, show),
\li_export_graph(Graph, download),
\li_schema_graph(Graph),
\li_delete_graph(Graph),
\li_persistent_graph(Graph)
])
]).
li_delete_graph(Graph) -->
{ logged_on(User),
catch(check_permission(User, write(_, unload(Graph))), _, fail), !,
http_link_to_id(unload_graph, [], Action)
},
html(li(form(action(Action),
[ input([type(hidden), name(graph), value(Graph)]),
input([type(hidden), name(resultFormat), value(html)]),
input([class(gaction), type(submit), value('Delete')]),
' this graph'
]))).
li_delete_graph(_) --> [].
li_persistent_graph(Graph) -->
{ logged_on(User),
catch(check_permission(User, write(_, persistent(Graph))), _, fail), !,
http_link_to_id(modify_persistency, [], Action),
( rdf_graph_property(Graph, persistent(true))
-> Op = (volatile), Value = off
; Op = (persistent), Value = on
)
}, !,
html(li(form(action(Action),
[ input([type(hidden), name(graph), value(Graph)]),
input([type(hidden), name(resultFormat), value(html)]),
input([type(hidden), name(persistent), value(Value)]),
'Make this graph ',
input([class(gaction), type(submit), value(Op)])
]))).
li_persistent_graph(_) --> [].
li_schema_graph(Graph) -->
{ http_link_to_id(export_graph_schema, [], Action),
download_options(show, Label, MimeType, Title)
},
html(li(form(action(Action),
[ input([type(hidden), name(graph), value(Graph)]),
input([type(hidden), name(mimetype), value(MimeType)]),
'Compute a schema for this graph and ',
input([class(saction), type(submit), value(Label),
title(Title)
]),
' the result as ',
\dl_format_menu
]))).
li_export_graph(Graph, How) -->
{ http_link_to_id(export_graph, [], Action),
download_options(How, Label, MimeType, Title)
},
html(li(form(action(Action),
[ input([type(hidden), name(graph), value(Graph)]),
input([type(hidden), name(mimetype), value(MimeType)]),
input([class(gaction), type(submit), value(Label),
title(Title)
]),
' this graph as ',
\dl_format_menu
]))).
download_options(show, 'Show', 'text/plain',
'Returns graph with MIME-type text/plain, \n\c
so it will be displayed in your browser').
download_options(download, 'Download', default,
'Return graph with its RDF MIME-type, \n\c
so most browsers will save it').
dl_format_menu -->
html(select(name(format),
[ option([value(turtle),selected], 'Turtle'),
option([value(canonical_turtle)], 'Canonical Turtle'),
option([value(rdfxml)], 'RDF/XML')
])).
%% list_classes(+Request)
%
% HTTP handler that lists all classes of all subjects that appear
% in the named graph. The output is an HTML page holding all
% referenced classes sorted by their label.
list_classes(Request) :-
http_parameters(Request,
[ graph(Graph, [description('Name of the graph')])
]),
types_in_graph(Graph, Map),
sort_pairs_by_label(Map, Sorted),
reply_html_page(cliopatria(default),
title('Classes in graph ~w'-[Graph]),
[ h1(['Classes in graph ', \graph_link(Graph)]),
\class_table(Sorted, Graph, [])
]).
class_table(Pairs, Graph, Options) -->
{ option(top_max(TopMax), Options, 500),
option(top_max(BottomMax), Options, 500)
},
html_requires(css('rdf.css')),
html(table(class(block),
[ \class_table_header
| \table_rows_top_bottom(class_row(Graph), Pairs,
TopMax, BottomMax)
])).
class_table_header -->
html(tr([ th('Class'),
th('#Instances')
])).
class_row(Graph, Class) -->
{ atom(Class), !,
findall(I, rdf_has(I, rdf:type, Class, Graph), IL),
sort(IL, Classes),
length(Classes, InstanceCount)
},
class_row(Graph, Class-InstanceCount).
class_row(Graph, Class-InstanceCount) -->
{ ( var(Graph)
-> Params = [class(Class)]
; Params = [graph(Graph), class(Class)]
),
http_link_to_id(list_instances, Params, ILink)
},
html([ td(\rdf_link(Class)),
td(class(int), a(href(ILink), InstanceCount))
]).
%% types_in_graph(+Graph, -Map:list(Type-InstanceCount))
%
% Generate a map of all types that appear in Graph with a count on
% the number of instances.
types_in_graph(Graph, Map) :-
findall(S, subject_in_graph(Graph, S), Subjects),
types(Subjects, Pairs),
transpose_pairs(Pairs, TypeSubj),
group_pairs_by_key(TypeSubj, TypeSubjs),
maplist(instance_count, TypeSubjs, Map).
types([], []).
types([S|T0], Types) :-
call_det(type_of(S,C), Det), !,
( Det == true
-> Types = [S-C|T],
types(T0, T)
; findall(C2, type_of(S,C2), Cs),
multi_class(Cs, S, Types, PT),
types(T0, PT)
).
multi_class([], _, Pairs, Pairs).
multi_class([H|T], S, [S-H|Pairs], PT) :-
multi_class(T, S, Pairs, PT).
type_of(Subject, Type) :-
( rdf_has(Subject, rdf:type, Type)
*-> true
; rdf_equal(Type, rdfs:'Resource')
).
:- meta_predicate
call_det(0, -).
call_det(G, Det) :-
call(G),
deterministic(Det).
instance_count(Type-Instances, Type-Count) :-
length(Instances, Count).
%% instance_in_graph(?Graph, ?Class, +Type,
%% -Subject, -PropertyCount) is nondet.
%
% True of Subject is an instance of Class with PropertyCount
% properties provided from Graph.
instance_in_graph(Graph, Class, any, S, C) :- !,
instance_in_graph(Graph, Class, S, C).
instance_in_graph(Graph, Class, bnode, S, C) :- !,
freeze(S, rdf_is_bnode(S)),
instance_in_graph(Graph, Class, S, C).
instance_in_graph(Graph, Class, S, C) :-
var(Class), !,
subject_in_graph(Graph, S),
property_count(Graph, S, C).
instance_in_graph(Graph, Class, S, C) :-
rdf_equal(Class, rdfs:'Resource'), !,
( rdf_has(S, rdf:type, Class),
once(rdf(S, _, _, Graph))
; subject_in_graph(Graph, S),
\+ rdf_has(S, rdf:type, _)
),
property_count(Graph, S, C).
instance_in_graph(Graph, Class, S, C) :-
rdf_has(S, rdf:type, Class),
once(rdf(S, _, _, Graph)),
property_count(Graph, S, C).
property_count(Graph, S, Count) :-
aggregate_all(count, rdf(S, _, _, Graph), Count).
%% graph_as_resource(+Graph, Options)// is det.
%
% Show resource info for a graph if it is described.
graph_as_resource(Graph, Options) -->
{ ( rdf(Graph, _, _)
; rdf(_, Graph, _)
; rdf(_, _, Graph)
), !
},
html([ h2([ 'Local view for "',
\location(Graph, _), '"'
]),
\local_view(Graph, _, Options)
]).
graph_as_resource(_, _) --> [].
/*******************************
* LIST INSTANCES *
*******************************/
%% list_instances(+Request)
%
% HTTP handler that lists instances that satisfy certain criteria.
list_instances(Request) :-
http_parameters(Request,
[ class(Class,
[ optional(true),
description('Limit to instances of this class')
]),
graph(Graph,
[ optional(true),
description('Limit to have at least \c
one property in graph')
]),
type(Type,
[ oneof([any, bnode]),
default(any),
description('Any instance or only bnodes?')
]),
sortBy(Sort,
[ oneof([label,properties]),
default(label),
description('How to sort the result-table')
])
]),
findall(I-PC, instance_in_graph(Graph, Class, Type, I, PC), IPairs),
sort_pairs_by_label(IPairs, TableByName),
( Sort == properties
-> reverse(TableByName, RevTableByName),
transpose_pairs(RevTableByName, FPairsUp),
reverse(FPairsUp, FPairsDown),
flip_pairs(FPairsDown, Table)
; Table = TableByName
),
reply_html_page(cliopatria(default),
title(\instance_table_title(Graph, Class, Sort)),
[ h1(\html_instance_table_title(Graph, Class, Sort)),
\instance_table(Table, [resource_format(nslabel)])
]).
instance_table_title(Graph, Class, Sort) -->
{ var(Class) }, !,
html('Instances in ~w sorted by ~w'-
[Graph, Sort]).
instance_table_title(Graph, Class, Sort) -->
{ rdf_display_label(Class, Label) },
html('Instances of ~w in ~w sorted by ~w'-
[Label, Graph, Sort]).
html_instance_table_title(Graph, Class, Sort) -->
html([ 'Instances',
\of_class(Class),
\in_graph(Graph),
\sorted_by(Sort)
]).
of_class(Class) -->
{ var(Class) }, !.
of_class(Class) -->
html([' of class ', \rdf_link(Class)]).
in_graph(Graph) -->
{ var(Graph) }, !.
in_graph(Graph) -->
html([' in graph ', \graph_link(Graph)]).
sorted_by(Sort) -->
html(' sorted by ~w'-[Sort]).
instance_table(Pairs, Options) -->
{ option(top_max(TopMax), Options, 500),
option(top_max(BottomMax), Options, 500)
},
html_requires(css('rdf.css')),
html(table(class(block),
[ \instance_table_header
| \table_rows_top_bottom(instance_row(Options), Pairs,
TopMax, BottomMax)
])).
instance_table_header -->
html(tr([ th('Instance'),
th('#Properties')
])).
instance_row(Options, R-C) -->
html([ td(\rdf_link(R, Options)),
td(class(int), C)
]).
/*******************************
* PREDICATES *
*******************************/
%% list_predicates(+Request)
%
% List all predicates used in graph, sorted by label.
list_predicates(Request) :-
http_parameters(Request,
[ graph(Graph, [])
]),
findall(Pred, predicate_in_graph(Graph, Pred), Preds),
sort_by_label(Preds, Sorted),
reply_html_page(cliopatria(default),
title('Predicates in graph ~w'-[Graph]),
[ h1(['Predicates in graph ', \graph_link(Graph)]),
\predicate_table(Sorted, Graph, [])
]).
predicate_table(Preds, Graph, Options) -->
{ option(top_max(TopMax), Options, 500),
option(bottom_max(BottomMax), Options, 500)
},
html_requires(css('rdf.css')),
html(table(class(block),
[ \predicate_table_header
| \table_rows_top_bottom(predicate_row(Graph), Preds,
TopMax, BottomMax)
])).
predicate_table_header -->
html(tr([ th('Predicate'),
th('#Triples'),
th('#Distinct subjects'),
th('#Distinct objects'),
th('Domain(s)'),
th('Range(s)')
])).
%% predicate_row(?Graph, +Pred) is det.
predicate_row(Graph, Pred) -->
{ predicate_statistics(Graph, Pred, Triples,
Subjects, Objects, Doms, Ranges),
( var(Graph)
-> Params = [predicate(Pred)]
; Params = [graph(Graph), predicate(Pred)]
),
http_link_to_id(list_triples, Params, PLink)
},
html([ td(\rdf_link(Pred)),
td(class(int), a(href(PLink), Triples)),
\resources(Subjects, subject, Params, []),
\resources(Objects, object, Params, []),
\resources(Doms, domain, Params, []),
\resources(Ranges, range, Params, [])
]).
resources([], _, _, _) --> !,
html(td(class(empty), -)).
resources([One], _, _, Options) --> !,
html(td(\rdf_link(One, Options))).
resources(Many, What, Params, _) --> !,
{ ( integer(Many)
-> Count = Many
; length(Many, Count)
),
http_link_to_id(list_predicate_resources, [side(What)|Params], Link)
},
html(td(class(int_c), a(href(Link), Count))).
:- dynamic
predicate_statistics_cache/8.
predicate_statistics(Graph, P, C, Subjects, Objects, Domains, Ranges) :-
var(Graph), !,
predicate_statistics_(Graph, P, C, Subjects, Objects, Domains, Ranges).
predicate_statistics(Graph, P, C, Subjects, Objects, Domains, Ranges) :-
rdf_md5(Graph, MD5),
predicate_statistics_cache(MD5, Graph, P, C,
Subjects, Objects, Domains, Ranges), !.
predicate_statistics(Graph, P, C, Subjects, Objects, Domains, Ranges) :-
rdf_md5(Graph, MD5),
debug(rdf_browse, 'Recomputing pred stats for ~p in ~w, MD5=~w',
[P, Graph, MD5]),
retractall(predicate_statistics_cache(MD5, Graph, P, _,
_, _, _, _)),
predicate_statistics_(Graph, P, C, SubjectL, ObjectL, DomainL, RangeL),
res_summary(SubjectL, Subjects),
res_summary(ObjectL, Objects),
res_summary(DomainL, Domains),
res_summary(RangeL, Ranges),
assertz(predicate_statistics_cache(MD5, Graph, P, C,
Subjects, Objects, Domains, Ranges)).
res_summary([], []) :- !.
res_summary([One], [One]) :- !.
res_summary(Many, Count) :-
length(Many, Count).
predicate_statistics_(Graph, P, C, Subjects, Objects, Domains, Ranges) :-
findall(S-O, rdf(S,P,O,Graph), Pairs),
length(Pairs, C),
pairs_keys_values(Pairs, Ss, Os),
sort(Ss, Subjects),
sort(Os, Objects),
resources_types(Subjects, Graph, Domains),
resources_types(Objects, Graph, Ranges).
resources_types(URIs, Graph, Types) :-
findall(T, resource_type_in(URIs, Graph, T), TList),
sort(TList, Types).
resource_type_in(List, Graph, T) :-
member(URI, List),
resource_type(URI, Graph, T).
%% resource_type(+URI, +Graph, -Type) is det.
resource_type(URI, Graph, T) :-
( URI = literal(Lit)
-> ( Lit = type(T, _)
-> true
; rdf_equal(T, rdfs:'Literal')
)
; rdf(URI, rdf:type, T, Graph)
*-> true
; rdf_equal(T, rdfs:'Resource')
).
/*******************************
* LIST RESOURCES *
*******************************/
%% list_predicate_resources(+Request)
%
% List resources related to a predicate. The _side_ argument is
% one of:
%
% * subject
% Display all subject values for the predicate
% * object
% Display all object values for the predicate
% * domain
% Display the types of all subject values
% * range
% Display the types of all object values.
%
% If the _skosmap_ attribute is =true=, an extra column is added
% that shows SKOS concepts that match literals. This only makes
% sense if _side_ = =object= and (some) objects are literals.