generated from DanySK/gradle-wrapper
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle.kts
92 lines (81 loc) · 2.51 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
import org.danilopianini.gradle.mavencentral.mavenCentral
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
plugins {
jacoco
kotlin("jvm")
id("kotlin-qa")
id("org.jetbrains.dokka")
id("org.danilopianini.git-sensitive-semantic-versioning")
id("org.danilopianini.publish-on-central")
}
repositories {
mavenCentral()
jcenter()
}
val additionalTools: Configuration by configurations.creating
dependencies {
implementation(kotlin("stdlib-jdk8"))
implementation("io.github.javaeden.orchid:OrchidCore:_")
implementation("org.apache.commons:commons-lang3:_")
implementation("org.danilopianini:khttp:_")
testImplementation("io.kotest:kotest-runner-junit5:_")
testImplementation("io.kotest:kotest-assertions-core-jvm:_")
additionalTools("org.jacoco:org.jacoco.core:_")
}
tasks.withType<KotlinCompile> {
kotlinOptions.jvmTarget = JavaVersion.VERSION_1_8.toString()
}
tasks.test {
useJUnitPlatform()
testLogging {
showStandardStreams = true
exceptionFormat = org.gradle.api.tasks.testing.logging.TestExceptionFormat.FULL
}
}
jacoco {
toolVersion = additionalTools.resolvedConfiguration.resolvedArtifacts
.find { "jacoco" in it.moduleVersion.id.name }
?.moduleVersion?.id?.version
?: toolVersion
}
tasks.jacocoTestReport {
reports {
// Used by Codecov.io
xml.isEnabled = true
}
}
if (System.getenv("CI") == true.toString()) {
signing {
val signingKey: String? by project
val signingPassword: String? by project
useInMemoryPgpKeys(signingKey, signingPassword)
}
}
group = "org.danilopianini"
publishOnCentral {
projectDescription = "An Orchid module with utilities for scientific websites"
projectLongName = "OrchidForScience"
repository("https://maven.pkg.github.com/DanySK/OrchidForScience".toLowerCase()) {
user = "DanySK"
password = System.getenv("GITHUB_TOKEN")
}
repository("https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/", "CentralS01") {
user = mavenCentral().user()
password = mavenCentral().password()
}
}
publishing {
publications {
withType<MavenPublication> {
pom {
developers {
developer {
name.set("Danilo Pianini")
email.set("danilo.pianini@gmail.com")
url.set("http://www.danilopianini.org/")
}
}
}
}
}
}