forked from crystal-lang/crystal
-
Notifications
You must be signed in to change notification settings - Fork 1
/
scheduler.cr
275 lines (232 loc) · 6.57 KB
/
scheduler.cr
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
require "crystal/system/event_loop"
require "crystal/system/print_error"
require "./fiber_channel"
require "fiber"
require "crystal/system/thread"
# :nodoc:
#
# Schedulers are tied to a thread, and must only ever be accessed from within
# this thread.
#
# Only the class methods are public and safe to use. Instance methods are
# protected and must never be called directly.
class Crystal::Scheduler
@event_loop = Crystal::EventLoop.create
def self.event_loop
Thread.current.scheduler.@event_loop
end
def self.current_fiber : Fiber
Thread.current.scheduler.@current
end
def self.enqueue(fiber : Fiber) : Nil
{% if flag?(:preview_mt) %}
th = fiber.@current_thread.lazy_get
if th.nil?
th = Thread.current.scheduler.find_target_thread
end
if th == Thread.current
Thread.current.scheduler.enqueue(fiber)
else
th.scheduler.send_fiber(fiber)
end
{% else %}
Thread.current.scheduler.enqueue(fiber)
{% end %}
end
def self.enqueue(fibers : Enumerable(Fiber)) : Nil
fibers.each do |fiber|
enqueue(fiber)
end
end
def self.reschedule : Nil
Thread.current.scheduler.reschedule
end
def self.resume(fiber : Fiber) : Nil
Thread.current.scheduler.resume(fiber)
end
def self.sleep(time : Time::Span) : Nil
Thread.current.scheduler.sleep(time)
end
def self.yield : Nil
Thread.current.scheduler.yield
end
def self.yield(fiber : Fiber) : Nil
Thread.current.scheduler.yield(fiber)
end
{% if flag?(:preview_mt) %}
def self.enqueue_free_stack(stack : Void*) : Nil
Thread.current.scheduler.enqueue_free_stack(stack)
end
{% end %}
{% if flag?(:preview_mt) %}
private getter(fiber_channel : Crystal::FiberChannel) { Crystal::FiberChannel.new }
@free_stacks = Deque(Void*).new
{% end %}
@lock = Crystal::SpinLock.new
@sleeping = false
# :nodoc:
def initialize(@main : Fiber)
@current = @main
@runnables = Deque(Fiber).new
end
protected def enqueue(fiber : Fiber) : Nil
@lock.sync { @runnables << fiber }
end
protected def enqueue(fibers : Enumerable(Fiber)) : Nil
@lock.sync { @runnables.concat fibers }
end
protected def resume(fiber : Fiber) : Nil
validate_resumable(fiber)
{% if flag?(:preview_mt) %}
set_current_thread(fiber)
GC.lock_read
{% elsif flag?(:interpreted) %}
# No need to change the stack bottom!
{% else %}
GC.set_stackbottom(fiber.@stack_bottom)
{% end %}
current, @current = @current, fiber
{% if flag?(:interpreted) %}
# TODO: ideally we could set this in the interpreter if the
# @context had a pointer back to the fiber.
# I also wonder why this isn't done always like that instead of in asm.
current.@context.resumable = 1
{% end %}
Fiber.swapcontext(pointerof(current.@context), pointerof(fiber.@context))
{% if flag?(:preview_mt) %}
GC.unlock_read
{% end %}
end
private def validate_resumable(fiber)
return if fiber.resumable?
if fiber.dead?
fatal_resume_error(fiber, "tried to resume a dead fiber")
else
fatal_resume_error(fiber, "can't resume a running fiber")
end
end
private def set_current_thread(fiber)
fiber.@current_thread.set(Thread.current)
end
private def fatal_resume_error(fiber, message)
Crystal::System.print_error "\nFATAL: %s: %s\n", message, fiber.to_s
caller.each { |line| Crystal::System.print_error " from %s\n", line }
exit 1
end
{% if flag?(:preview_mt) %}
protected def enqueue_free_stack(stack)
@free_stacks.push stack
end
private def release_free_stacks
while stack = @free_stacks.shift?
Fiber.stack_pool.release stack
end
end
{% end %}
protected def reschedule : Nil
loop do
if runnable = @lock.sync { @runnables.shift? }
unless runnable == @current
runnable.resume
end
break
else
@event_loop.run_once
end
end
{% if flag?(:preview_mt) %}
release_free_stacks
{% end %}
end
protected def sleep(time : Time::Span) : Nil
@current.resume_event.add(time)
reschedule
end
protected def yield : Nil
# TODO: Fiber switching and libevent for wasm32
{% unless flag?(:wasm32) %}
sleep(0.seconds)
{% end %}
end
protected def yield(fiber : Fiber) : Nil
@current.resume_event.add(0.seconds)
resume(fiber)
end
{% if flag?(:preview_mt) %}
@rr_target = 0
protected def find_target_thread
if workers = @@workers
@rr_target &+= 1
workers[@rr_target % workers.size]
else
Thread.current
end
end
def run_loop
fiber_channel = self.fiber_channel
loop do
@lock.lock
if runnable = @runnables.shift?
@runnables << Fiber.current
@lock.unlock
runnable.resume
else
@sleeping = true
@lock.unlock
fiber = fiber_channel.receive
@lock.lock
@sleeping = false
@runnables << Fiber.current
@lock.unlock
fiber.resume
end
end
end
def send_fiber(fiber : Fiber)
@lock.lock
if @sleeping
fiber_channel.send(fiber)
else
@runnables << fiber
end
@lock.unlock
end
def self.init_workers
count = worker_count
pending = Atomic(Int32).new(count - 1)
@@workers = Array(Thread).new(count) do |i|
if i == 0
worker_loop = Fiber.new(name: "Worker Loop") { Thread.current.scheduler.run_loop }
Thread.current.scheduler.enqueue worker_loop
Thread.current
else
Thread.new do
scheduler = Thread.current.scheduler
pending.sub(1)
scheduler.run_loop
end
end
end
# Wait for all worker threads to be fully ready to be used
while pending.get > 0
Fiber.yield
end
end
private def self.worker_count
env_workers = ENV["CRYSTAL_WORKERS"]?
if env_workers && !env_workers.empty?
workers = env_workers.to_i?
if !workers || workers < 1
Crystal::System.print_error "FATAL: Invalid value for CRYSTAL_WORKERS: %s\n", env_workers
exit 1
end
workers
else
# TODO: default worker count, currently hardcoded to 4 that seems to be something
# that is beneficial for many scenarios without adding too much contention.
# In the future we could use the number of cores or something associated to it.
4
end
end
{% end %}
end