forked from Expander/FlexibleSUSY
-
Notifications
You must be signed in to change notification settings - Fork 14
/
FlexibleSUSY.m
3406 lines (3131 loc) · 210 KB
/
FlexibleSUSY.m
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
BeginPackage["FlexibleSUSY`",
{"SARAH`", "AnomalousDimension`", "BetaFunction`",
"TextFormatting`", "CConversion`", "TreeMasses`",
"EWSB`", "Traces`", "SelfEnergies`", "Vertices`",
"Phases`", "LoopMasses`", "WriteOut`", "Constraint`",
"ThresholdCorrections`", "ConvergenceTester`", "Utils`",
"ThreeLoopSM`", "ThreeLoopMSSM`", "Observables`",
"GMuonMinus2`", "EffectiveCouplings`", "SemiAnalytic`",
"FlexibleEFTHiggsMatching`", "FSMathLink`",
"FlexibleTower`"}];
$flexiblesusyMetaDir = DirectoryName[FindFile[$Input]];
$flexiblesusyConfigDir = FileNameJoin[{ParentDirectory[$flexiblesusyMetaDir], "config"}];
$flexiblesusyTemplateDir = FileNameJoin[{ParentDirectory[$flexiblesusyMetaDir], "templates"}];
FS`Version = StringTrim[FSImportString[FileNameJoin[{$flexiblesusyConfigDir,"version"}]]];
FS`GitCommit = StringTrim[FSImportString[FileNameJoin[{$flexiblesusyConfigDir,"git_commit"}]]];
FS`Authors = {"P. Athron", "J.-h. Park", "D. Stöckinger", "A. Voigt"};
FS`Years = "2013-2015";
FS`References = Get[FileNameJoin[{$flexiblesusyConfigDir,"references"}]];
Print["==================================================================="];
Print[Style["FlexibleSUSY " <> FS`Version, Larger, Bold, Blue]];
Print[" by " <> Utils`StringJoinWithSeparator[FS`Authors, ", "] <> ", " <>
FS`Years];
Print[""];
Print[Style["References:", Blue]];
Print[" " <> #]& /@ FS`References;
Print[""];
Print[Style["Download and Documentation:", Blue]];
Print[" https://flexiblesusy.hepforge.org"];
Print["==================================================================="];
Print[""];
Print["meta code directory: ", $flexiblesusyMetaDir];
Print["config directory : ", $flexiblesusyConfigDir];
Print["templates directory: ", $flexiblesusyTemplateDir];
MakeFlexibleSUSY::usage="Creates a spectrum generator given a
FlexibleSUSY model file (FlexibleSUSY.m).
Example:
MakeFlexibleSUSY[
InputFile -> \"models/<model>/FlexibleSUSY.m\",
OutputDirectory -> \"models/<model>/\",
DebugOutput -> False];
Options:
InputFile: The name of the model file.
OutputDirectory: The output directory for the generated code.
DebugOutput (True|False): Enable/Disable debug output while running
the Mathematica meta code.
";
LowPrecision::usage="";
MediumPrecision::usage="";
HighPrecision::usage="";
GUTNormalization::usage="Returns GUT normalization of a given coupling";
BETA::usage = "Head for beta functions"
FSModelName;
FSOutputDir = ""; (* directory for generated code *)
FSLesHouchesList;
FSUnfixedParameters;
EWSBOutputParameters = {};
EWSBInitialGuess = {};
EWSBSubstitutions = {};
SUSYScale;
SUSYScaleFirstGuess;
SUSYScaleInput = {};
SUSYScaleMinimum;
SUSYScaleMaximum;
HighScale;
HighScaleFirstGuess;
HighScaleInput = {};
HighScaleMinimum;
HighScaleMaximum;
LowScale;
LowScaleFirstGuess;
LowScaleInput = {};
LowScaleMinimum;
LowScaleMaximum;
InitialGuessAtLowScale = {};
InitialGuessAtSUSYScale = {};
InitialGuessAtHighScale = {};
OnlyLowEnergyFlexibleSUSY = False;
FlexibleEFTHiggs = False;
SUSYScaleMatching={};
AutomaticInputAtMSUSY = True; (* input unfixed parameters at MSUSY *)
TreeLevelEWSBSolution = {};
Pole;
LowEnergyConstant;
LowEnergyGaugeCoupling;
FSMinimize;
FSFindRoot;
FSSolveEWSBFor;
FSSolveEWSBTreeLevelFor = {};
Temporary;
MZ;
MT;
MZDRbar;
MWDRbar;
EDRbar;
ThetaWDRbar;
SCALE;
THRESHOLD;
VEV::usage = "running SM-like VEV in the full model";
UseHiggs2LoopNMSSM;
EffectiveMu;
EffectiveMASqr;
UseSM3LoopRGEs = False;
UseMSSM3LoopRGEs = False;
UseHiggs2LoopSM;
UseHiggs3LoopSplit;
UseYukawa3LoopQCD = Automatic;
FSRGELoopOrder = 2; (* RGE loop order (0, 1 or 2) *)
PotentialLSPParticles = {};
ExtraSLHAOutputBlocks = {};
FSExtraInputParameters = {};
FSAuxiliaryParameterInfo = {};
IMEXTPAR = {};
(* Standard Model input parameters (SLHA input parameters) *)
(* {parameter, {"block", entry}, type} *)
SMINPUTS = {
{AlphaEMInvInput , {"SMINPUTS", 1}, CConversion`ScalarType[CConversion`realScalarCType]},
{GFermiInput , {"SMINPUTS", 2}, CConversion`ScalarType[CConversion`realScalarCType]},
{AlphaSInput , {"SMINPUTS", 3}, CConversion`ScalarType[CConversion`realScalarCType]},
{MZPoleInput , {"SMINPUTS", 4}, CConversion`ScalarType[CConversion`realScalarCType]},
{MBottomMbottomInput, {"SMINPUTS", 5}, CConversion`ScalarType[CConversion`realScalarCType]},
{MTopPoleInput , {"SMINPUTS", 6}, CConversion`ScalarType[CConversion`realScalarCType]},
{MTauPoleInput , {"SMINPUTS", 7}, CConversion`ScalarType[CConversion`realScalarCType]},
{MNeutrino3PoleInput, {"SMINPUTS", 8}, CConversion`ScalarType[CConversion`realScalarCType]},
{MWPoleInput , {"SMINPUTS", 10}, CConversion`ScalarType[CConversion`realScalarCType]},
{MElectronPoleInput , {"SMINPUTS", 11}, CConversion`ScalarType[CConversion`realScalarCType]},
{MNeutrino1PoleInput, {"SMINPUTS", 12}, CConversion`ScalarType[CConversion`realScalarCType]},
{MMuonPoleInput , {"SMINPUTS", 13}, CConversion`ScalarType[CConversion`realScalarCType]},
{MNeutrino2PoleInput, {"SMINPUTS", 14}, CConversion`ScalarType[CConversion`realScalarCType]},
{MDown2GeVInput , {"SMINPUTS", 21}, CConversion`ScalarType[CConversion`realScalarCType]},
{MUp2GeVInput , {"SMINPUTS", 22}, CConversion`ScalarType[CConversion`realScalarCType]},
{MStrange2GeVInput , {"SMINPUTS", 23}, CConversion`ScalarType[CConversion`realScalarCType]},
{MCharmMCharm , {"SMINPUTS", 24}, CConversion`ScalarType[CConversion`realScalarCType]}
};
(* renormalization schemes *)
DRbar;
MSbar;
FSRenormalizationScheme = DRbar;
(* all model parameters are real by default *)
SARAH`RealParameters = { All };
(* precision of pole mass calculation *)
DefaultPoleMassPrecision = MediumPrecision;
HighPoleMassPrecision = {SARAH`HiggsBoson, SARAH`PseudoScalar, SARAH`ChargedHiggs};
MediumPoleMassPrecision = {};
LowPoleMassPrecision = {};
FSEigenstates = SARAH`EWSB;
FSSolveEWSBTimeConstraint = 120;
FSSimplifyBetaFunctionsTimeConstraint = 120;
FSSolveWeinbergAngleTimeConstraint = 120;
FSCheckPerturbativityOfDimensionlessParameters = True;
FSPerturbativityThreshold = N[Sqrt[4 Pi]];
FSMaximumExpressionSize = 100;
(* list of masses and parameters to check for convergence
Example:
FSConvergenceCheck = {
M[hh], g3, Yu, Yd[3,3], Ye, B[\[Mu]]
};
*)
FSConvergenceCheck = Automatic;
(* EWSB solvers *)
GSLHybrid; (* hybrid method *)
GSLHybridS; (* hybrid method with dynamic step size *)
GSLBroyden; (* Broyden method *)
GSLNewton; (* Newton method *)
FPIRelative; (* Fixed point iteration, convergence crit. relative step size *)
FPIAbsolute; (* Fixed point iteration, convergence crit. absolute step size *)
FPITadpole; (* Fixed point iteration, convergence crit. relative step size + tadpoles *)
FSEWSBSolvers = { FPIRelative, GSLHybridS, GSLBroyden };
(* BVP solvers *)
TwoScaleSolver; (* two-scale algorithm *)
LatticeSolver; (* lattice algorithm *)
SemiAnalyticSolver; (* semi-analytic algorithm *)
FSBVPSolvers = { TwoScaleSolver };
(* macros *)
IF;
SUM;
(* input value for the calculation of the weak mixing angle *)
FSFermiConstant;
FSMassW;
{FSHiggs, FSHyperchargeCoupling,
FSLeftCoupling, FSStrongCoupling, FSVEVSM1, FSVEVSM2, FSNeutralino,
FSChargino, FSNeutralinoMM, FSCharginoMinusMM, FSCharginoPlusMM,
FSHiggsMM, FSSelectronL, FSSelectronNeutrinoL, FSSmuonL,
FSSmuonNeutrinoL, FSVectorW, FSVectorZ, FSElectronYukawa};
FSWeakMixingAngleOptions = {
FlexibleSUSY`FSWeakMixingAngleInput -> FSFermiConstant, (* or FSMassW *)
FlexibleSUSY`FSWeakMixingAngleExpr -> ArcSin[Sqrt[1 - Mass[SARAH`VectorW]^2/Mass[SARAH`VectorZ]^2]],
FlexibleSUSY`FSHiggs -> SARAH`HiggsBoson,
FlexibleSUSY`FSHyperchargeCoupling -> SARAH`hyperchargeCoupling,
FlexibleSUSY`FSLeftCoupling -> SARAH`leftCoupling,
FlexibleSUSY`FSStrongCoupling -> SARAH`strongCoupling,
FlexibleSUSY`FSVEVSM1 -> SARAH`VEVSM1,
FlexibleSUSY`FSVEVSM2 -> SARAH`VEVSM2,
FlexibleSUSY`FSNeutralino :> Parameters`GetParticleFromDescription["Neutralinos"],
FlexibleSUSY`FSChargino :> Parameters`GetParticleFromDescription["Charginos"],
FlexibleSUSY`FSNeutralinoMM -> SARAH`NeutralinoMM,
FlexibleSUSY`FSCharginoMinusMM -> SARAH`CharginoMinusMM,
FlexibleSUSY`FSCharginoPlusMM -> SARAH`CharginoPlusMM,
FlexibleSUSY`FSHiggsMM -> SARAH`HiggsMixingMatrix,
FlexibleSUSY`FSSelectronL :> Sum[Susyno`LieGroups`conj[SARAH`SleptonMM[Susyno`LieGroups`i,1]] SARAH`SleptonMM[Susyno`LieGroups`i,1] FlexibleSUSY`M[SARAH`Selectron[Susyno`LieGroups`i]], {Susyno`LieGroups`i,1,TreeMasses`GetDimension[SARAH`Selectron]}],
FlexibleSUSY`FSSelectronNeutrinoL :> Sum[Susyno`LieGroups`conj[SARAH`SneutrinoMM[Susyno`LieGroups`i,1]] SARAH`SneutrinoMM[Susyno`LieGroups`i,1] FlexibleSUSY`M[SARAH`Sneutrino[Susyno`LieGroups`i]], {Susyno`LieGroups`i,1,TreeMasses`GetDimension[SARAH`Sneutrino]}],
FlexibleSUSY`FSSmuonL :> Sum[Susyno`LieGroups`conj[SARAH`SleptonMM[Susyno`LieGroups`i,2]] SARAH`SleptonMM[Susyno`LieGroups`i,2] FlexibleSUSY`M[SARAH`Selectron[Susyno`LieGroups`i]], {Susyno`LieGroups`i,1,TreeMasses`GetDimension[SARAH`Selectron]}],
FlexibleSUSY`FSSmuonNeutrinoL :> Sum[Susyno`LieGroups`conj[SARAH`SneutrinoMM[Susyno`LieGroups`i,2]] SARAH`SneutrinoMM[Susyno`LieGroups`i,2] FlexibleSUSY`M[SARAH`Sneutrino[Susyno`LieGroups`i]], {Susyno`LieGroups`i,1,TreeMasses`GetDimension[SARAH`Sneutrino]}],
FlexibleSUSY`FSVectorW -> SARAH`VectorW,
FlexibleSUSY`FSVectorZ -> SARAH`VectorZ,
FlexibleSUSY`FSElectronYukawa -> SARAH`ElectronYukawa
};
ReadPoleMassPrecisions::ImpreciseHiggs="Warning: Calculating the Higgs pole mass M[`1`] with `2` will lead to an inaccurate result! Please select MediumPrecision or HighPrecision (recommended) for `1`.";
tadpole::usage="symbolic expression for a tadpole contribution in the
EWSB eqs. The index corresponds to the ordering of the tadpole
equations in SARAH`TadpoleEquations[] .";
NoScale::usage="placeholder indicating an SLHA block should not
have a scale associated with it.";
CurrentScale::usage="placeholder indicating the current renormalization
scale of the model.";
FSDebugOutput = False;
Begin["`Private`"];
allIndexReplacementRules = {};
GetIndexReplacementRules[] := allIndexReplacementRules;
allBetaFunctions = {};
GetBetaFunctions[] := allBetaFunctions;
allOutputParameters = {};
numberOfModelParameters = 0;
allEWSBSolvers = { GSLHybrid, GSLHybridS, GSLBroyden, GSLNewton,
FPIRelative, FPIAbsolute, FPITadpole };
allBVPSolvers = { TwoScaleSolver, LatticeSolver, SemiAnalyticSolver };
HaveEWSBSolver[solver_] := MemberQ[FlexibleSUSY`FSEWSBSolvers, solver];
HaveBVPSolver[solver_] := MemberQ[FlexibleSUSY`FSBVPSolvers, solver];
PrintHeadline[text_] :=
Block[{},
Print[""];
Print["---------------------------------"];
Print[text];
Print["---------------------------------"];
];
DecomposeVersionString[version_String] :=
ToExpression /@ StringSplit[version, "."];
ToVersionString[{major_Integer, minor_Integer, patch_Integer}] :=
ToString[major] <> "." <> ToString[minor] <> "." <> ToString[patch];
DebugPrint[msg___] :=
If[FlexibleSUSY`FSDebugOutput,
Print["Debug<FlexibleSUSY>: ", Sequence @@ InputFormOfNonStrings /@ {msg}]];
CheckSARAHVersion[] :=
Module[{minimRequired, minimRequiredVersionFile, sarahVersion},
Print["Checking SARAH version ..."];
minimRequiredVersionFile = FileNameJoin[{$flexiblesusyConfigDir,
"required_sarah_version.m"}];
(* reading minimum required SARAH version from config file *)
minimRequired = Get[minimRequiredVersionFile];
If[minimRequired === $Failed,
Print["Error: Cannot read required SARAH version from file ",
minimRequiredVersionFile];
Print[" Did you run configure?"];
Quit[1];
];
sarahVersion = DecomposeVersionString[SA`Version];
If[sarahVersion[[1]] < minimRequired[[1]] ||
(sarahVersion[[1]] == minimRequired[[1]] &&
sarahVersion[[2]] < minimRequired[[2]]) ||
(sarahVersion[[1]] == minimRequired[[1]] &&
sarahVersion[[2]] == minimRequired[[2]] &&
sarahVersion[[3]] < minimRequired[[3]]),
Print["Error: SARAH version ", SA`Version, " no longer supported!"];
Print["Please use version ", ToVersionString[minimRequired],
" or higher"];
Quit[1];
];
];
CheckFermiConstantInputRequirements[requiredSymbols_List, printout_:True] :=
Module[{resolvedSymbols, symbols, areDefined, availPars},
resolvedSymbols = requiredSymbols /. FlexibleSUSY`FSWeakMixingAngleOptions;
resolvedSymbols = resolvedSymbols /. {
a_[idx__] :> a /; And @@ (NumberQ /@ {idx})
};
symbols = DeleteDuplicates[Cases[resolvedSymbols, _Symbol, {0,Infinity}]];
availPars = Join[TreeMasses`GetParticles[],
Parameters`GetInputParameters[],
Parameters`GetModelParameters[],
Parameters`GetOutputParameters[]];
areDefined = MemberQ[availPars, #]& /@ symbols;
If[printout,
Print["Unknown symbol: ", #]& /@
Cases[Utils`Zip[areDefined, symbols], {False, p_} :> p];
];
And @@ areDefined
];
CheckFermiConstantInputRequirementsForSUSYModel[] :=
CheckFermiConstantInputRequirements[
{FSHiggs, FSHyperchargeCoupling,
FSLeftCoupling, FSStrongCoupling, FSVEVSM1, FSVEVSM2,
FSNeutralino, FSChargino, FSNeutralinoMM, FSCharginoMinusMM,
FSCharginoPlusMM, FSHiggsMM, FSSelectronL, FSSelectronNeutrinoL,
FSSmuonL, FSSmuonNeutrinoL, FSVectorW, FSVectorZ,
FSElectronYukawa}
];
CheckFermiConstantInputRequirementsForNonSUSYModel[] :=
CheckFermiConstantInputRequirements[
{FSHiggs, FSHyperchargeCoupling,
FSLeftCoupling, FSStrongCoupling, FSVectorW, FSVectorZ,
FSElectronYukawa}
];
CheckWeakMixingAngleInputRequirements[input_] :=
Switch[input,
FlexibleSUSY`FSFermiConstant,
Switch[SARAH`SupersymmetricModel,
True,
If[CheckFermiConstantInputRequirementsForSUSYModel[],
input
,
Print["Error: cannot use ", input, " because model"
" requirements are not fulfilled"];
Print[" Using default input: ", FlexibleSUSY`FSMassW];
FlexibleSUSY`FSMassW
],
False,
If[CheckFermiConstantInputRequirementsForNonSUSYModel[],
input
,
Print["Error: cannot use ", input, " because model"
" requirements are not fulfilled"];
Print[" Using default input: ", FlexibleSUSY`FSMassW];
FlexibleSUSY`FSMassW
],
_,
Print["Error: model type: ", SARAH`SupersymmetricModel];
Print[" Using default input: ", FlexibleSUSY`FSMassW];
FlexibleSUSY`FSMassW
],
FlexibleSUSY`FSMassW,
input,
_,
Print["Error: unknown input ", input];
Print[" Using default input: ", FlexibleSUSY`FSMassW];
FlexibleSUSY`FSMassW
];
CheckEWSBSolvers[solvers_List] :=
Module[{invalidSolvers},
invalidSolvers = Complement[solvers, allEWSBSolvers];
If[invalidSolvers =!= {},
Print["Error: invalid EWSB solvers requested: ", invalidSolvers];
Quit[1];
];
];
CheckBVPSolvers[solvers_List] :=
Module[{invalidSolvers},
invalidSolvers = Complement[solvers, allBVPSolvers];
If[invalidSolvers =!= {},
Print["Error: invalid BVP solvers requested: ", invalidSolvers];
Quit[1];
];
];
CheckModelFileSettings[] :=
Module[{},
(* FlexibleSUSY model name *)
If[!ValueQ[FlexibleSUSY`FSModelName] || Head[FlexibleSUSY`FSModelName] =!= String,
Print["Warning: FlexibleSUSY`FSModelName not defined!",
" I'm using Model`Name from SARAH: ", Model`Name];
FlexibleSUSY`FSModelName = Model`Name;
];
(* Set OnlyLowEnergyFlexibleSUSY to False by default *)
If[!ValueQ[FlexibleSUSY`OnlyLowEnergyFlexibleSUSY] ||
(FlexibleSUSY`OnlyLowEnergyFlexibleSUSY =!= True &&
FlexibleSUSY`OnlyLowEnergyFlexibleSUSY =!= False),
FlexibleSUSY`OnlyLowEnergyFlexibleSUSY = False;
];
If[Head[FlexibleSUSY`InitialGuessAtLowScale] =!= List,
FlexibleSUSY`InitialGuessAtLowScale = {};
];
If[Head[FlexibleSUSY`InitialGuessAtSUSYScale] =!= List,
FlexibleSUSY`InitialGuessAtSUSYScale = {};
];
If[Head[FlexibleSUSY`InitialGuessAtHighScale] =!= List,
FlexibleSUSY`InitialGuessAtHighScale = {};
];
(* HighScale *)
If[!ValueQ[FlexibleSUSY`HighScale],
If[!FlexibleSUSY`OnlyLowEnergyFlexibleSUSY,
Print["Warning: FlexibleSUSY`HighScale should be",
" set in the model file!"];
];
FlexibleSUSY`HighScale := 2 10^16;
];
If[!ValueQ[FlexibleSUSY`HighScaleFirstGuess],
If[!FlexibleSUSY`OnlyLowEnergyFlexibleSUSY,
Print["Warning: FlexibleSUSY`HighScaleFirstGuess should be",
" set in the model file!"];
];
FlexibleSUSY`HighScaleFirstGuess = 2.0 10^16;
];
If[Head[FlexibleSUSY`HighScaleInput] =!= List,
FlexibleSUSY`HighScaleInput = {};
];
(* LowScale *)
If[!ValueQ[FlexibleSUSY`LowScale],
Print["Warning: FlexibleSUSY`LowScale should be",
" set in the model file!"];
FlexibleSUSY`LowScale := LowEnergyConstant[MZ];
];
If[!ValueQ[FlexibleSUSY`LowScaleFirstGuess],
Print["Warning: FlexibleSUSY`LowScaleFirstGuess should be",
" set in the model file!"];
FlexibleSUSY`LowScaleFirstGuess = LowEnergyConstant[MZ];
];
If[Head[FlexibleSUSY`LowScaleInput] =!= List,
FlexibleSUSY`LowScaleInput = {};
];
(* SUSYScale *)
If[!ValueQ[FlexibleSUSY`SUSYScale],
Print["Warning: FlexibleSUSY`SUSYScale should be",
" set in the model file!"];
FlexibleSUSY`SUSYScale := 1000;
];
If[!ValueQ[FlexibleSUSY`SUSYScaleFirstGuess],
Print["Warning: FlexibleSUSY`SUSYScaleFirstGuess should be",
" set in the model file!"];
FlexibleSUSY`SUSYScaleFirstGuess = 1000;
];
If[Head[FlexibleSUSY`SUSYScaleInput] =!= List,
FlexibleSUSY`SUSYScaleInput = {};
];
If[Head[SARAH`MINPAR] =!= List,
SARAH`MINPAR = {};
];
If[Head[SARAH`EXTPAR] =!= List,
SARAH`EXTPAR = {};
];
If[Head[IMEXTPAR] =!= List,
IMEXTPAR = {};
];
If[Head[FlexibleSUSY`TreeLevelEWSBSolution] =!= List,
FlexibleSUSY`TreeLevelEWSBSolution = {};
];
If[Head[FlexibleSUSY`ExtraSLHAOutputBlocks] =!= List,
FlexibleSUSY`ExtraSLHAOutputBlocks = {};
];
If[Head[FlexibleSUSY`EWSBOutputParameters] =!= List,
Print["Error: EWSBOutputParameters has to be set to a list",
" of model parameters chosen to be output of the EWSB eqs."];
Quit[1];
];
If[Head[FlexibleSUSY`EWSBInitialGuess] =!= List,
FlexibleSUSY`EWSBInitialGuess = {};
];
If[Head[FlexibleSUSY`EWSBSubstitutions] =!= List,
FlexibleSUSY`EWSBSubstitutions = {};
];
If[Head[FlexibleSUSY`FSExtraInputParameters] =!= List,
Print["Error: FSExtraInputParameters has to be set to a list!"];
Quit[1];
,
If[!(And @@ (MatchQ[#,{_,_,_}]& /@ FlexibleSUSY`FSExtraInputParameters)),
Print["Error: FSExtraInputParameters must be of the form",
" {{A, AInput, {3,3}}, ... }"];
];
];
If[Head[FlexibleSUSY`FSAuxiliaryParameterInfo] =!= List,
Print["Error: FSAuxiliaryParameterInfo has to be set to a list!"];
Quit[1];
,
If[!(And @@ (MatchQ[#,{_, {__}}]& /@ FlexibleSUSY`FSAuxiliaryParameterInfo)),
Print["Error: FSAuxiliaryParameterInfo must be of the form",
" {{par, {property -> value, ...}}, ... }"];
];
];
CheckEWSBSolvers[FlexibleSUSY`FSEWSBSolvers];
CheckBVPSolvers[FlexibleSUSY`FSBVPSolvers];
];
CheckExtraParametersUsage[parameters_List, boundaryConditions_List] :=
Module[{usedCases, multiplyUsedPars},
usedCases = Function[par, !FreeQ[#, par]& /@ boundaryConditions] /@ parameters;
multiplyUsedPars = Position[Count[#, True]& /@ usedCases, n_ /; n > 1];
If[multiplyUsedPars =!= {},
Print["Warning: the following auxiliary parameters appear at"];
Print[" multiple scales, but do not run:"];
Print[" ", Extract[parameters, multiplyUsedPars]];
];
];
ReplaceIndicesInUserInput[rules_] :=
Block[{},
FlexibleSUSY`InitialGuessAtLowScale = FlexibleSUSY`InitialGuessAtLowScale /. rules;
FlexibleSUSY`InitialGuessAtSUSYScale = FlexibleSUSY`InitialGuessAtSUSYScale /. rules;
FlexibleSUSY`InitialGuessAtHighScale = FlexibleSUSY`InitialGuessAtHighScale /. rules;
FlexibleSUSY`HighScale = FlexibleSUSY`HighScale /. rules;
FlexibleSUSY`HighScaleFirstGuess = FlexibleSUSY`HighScaleFirstGuess /. rules;
FlexibleSUSY`HighScaleInput = FlexibleSUSY`HighScaleInput /. rules;
FlexibleSUSY`LowScale = FlexibleSUSY`LowScale /. rules;
FlexibleSUSY`LowScaleFirstGuess = FlexibleSUSY`LowScaleFirstGuess /. rules;
FlexibleSUSY`LowScaleInput = FlexibleSUSY`LowScaleInput /. rules;
FlexibleSUSY`SUSYScale = FlexibleSUSY`SUSYScale /. rules;
FlexibleSUSY`SUSYScaleFirstGuess = FlexibleSUSY`SUSYScaleFirstGuess /. rules;
FlexibleSUSY`SUSYScaleInput = FlexibleSUSY`SUSYScaleInput /. rules;
];
EvaluateUserInput[] :=
Block[{},
FlexibleSUSY`HighScaleInput = Map[Evaluate, FlexibleSUSY`HighScaleInput, {0,Infinity}];
FlexibleSUSY`LowScaleInput = Map[Evaluate, FlexibleSUSY`LowScaleInput , {0,Infinity}];
FlexibleSUSY`SUSYScaleInput = Map[Evaluate, FlexibleSUSY`SUSYScaleInput, {0,Infinity}];
];
GUTNormalization[coupling_] :=
Parameters`GetGUTNormalization[coupling];
ParticleIndexRule[par_, name_String] := {
"@" <> name <> "@" -> ToValidCSymbolString[par],
"@" <> name <> "_" ~~ num___ ~~ "@" /; StringFreeQ[num, "@"] :>
ToValidCSymbolString[par] <> If[TreeMasses`GetDimension[par] > 1, "(" <> num <> ")", ""],
"@" <> name <> "(" ~~ num___ ~~ ")@" /; StringFreeQ[num, "@"] :>
ToValidCSymbolString[par] <> If[TreeMasses`GetDimension[par] > 1, "(" <> num <> ")", "()"]
};
GenerationIndexRule[par_, name_String] :=
"@Generations(" ~~ name ~~ ")@" :>
ToString[TreeMasses`GetDimension[par]];
GeneralReplacementRules[] :=
Join[
ParticleIndexRule[SARAH`VectorZ, "VectorZ"],
ParticleIndexRule[SARAH`VectorW, "VectorW"],
ParticleIndexRule[SARAH`VectorP, "VectorP"],
ParticleIndexRule[SARAH`VectorG, "VectorG"],
ParticleIndexRule[SARAH`TopQuark, "TopQuark"],
ParticleIndexRule[SARAH`BottomQuark, "BottomQuark"],
ParticleIndexRule[SARAH`Electron, "Electron"],
ParticleIndexRule[SARAH`Neutrino, "Neutrino"],
ParticleIndexRule[SARAH`HiggsBoson, "HiggsBoson"],
ParticleIndexRule[SARAH`PseudoScalarBoson, "PseudoScalarBoson"],
ParticleIndexRule[SARAH`ChargedHiggs, "ChargedHiggs"],
ParticleIndexRule[SARAH`TopSquark, "TopSquark"],
ParticleIndexRule[SARAH`BottomSquark, "BottomSquark"],
ParticleIndexRule[SARAH`Sneutrino, "Sneutrino"],
ParticleIndexRule[SARAH`Selectron, "Selectron"],
ParticleIndexRule[SARAH`Gluino, "Gluino"],
{
GenerationIndexRule[SARAH`VectorZ, "VectorZ"],
GenerationIndexRule[SARAH`VectorW, "VectorW"],
GenerationIndexRule[SARAH`VectorP, "VectorP"],
GenerationIndexRule[SARAH`VectorG, "VectorG"],
GenerationIndexRule[SARAH`TopQuark, "TopQuark"],
GenerationIndexRule[SARAH`BottomQuark, "BottomQuark"],
GenerationIndexRule[SARAH`Electron, "Electron"],
GenerationIndexRule[SARAH`Neutrino, "Neutrino"],
GenerationIndexRule[SARAH`HiggsBoson, "HiggsBoson"],
GenerationIndexRule[SARAH`PseudoScalarBoson, "PseudoScalarBoson"],
GenerationIndexRule[SARAH`ChargedHiggs, "ChargedHiggs"],
GenerationIndexRule[SARAH`TopSquark, "TopSquark"],
GenerationIndexRule[SARAH`BottomSquark, "BottomSquark"],
GenerationIndexRule[SARAH`Sneutrino, "Sneutrino"],
GenerationIndexRule[SARAH`Selectron, "Selectron"],
GenerationIndexRule[SARAH`Gluino, "Gluino"]
},
{ "@UpYukawa@" -> ToValidCSymbolString[SARAH`UpYukawa],
"@DownYukawa@" -> ToValidCSymbolString[SARAH`DownYukawa],
"@ElectronYukawa@" -> ToValidCSymbolString[SARAH`ElectronYukawa],
"@LeftUpMixingMatrix@" -> ToValidCSymbolString[SARAH`UpMatrixL],
"@LeftDownMixingMatrix@" -> ToValidCSymbolString[SARAH`DownMatrixL],
"@RightUpMixingMatrix@" -> ToValidCSymbolString[SARAH`UpMatrixR],
"@RightDownMixingMatrix@"-> ToValidCSymbolString[SARAH`DownMatrixR],
"@hyperchargeCoupling@" -> ToValidCSymbolString[SARAH`hyperchargeCoupling],
"@leftCoupling@" -> ToValidCSymbolString[SARAH`leftCoupling],
"@strongCoupling@" -> ToValidCSymbolString[SARAH`strongCoupling],
"@hyperchargeCouplingGutNormalization@" -> RValueToCFormString[Parameters`GetGUTNormalization[SARAH`hyperchargeCoupling]],
"@leftCouplingGutNormalization@" -> RValueToCFormString[Parameters`GetGUTNormalization[SARAH`leftCoupling]],
"@hyperchargeCouplingInverseGutNormalization@" -> RValueToCFormString[1/Parameters`GetGUTNormalization[SARAH`hyperchargeCoupling]],
"@leftCouplingInverseGutNormalization@" -> RValueToCFormString[1/Parameters`GetGUTNormalization[SARAH`leftCoupling]],
"@perturbativityThreshold@" -> ToString[N[FlexibleSUSY`FSPerturbativityThreshold]],
"@ModelName@" -> FlexibleSUSY`FSModelName,
"@numberOfModelParameters@" -> ToString[numberOfModelParameters],
"@numberOfParticles@" -> ToString[Length @ GetLoopCorrectedParticles[FlexibleSUSY`FSEigenstates]],
"@numberOfSMParticles@" -> ToString[Length @ Select[GetLoopCorrectedParticles[FlexibleSUSY`FSEigenstates], SARAH`SMQ]],
"@numberOfBSMParticles@" -> ToString[Length @ Complement[GetLoopCorrectedParticles[FlexibleSUSY`FSEigenstates],
Select[GetLoopCorrectedParticles[FlexibleSUSY`FSEigenstates], SARAH`SMQ]]],
"@InputParameter_" ~~ num_ ~~ "@" /; IntegerQ[ToExpression[num]] :> CConversion`ToValidCSymbolString[
If[Parameters`GetInputParameters[] === {},
"",
Parameters`GetInputParameters[][[ToExpression[num]]]
]
],
"@setInputParameterTo[" ~~ num_ ~~ "," ~~ value__ ~~ "]@" /; IntegerQ[ToExpression[num]] :>
If[Parameters`GetInputParameters[] === {},
"",
IndentText[IndentText[
Parameters`SetInputParameter[
Parameters`GetInputParameters[][[ToExpression[num]]],
value,
"INPUTPARAMETER"
]
]]
],
"@ModelTypes@" -> FlexibleTower`GetModelTypes[],
"@DateAndTime@" -> DateString[],
"@SARAHVersion@" -> SA`Version,
"@FlexibleSUSYVersion@" -> FS`Version,
"@FlexibleSUSYGitCommit@" -> FS`GitCommit
}
];
WriteRGEClass[betaFun_List, anomDim_List, files_List,
templateFile_String, makefileModuleTemplates_List,
additionalTraces_List:{}, numberOfBaseClassParameters_:0] :=
Module[{beta, setter, getter, parameterDef, set,
display,
cCtorParameterList, parameterCopyInit, betaParameterList,
anomDimPrototypes, anomDimFunctions, printParameters, parameters,
numberOfParameters, clearParameters,
singleBetaFunctionsDecls, singleBetaFunctionsDefsFiles,
traceDefs, calcTraces, sarahTraces},
(* extract list of parameters from the beta functions *)
parameters = BetaFunction`GetName[#]& /@ betaFun;
(* count number of parameters *)
numberOfParameters = BetaFunction`CountNumberOfParameters[betaFun] + numberOfBaseClassParameters;
(* create C++ functions and parameter declarations *)
sarahTraces = Traces`ConvertSARAHTraces[additionalTraces];
beta = BetaFunction`CreateBetaFunction[betaFun];
setter = BetaFunction`CreateSetters[betaFun];
getter = BetaFunction`CreateGetters[betaFun];
parameterDef = BetaFunction`CreateParameterDefinitions[betaFun];
set = BetaFunction`CreateSetFunction[betaFun, numberOfBaseClassParameters];
display = BetaFunction`CreateDisplayFunction[betaFun, numberOfBaseClassParameters];
cCtorParameterList = BetaFunction`CreateCCtorParameterList[betaFun];
parameterCopyInit = BetaFunction`CreateCCtorInitialization[betaFun];
betaParameterList = BetaFunction`CreateParameterList[betaFun, "beta_"];
clearParameters = BetaFunction`ClearParameters[betaFun];
anomDimPrototypes = AnomalousDimension`CreateAnomDimPrototypes[anomDim];
anomDimFunctions = AnomalousDimension`CreateAnomDimFunctions[anomDim];
printParameters = WriteOut`PrintParameters[parameters, "ostr"];
singleBetaFunctionsDecls = BetaFunction`CreateSingleBetaFunctionDecl[betaFun];
traceDefs = Traces`CreateTraceDefs[betaFun];
traceDefs = traceDefs <> Traces`CreateSARAHTraceDefs[sarahTraces];
calcTraces = {Traces`CreateSARAHTraceCalculation[sarahTraces, "TRACE_STRUCT"],
Sequence @@ Traces`CreateTraceCalculation[betaFun, "TRACE_STRUCT"] };
WriteOut`ReplaceInFiles[files,
{ "@beta@" -> IndentText[WrapLines[beta]],
"@clearParameters@" -> IndentText[WrapLines[clearParameters]],
"@display@" -> IndentText[display],
"@set@" -> IndentText[set],
"@cCtorParameterList@" -> WrapLines[cCtorParameterList],
"@parameterCopyInit@" -> WrapLines[parameterCopyInit],
"@betaParameterList@" -> betaParameterList,
"@parameterDef@" -> IndentText[parameterDef],
"@cCtorParameterList@" -> WrapLines[cCtorParameterList],
"@setter@" -> IndentText[setter],
"@getter@" -> IndentText[getter],
"@anomDimPrototypes@" -> IndentText[anomDimPrototypes],
"@anomDimFunctions@" -> WrapLines[anomDimFunctions],
"@numberOfParameters@" -> RValueToCFormString[numberOfParameters],
"@printParameters@" -> IndentText[printParameters],
"@singleBetaFunctionsDecls@" -> IndentText[singleBetaFunctionsDecls],
"@traceDefs@" -> IndentText[IndentText[traceDefs]],
"@calc1LTraces@" -> IndentText @ IndentText[WrapLines[calcTraces[[1]] <> "\n" <> calcTraces[[2]]]],
"@calc2LTraces@" -> IndentText @ IndentText[WrapLines[calcTraces[[3]]]],
"@calc3LTraces@" -> IndentText @ IndentText[WrapLines[calcTraces[[4]]]],
Sequence @@ GeneralReplacementRules[]
} ];
singleBetaFunctionsDefsFiles = BetaFunction`CreateSingleBetaFunctionDefs[betaFun, templateFile, sarahTraces];
Print["Creating makefile module for the beta functions ..."];
WriteMakefileModule[singleBetaFunctionsDefsFiles,
makefileModuleTemplates];
];
WriteInputParameterClass[inputParameters_List, files_List] :=
Module[{defineInputParameters, printInputParameters, get, set, inputPars},
inputPars = {First[#], #[[3]]}& /@ inputParameters;
defineInputParameters = Constraint`DefineInputParameters[inputPars];
printInputParameters = WriteOut`PrintInputParameters[inputPars,"ostr"];
get = Parameters`CreateInputParameterArrayGetter[inputPars];
set = Parameters`CreateInputParameterArraySetter[inputPars];
WriteOut`ReplaceInFiles[files,
{ "@defineInputParameters@" -> IndentText[defineInputParameters],
"@printInputParameters@" -> IndentText[printInputParameters],
"@get@" -> IndentText[get],
"@set@" -> IndentText[set],
Sequence @@ GeneralReplacementRules[]
} ];
];
WriteConstraintClass[condition_, settings_List, scaleFirstGuess_,
{minimumScale_, maximumScale_}, files_List] :=
Module[{applyConstraint = "", calculateScale, scaleGuess,
restrictScale,
temporarySetting = "",
setDRbarYukawaCouplings,
calculateDRbarMasses,
calculateDeltaAlphaEm, calculateDeltaAlphaS,
calculateGaugeCouplings,
calculateThetaW,
recalculateMWPole,
checkPerturbativityForDimensionlessParameters = ""},
Constraint`SetBetaFunctions[GetBetaFunctions[]];
applyConstraint = Constraint`ApplyConstraints[settings];
calculateScale = Constraint`CalculateScale[condition, "scale"];
scaleGuess = Constraint`CalculateScale[scaleFirstGuess, "initial_scale_guess"];
restrictScale = Constraint`RestrictScale[{minimumScale, maximumScale}];
temporarySetting = Constraint`SetTemporarily[settings];
calculateDeltaAlphaEm = ThresholdCorrections`CalculateDeltaAlphaEm[FlexibleSUSY`FSRenormalizationScheme];
calculateDeltaAlphaS = ThresholdCorrections`CalculateDeltaAlphaS[FlexibleSUSY`FSRenormalizationScheme];
calculateThetaW = ThresholdCorrections`CalculateThetaW[FSWeakMixingAngleOptions,SARAH`SupersymmetricModel];
calculateGaugeCouplings = ThresholdCorrections`CalculateGaugeCouplings[];
recalculateMWPole = ThresholdCorrections`RecalculateMWPole[FSWeakMixingAngleOptions];
setDRbarYukawaCouplings = {
ThresholdCorrections`SetDRbarYukawaCouplingTop[settings],
ThresholdCorrections`SetDRbarYukawaCouplingBottom[settings],
ThresholdCorrections`SetDRbarYukawaCouplingElectron[settings]
};
calculateDRbarMasses = {
LoopMasses`CallCalculateDRbarMass["Up Quark" , "Up-Quarks" , 1, "upQuarksDRbar", "qedqcd.displayMass(softsusy::mUp)" ],
LoopMasses`CallCalculateDRbarMass["Charmed Quark" , "Up-Quarks" , 2, "upQuarksDRbar", "qedqcd.displayMass(softsusy::mCharm)" ],
LoopMasses`CallCalculateDRbarMass["Top Quark" , "Up-Quarks" , 3, "upQuarksDRbar", "qedqcd.displayPoleMt()" ],
LoopMasses`CallCalculateDRbarMass["Down Quark" , "Down-Quarks", 1, "downQuarksDRbar", "qedqcd.displayMass(softsusy::mDown)" ],
LoopMasses`CallCalculateDRbarMass["Strange Quark" , "Down-Quarks", 2, "downQuarksDRbar", "qedqcd.displayMass(softsusy::mStrange)" ],
LoopMasses`CallCalculateDRbarMass["Bottom Quark" , "Down-Quarks", 3, "downQuarksDRbar", "qedqcd.displayMass(softsusy::mBottom)" ],
LoopMasses`CallCalculateDRbarMass["Electron" , "Leptons" , 1, "downLeptonsDRbar", "qedqcd.displayMass(softsusy::mElectron)"],
LoopMasses`CallCalculateDRbarMass["Muon" , "Leptons" , 2, "downLeptonsDRbar", "qedqcd.displayMass(softsusy::mMuon)" ],
LoopMasses`CallCalculateDRbarMass["Tau" , "Leptons" , 3, "downLeptonsDRbar", "qedqcd.displayMass(softsusy::mTau)" ],
LoopMasses`CallCalculateDRbarMass["Electron Neutrino", "Neutrinos" , 1, "neutrinoDRbar", "qedqcd.displayNeutrinoPoleMass(1)" ],
LoopMasses`CallCalculateDRbarMass["Muon Neutrino" , "Neutrinos" , 2, "neutrinoDRbar", "qedqcd.displayNeutrinoPoleMass(2)" ],
LoopMasses`CallCalculateDRbarMass["Tau Neutrino" , "Neutrinos" , 3, "neutrinoDRbar", "qedqcd.displayNeutrinoPoleMass(3)" ]
};
If[FSCheckPerturbativityOfDimensionlessParameters,
checkPerturbativityForDimensionlessParameters =
Constraint`CheckPerturbativityForParameters[
Parameters`GetModelParametersWithMassDimension[0],
FlexibleSUSY`FSPerturbativityThreshold
];
];
WriteOut`ReplaceInFiles[files,
{ "@applyConstraint@" -> IndentText[WrapLines[applyConstraint]],
"@calculateScale@" -> IndentText[WrapLines[calculateScale]],
"@scaleGuess@" -> IndentText[WrapLines[scaleGuess]],
"@restrictScale@" -> IndentText[WrapLines[restrictScale]],
"@temporarySetting@" -> IndentText[WrapLines[temporarySetting]],
"@calculateGaugeCouplings@" -> IndentText[WrapLines[calculateGaugeCouplings]],
"@calculateDeltaAlphaEm@" -> IndentText[WrapLines[calculateDeltaAlphaEm]],
"@calculateDeltaAlphaS@" -> IndentText[WrapLines[calculateDeltaAlphaS]],
"@calculateThetaW@" -> IndentText[WrapLines[calculateThetaW]],
"@recalculateMWPole@" -> IndentText[WrapLines[recalculateMWPole]],
"@calculateDRbarMassUp@" -> IndentText[IndentText[calculateDRbarMasses[[1]]]],
"@calculateDRbarMassCharm@" -> IndentText[IndentText[calculateDRbarMasses[[2]]]],
"@calculateDRbarMassTop@" -> IndentText[IndentText[calculateDRbarMasses[[3]]]],
"@calculateDRbarMassDown@" -> IndentText[IndentText[calculateDRbarMasses[[4]]]],
"@calculateDRbarMassStrange@" -> IndentText[IndentText[calculateDRbarMasses[[5]]]],
"@calculateDRbarMassBottom@" -> IndentText[IndentText[calculateDRbarMasses[[6]]]],
"@calculateDRbarMassElectron@"-> IndentText[IndentText[calculateDRbarMasses[[7]]]],
"@calculateDRbarMassMuon@" -> IndentText[IndentText[calculateDRbarMasses[[8]]]],
"@calculateDRbarMassTau@" -> IndentText[IndentText[calculateDRbarMasses[[9]]]],
"@calculateDRbarMassElectronNeutrino@"-> IndentText[IndentText[calculateDRbarMasses[[10]]]],
"@calculateDRbarMassMuonNeutrino@" -> IndentText[IndentText[calculateDRbarMasses[[11]]]],
"@calculateDRbarMassTauNeutrino@" -> IndentText[IndentText[calculateDRbarMasses[[12]]]],
"@setDRbarUpQuarkYukawaCouplings@" -> IndentText[WrapLines[setDRbarYukawaCouplings[[1]]]],
"@setDRbarDownQuarkYukawaCouplings@" -> IndentText[WrapLines[setDRbarYukawaCouplings[[2]]]],
"@setDRbarElectronYukawaCouplings@" -> IndentText[WrapLines[setDRbarYukawaCouplings[[3]]]],
"@checkPerturbativityForDimensionlessParameters@" -> IndentText[checkPerturbativityForDimensionlessParameters],
Sequence @@ GeneralReplacementRules[]
} ];
];
WriteSemiAnalyticConstraintClass[condition_, settings_List, scaleFirstGuess_,
{minimumScale_, maximumScale_},
mustSetSemiAnalyticBCs_, semiAnalyticSolns_List, files_List] :=
Module[{applyConstraint = "", calculateScale, scaleGuess,
restrictScale,
temporarySetting = "", temporaryResetting = "",
setDRbarYukawaCouplings,
calculateDRbarMasses,
calculateDeltaAlphaEm, calculateDeltaAlphaS,
calculateGaugeCouplings,
calculateThetaW,
recalculateMWPole,
checkPerturbativityForDimensionlessParameters = "",
semiAnalyticForwardDecls = "",
semiAnalyticConstraint = "",
setSemiAnalyticConstraint = "",
clearSemiAnalyticConstraint = "",
updateSemiAnalyticConstraint = "",
saveBoundaryValueParameters = ""},
Constraint`SetBetaFunctions[GetBetaFunctions[]];
applyConstraint = Constraint`ApplyConstraints[settings];
calculateScale = Constraint`CalculateScale[condition, "scale"];
scaleGuess = Constraint`CalculateScale[scaleFirstGuess, "initial_scale_guess"];
restrictScale = Constraint`RestrictScale[{minimumScale, maximumScale}];
temporarySetting = Constraint`SetTemporarily[settings];
calculateDeltaAlphaEm = ThresholdCorrections`CalculateDeltaAlphaEm[FlexibleSUSY`FSRenormalizationScheme];
calculateDeltaAlphaS = ThresholdCorrections`CalculateDeltaAlphaS[FlexibleSUSY`FSRenormalizationScheme];
calculateThetaW = ThresholdCorrections`CalculateThetaW[FSWeakMixingAngleOptions,SARAH`SupersymmetricModel];
calculateGaugeCouplings = ThresholdCorrections`CalculateGaugeCouplings[];
recalculateMWPole = ThresholdCorrections`RecalculateMWPole[FSWeakMixingAngleOptions];
setDRbarYukawaCouplings = {
ThresholdCorrections`SetDRbarYukawaCouplingTop[settings],
ThresholdCorrections`SetDRbarYukawaCouplingBottom[settings],
ThresholdCorrections`SetDRbarYukawaCouplingElectron[settings]
};
calculateDRbarMasses = {
LoopMasses`CallCalculateDRbarMass["Up Quark" , "Up-Quarks" , 1, "upQuarksDRbar", "qedqcd.displayMass(softsusy::mUp)" ],
LoopMasses`CallCalculateDRbarMass["Charmed Quark" , "Up-Quarks" , 2, "upQuarksDRbar", "qedqcd.displayMass(softsusy::mCharm)" ],
LoopMasses`CallCalculateDRbarMass["Top Quark" , "Up-Quarks" , 3, "upQuarksDRbar", "qedqcd.displayPoleMt()" ],
LoopMasses`CallCalculateDRbarMass["Down Quark" , "Down-Quarks", 1, "downQuarksDRbar", "qedqcd.displayMass(softsusy::mDown)" ],
LoopMasses`CallCalculateDRbarMass["Strange Quark" , "Down-Quarks", 2, "downQuarksDRbar", "qedqcd.displayMass(softsusy::mStrange)" ],
LoopMasses`CallCalculateDRbarMass["Bottom Quark" , "Down-Quarks", 3, "downQuarksDRbar", "qedqcd.displayMass(softsusy::mBottom)" ],
LoopMasses`CallCalculateDRbarMass["Electron" , "Leptons" , 1, "downLeptonsDRbar", "qedqcd.displayMass(softsusy::mElectron)"],
LoopMasses`CallCalculateDRbarMass["Muon" , "Leptons" , 2, "downLeptonsDRbar", "qedqcd.displayMass(softsusy::mMuon)" ],
LoopMasses`CallCalculateDRbarMass["Tau" , "Leptons" , 3, "downLeptonsDRbar", "qedqcd.displayMass(softsusy::mTau)" ],
LoopMasses`CallCalculateDRbarMass["Electron Neutrino", "Neutrinos" , 1, "neutrinoDRbar", "qedqcd.displayNeutrinoPoleMass(1)" ],
LoopMasses`CallCalculateDRbarMass["Muon Neutrino" , "Neutrinos" , 2, "neutrinoDRbar", "qedqcd.displayNeutrinoPoleMass(2)" ],
LoopMasses`CallCalculateDRbarMass["Tau Neutrino" , "Neutrinos" , 3, "neutrinoDRbar", "qedqcd.displayNeutrinoPoleMass(3)" ]
};
If[FSCheckPerturbativityOfDimensionlessParameters,
checkPerturbativityForDimensionlessParameters =
Constraint`CheckPerturbativityForParameters[
Parameters`GetModelParametersWithMassDimension[0],
FlexibleSUSY`FSPerturbativityThreshold
];
];
If[mustSetSemiAnalyticBCs,
semiAnalyticForwardDecls = "template <class T>\nclass " <> FlexibleSUSY`FSModelName <> "_soft_parameters_constraint;\n\n";
semiAnalyticConstraint = FlexibleSUSY`FSModelName <> "_soft_parameters_constraint<Semi_analytic>* soft_constraint{nullptr};\n";
setSemiAnalyticConstraint = "void set_soft_parameters_constraint(" <> FlexibleSUSY`FSModelName
<> "_soft_parameters_constraint<Semi_analytic>* sc) { soft_constraint = sc; }\n";
clearSemiAnalyticConstraint = "soft_constraint = nullptr;\n";
updateSemiAnalyticConstraint = "if (soft_constraint) soft_constraint->set_boundary_scale(scale);\n";
saveBoundaryValueParameters = SemiAnalytic`SaveBoundaryValueParameters[semiAnalyticSolns];
];
WriteOut`ReplaceInFiles[files,
{ "@applyConstraint@" -> IndentText[WrapLines[applyConstraint]],
"@calculateScale@" -> IndentText[WrapLines[calculateScale]],
"@scaleGuess@" -> IndentText[WrapLines[scaleGuess]],
"@restrictScale@" -> IndentText[WrapLines[restrictScale]],
"@temporarySetting@" -> IndentText[WrapLines[temporarySetting]],
"@temporaryResetting@" -> IndentText[WrapLines[temporaryResetting]],
"@calculateGaugeCouplings@" -> IndentText[WrapLines[calculateGaugeCouplings]],
"@calculateDeltaAlphaEm@" -> IndentText[WrapLines[calculateDeltaAlphaEm]],
"@calculateDeltaAlphaS@" -> IndentText[WrapLines[calculateDeltaAlphaS]],
"@calculateThetaW@" -> IndentText[WrapLines[calculateThetaW]],
"@recalculateMWPole@" -> IndentText[WrapLines[recalculateMWPole]],
"@calculateDRbarMassUp@" -> IndentText[IndentText[calculateDRbarMasses[[1]]]],
"@calculateDRbarMassCharm@" -> IndentText[IndentText[calculateDRbarMasses[[2]]]],
"@calculateDRbarMassTop@" -> IndentText[IndentText[calculateDRbarMasses[[3]]]],
"@calculateDRbarMassDown@" -> IndentText[IndentText[calculateDRbarMasses[[4]]]],
"@calculateDRbarMassStrange@" -> IndentText[IndentText[calculateDRbarMasses[[5]]]],
"@calculateDRbarMassBottom@" -> IndentText[IndentText[calculateDRbarMasses[[6]]]],
"@calculateDRbarMassElectron@"-> IndentText[IndentText[calculateDRbarMasses[[7]]]],
"@calculateDRbarMassMuon@" -> IndentText[IndentText[calculateDRbarMasses[[8]]]],
"@calculateDRbarMassTau@" -> IndentText[IndentText[calculateDRbarMasses[[9]]]],
"@calculateDRbarMassElectronNeutrino@"-> IndentText[IndentText[calculateDRbarMasses[[10]]]],
"@calculateDRbarMassMuonNeutrino@" -> IndentText[IndentText[calculateDRbarMasses[[11]]]],
"@calculateDRbarMassTauNeutrino@" -> IndentText[IndentText[calculateDRbarMasses[[12]]]],
"@setDRbarUpQuarkYukawaCouplings@" -> IndentText[WrapLines[setDRbarYukawaCouplings[[1]]]],
"@setDRbarDownQuarkYukawaCouplings@" -> IndentText[WrapLines[setDRbarYukawaCouplings[[2]]]],
"@setDRbarElectronYukawaCouplings@" -> IndentText[WrapLines[setDRbarYukawaCouplings[[3]]]],
"@checkPerturbativityForDimensionlessParameters@" -> IndentText[checkPerturbativityForDimensionlessParameters],
"@semiAnalyticForwardDecls@" -> semiAnalyticForwardDecls,
"@semiAnalyticConstraint@" -> IndentText[semiAnalyticConstraint],
"@setSemiAnalyticConstraint@" -> IndentText[setSemiAnalyticConstraint],
"@clearSemiAnalyticConstraint@" -> IndentText[clearSemiAnalyticConstraint],
"@updateSemiAnalyticConstraint@" -> IndentText[updateSemiAnalyticConstraint],
"@saveBoundaryValueParameters@" -> IndentText[WrapLines[saveBoundaryValueParameters]],
Sequence @@ GeneralReplacementRules[]
} ];
];
WriteInitialGuesserClass[lowScaleGuess_List, susyScaleGuess_List, highScaleGuess_List, files_List] :=
Module[{initialGuessAtLowScale, initialGuessAtLowScaleGaugeCouplings = "",
initialGuessAtHighScale, setDRbarYukawaCouplings,
allSettings},
initialGuessAtLowScale = Constraint`ApplyConstraints[lowScaleGuess];
initialGuessAtLowScaleGaugeCouplings = Constraint`InitialGuessAtLowScaleGaugeCouplings[];
initialGuessAtSUSYScale = Constraint`ApplyConstraints[susyScaleGuess];
initialGuessAtHighScale = Constraint`ApplyConstraints[highScaleGuess];
allSettings = Join[lowScaleGuess, highScaleGuess];
setDRbarYukawaCouplings = {
ThresholdCorrections`SetDRbarYukawaCouplingTop[allSettings],
ThresholdCorrections`SetDRbarYukawaCouplingBottom[allSettings],
ThresholdCorrections`SetDRbarYukawaCouplingElectron[allSettings]
};
WriteOut`ReplaceInFiles[files,
{ "@initialGuessAtLowScale@" -> IndentText[WrapLines[initialGuessAtLowScale]],
"@initialGuessAtLowScaleGaugeCouplings@" -> IndentText[WrapLines[initialGuessAtLowScaleGaugeCouplings]],
"@initialGuessAtSUSYScale@" -> IndentText[WrapLines[initialGuessAtSUSYScale]],
"@initialGuessAtHighScale@" -> IndentText[WrapLines[initialGuessAtHighScale]],
"@setDRbarUpQuarkYukawaCouplings@" -> IndentText[WrapLines[setDRbarYukawaCouplings[[1]]]],
"@setDRbarDownQuarkYukawaCouplings@" -> IndentText[WrapLines[setDRbarYukawaCouplings[[2]]]],
"@setDRbarElectronYukawaCouplings@" -> IndentText[WrapLines[setDRbarYukawaCouplings[[3]]]],
Sequence @@ GeneralReplacementRules[]
} ];
];
WriteConvergenceTesterClass[parameters_, files_List] :=
Module[{compareFunction},
compareFunction = ConvergenceTester`CreateCompareFunction[parameters];
WriteOut`ReplaceInFiles[files,
{ "@compareFunction@" -> IndentText[WrapLines[compareFunction]],
Sequence @@ GeneralReplacementRules[]
} ];
];
FindVEV[gauge_] :=
Module[{result, vev},
vev = Cases[SARAH`DEFINITION[FlexibleSUSY`FSEigenstates][SARAH`VEVs],
{_,{v_,_},{gauge,_},{p_,_},___} | {_,{v_,_},{s_,_},{gauge,_},___} :> v];
If[vev === {},
Print["Error: could not find VEV for gauge eigenstate ", gauge];
Quit[1];
];
vev[[1]]
];
GetDimOfVEV[vev_] :=
Switch[SARAH`getDimParameters[vev],
{} , 1,
{0} , 1,
{1} , 1,
{idx_} , SARAH`getDimParameters[vev][[1]]
];
ExpandIndices[sym_, 1] := sym;
ExpandIndices[sym_, number_] :=
Table[sym[i], {i,1,number}];
ExpandGaugeIndices[gauge_List] :=
Flatten[ExpandIndices[#, GetDimOfVEV[FindVEV[#]]]& /@ gauge];
ExpandVEVIndices[vev_] :=
ExpandIndices[vev, GetDimOfVEV[vev]];
(* Returns a list of three-component lists where the information is
stored which Higgs corresponds to which EWSB eq. and whether the
corresponding tadpole is real or imaginary (only in models with CP
violation).
Example: MRSSM
In[] := CreateHiggsToEWSBEqAssociation[]
Out[] = {{hh, 1, Re}, {hh, 2, Re}, {hh, 4, Re}, {hh, 3, Re}}
This result means:
EWSB eq. 1 corresponds to hh[1], the 1L tadpole[1] is real
EWSB eq. 2 corresponds to hh[2], the 1L tadpole[2] is real
EWSB eq. 3 corresponds to hh[4], the 1L tadpole[3] is real
EWSB eq. 4 corresponds to hh[3], the 1L tadpole[4] is real
*)
CreateHiggsToEWSBEqAssociation[] :=
Module[{vevs},
vevs = Cases[SARAH`DEFINITION[FlexibleSUSY`FSEigenstates][SARAH`VEVs],