build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {

    repositories {
        google()
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:4.2.1'

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

// define global parameters
allprojects {
    repositories {
        // local maven
        mavenLocal()

        // basic repositories
        google()
        mavenCentral()
    }

    tasks.withType(JavaCompile) {
        options.compilerArgs << '-Xlint:deprecation'
        options.deprecation = true
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

ext.getGitConfig = {final String configKey ->
    final def stdout = new ByteArrayOutputStream()
    exec {
        commandLine 'git', 'config', configKey
        standardOutput = stdout
        ignoreExitValue = true
    }
    stdout.toString().trim()
}

ext.getContactEmail = {
    //get play store email
    String email = getGitConfig('app.email')
    if(!email.contains('@')) {
        //fallback
        email = getGitConfig('user.email')
    }

    if(!email.contains('@') || email.contains('noreply')){
        throw new InvalidUserDataException('app contact email is missing: git config --add app.email')
    }
    email
}