forked from pharo-project/pharo
/
Locale.class.st
417 lines (346 loc) · 10.4 KB
/
Locale.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
"
Main comment stating the purpose of this class and relevant relationship to other classes.
http://www.w3.org/WAI/ER/IG/ert/iso639.htm
http://www.oasis-open.org/cover/iso639a.html
See also
http://oss.software.ibm.com/cvs/icu/~checkout~/icuhtml/design/language_code_issues.html
http://www.w3.org/Protocols/rfc2616/rfc2616-sec3.html#sec3.10
ISO 3166
http://mitglied.lycos.de/buran/knowhow/codes/locales/
"
Class {
#name : #Locale,
#superclass : #Object,
#instVars : [
'id'
],
#classVars : [
'Activated',
'Current',
'CurrentPlatform',
'KnownLocales',
'LanguageSymbols',
'PlatformEncodings'
],
#classInstVars : [
'localeAnnouncer'
],
#category : #'System-Localization-Locales'
}
{ #category : #settings }
Locale class >> activated [
^ Activated ifNil: [Activated := false]
]
{ #category : #settings }
Locale class >> activated: aBoolean [
Activated := aBoolean
]
{ #category : #accessing }
Locale class >> current [
"Current := nil"
Current ifNil: [
Current := self determineCurrentLocale.
"Transcript show: 'Current locale: ' , Current localeID asString; cr"].
^Current
]
{ #category : #accessing }
Locale class >> currentPlatform [
"CurrentPlatform := nil"
CurrentPlatform ifNil: [CurrentPlatform := self determineCurrentLocale].
^CurrentPlatform
]
{ #category : #accessing }
Locale class >> currentPlatform: locale [
CurrentPlatform := locale
]
{ #category : #accessing }
Locale class >> currentPlatform: locale during: aBlock [
"Alter current language platform during a block"
| backupPlatform |
backupPlatform := self currentPlatform.
[self currentPlatform: locale.
aBlock value]
ensure: [self currentPlatform: backupPlatform]
]
{ #category : #'platform specific' }
Locale class >> defaultEncodingName: languageSymbol [
| encodings platformName osVersion |
platformName := Smalltalk os platformName.
osVersion := Smalltalk os version.
encodings := self platformEncodings at: languageSymbol
ifAbsent: [self platformEncodings at: #default].
encodings at: platformName ifPresent: [:encoding | ^encoding].
encodings at: platformName , ' ' , osVersion
ifPresent: [:encoding | ^encoding].
^encodings at: #default
]
{ #category : #private }
Locale class >> defaultLocales [
"return IDs of default locales"
^ #(de en ja 'ja-kids' nl no sv)
]
{ #category : #private }
Locale class >> determineCurrentLocale [
"For now just return the default locale.
A smarter way would be to determine the current platforms default locale."
"Locale determineCurrentLocale"
^self new determineLocale
]
{ #category : #private }
Locale class >> initKnownLocales [
| locales |
locales := Dictionary new.
"Init the locales for which we have translations"
self defaultLocales do: [:id |
locales at: id put: (self new localeID: id)].
^locales
]
{ #category : #initialization }
Locale class >> initialize [
SessionManager default
registerSystemClassNamed: self name
]
{ #category : #initialization }
Locale class >> initializePlatformEncodings [
"Locale initializePlatformEncodings"
| platform |
PlatformEncodings ifNil: [ PlatformEncodings := Dictionary new ].
platform := PlatformEncodings at: 'default' ifAbsentPut: Dictionary new.
platform
at: 'default' put: 'iso8859-1';
at: 'Win32 CE' put: 'utf-8'.
platform := PlatformEncodings at: 'ja' ifAbsentPut: Dictionary new.
platform
at: 'default' put: 'shift-jis';
at: 'unix' put: 'euc-jp';
at: 'Win32 CE' put: 'utf-8'.
platform := PlatformEncodings at: 'ko' ifAbsentPut: Dictionary new.
platform
at: 'default' put: 'euc-kr';
at: 'Win32 CE' put: 'utf-8'.
platform := PlatformEncodings at: 'zh' ifAbsentPut: Dictionary new.
platform
at: 'default' put: 'gb2312';
at: 'unix' put: 'euc-cn';
at: 'Win32 CE' put: 'utf-8'.
]
{ #category : #accessing }
Locale class >> isoLanguage: isoLanguage [
^self isoLanguage: isoLanguage isoCountry: nil
]
{ #category : #accessing }
Locale class >> isoLanguage: isoLanguage isoCountry: isoCountry [
^self localeID: (LocaleID isoLanguage: isoLanguage isoCountry: isoCountry)
]
{ #category : #private }
Locale class >> knownLocales [
"KnownLocales := nil"
^KnownLocales ifNil: [KnownLocales := self initKnownLocales]
]
{ #category : #accessing }
Locale class >> languageSymbol: languageSymbol [
"Locale languageSymbol: #Deutsch"
^self isoLanguage: (LanguageSymbols at: languageSymbol)
]
{ #category : #'system startup' }
Locale class >> localTimeZone [
^ LocalTimeZone new
]
{ #category : #announcing }
Locale class >> localeAnnouncer [
^localeAnnouncer ifNil: [ localeAnnouncer := Announcer new ]
]
{ #category : #accessing }
Locale class >> localeID: id [
^self knownLocales at: id ifAbsentPut: [Locale new localeID: id]
]
{ #category : #accessing }
Locale class >> platformEncodings [
PlatformEncodings isEmptyOrNil ifTrue: [ self initializePlatformEncodings ].
^PlatformEncodings
]
{ #category : #'system startup' }
Locale class >> startUp: resuming [
| newID |
resuming ifFalse: [^self].
DateAndTime localTimeZone: self localTimeZone.
(self activated)
ifTrue: [
newID := self current determineLocaleID.
newID ~= LocaleID current
ifTrue: [self switchToID: newID]]
]
{ #category : #accessing }
Locale class >> stringForLanguageNameIs: localeID [
"Answer a string for a menu determining whether the given
symbol is the project's natural language"
^ (self current localeID = localeID
ifTrue: ['<yes>']
ifFalse: ['<no>'])
, localeID displayLanguage
]
{ #category : #accessing }
Locale class >> switchTo: locale [
"Locale switchTo: Locale isoLanguage: 'de'"
Current localeID = locale localeID
ifFalse: [
|announcement|
announcement := LocaleChanged from: Current to: locale.
Current := locale.
CurrentPlatform := locale.
self localeAnnouncer announce: announcement ]
]
{ #category : #accessing }
Locale class >> switchToID: localeID [
"Locale switchToID: (LocaleID isoLanguage: 'de') "
self switchTo: (Locale localeID: localeID)
]
{ #category : #accessing }
Locale >> determineLocale [
self localeID: self determineLocaleID
]
{ #category : #accessing }
Locale >> determineLocaleID [
"Locale current determineLocaleID"
| langCode isoLang countryCode isoCountry |
langCode := self fetchISO2Language.
isoLang := langCode
ifNil: [^self localeID]
ifNotNil: [langCode].
countryCode := self primCountry copyUpTo: 0 asCharacter.
isoCountry := countryCode
ifNil: [^LocaleID isoLanguage: isoLang]
ifNotNil: [countryCode].
^LocaleID isoLanguage: isoLang isoCountry: isoCountry
]
{ #category : #private }
Locale >> fetchISO2Language [
"Locale current fetchISO2Language"
| lang isoLang |
lang := self primLanguage.
lang ifNil: [ ^ nil ].
lang := lang copyUpTo: 0 asCharacter.
lang size = 2 ifTrue: [ ^ lang ].
isoLang := ISOLanguageDefinition iso3LanguageDefinition: lang.
^ isoLang ifNotNil: [ isoLang iso2 ]
]
{ #category : #accessing }
Locale >> isoCountry [
^self localeID isoCountry
]
{ #category : #accessing }
Locale >> isoLanguage [
^self localeID isoLanguage
]
{ #category : #accessing }
Locale >> isoLocale [
"<language>-<country>"
^self isoCountry
ifNil: [self isoLanguage]
ifNotNil: [self isoLanguage , '-' , self isoCountry]
]
{ #category : #accessing }
Locale >> localeID [
^id
]
{ #category : #accessing }
Locale >> localeID: anID [
id := anID
]
{ #category : #'system primitives' }
Locale >> primCountry [
"Returns string with country tag according to ISO 639"
<primitive: 'primitiveCountry' module: 'LocalePlugin'>
^'FR'
]
{ #category : #'system primitives' }
Locale >> primCurrencyNotation [
"Returns boolean if symbol is pre- (true) or post-fix (false)"
<primitive: 'primitiveCurrencyNotation' module: 'LocalePlugin'>
^true
]
{ #category : #'system primitives' }
Locale >> primCurrencySymbol [
"Returns string with currency symbol"
<primitive: 'primitiveCurrencySymbol' module:'LocalePlugin'>
^'$'
]
{ #category : #'system primitives' }
Locale >> primDST [
"Returns boolean if DST (daylight saving time) is active or not"
<primitive:'primitiveDaylightSavings' module: 'LocalePlugin'>
^false
]
{ #category : #'system primitives' }
Locale >> primDecimalSymbol [
"Returns string with e.g. '.' or ','"
<primitive:'primitiveDecimalSymbol' module: 'LocalePlugin'>
^'.'
]
{ #category : #'system primitives' }
Locale >> primDigitGrouping [
"Returns string with e.g. '.' or ',' (thousands etc)"
<primitive:'primitiveDigitGroupingSymbol' module: 'LocalePlugin'>
^','
]
{ #category : #'system primitives' }
Locale >> primLanguage [
"returns string with language tag according to ISO 639"
<primitive:'primitiveLanguage' module: 'LocalePlugin'>
^'en'
]
{ #category : #'system primitives' }
Locale >> primLongDateFormat [
"Returns the long date format
d day, m month, y year,
double symbol is null padded, single not padded (m=6, mm=06)
dddd weekday
mmmm month name"
<primitive:'primitiveLongDateFormat' module: 'LocalePlugin'>
^'dddd, mmmm d, yyyy'
]
{ #category : #'system primitives' }
Locale >> primMeasurement [
"Returns boolean denoting metric(true) or imperial(false)."
<primitive:'primitiveMeasurementMetric' module: 'LocalePlugin'>
^true
]
{ #category : #'system primitives' }
Locale >> primShortDateFormat [
"Returns the short date format
d day, m month, y year,
double symbol is null padded, single not padded (m=6, mm=06)
dddd weekday
mmmm month name"
<primitive:'primitiveShortDateFormat' module: 'LocalePlugin'>
^'m/d/yy'
]
{ #category : #'system primitives' }
Locale >> primTimeFormat [
"Returns string time format
Format is made up of
h hour (h 12, H 24), m minute, s seconds, x (am/pm String)
double symbol is null padded, single not padded (h=6, hh=06)"
<primitive:'primitiveTimeFormat' module: 'LocalePlugin'>
^'h:mmx'
]
{ #category : #'system primitives' }
Locale >> primTimezone [
"The offset from UTC in minutes, with positive offsets being towards the east.
(San Francisco is in UTC -07*60 and Paris is in UTC +02*60 (daylight savings is not in effect)."
<primitive:'primitiveTimezoneOffset' module: 'LocalePlugin'>
^0
]
{ #category : #'system primitives' }
Locale >> primVMOffsetToUTC [
"Returns the offset in minutes between the VM and UTC.
If the VM does not support UTC times, this is 0.
Also gives us backward compatibility with old VMs as the primitive will fail and we then can return 0."
<primitive:'primitiveVMOffsetToUTC' module: 'LocalePlugin'>
^0
]
{ #category : #printing }
Locale >> printOn: aStream [
super printOn: aStream.
aStream nextPutAll: '(' ; print: id ; nextPutAll: ')'
]