-
Notifications
You must be signed in to change notification settings - Fork 51
/
Looking for undesirable events.sql
271 lines (252 loc) · 8.17 KB
/
Looking for undesirable events.sql
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
-- Looking for undesirable events
-- Part of the SQL Server DBA Toolbox at https://github.com/DavidSchanzer/Sql-Server-DBA-Toolbox
-- This script creates an Extended Events session called "LookingForUndesirableEvents" that includes the following events:
-- database_file_size_change
-- database_started
-- lock_deadlock
-- lock_timeout_greater_than_0
-- long_io_detected
-- query_store_plan_forcing_failed
-- exchange_spill
-- execution_warning
-- hash_spill_details
-- hash_warning
-- query_memory_grant_blocking
-- query_memory_grants
-- window_spool_ondisk_warning
-- It then starts the EE session, collects data for 5 mins and shreds the XML collected.
-- From https://karaszi.com/looking-for-strange
--Stop trace if started
IF EXISTS
(
SELECT *
FROM sys.dm_xe_sessions
WHERE name = 'LookingForUndesirableEvents'
)
ALTER EVENT SESSION LookingForUndesirableEvents ON SERVER STATE = STOP;
--Delete trace if exists
IF EXISTS
(
SELECT *
FROM sys.server_event_sessions
WHERE name = 'LookingForUndesirableEvents'
)
DROP EVENT SESSION LookingForUndesirableEvents ON SERVER;
--Create trace
CREATE EVENT SESSION LookingForUndesirableEvents
ON SERVER
ADD EVENT sqlserver.database_file_size_change
(ACTION
(
sqlserver.client_app_name,
sqlserver.client_hostname,
sqlserver.database_name,
sqlserver.server_instance_name,
sqlserver.server_principal_name,
sqlserver.sql_text
)),
ADD EVENT sqlserver.database_started
(ACTION
(
sqlserver.client_app_name,
sqlserver.client_hostname,
sqlserver.database_name,
sqlserver.server_instance_name,
sqlserver.server_principal_name,
sqlserver.sql_text
)),
ADD EVENT sqlserver.lock_deadlock
(ACTION
(
sqlserver.client_app_name,
sqlserver.client_hostname,
sqlserver.database_name,
sqlserver.server_instance_name,
sqlserver.server_principal_name,
sqlserver.sql_text
)),
ADD EVENT sqlserver.lock_timeout_greater_than_0
(ACTION
(
sqlserver.client_app_name,
sqlserver.client_hostname,
sqlserver.database_name,
sqlserver.server_instance_name,
sqlserver.server_principal_name,
sqlserver.sql_text
)),
ADD EVENT sqlserver.long_io_detected
(ACTION
(
sqlserver.client_app_name,
sqlserver.client_hostname,
sqlserver.database_name,
sqlserver.server_instance_name,
sqlserver.server_principal_name,
sqlserver.sql_text
)),
--Begin performance section
ADD EVENT qds.query_store_plan_forcing_failed
(ACTION
(
sqlserver.client_app_name,
sqlserver.client_hostname,
sqlserver.database_name,
sqlserver.server_instance_name,
sqlserver.server_principal_name,
sqlserver.sql_text
)),
ADD EVENT sqlserver.exchange_spill
(ACTION
(
sqlserver.client_app_name,
sqlserver.client_hostname,
sqlserver.database_name,
sqlserver.server_instance_name,
sqlserver.server_principal_name,
sqlserver.sql_text
)),
ADD EVENT sqlserver.execution_warning
(ACTION
(
sqlserver.client_app_name,
sqlserver.client_hostname,
sqlserver.database_name,
sqlserver.server_instance_name,
sqlserver.server_principal_name,
sqlserver.sql_text
)),
ADD EVENT sqlserver.hash_spill_details
(ACTION
(
sqlserver.client_app_name,
sqlserver.client_hostname,
sqlserver.database_name,
sqlserver.server_instance_name,
sqlserver.server_principal_name,
sqlserver.sql_text
)),
ADD EVENT sqlserver.hash_warning
(ACTION
(
sqlserver.client_app_name,
sqlserver.client_hostname,
sqlserver.database_name,
sqlserver.server_instance_name,
sqlserver.server_principal_name,
sqlserver.sql_text
)),
ADD EVENT sqlserver.query_memory_grant_blocking
(ACTION
(
sqlserver.client_app_name,
sqlserver.client_hostname,
sqlserver.database_name,
sqlserver.server_instance_name,
sqlserver.server_principal_name,
sqlserver.sql_text
)),
ADD EVENT sqlserver.query_memory_grants
(ACTION
(
sqlserver.client_app_name,
sqlserver.client_hostname,
sqlserver.database_name,
sqlserver.server_instance_name,
sqlserver.server_principal_name,
sqlserver.sql_text
)),
ADD EVENT sqlserver.window_spool_ondisk_warning
(ACTION
(
sqlserver.client_app_name,
sqlserver.client_hostname,
sqlserver.database_name,
sqlserver.server_instance_name,
sqlserver.server_principal_name,
sqlserver.sql_text
))
--End performance section
ADD TARGET package0.event_file
(SET filename = 'c:\temp\LookingForUndesirableEvents.xel', max_file_size = 10, max_rollover_files = 5)
WITH
(
MAX_MEMORY = 10MB,
MAX_EVENT_SIZE = 10MB,
STARTUP_STATE = ON,
MAX_DISPATCH_LATENCY = 5 SECONDS,
EVENT_RETENTION_MODE = ALLOW_MULTIPLE_EVENT_LOSS
);
GO
--Start EE session
ALTER EVENT SESSION LookingForUndesirableEvents ON SERVER STATE = START
-- Allow it to collect events for 5 mins
WAITFOR DELAY '00:05:00'
GO
-- Now display the results
DECLARE @SessionName sysname = 'LookingForUndesirableEvents';
IF OBJECT_ID('tempdb..#Events') IS NOT NULL
BEGIN
DROP TABLE #Events;
END;
IF OBJECT_ID('tempdb..#Queries') IS NOT NULL
BEGIN
DROP TABLE #Queries;
END;
DECLARE @Target_File NVARCHAR(1000),
@Target_Dir NVARCHAR(1000),
@Target_File_WildCard NVARCHAR(1000);
SELECT @Target_File = CAST(t.target_data AS XML).value('EventFileTarget[1]/File[1]/@name', 'NVARCHAR(256)')
FROM sys.dm_xe_session_targets AS t
INNER JOIN sys.dm_xe_sessions AS s
ON s.address = t.event_session_address
WHERE s.name = @SessionName
AND t.target_name = 'event_file';
SELECT @Target_File;
SELECT @Target_Dir = LEFT(@Target_File, LEN(@Target_File) - CHARINDEX('\', REVERSE(@Target_File)));
SELECT @Target_File_WildCard = @Target_Dir + N'\' + @SessionName + N'_*.xel';
SELECT CAST(F.event_data AS XML) AS event_data_XML
INTO #Events
FROM sys.fn_xe_file_target_read_file(@Target_File_WildCard, NULL, NULL, NULL) AS F
ORDER BY file_name DESC ,
F.file_offset DESC;
SELECT event_data_XML.value('(event/@name)[1]', 'varchar(50)') AS EventType,
DATEADD(
HOUR,
DATEDIFF(HOUR, GETUTCDATE(), GETDATE()),
CAST(event_data_XML.value('(event/@timestamp)[1]', 'varchar(50)') AS DATETIME2)
) AS TimeStamp,
event_data_XML.value('(/event/action [@name=''server_principal_name'']/value)[1]', 'NVARCHAR(256)') AS Username,
event_data_XML.value('(/event/action [@name=''database_name'']/value)[1]', 'NVARCHAR(256)') AS Database_Name,
event_data_XML.value('(/event/action [@name=''client_app_name'']/value)[1]', 'NVARCHAR(256)') AS client_app_name,
event_data_XML.value('(/event/action [@name=''sql_text'']/value)[1]', 'NVARCHAR(4000)') AS sql_text,
event_data_XML.value('(/event/action [@name=''client_hostname'']/value)[1]', 'NVARCHAR(256)') AS client_hostname,
event_data_XML AS EventDetails
INTO #Queries
FROM #Events;
SELECT q.EventType,
q.TimeStamp,
q.Username,
q.Database_Name,
CASE LEFT(q.client_app_name, 29)
WHEN 'SQLAgent - TSQL JobStep (Job ' THEN
'SQLAgent Job: ' +
(
SELECT sj.name COLLATE DATABASE_DEFAULT
FROM msdb..sysjobs AS sj
WHERE SUBSTRING(q.client_app_name, 32, 32) = (SUBSTRING(sys.fn_varbintohexstr(sj.job_id), 3, 100))
) + ' - ' + SUBSTRING(q.client_app_name, 67, LEN(q.client_app_name) - 67)
ELSE
q.client_app_name
END AS client_app_name,
q.client_hostname,
q.sql_text,
q.EventDetails
FROM #Queries AS q
ORDER BY q.TimeStamp DESC;
GO
-- Stop the EE session
ALTER EVENT SESSION LookingForUndesirableEvents
ON SERVER
STATE = STOP;
GO