/
zonal.ncl
220 lines (191 loc) · 7.58 KB
/
zonal.ncl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
; #############################################################################
; PROCEDURE FOR THE ZONAL PLOT OF THE PERFORMANCE METRICS
; Authors: Mattia Righi (DLR, Germany) and Franziska Winterstein (DLR, Germany)
; ESMVal project
; #############################################################################
load "$diag_scripts/shared/plot/style.ncl"
load "$diag_scripts/shared/plot/zonalmean_profile.ncl"
procedure perfmetrics_ptype_script()
begin
; Start loop over datasets, make sure reference dataset is calculated first
modidx = ispan(0, nDatasets - 1, 1)
modidx := array_append_record(ref_ind, modidx(ind(modidx.ne.ref_ind)), 0)
if (isatt(diag_script_info, "annots")) then
annots = metadata_att_as_array(info_items, diag_script_info@annots)
else
annots = project_style(info_items, diag_script_info, "annots")
end if
print(annots)
; Loop over datasets
do ii = 0, dimsizes(modidx) - 1
imod = modidx(ii)
log_debug("Processing " + datasetnames(imod))
; Check if difference is possible
if (diag_script_info@plot_diff .and. imod.ne.ref_ind) then
l_diff = True
else
l_diff = False
end if
; Set path for saving processed data
system("mkdir -p " + config_user_info@work_dir)
fname_abs = \
str_join((/"perfmetrics", "zonal", annots(imod), var0, \
diag_script_info@time_avg, diag_script_info@region/), "_")
workpath_abs = config_user_info@work_dir + fname_abs + ".nc"
plotpath_abs = config_user_info@plot_dir + fname_abs
fname_diff = \
str_join((/"perfmetrics", "zonal", \
annots(imod) + "-" + annots(ref_ind), var0, \
diag_script_info@time_avg, diag_script_info@region/), "_")
workpath_diff = config_user_info@work_dir + fname_diff + ".nc"
plotpath_diff = config_user_info@plot_dir + fname_diff
; Determine start/end year
start_year = info_items[imod]@start_year
end_year = info_items[imod]@end_year
; Read data
var = read_data(info_items[imod])
; Calculate zonal mean
var_zon = dim_avg_Wrap(var)
delete(var)
; Calculate time average and standard deviation w.r.t.
; interannual variability
var_avg = time_operations(var_zon, start_year, end_year, "average", \
diag_script_info@time_avg, True)
var_std = interannual_variability(var_zon, start_year, end_year, \
diag_script_info@time_avg, "None")
delete(var_zon)
; Store in global array
var_all = new(array_append_record(dimsizes(var_avg), 2, 0), float)
var_all!2 = "statistic"
var_all&statistic = (/"mean", "stddev"/)
var_all(:, :, 0) = var_avg
var_all(:, :, 1) = var_std
var_all@var = var0
var_all@diag_script = (/DIAG_SCRIPT/)
copy_VarAtts(diag_script_info, var_all)
var_all@ref_model = variable_info[0]@reference_dataset
delete(var_avg)
delete(var_std)
; Store reference dataset
if (imod.eq.ref_ind) then
var_ref = var_all
end if
; Calculate difference
if (l_diff) then
var_diff = var_all(:, :, 0)
var_diff = var_all(:, :, 0) - var_ref(:, :, 0)
end if
; Write output
var_all@ncdf = workpath_abs
ncdf_abs = ncdf_write(var_all, workpath_abs)
if (l_diff) then
var_diff@ncdf = workpath_diff
ncdf_diff = ncdf_write(var_diff, workpath_diff)
end if
; Convert units for plotting (if required)
if (isatt(diag_script_info, "plot_units")) then
var_all = convert_units(var_all, diag_script_info@plot_units)
if (l_diff)
var_diff = convert_units(var_diff, diag_script_info@plot_units)
end if
end if
; Absolute plot
plot_var = var_all(:, :, 0)
plot_var@res_tiMainString = annots(imod)
plot_var@res_cnLevelSelectionMode = "ExplicitLevels"
plot_var@res_cnLevels = diag_script_info@abs_levs
plot_var@res_trYMinF = diag_script_info@zonal_ymin
plot_var@res_gsnLeftString = \
plot_var@long_name + " [" + format_units(plot_var@units) + "]"
copy_VarMeta(diag_script_info, plot_var)
wks = gsn_open_wks(file_type, plotpath_abs)
gsn_define_colormap(wks, diag_script_info@zonal_cmap)
plot = zonalmean_profile(wks, plot_var, var0)
draw(plot)
frame(wks)
delete(plot_var@res_cnLevels)
delete(wks)
delete(plot)
; Call provenance logger
log_provenance(ncdf_abs, \
plotpath_abs + "." + file_type, \
"Zonal mean of variable " + var0, \
(/"mean", "stddev"/), \
diag_script_info@region, \
"zonal", \
(/"winterstein_franziska", "righi_mattia", \
"eyring_veronika"/), \
(/"righi15gmd", "gleckler08jgr"/), \
info_items[imod]@filename)
; Difference plot to the reference
if (.not.l_diff) then
continue
end if
plot_var = var_diff
plot_var@res_tiMainString = annots(imod) + " - " + annots(ref_ind)
if (isatt(diag_script_info, "t_test")) then
plot_var@res_gsnLeftString = plot_var@res_gsnLeftString + " - " + \
sprinti("%2i", toint(100 * diag_script_info@conf_level)) + "% c.l."
end if
plot_var@res_cnLevelSelectionMode = "ExplicitLevels"
plot_var@res_cnLevels = diag_script_info@diff_levs
plot_var@res_cnMissingValFillColor = "gray70"
plot_var@res_gsnSpreadColorEnd = -2
wks = gsn_open_wks(file_type, plotpath_diff)
gsn_merge_colormaps(wks, "temp_19lev", "gray70")
plot = zonalmean_profile(wks, plot_var, var0)
delete(plot_var@res_cnLevels)
; Apply t-test (assuming different population variances)
caption = "Difference in zonal mean of variable " + var0
if (diag_script_info@t_test) then
x1 = var_all(:, :, 0)
x2 = var_ref(:, :, 0)
s1 = var_all(:, :, 1) ^ 2
s2 = var_ref(:, :, 1) ^ 2
n1 = info_items[imod]@end_year - info_items[imod]@start_year + 1
n2 = info_items[ref_ind]@end_year - info_items[ref_ind]@start_year + 1
prob = ttest(x1, s1, n1, x2, s2, n2, True, False)
plot_var = 1. - prob
delete(prob)
; Mask non-significant values
plot_var@res_cnMissingValFillColor = -1
plot_var@res_gsnDraw = False
plot_var@res_gsnFrame = False
plot_var@res_cnLevelSelectionMode = "ExplicitLevels"
plot_var@res_cnLevels := diag_script_info@conf_level
if (diag_script_info@stippling) then
plot_var@res_cnFillColors = (/"black", "transparent"/)
plot_var@res_cnFillPattern = 17
caption = caption + " (non-significant points are stippled)"
else
plot_var@res_cnFillColors = (/"gray70", "transparent"/)
caption = caption + " (non-significant points are masked out in gray)"
end if
plot_var@res_cnInfoLabelOn = False
plot_var@res_cnLinesOn = False
plot_var@res_cnLineLabelsOn = False
plot_var@res_lbLabelBarOn = False
plot_var@res_gsnLeftString = ""
delete(plot_var@long_name)
plot2 = zonalmean_profile(wks, plot_var, var0)
overlay(plot, plot2)
draw(plot)
frame(wks)
delete(wks)
delete(plot)
delete(plot2)
delete(plot_var)
end if
; Call provenance logger
log_provenance(ncdf_diff, \
plotpath_diff + "." + file_type, \
caption, \
(/"mean", "stddev", "diff"/), \
diag_script_info@region, \
"zonal", \
(/"winterstein_franziska", "righi_mattia", \
"eyring_veronika"/), \
(/"righi15gmd", "gleckler08jgr"/), \
info_items[imod]@filename)
end do
end