/
exercise-5.1.rkt
174 lines (140 loc) · 5.51 KB
/
exercise-5.1.rkt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
#lang eopl
;; Exercise 5.1 [★] Implement this data type of continuations using the procedural representation.
;; Grammar.
(define the-lexical-spec
'([whitespace (whitespace) skip]
[comment ("%" (arbno (not #\newline))) skip]
[identifier (letter (arbno (or letter digit "_" "-" "?"))) symbol]
[number (digit (arbno digit)) number]
[number ("-" digit (arbno digit)) number]))
(define the-grammar
'([program (expression) a-program]
[expression (number) const-exp]
[expression ("-" "(" expression "," expression ")") diff-exp]
[expression ("zero?" "(" expression ")") zero?-exp]
[expression ("if" expression "then" expression "else" expression) if-exp]
[expression (identifier) var-exp]
[expression ("let" identifier "=" expression "in" expression) let-exp]
[expression ("proc" "(" identifier ")" expression) proc-exp]
[expression ("(" expression expression ")") call-exp]
[expression ("letrec" identifier "(" identifier ")" "=" expression "in" expression) letrec-exp]))
(sllgen:make-define-datatypes the-lexical-spec the-grammar)
(define scan&parse (sllgen:make-string-parser the-lexical-spec the-grammar))
;; Data structures.
(define-datatype proc proc?
[procedure [bvar symbol?]
[body expression?]
[env environment?]])
(define-datatype expval expval?
[num-val [value number?]]
[bool-val [boolean boolean?]]
[proc-val [proc proc?]])
(define expval-extractor-error
(lambda (variant value)
(eopl:error 'expval-extractors "Looking for a ~s, found ~s" variant value)))
(define expval->num
(lambda (v)
(cases expval v
[num-val (num) num]
[else (expval-extractor-error 'num v)])))
(define expval->bool
(lambda (v)
(cases expval v
[bool-val (bool) bool]
[else (expval-extractor-error 'bool v)])))
(define expval->proc
(lambda (v)
(cases expval v
[proc-val (proc) proc]
[else (expval-extractor-error 'proc v)])))
(define-datatype environment environment?
[empty-env]
[extend-env [bvar symbol?]
[bval expval?]
[saved-env environment?]]
[extend-env-rec [p-name symbol?]
[b-var symbol?]
[p-body expression?]
[saved-env environment?]])
(define identifier? symbol?)
;; Continuations.
(define (end-cont)
(let ([used #f])
(lambda (val)
(if used
(eopl:error "Continuation is already used.")
(begin (set! used #t)
val)))))
(define (zero1-cont cont)
(lambda (val)
(apply-cont cont (bool-val (zero? (expval->num val))))))
(define (let-exp-cont var body env cont)
(lambda (val)
(value-of/k body (extend-env var val env) cont)))
(define (if-test-cont exp2 exp3 env cont)
(lambda (val)
(if (expval->bool val)
(value-of/k exp2 env cont)
(value-of/k exp3 env cont))))
(define (diff1-cont exp2 env cont)
(lambda (val)
(value-of/k exp2 env (diff2-cont val cont))))
(define (diff2-cont val1 cont)
(lambda (val)
(apply-cont cont (num-val (- (expval->num val1)
(expval->num val))))))
(define (rator-cont rand env cont)
(lambda (val)
(value-of/k rand env (rand-cont val cont))))
(define (rand-cont val1 cont)
(lambda (val)
(apply-procedure/k (expval->proc val1)
val
cont)))
;; Interpreter.
(define apply-procedure/k
(lambda (proc1 arg cont)
(cases proc proc1
[procedure (var body saved-env) (value-of/k body
(extend-env var arg saved-env)
cont)])))
(define apply-cont
(lambda (cont val)
(cont val)))
(define apply-env
(lambda (env search-sym)
(cases environment env
[empty-env () (eopl:error 'apply-env "No binding for ~s" search-sym)]
[extend-env (var val saved-env) (if (eqv? search-sym var)
val
(apply-env saved-env search-sym))]
[extend-env-rec (p-name b-var p-body saved-env) (if (eqv? search-sym p-name)
(proc-val (procedure b-var p-body env))
(apply-env saved-env search-sym))])))
(define value-of/k
(lambda (exp env cont)
(cases expression exp
[const-exp (num) (apply-cont cont (num-val num))]
[var-exp (var) (apply-cont cont (apply-env env var))]
[proc-exp (var body) (apply-cont cont (proc-val (procedure var body env)))]
[letrec-exp (p-name b-var p-body letrec-body) (value-of/k letrec-body
(extend-env-rec p-name b-var p-body env)
cont)]
[zero?-exp (exp1) (value-of/k exp1 env (zero1-cont cont))]
[let-exp (var exp1 body) (value-of/k exp1 env (let-exp-cont var body env cont))]
[if-exp (exp1 exp2 exp3) (value-of/k exp1 env (if-test-cont exp2 exp3 env cont))]
[diff-exp (exp1 exp2) (value-of/k exp1 env (diff1-cont exp2 env cont))]
[call-exp (rator rand) (value-of/k rator env (rator-cont rand env cont))])))
(define (init-env)
(empty-env))
(define value-of-program
(lambda (pgm)
(cases program pgm
[a-program (exp1) (value-of/k exp1
(init-env)
(end-cont))])))
;; Interface.
(define run
(lambda (string)
(value-of-program (scan&parse string))))
(provide bool-val num-val run)