-
Notifications
You must be signed in to change notification settings - Fork 2
/
CMakeLists.txt
272 lines (234 loc) · 8.82 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
cmake_minimum_required(VERSION 3.21 FATAL_ERROR)
########################################################################################################################
## Define project
########################################################################################################################
project(SHR
VERSION 0.4.0.0
LANGUAGES CXX
DESCRIPTION "A mod that simulates changes in heart rate and their effects on the player."
)
string(TIMESTAMP PROJECT_CONFIGURE_YEAR "%Y" UTC)
set(PROJECT_AUTHOR "GrazedAnkle")
set(PROJECT_FRIENDLY_NAME "Skyrim Heart Rate for SKSE64")
set(PROJECT_COPYRIGHT "SHR Copyright (C) ${PROJECT_CONFIGURE_YEAR} ${PROJECT_AUTHOR}")
set(CMAKE_CXX_STANDARD 23)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
configure_file(
src/version.rc.in
${CMAKE_CURRENT_BINARY_DIR}/version.rc
@ONLY
)
configure_file(
src/fomod/info.xml.in
${CMAKE_CURRENT_BINARY_DIR}/Distribution/fomod/info.xml
@ONLY
)
configure_file(
src/fomod/ModuleConfig.xml.in
${CMAKE_CURRENT_BINARY_DIR}/Distribution/fomod/ModuleConfig.xml
@ONLY
)
set(PUBLIC_HEADER_DIR "${CMAKE_CURRENT_SOURCE_DIR}/include/${PROJECT_NAME}")
set(headers)
set(sources
src/Main.cpp
src/Config.cpp
src/InputHandler.cpp
src/Logging.cpp
src/SkyrimHeartRate.cpp
src/EventHandler.cpp
src/Sound.cpp
src/Strings.cpp
${CMAKE_CURRENT_BINARY_DIR}/version.rc
)
set(tests)
source_group(TREE ${CMAKE_CURRENT_SOURCE_DIR}
FILES
${headers}
${sources}
${tests}
)
#########################################################################################################################
### Build options
#########################################################################################################################
option(BUILD_TESTS "Build unit tests." OFF)
message("Options:")
message(" Tests: ${BUILD_TESTS}")
########################################################################################################################
## Add CMake features
########################################################################################################################
include(CheckIPOSupported)
include(GNUInstallDirs)
########################################################################################################################
## Find dependencies
########################################################################################################################
find_package(CommonLibSSE REQUIRED)
find_package(toml11 CONFIG REQUIRED)
if(BUILD_TESTS)
find_package(Catch2 CONFIG REQUIRED)
endif()
########################################################################################################################
## Configuration for all targets
########################################################################################################################
if(WIN32)
add_compile_definitions(
UNICODE
_UNICODE
_AMD64_
NOMINMAX
WIN32_LEAN_AND_MEAN
)
endif()
if(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
add_compile_definitions(
__cpp_lib_char8_t
__cpp_consteval
__cpp_lib_format
)
endif()
check_ipo_supported(RESULT USE_IPO OUTPUT IPO_OUTPUT)
if(USE_IPO)
set(CMAKE_INTERPROCEDURAL_OPTIMIZATION ON)
else()
message(WARNING "Interprocedural optimizations are not supported.")
endif()
########################################################################################################################
## Configure target DLL
########################################################################################################################
add_commonlibsse_plugin(${PROJECT_NAME} SOURCES ${headers} ${sources})
add_library("${PROJECT_NAME}::${PROJECT_NAME}" ALIAS "${PROJECT_NAME}")
target_include_directories(${PROJECT_NAME}
PRIVATE
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src>
$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}/src>
$<INSTALL_INTERFACE:src>
)
target_include_directories(${PROJECT_NAME}
PUBLIC
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
)
target_link_libraries(${PROJECT_NAME}
PRIVATE
toml11::toml11
)
target_precompile_headers(${PROJECT_NAME}
PRIVATE
src/pch.hpp
)
# CMake flags for Release builds are suboptimal.
# See: https://gitlab.kitware.com/cmake/cmake/-/issues/20812.
# See: https://stackoverflow.com/questions/28178978/how-to-generate-pdb-files-for-release-build-with-cmake-flags.
if(MSVC)
target_compile_options(${PROJECT_NAME}
PRIVATE
$<$<CONFIG:Release>:/Zc:inline>
$<$<CONFIG:Release>:/Zi>
$<$<CONFIG:Release>:/Gy>
)
target_link_options(${PROJECT_NAME}
PRIVATE
$<$<CONFIG:Release>:/DEBUG>
$<$<CONFIG:Release>:/INCREMENTAL:NO>
$<$<CONFIG:Release>:/OPT:REF>
$<$<CONFIG:Release>:/OPT:ICF>
)
elseif((CMAKE_CXX_COMPILER_ID STREQUAL "GNU") OR (CMAKE_CXX_COMPILER_ID MATCHES ".*Clang"))
target_compile_options(${PROJECT_NAME}
PRIVATE
$<$<CONFIG:Release>:-g>
)
target_link_options(${PROJECT_NAME}
PRIVATE
$<$<CONFIG:Release>:-g>
)
if(WIN32)
target_compile_options(${PROJECT_NAME}
PRIVATE
$<$<CONFIG:Release>:-gcodeview>
)
endif()
endif()
install(
DIRECTORY "${PUBLIC_HEADER_DIR}"
DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}"
)
install(
TARGETS ${PROJECT_NAME}
DESTINATION "${CMAKE_INSTALL_LIBDIR}"
)
# Automatic deployment to FOMOD directory.
if(CMAKE_BUILD_TYPE STREQUAL "Debug")
set(BUILD_NAME "Debug")
else()
set(BUILD_NAME "Release")
endif()
install(DIRECTORY DESTINATION "${CMAKE_CURRENT_BINARY_DIR}/Distribution/Papyrus${BUILD_NAME}/")
add_custom_command(TARGET ${PROJECT_NAME} POST_BUILD
COMMAND ${CMAKE_COMMAND} -E make_directory "${CMAKE_CURRENT_BINARY_DIR}/Distribution/Plugin${BUILD_NAME}/"
)
add_custom_command(TARGET ${PROJECT_NAME} POST_BUILD
COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:${PROJECT_NAME}> "${CMAKE_CURRENT_BINARY_DIR}/Distribution/Plugin${BUILD_NAME}/"
)
if(CMAKE_BUILD_TYPE STREQUAL "Debug")
add_custom_command(TARGET ${PROJECT_NAME} POST_BUILD
COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_PDB_FILE:${PROJECT_NAME}> "${CMAKE_CURRENT_BINARY_DIR}/Distribution/Plugin${BUILD_NAME}/"
)
endif()
add_custom_command(TARGET ${PROJECT_NAME} POST_BUILD
COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/contrib/Distribution "${CMAKE_CURRENT_BINARY_DIR}/Distribution"
)
file(GLOB_RECURSE OUTPUT_DLLS "${CMAKE_CURRENT_BINARY_DIR}/Distribution/**/*.dll")
file(GLOB_RECURSE OUTPUT_PDBS "${CMAKE_CURRENT_BINARY_DIR}/Distribution/**/*.pdb")
file(GLOB_RECURSE OUTPUT_SCRIPTS "${CMAKE_CURRENT_BINARY_DIR}/Distribution/**/*.pex")
set_property(TARGET ${PROJECT_NAME}
APPEND PROPERTY ADDITIONAL_CLEAN_FILES "${OUTPUT_DLLS}"
)
set_property(TARGET ${PROJECT_NAME}
APPEND PROPERTY ADDITIONAL_CLEAN_FILES "${OUTPUT_PDBS}"
)
set_property(TARGET ${PROJECT_NAME}
APPEND PROPERTY ADDITIONAL_CLEAN_FILES "${OUTPUT_SCRIPTS}"
)
set(DISTRIBUTION_ARCHIVE_NAME "${PROJECT_NAME}-SKSE64-${PROJECT_VERSION}")
add_custom_target(Distribution ALL
COMMAND ${CMAKE_COMMAND} -E tar "cvf" "${CMAKE_CURRENT_BINARY_DIR}/${DISTRIBUTION_ARCHIVE_NAME}.zip" --format=zip -- .
WORKING_DIRECTORY "${CMAKE_CURRENT_BINARY_DIR}/Distribution"
)
set_property(TARGET ${PROJECT_NAME}
APPEND PROPERTY ADDITIONAL_CLEAN_FILES "${CMAKE_CURRENT_BINARY_DIR}/${DISTRIBUTION_ARCHIVE_NAME}.zip"
)
add_dependencies(Distribution
${PROJECT_NAME}
)
# Automatic deployment to Mod Organizer 2 mod directory.
foreach(DEPLOY_TARGET $ENV{${PROJECT_NAME}Targets})
message("Adding deployment target ${DEPLOY_TARGET}.")
add_custom_command(TARGET ${PROJECT_NAME} POST_BUILD
COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:${PROJECT_NAME}> "${DEPLOY_TARGET}/SKSE/Plugins/"
)
add_custom_command(TARGET ${PROJECT_NAME} POST_BUILD
COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_PDB_FILE:${PROJECT_NAME}> "${DEPLOY_TARGET}/SKSE/Plugins/"
)
endforeach()
########################################################################################################################
## Configure unit tests
########################################################################################################################
if(BUILD_TESTS AND NOT " ${tests}" STREQUAL " ")
include(CTest)
include(Catch)
add_executable(${PROJECT_NAME}Tests
${headers}
${tests}
)
target_link_libraries(${PROJECT_NAME}Tests
PRIVATE
${PROJECT_NAME}
Catch2::Catch2WithMain
)
target_precompile_headers(${PROJECT_NAME}Tests
PRIVATE
src/pch.hpp
)
catch_discover_tests(${PROJECT_NAME}Tests)
add_test(NAME ${PROJECT_NAME}Tests COMMAND ${PROJECT_NAME}Tests)
endif()