forked from Expander/FlexibleSUSY
-
Notifications
You must be signed in to change notification settings - Fork 14
/
Parameters.m
1570 lines (1282 loc) · 65.8 KB
/
Parameters.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
BeginPackage["Parameters`", {"SARAH`", "CConversion`", "Utils`", "Phases`"}];
{ FSModelParameters, FSInputParameters, FSOutputParameters,
FSPhysicalOutputParameters, FSPhases, FSDerivedParameters,
FSExtraParameters };
FindSymbolDef::usage="";
CreateParameterDefinition::usage="";
CreateParameterDefinitionAndDefaultInitialize::usage="";
CreateSetAssignment::usage="";
CreateDisplayAssignment::usage="";
CreateParameterSARAHNames::usage="";
CreateParameterEnums::usage="";
CreateInputParameterEnum::usage="";
CreateInputParameterNames::usage="";
CreateStdVectorNamesAssignment::usage="";
CreateInputParameterArrayGetter::usage="";
CreateInputParameterArraySetter::usage="";
CreateEnumName::usage="Creates enum symbol for given parameter";
DecomposeParameter::usage="decomposes parameter into its real components";
SetParameter::usage="set model parameter";
SetSMParameter::usage="sets a SM input parameter in the QedQcd class";
SetInputParameter::usage="set input parameter to value";
AddInputParameters::usage="add an input parameter";
AddExtraParameters::usage="add an extra parameter";
SetPhases::usage="sets field phases";
GetPhases::usage="returns field phases";
SetPhase::usage="sets a phase to a value";
ApplyGUTNormalization::usage="Returns a list of repacement rules for
gauge couplings, which replace non-normalized gauge couplings
(e.g. gY) by normalized ones (e.g. g1).";
GetGUTNormalization::usage="Returns GUT normalization of the given
coupling";
CreateIndexReplacementRules::usage="";
AddRealParameter::usage="";
SetRealParameters::usage="";
SaveParameterLocally::usage="Save parameters in local variables";
GetType::usage="";
GetPhase::usage="";
HasPhase::usage="";
GetRealTypeFromDimension::usage="";
GetComplexTypeFromDimension::usage="";
GetParameterDimensions::usage="";
GetThirdGeneration::usage="returns parameter with third generation index";
GuessInputParameterType::usage="returns a guess for the type of the parameter";
GuessExtraParameterType::usage="returns a guess for the type of the parameter";
IsRealParameter::usage="";
IsComplexParameter::usage="";
IsRealExpression::usage="";
IsMatrix::usage="returns True if parameter is a matrix";
IsSymmetricMatrixParameter::usage="returns True if parameter is a matrix";
IsTensor::usage="returns True if parameter is a matrix";
IsModelParameter::usage="returns True if parameter is a model parameter";
IsInputParameter::usage="returns True if parameter is an input parameter";
IsOutputParameter::usage="returns True if parameter is a defined output parameter";
IsIndex::usage="returns True if given symbol is an index";
IsPhase::usage="returns True if given symbol is a phase";
IsDerivedParameter::usage="returns True if parameter is a derived parameter";
IsExtraParameter::usage="returns True if parameter is a defined extra parameter";
GetIndices::usage="returns list of indices from a given parameter";
AllModelParametersAreReal::usage="returns True if all model parameters
are real, False otherwise";
SetInputParameters::usage="";
SetModelParameters::usage="";
SetOutputParameters::usage="";
SetExtraParameters::usage="";
GetInputParameters::usage="";
GetInputParametersAndTypes::usage="";
GetModelParameters::usage="";
GetOutputParameters::usage="";
GetExtraParameters::usage="";
GetExtraParametersAndTypes::usage="";
GetModelParametersWithMassDimension::usage="Returns model parameters
with given mass dimension";
FindMacro::usage="Returns preprocessor macro for parameter";
WrapPreprocessorMacroAround::usage="Applies preprocessor symbols
to parameters";
GetDependenceSPhenoSymbols::usage="Returns list of symbols for which a
DependenceSPheno rule is defined";
GetDependenceSPhenoRules::usage="Returns list of replacement rules for
symbols for which a DependenceSPheno rule is defined";
GetOutputParameterDependencies::usage="Returns list of output
parameters which appear in the given expression";
GetIntermediateOutputParameterDependencies::usage="Returns list of
intermediate output parameters which appear in the given expression";
CreateLocalConstRefs::usage="creates local const references to model
parameters / input parameters.";
CreateLocalConstRefsForBetas::usage="";
CreateLocalConstRefsForInputParameters::usage="creates local const
references for all input parameters in the given expression.";
CreateLocalConstRefsForPhysicalParameters::usage="creates local const
references for all physical output parameters in the given
expression.";
FillInputParametersFromTuples::usage="";
DecreaseIndexLiterals::usage="";
IncreaseIndexLiterals::usage="";
DecreaseSumIndices::usage="";
ExpressionToString::usage="Converts an expression to a valid C++
string.";
GetEffectiveMu::usage="";
GetEffectiveMASqr::usage="";
GetParameterFromDescription::usage="Returns model parameter from a
given description string.";
GetParticleFromDescription::usage="Returns particle symbol from a
given description string.";
GetPDGCodesForParticle::usage="Returns the PDG codes for a particle."
NumberOfIndependentEntriesOfSymmetricMatrix::usage="Returns number of
independent parameters of a real symmetric nxn matrix";
ExpandExpressions::usage="";
AppendGenerationIndices::usage="";
StripIndices::usage="removes indices from model parameter";
StripIndicesRules::usage="removes given indices from a symbol";
StripSARAHIndicesRules::usage="removes SARAH-specific indices from a symbol";
ReplaceAllRespectingSARAHHeads::usage="applies given rules, respecting
SARAH heads SARAH`B, SARAH`L, SARAH`T and SARAH`Q";
FindAllParameters::usage = "returns list of all parameters contained
in the given expression";
FindAllParametersClassified::usage = "returns list of all parameters
contained in the given expression, classified by their meaning.";
FindSLHABlock::usage = "returns SLHA input block name for given
parameter";
Begin["`Private`"];
allInputParameters = {};
allExtraParameters = {};
allModelParameters = {};
allOutputParameters = {};
allPhases = {};
(* list storing mass dimensions for input and extra parameters *)
extraMassDimensions = {};
AddMassDimensionInfo[par_, dim_?NumberQ] :=
Module[{parNames},
parNames = #[[1]]& /@ extraMassDimensions;
If[!MemberQ[parNames, par],
extraMassDimensions = Utils`ForceJoin[extraMassDimensions, {{par, dim}}];,
pos = Position[parNames, par, 1];
extraMassDimensions = ReplacePart[extraMassDimensions, pos -> {par, dim}];
];
];
AddMassDimensionInfo[par_, dim_] :=
Print["Error: mass dimension for parameter ", par,
" must be a number"];
GuessInputParameterType[Sign[par_]] :=
CConversion`ScalarType[CConversion`integerScalarCType];
GuessInputParameterType[FlexibleSUSY`Phase[par_]] :=
CConversion`ScalarType[CConversion`complexScalarCType];
GuessInputParameterType[par_] :=
CConversion`ScalarType[CConversion`realScalarCType];
GuessExtraParameterType[Sign[par_]] :=
CConversion`ScalarType[CConversion`integerScalarCType];
GuessExtraParameterType[FlexibleSUSY`Phase[par_]] :=
CConversion`ScalarType[CConversion`complexScalarCType];
GuessExtraParameterType[par_] :=
If[IsRealParameter[par],
CConversion`ScalarType[CConversion`realScalarCType],
CConversion`ScalarType[CConversion`complexScalarCType]
];
UpdateParameterInfo[currentPars_List, {par_, block_, type_}] :=
Module[{parNames, pos, updatedPars},
parNames = #[[1]]& /@ currentPars;
If[!MemberQ[parNames, par],
updatedPars = Utils`ForceJoin[currentPars, {{par, block, type}}];,
pos = Position[parNames, par, 1];
updatedPars = ReplacePart[currentPars, pos -> {par, block, type}];
];
If[CConversion`GetElementType[type] === CConversion`realScalarCType ||
CConversion`GetElementType[type] === CConversion`integerScalarCType,
AddRealParameter[par];
];
Return[updatedPars];
];
UpdateParameterInfo[currentPars_List, {par_, type_}] :=
Module[{parNames, pos, updatedPars},
parNames = #[[1]]& /@ currentPars;
If[!MemberQ[parNames, par],
updatedPars = Utils`ForceJoin[currentPars, {{par, type}}];,
pos = Position[parNames, par, 1];
updatedPars = ReplacePart[currentPars, pos -> {par, type}];
];
If[CConversion`GetElementType[type] === CConversion`realScalarCType ||
CConversion`GetElementType[type] === CConversion`integerScalarCType,
AddRealParameter[par];
];
Return[updatedPars];
];
AddInputParameterInfo[{par_, block_, type_}] :=
allInputParameters = UpdateParameterInfo[allInputParameters, {par, block, type}];
AddInputParameterInfo[{par_, type_}] :=
allInputParameters = UpdateParameterInfo[allInputParameters, {par, {}, type}];
AddInputParameterInfo[par_] :=
AddInputParameterInfo[{par, {}, GuessInputParameterType[par]}];
SetInputParameters[pars_List] :=
(
allInputParameters = {};
AddInputParameterInfo /@ pars;
)
SetInputParameterType[par_?IsInputParameter, type_] :=
Module[{pos, updated},
pos = Position[allInputParameters, {par, _, _}];
updated = Extract[allInputParameters, pos] /. {par, block_, oldType_} :> {par, block, type};
allInputParameters = ReplacePart[allInputParameters, MapThread[Rule, {pos, updated}]];
];
SetInputParameterType[par_, type_] :=
Print["Error: ", par, " is not an input parameter!"];
SetInputParameterDimensions[par_?IsInputParameter, dims_] :=
Module[{pos, updated},
pos = Position[allInputParameters, {par, _, _}];
updated = Extract[allInputParameters, pos];
updated = ({#[[1]], #[[2]], If[CConversion`IsRealType[#[[2]]],
GetRealTypeFromDimension[dims],
GetComplexTypeFromDimension[dims]]})& /@ updated;
allInputParameters = ReplacePart[allInputParameters, MapThread[Rule, {pos, updated}]];
];
SetInputParameterDimensions[par_, dims_] :=
Print["Error: ", par, " is not an input parameter!"];
AddInputParameters[pars_List] := AddInputParameterInfo /@ pars;
AddExtraParameterInfo[{par_, type_}] :=
allExtraParameters = UpdateParameterInfo[allExtraParameters, {par, type}];
AddExtraParameterInfo[par_] :=
AddExtraParameterInfo[{par, GuessExtraParameterType[par]}];
SetExtraParameters[pars_List] :=
(
allExtraParameters = {};
AddExtraParameterInfo /@ pars;
)
AddExtraParameters[pars_List] := AddExtraParameterInfo /@ pars;
SetModelParameters[pars_List] := allModelParameters = DeleteDuplicates[pars];
SetOutputParameters[pars_List] := allOutputParameters = DeleteDuplicates[pars];
SetPhases[phases_List] := allPhases = DeleteDuplicates[phases];
GetInputParameters[] := First /@ allInputParameters;
GetInputParametersAndTypes[] := allInputParameters;
GetModelParameters[] := allModelParameters;
GetOutputParameters[] := allOutputParameters;
GetPhases[] := allPhases;
GetExtraParameters[] := First /@ allExtraParameters;
GetExtraParametersAndTypes[] := allExtraParameters;
additionalRealParameters = {};
AddRealParameter[parameter_List] :=
additionalRealParameters = DeleteDuplicates[Join[additionalRealParameters, parameter]];
AddRealParameter[parameter_] :=
additionalRealParameters = DeleteDuplicates[Join[additionalRealParameters, {parameter}]];
SetRealParameters[parameters_List] :=
additionalRealParameters = parameters;
DebugPrint[msg___] :=
If[FlexibleSUSY`FSDebugOutput,
Print["Debug<Parameters>: ", Sequence @@ InputFormOfNonStrings /@ {msg}]];
FindSymbolDef[sym_, opt_:DependenceNum] :=
Module[{symDef},
symDef = Cases[SARAH`ParameterDefinitions,
{sym, {___, opt -> definition_, ___}} :> definition];
If[Head[symDef] =!= List || symDef === {},
Print["Error: Could not find definition of ",
sym, " in SARAH`ParameterDefinitions"];
Return[0];
];
If[Length[symDef] > 1,
Print["Warning: ", sym, " defined multiple times"];
];
symDef = symDef[[1]];
Return[symDef];
];
FindAllParametersFromList[expr_, parameters_List] :=
Module[{symbols, compactExpr},
compactExpr = RemoveProtectedHeads[expr];
(* find all parameters with SARAH head *)
symbols = DeleteDuplicates[Flatten[
{ Cases[compactExpr, SARAH`L[a_][__] /; MemberQ[parameters,SARAH`L[a]] :> SARAH`L[a], {0,Infinity}],
Cases[compactExpr, SARAH`B[a_][__] /; MemberQ[parameters,SARAH`B[a]] :> SARAH`B[a], {0,Infinity}],
Cases[compactExpr, SARAH`T[a_][__] /; MemberQ[parameters,SARAH`T[a]] :> SARAH`T[a], {0,Infinity}],
Cases[compactExpr, SARAH`Q[a_][__] /; MemberQ[parameters,SARAH`Q[a]] :> SARAH`Q[a], {0,Infinity}],
Cases[compactExpr, SARAH`L[a_] /; MemberQ[parameters,SARAH`L[a]] :> SARAH`L[a], {0,Infinity}],
Cases[compactExpr, SARAH`B[a_] /; MemberQ[parameters,SARAH`B[a]] :> SARAH`B[a], {0,Infinity}],
Cases[compactExpr, SARAH`T[a_] /; MemberQ[parameters,SARAH`T[a]] :> SARAH`T[a], {0,Infinity}],
Cases[compactExpr, SARAH`Q[a_] /; MemberQ[parameters,SARAH`Q[a]] :> SARAH`Q[a], {0,Infinity}]
}]];
(* remove parameters found from compactExpr *)
compactExpr = compactExpr /. (RuleDelayed[#, Evaluate[CConversion`ToValidCSymbolString[#]]]& /@ symbols);
(* find all parameters without SARAH head in compactExpr *)
symbols = Join[symbols,
{ Cases[compactExpr, a_Symbol /; MemberQ[parameters,a], {0,Infinity}],
Cases[compactExpr, a_[__] /; MemberQ[parameters,a] :> a, {0,Infinity}],
Cases[compactExpr, FlexibleSUSY`M[a_] /; MemberQ[parameters,FlexibleSUSY`M[a]], {0,Infinity}],
Cases[compactExpr, FlexibleSUSY`M[a_[__]] /; MemberQ[parameters,FlexibleSUSY`M[a]] :> FlexibleSUSY`M[a], {0,Infinity}]
}];
DeleteDuplicates[Flatten[symbols]]
];
(* Returns all parameters within an expression *)
FindAllParameters[expr_, exceptions_:{}] :=
Module[{allParameters, allOutPars},
allOutPars = DeleteDuplicates[Flatten[
Join[allOutputParameters,
allOutputParameters /. FlexibleSUSY`M[{a__}] :> FlexibleSUSY`M[a],
allOutputParameters /. FlexibleSUSY`M[{a__}] :> (FlexibleSUSY`M /@ {a})
]]];
allParameters = DeleteDuplicates[
Join[allModelParameters, allOutPars,
GetInputParameters[], Phases`GetArg /@ allPhases,
GetDependenceSPhenoSymbols[], GetExtraParameters[]]];
allParameters = DeleteCases[allParameters, p_ /; MemberQ[exceptions, p]];
FindAllParametersFromList[expr, allParameters]
];
FindAllParametersClassified[expr_, exceptions_:{}] :=
Module[{symbols = DeleteDuplicates[Flatten[FindAllParameters[expr, exceptions]]],
inputPars, modelPars, outputPars, extraPars,
poleMasses, phases, depNum, allOutPars},
allOutPars = DeleteDuplicates[Flatten[
Join[allOutputParameters,
allOutputParameters /. FlexibleSUSY`M[{a__}] :> FlexibleSUSY`M[a],
allOutputParameters /. FlexibleSUSY`M[{a__}] :> (FlexibleSUSY`M /@ {a})
]]];
poleMasses = {
Cases[expr, FlexibleSUSY`Pole[FlexibleSUSY`M[a_]] /; MemberQ[allOutputParameters,FlexibleSUSY`M[a]] :> FlexibleSUSY`M[a], {0,Infinity}],
Cases[expr, FlexibleSUSY`Pole[FlexibleSUSY`M[a_[__]]] /; MemberQ[allOutputParameters,FlexibleSUSY`M[a]] :> FlexibleSUSY`M[a], {0,Infinity}]
};
poleMasses = DeleteDuplicates[Flatten[poleMasses]];
inputPars = DeleteDuplicates[Select[symbols, (MemberQ[GetInputParameters[],#])&]];
modelPars = DeleteDuplicates[Select[symbols, (MemberQ[allModelParameters,#])&]];
outputPars = DeleteDuplicates[Select[symbols, (MemberQ[allOutPars,#])&]];
phases = DeleteDuplicates[Select[symbols, (MemberQ[Phases`GetArg /@ allPhases,#])&]];
depNum = DeleteDuplicates[Select[symbols, (MemberQ[GetDependenceSPhenoSymbols[],#])&]];
extraPars = DeleteDuplicates[Select[symbols, (MemberQ[GetExtraParameters[],#])&]];
{
FSModelParameters -> modelPars,
FSInputParameters -> inputPars,
FSOutputParameters -> outputPars,
FSPhysicalOutputParameters -> poleMasses,
FSPhases -> phases,
FSDerivedParameters -> depNum,
FSExtraParameters -> extraPars
}
];
ReplaceAllRespectingSARAHHeads[expr_, rules_] :=
Module[{pars, parsWithoutHeads, removeHeadsRules,
uniqueRules, uniqueExpr, uniqueSubs},
pars = Parameters`FindAllParameters[(#[[1]])& /@ rules];
removeHeadsRules = { SARAH`L[p_][__] :> p, SARAH`L[p_] :> p,
SARAH`B[p_][__] :> p, SARAH`B[p_] :> p,
SARAH`T[p_][__] :> p, SARAH`T[p_] :> p,
SARAH`Q[p_][__] :> p, SARAH`Q[p_] :> p
};
parsWithoutHeads = DeleteDuplicates[pars /. removeHeadsRules];
uniqueRules = DeleteDuplicates @ Flatten[{
Rule[SARAH`L[#], CConversion`ToValidCSymbol[SARAH`L[#]]],
Rule[SARAH`B[#], CConversion`ToValidCSymbol[SARAH`B[#]]],
Rule[SARAH`T[#], CConversion`ToValidCSymbol[SARAH`T[#]]],
Rule[SARAH`Q[#], CConversion`ToValidCSymbol[SARAH`Q[#]]]
}& /@ parsWithoutHeads];
uniqueExpr = expr /. uniqueRules;
uniqueSubs = rules /. uniqueRules;
(uniqueExpr /. uniqueSubs) /. (Reverse /@ uniqueRules)
];
IsScalar[sym_] :=
Length[SARAH`getDimParameters[sym]] === 1 || Length[SARAH`getDimParameters[sym]] == 0;
IsScalar[sym_?IsInputParameter] :=
MatchQ[GetType[sym], CConversion`ScalarType[_]];
IsScalar[sym_?IsExtraParameter] :=
MatchQ[GetType[sym], CConversion`ScalarType[_]];
IsMatrix[sym_[Susyno`LieGroups`i1, SARAH`i2]] :=
IsMatrix[sym];
IsMatrix[sym_] :=
Length[SARAH`getDimParameters[sym]] === 2;
IsMatrix[sym_?IsInputParameter] :=
MatchQ[GetType[sym], CConversion`MatrixType[__]];
IsMatrix[sym_?IsExtraParameter] :=
MatchQ[GetType[sym], CConversion`MatrixType[__]];
IsSymmetricMatrixParameter[sym_[Susyno`LieGroups`i1, SARAH`i2]] :=
IsSymmetricMatrixParameter[sym];
IsSymmetricMatrixParameter[sym_] :=
IsMatrix[sym] && MemberQ[SARAH`ListSoftBreakingScalarMasses, sym];
IsTensor[sym_[Susyno`LieGroups`i1, SARAH`i2, SARAH`i3]] :=
IsTensor[sym];
IsTensor[sym_?IsInputParameter] :=
MatchQ[GetType[sym], CConversion`TensorType[__]];
IsTensor[sym_?IsExtraParameter] :=
MatchQ[GetType[sym], CConversion`TensorType[__]];
IsTensor[sym_] :=
Length[SARAH`getDimParameters[sym]] > 2;
AllModelParametersAreReal[] := MemberQ[SARAH`RealParameters, All];
sarahIndices = {
SARAH`gt1, SARAH`gt2, SARAH`gt3, SARAH`gt4,
Susyno`LieGroups`i1 , SARAH`i2 , SARAH`i3 , SARAH`i4
};
IsIndex[i_?NumberQ] := True;
IsIndex[i_ /; MemberQ[sarahIndices,i]] := True;
IsIndex[_] := False;
IsIndex[indices_List] := And @@ (IsIndex /@ indices);
IsIndex[indices__] := IsIndex[{indices}];
GetIndices[parameter_[indices__] /; And @@ (IsIndex /@ {indices})] := {indices};
GetIndices[parameter_] := {};
IsPhase[parameter_] := MemberQ[Phases`GetArg /@ allPhases, Phases`GetArg[parameter]];
IsModelParameter[parameter_] := MemberQ[allModelParameters, parameter];
IsModelParameter[Re[parameter_]] := IsModelParameter[parameter];
IsModelParameter[Im[parameter_]] := IsModelParameter[parameter];
IsModelParameter[FlexibleSUSY`Temporary[parameter_]] := IsModelParameter[parameter];
IsModelParameter[parameter_[indices__] /; And @@ (IsIndex /@ {indices})] :=
IsModelParameter[parameter];
IsInputParameter[parameter_] := MemberQ[GetInputParameters[], parameter];
IsInputParameter[parameter_[indices__] /; And @@ (IsIndex /@ {indices})] :=
IsInputParameter[parameter];
IsOutputParameter[lst_List] := And @@ (IsOutputParameter /@ lst);
IsOutputParameter[sym_] := MemberQ[GetOutputParameters[],sym];
IsDerivedParameter[parameter_] := MemberQ[GetDependenceSPhenoSymbols[], parameter];
IsDerivedParameter[parameter_[indices__] /; And @@ (IsIndex /@ {indices})] :=
IsDerivedParameter[parameter];
IsExtraParameter[parameter_] := MemberQ[GetExtraParameters[], parameter];
IsExtraParameter[parameter_[indices__] /; And @@ (IsIndex /@ {indices})] :=
IsExtraParameter[parameter];
IsRealParameter[Re[sym_]] := True;
IsRealParameter[Im[sym_]] := True;
IsRealParameter[FlexibleSUSY`M[_]] := True;
IsRealParameter[sym_] :=
(IsModelParameter[sym] && AllModelParametersAreReal[]) ||
(IsInputParameter[sym] && CConversion`IsRealType[GetType[sym]]) ||
(IsExtraParameter[sym] && CConversion`IsRealType[GetType[sym]]) ||
MemberQ[Utils`ForceJoin[SARAH`realVar, additionalRealParameters, SARAH`RealParameters], sym];
IsComplexParameter[sym_] :=
!IsRealParameter[sym];
IsRealExpression[parameter_ /; IsModelParameter[parameter]] :=
IsRealParameter[parameter];
IsRealExpression[expr_?NumericQ] :=
Element[expr, Reals];
IsRealExpression[_Complex] := False;
IsRealExpression[_Real] := True;
IsRealExpression[expr_[Susyno`LieGroups`i1, SARAH`i2]] :=
IsRealExpression[expr];
IsRealExpression[HoldPattern[SARAH`Delta[_,_]]] := True;
IsRealExpression[HoldPattern[SARAH`ThetaStep[_,_]]] := True;
IsRealExpression[Cos[_]] := True;
IsRealExpression[Sin[_]] := True;
IsRealExpression[ArcCos[_]] := True;
IsRealExpression[ArcSin[_]] := True;
IsRealExpression[ArcTan[_]] := True;
IsRealExpression[Power[a_,b_]] := IsRealExpression[a] && IsRealExpression[b];
IsRealExpression[Susyno`LieGroups`conj[expr_]] :=
IsRealExpression[expr];
IsRealExpression[SARAH`Conj[expr_]] := IsRealExpression[expr];
IsRealExpression[Conjugate[expr_]] := IsRealExpression[expr];
IsRealExpression[Transpose[expr_]] := IsRealExpression[expr];
IsRealExpression[SARAH`Tp[expr_]] := IsRealExpression[expr];
IsRealExpression[SARAH`Adj[expr_]] := IsRealExpression[expr];
IsRealExpression[bar[expr_]] := IsRealExpression[expr];
IsRealExpression[expr_Symbol] := IsRealParameter[expr];
IsRealExpression[Times[Conjugate[a_],a_]] := True;
IsRealExpression[Times[a_,Conjugate[a_]]] := True;
IsRealExpression[Times[Susyno`LieGroups`conj[a_],a_]] := True;
IsRealExpression[Times[a_,Susyno`LieGroups`conj[a_]]] := True;
IsRealExpression[Times[SARAH`Conj[a_],a_]] := True;
IsRealExpression[Times[a_,SARAH`Conj[a_]]] := True;
IsRealExpression[factors_Times] :=
And @@ (IsRealExpression[#]& /@ (List @@ factors));
IsRealExpression[terms_Plus] :=
And @@ (IsRealExpression[#]& /@ (List @@ terms));
IsHermitian[a_] :=
Or[IsScalar[a] && IsRealParameter[a],
IsSymmetricMatrixParameter[a] && IsRealParameter[a],
MemberQ[SARAH`ListSoftBreakingScalarMasses, a]
];
(* helper function which calculates the adjoint of an expression *)
FSAdj[Susyno`LieGroups`conj[a_]] := SARAH`Tp[a];
FSAdj[SARAH`Tp[a_]] := a /; IsRealParameter[a];
FSAdj[SARAH`Tp[a_]] := Susyno`LieGroups`conj[a];
FSAdj[a_] := a /; IsHermitian[a];
FSAdj[a_] := SARAH`Adj[a];
FSAdj[a__] := Sequence @@ (FSAdj /@ Reverse[{a}]);
TraceEquality[SARAH`trace[a__], SARAH`trace[b__]] :=
Or @@ (({a} === #)& /@ NestList[RotateLeft, {b}, Length[{b}] - 1]);
(* if all parameters in the trace are real, the trace is real *)
IsRealExpression[SARAH`trace[a__]] :=
True /; And @@ (IsRealParameter /@ FindAllParameters[{a}]);
IsRealExpression[SARAH`trace[a__]] :=
TraceEquality[SARAH`trace[a] /. SARAH`Adj -> FSAdj, SARAH`trace[FSAdj[a]]];
IsRealExpression[terms_SARAH`MatMul] :=
And @@ (IsRealExpression[#]& /@ (List @@ terms));
IsRealExpression[sum[index_, start_, stop_, expr_]] :=
IsRealExpression[expr];
IsRealExpression[otherwise_] := False;
HasPhase[particle_] :=
MemberQ[#[[1]]& /@ SARAH`ParticlePhases, particle];
GetPhase[particle_ /; HasPhase[particle]] :=
Cases[SARAH`ParticlePhases, {particle, phase_} :> phase][[1]];
GetPhase[_] := Null;
GetTypeFromDimension[sym_, {}] :=
If[IsRealParameter[sym],
CConversion`ScalarType[CConversion`realScalarCType],
CConversion`ScalarType[CConversion`complexScalarCType]
];
GetTypeFromDimension[sym_, {0|1}] :=
GetTypeFromDimension[sym, {}];
GetTypeFromDimension[sym_, {num_?NumberQ}] :=
Module[{scalarType},
scalarType = If[IsRealParameter[sym],
CConversion`realScalarCType,
CConversion`complexScalarCType
];
CConversion`VectorType[scalarType, num]
];
GetTypeFromDimension[sym_, {num1_?NumberQ, num2_?NumberQ}] :=
If[IsRealParameter[sym],
CConversion`MatrixType[CConversion`realScalarCType, num1, num2],
CConversion`MatrixType[CConversion`complexScalarCType, num1, num2]
];
GetTypeFromDimension[sym_, {dims__} /; Length[{dims}] > 2 && (And @@ (NumberQ /@ {dims}))] :=
If[IsRealParameter[sym],
CConversion`TensorType[CConversion`realScalarCType, dims],
CConversion`TensorType[CConversion`complexScalarCType, dims]
];
GetRealTypeFromDimension[{}] :=
CConversion`ScalarType[CConversion`realScalarCType];
GetRealTypeFromDimension[{0}] :=
GetRealTypeFromDimension[{}];
GetRealTypeFromDimension[{1}] :=
GetRealTypeFromDimension[{}];
GetRealTypeFromDimension[{num_?NumberQ}] :=
CConversion`VectorType[CConversion`realScalarCType, num];
GetRealTypeFromDimension[{num1_?NumberQ, num2_?NumberQ}] :=
CConversion`MatrixType[CConversion`realScalarCType, num1, num2];
GetRealTypeFromDimension[{dims__} /; Length[{dims}] > 2 && (And @@ (NumberQ /@ {dims}))] :=
CConversion`TensorType[CConversion`realScalarCType, dims];
GetComplexTypeFromDimension[{}] :=
CConversion`ScalarType[CConversion`complexScalarCType];
GetComplexTypeFromDimension[{0}] :=
GetComplexTypeFromDimension[{}];
GetComplexTypeFromDimension[{1}] :=
GetComplexTypeFromDimension[{}];
GetComplexTypeFromDimension[{num_?NumberQ}] :=
CConversion`VectorType[CConversion`complexScalarCType, num];
GetComplexTypeFromDimension[{num1_?NumberQ, num2_?NumberQ}] :=
CConversion`MatrixType[CConversion`complexScalarCType, num1, num2];
GetComplexTypeFromDimension[{dims__} /; Length[{dims}] > 2 && (And @@ (NumberQ /@ {dims}))] :=
CConversion`TensorType[CConversion`complexScalarCType, dims];
GetType[FlexibleSUSY`SCALE] := GetRealTypeFromDimension[{}];
GetType[FlexibleSUSY`M[sym_]] :=
GetRealTypeFromDimension[{SARAH`getGen[sym, FlexibleSUSY`FSEigenstates]}];
GetType[sym_?IsInputParameter] :=
Cases[GetInputParametersAndTypes[], {sym, _, type_} :> type][[1]];
GetType[sym_?IsExtraParameter] :=
Cases[GetExtraParametersAndTypes[], {sym, type_} :> type][[1]];
GetType[sym_] :=
GetTypeFromDimension[sym, SARAH`getDimParameters[sym]];
GetType[sym_[indices__] /; And @@ (IsIndex /@ {indices})] :=
GetType[sym]
GetParameterDimensions[sym_ /; (IsInputParameter[sym] || IsExtraParameter[sym])] :=
Module[{type},
type = GetType[sym];
Switch[type,
CConversion`ScalarType[_], {1},
CConversion`VectorType[_, n_], {type[[2]]},
CConversion`ArrayType[_, n_], {type[[2]]},
CConversion`MatrixType[_, m_, n_], {type[[2]], type[[3]]},
CConversion`TensorType[_, indices__], List @@ Rest[type],
_, Print["Error: unknown parameter type: ", ToString[type]]; Quit[1];
]
];
GetParameterDimensions[sym_] :=
Module[{dim},
dim = SARAH`getDimParameters[sym];
Switch[dim,
{}, {1},
{0}, {1},
_, dim
]
];
CreateIndexReplacementRule[{parameter_, CConversion`ScalarType[_]}] := {};
CreateIndexReplacementRule[{parameter_, CConversion`VectorType[_,_] | CConversion`ArrayType[_,_]}] :=
Module[{i},
RuleDelayed @@ Rule[parameter[i_], parameter[i-1]]
];
CreateIndexReplacementRule[{parameter_, CConversion`MatrixType[_,_,_]}] :=
Module[{i,j},
RuleDelayed @@ Rule[parameter[i_,j_], parameter[i-1,j-1]]
];
CreateIndexReplacementRule[{parameter_, CConversion`TensorType[_,_,_,_]}] :=
Module[{i,j,k},
RuleDelayed @@ Rule[parameter[i_,j_,k_], parameter[i-1,j-1,k-1]]
];
CreateIndexReplacementRule[{parameter_, CConversion`TensorType[_,_,_,_,_]}] :=
Module[{i,j,k,l},
RuleDelayed @@ Rule[parameter[i_,j_,k_,l_], parameter[i-1,j-1,k-1,l-1]]
];
CreateIndexReplacementRule[parameter_ /; (IsInputParameter[parameter] || IsExtraParameter[parameter])] :=
CreateIndexReplacementRule[{parameter, GetType[parameter]}];
CreateIndexReplacementRule[parameter_] :=
Module[{i,j,k,l, dim, rule},
dim = SARAH`getDimParameters[parameter];
rule = {};
Switch[Length[dim],
1, rule = RuleDelayed @@ Rule[parameter[i_], parameter[i-1]];,
2, rule = RuleDelayed @@ Rule[parameter[i_,j_], parameter[i-1,j-1]];,
3, rule = RuleDelayed @@ Rule[parameter[i_,j_,k_], parameter[i-1,j-1,k-1]];,
4, rule = RuleDelayed @@ Rule[parameter[i_,j_,k_,l_], parameter[i-1,j-1,k-1,l-1]];
];
rule
];
CreateIndexReplacementRules[pars_List] :=
Flatten[CreateIndexReplacementRule /@ pars];
GetGUTNormalization[coupling_Symbol] :=
Module[{pos, norm},
pos = Position[SARAH`Gauge, coupling];
If[pos =!= {},
norm = SARAH`GUTren[pos[[1,1]]];
If[NumericQ[norm],
Return[norm];
];
];
Return[1];
];
ApplyGUTNormalization[] :=
Module[{i, rules = {}, coupling},
For[i = 1, i <= Length[SARAH`Gauge], i++,
If[NumericQ[SARAH`GUTren[i]],
coupling = SARAH`Gauge[[i,4]];
AppendTo[rules, Rule[coupling, coupling SARAH`GUTren[i]]];
];
];
Return[rules];
];
CreateParameterDefinition[par_] :=
CConversion`CreateCType[GetType[par]] <> " " <> CConversion`ToValidCSymbolString[par] <> ";\n";
CreateParameterDefinition[{par_, type_}] :=
CConversion`CreateCType[type] <> " " <> CConversion`ToValidCSymbolString[par] <> ";\n";
CreateParameterDefinition[{par_, block_, type_}] :=
CConversion`CreateCType[type] <> " " <> CConversion`ToValidCSymbolString[par] <> ";\n";
CreateParameterDefinitionAndDefaultInitialize[par_] :=
CConversion`CreateCType[GetType[par]] <> " " <> CConversion`ToValidCSymbolString[par] <> "{};\n";
CreateParameterDefinitionAndDefaultInitialize[{par_, type_}] :=
CConversion`CreateCType[type] <> " " <> CConversion`ToValidCSymbolString[par] <>
CConversion`CreateDefaultAggregateInitialization[type] <> ";\n";
CreateParameterDefinitionAndDefaultInitialize[{par_, block_, type_}] :=
CConversion`CreateCType[type] <> " " <> CConversion`ToValidCSymbolString[par] <>
CConversion`CreateDefaultAggregateInitialization[type] <> ";\n";
CreateSetAssignment[name_, startIndex_, parameterType_, struct_:"pars"] :=
Block[{},
Print["Error: CreateSetAssignment: unknown parameter type: ", ToString[parameterType]];
Quit[1];
];
CreateSetAssignment[name_, startIndex_, CConversion`ScalarType[CConversion`realScalarCType | CConversion`integerScalarCType], struct_:"pars"] :=
Module[{ass = ""},
ass = name <> " = " <> struct <> "(" <> ToString[startIndex] <> ");\n";
Return[{ass, 1}];
];
CreateSetAssignment[name_, startIndex_, CConversion`ScalarType[CConversion`complexScalarCType], struct_:"pars"] :=
Module[{ass = "", type},
type = CConversion`CreateCType[CConversion`ScalarType[CConversion`complexScalarCType]];
ass = name <> " = " <> type <> "(" <> struct <> "(" <> ToString[startIndex] <>
"), " <> struct <> "(" <> ToString[startIndex + 1] <> "));\n";
Return[{ass, 2}];
];
CreateSetAssignment[name_, startIndex_, (CConversion`VectorType | CConversion`ArrayType)[CConversion`realScalarCType, rows_], struct_:"pars"] :=
Module[{ass = "", i, count = 0},
For[i = 0, i < rows, i++; count++,
ass = ass <> name <> "(" <> ToString[i] <> ") = " <> struct <> "(" <>
ToString[startIndex + count] <> ");\n";
];
If[rows != count,
Print["Error: CreateSetAssignment: something is wrong with the indices: "
<> ToString[rows] <> " != " <> ToString[count]];];
Return[{ass, rows}];
];
CreateSetAssignment[name_, startIndex_, (CConversion`VectorType | CConversion`ArrayType)[CConversion`complexScalarCType, rows_], struct_:"pars"] :=
Module[{ass = "", i, count = 0, type},
type = CConversion`CreateCType[CConversion`ScalarType[complexScalarCType]];
For[i = 0, i < rows, i++; count+=2,
ass = ass <> name <> "(" <> ToString[i] <> ") = " <>
type <> "(" <> struct <>
"(" <> ToString[startIndex + count ] <> "), " <> struct <>
"(" <> ToString[startIndex + count + 1] <> "));\n";
];
If[2 * rows != count,
Print["Error: CreateSetAssignment: something is wrong with the indices: "
<> ToString[rows] <> " != " <> ToString[count]];];
Return[{ass, count}];
];
CreateSetAssignment[name_, startIndex_, CConversion`MatrixType[CConversion`realScalarCType, rows_, cols_], struct_:"pars"] :=
Module[{ass = "", i, j, count = 0},
For[i = 0, i < rows, i++,
For[j = 0, j < cols, j++; count++,
ass = ass <> name <> "(" <> ToString[i] <> "," <> ToString[j]
<> ") = " <> struct <> "(" <> ToString[startIndex + count] <> ");\n";
];
];
If[rows * cols != count,
Print["Error: CreateSetAssignment: something is wrong with the indices: "
<> ToString[rows * cols] <> " != " <> ToString[count]];];
Return[{ass, count}];
];
CreateSetAssignment[name_, startIndex_, CConversion`MatrixType[CConversion`complexScalarCType, rows_, cols_], struct_:"pars"] :=
Module[{ass = "", i, j, count = 0, type},
type = CConversion`CreateCType[CConversion`ScalarType[complexScalarCType]];
For[i = 0, i < rows, i++,
For[j = 0, j < cols, j++; count+=2,
ass = ass <> name <> "(" <> ToString[i] <> "," <> ToString[j] <>
") = " <> type <> "(" <> struct <>
"(" <> ToString[startIndex + count ] <> "), " <> struct <>
"(" <> ToString[startIndex + count + 1] <> "));\n";
];
];
If[2 * rows * cols != count,
Print["Error: CreateSetAssignment: something is wrong with the indices: "
<> ToString[2 rows * cols] <> " != " <> ToString[count]];];
Return[{ass, count}];
];
CreateSetAssignment[name_, startIndex_, CConversion`TensorType[CConversion`realScalarCType, dim1_, dim2_, dim3_]] :=
Module[{ass = "", i, j, k, count = 0},
For[i = 0, i < dim1, i++,
For[j = 0, j < dim2, j++,
For[k = 0, k < dim3, k++; count++,
ass = ass <> name <> "(" <> ToString[i] <> "," <> ToString[j] <>
"," <> ToString[k] <>
") = pars(" <> ToString[startIndex + count] <> ");\n";
];
];
];
If[dim1 * dim2 * dim3 != count,
Print["Error: CreateSetAssignment: something is wrong with the indices: "
<> ToString[dim1 dim2 dim3] <> " != " <> ToString[count]];];
Return[{ass, count}];
];
CreateSetAssignment[name_, startIndex_, CConversion`TensorType[CConversion`complexScalarCType, dim1_, dim2_, dim3_]] :=
Module[{ass = "", i, j, k, count = 0, type},
type = CConversion`CreateCType[CConversion`ScalarType[complexScalarCType]];
For[i = 0, i < dim1, i++,
For[j = 0, j < dim2, j++,
For[k = 0, k < dim3, k++; count+=2,
ass = ass <> name <> "(" <> ToString[i] <> "," <> ToString[j] <> "," <>
ToString[k] <> ") = " <> type <> "(" <>
"pars(" <> ToString[startIndex + count ] <> "), " <>
"pars(" <> ToString[startIndex + count + 1] <> "));\n";
];
];
];
If[2 * dim1 * dim2 * dim3 != count,
Print["Error: CreateSetAssignment: something is wrong with the indices: "
<> ToString[2 dim1 dim2 dim3] <> " != " <> ToString[count]];];
Return[{ass, count}];
];
(* assigns the parameter (str) to the container element *)
DisplayAssignParSet[str_String, startIndex_, currIdx_, struct_String] :=
struct <> "(" <> ToString[startIndex + currIdx - 1] <> ") = " <> str <> ";\n";
(* creates parameter name and calls SetterFunc[] (= DisplayAssignParSet[] by default) *)
DisplayAssignPar[(h:(Re|Im))[(par_String)[idx__]], startIndex_, currIdx_, struct_String, SetterFunc_:DisplayAssignParSet] :=
SetterFunc[ToString[h] <> "(" <> par <> "(" <>
Utils`StringJoinWithSeparator[{idx}, ","] <>
"))", startIndex, currIdx, struct];
DisplayAssignPar[(par_String)[idx__], startIndex_, currIdx_, struct_String, SetterFunc_:DisplayAssignParSet] :=
SetterFunc[par <> "(" <>
Utils`StringJoinWithSeparator[{idx}, ","] <>
")", startIndex, currIdx, struct];
DisplayAssignPar[(h:(Re|Im))[par_String], startIndex_, currIdx_, struct_String, SetterFunc_:DisplayAssignParSet] :=
SetterFunc[ToString[h] <> "(" <> par <> ")", startIndex, currIdx, struct];
DisplayAssignPar[par_, startIndex_, currIdx_, struct_String, SetterFunc_:DisplayAssignParSet] :=
SetterFunc[CConversion`RValueToCFormString[par], startIndex, currIdx, struct];
CreateDisplayAssignment[name_, startIndex_, type_, struct_:"pars"] :=
{ StringJoin @
MapIndexed[DisplayAssignPar[#1,startIndex,First[#2],struct]&,
DecomposeParameter[name, type]],
Length[DecomposeParameter[name, type]]
};
(* assigns the string (str) to the std container element *)
DisplayAssignNameSet[str_String, startIndex_, currIdx_, struct_String] :=
struct <> "[" <> ToString[startIndex + currIdx - 1] <> "] = \"" <> str <> "\";\n";
(* creates parameter name and calls DisplayAssignNameSet[] *)
DisplayAssignName[par_, startIndex_, currIdx_, struct_String] :=
DisplayAssignPar[par, startIndex, currIdx, struct, DisplayAssignNameSet];
CreateStdVectorNamesAssignment[name_, startIndex_, type_, struct_:"names"] :=
{ StringJoin @
MapIndexed[DisplayAssignName[#1,startIndex,First[#2],struct]&,
DecomposeParameter[name, type]],
Length[DecomposeParameter[name, type]]
};
CreateParameterSARAHNameStr[par_] :=
"\"" <> CConversion`RValueToCFormString[par] <> "\"";
CreateParameterSARAHNames[name_, type_] :=
Utils`StringJoinWithSeparator[CreateParameterSARAHNameStr /@ DecomposeParameter[name, type], ", "];
(* decomposes a parameter into its real pieces *)
DecomposeParameter[par_, parameterType_] :=
Block[{},
Print["Error: DecomposeParameter: unknown parameter type: ",
ToString[parameterType]];
Quit[1];
];
DecomposeParameter[name_, CConversion`ScalarType[CConversion`realScalarCType | CConversion`integerScalarCType]] :=
{ name };
DecomposeParameter[name_, CConversion`ScalarType[CConversion`complexScalarCType]] :=
{ Re[name], Im[name] };
DecomposeParameter[name_, (CConversion`VectorType|CConversion`ArrayType)[CConversion`realScalarCType, rows_]] :=
Array[name, rows, 0];
DecomposeParameter[name_, (CConversion`VectorType|CConversion`ArrayType)[CConversion`complexScalarCType, rows_]] :=
Flatten[{Re[#], Im[#]}& /@ Array[name, rows, 0]];
DecomposeParameter[name_, CConversion`MatrixType[CConversion`realScalarCType, rows_, cols_]] :=
Flatten[Array[name, {rows, cols}, 0]];
DecomposeParameter[name_, CConversion`MatrixType[CConversion`complexScalarCType, rows_, cols_]] :=
Flatten[{Re[#], Im[#]}& /@ Flatten[Array[name, {rows,cols}, 0]]];
DecomposeParameter[name_, CConversion`TensorType[CConversion`realScalarCType, dims__]] :=
Flatten[Array[name, {dims}, 0]];
DecomposeParameter[name_, CConversion`TensorType[CConversion`complexScalarCType, dims__]] :=
Flatten[{Re[#], Im[#]}& /@ Flatten[Array[name, {dims}, 0]]];
CreateEnumName[(h:(Re|Im))[par_]] :=
CreateEnumName[h] <> CreateEnumName[par];
CreateEnumName[par_[idx__]] :=
CreateEnumName[par] <>
Utils`StringJoinWithSeparator[{idx}, "_", CConversion`ToValidCSymbolString];
CreateEnumName[par_] :=