/
paicehusk_perl.pl
executable file
·191 lines (156 loc) · 4.35 KB
/
paicehusk_perl.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
#!/usr/bin/perl
use strict;
use warnings;
######################################
## To run:
## paice.pl <rulefile> <wordfile>
## Stems are output to stdout.
## Stems and rule info are output to
## stderr.
######################################
if (scalar @ARGV < 2)
{
die "Usage: paicehusk_perl.pl <rulefile> <wordfile>";
}
my $ruleset = &LoadRules($ARGV[0]);
unless ($ruleset)
{
die "Could not open rules file: $ARGV[0]";
}
my $wordfile;
open($wordfile, $ARGV[1]) or die "Could not open words file: $ARGV[1]";
foreach my $line (<$wordfile>)
{
# process each word in line
while ($line =~ s/([A-Za-z]+)//)
{
my $debug = '';
my $stem = &StemWord(lc($1), $ruleset, \$debug);
print "$stem\n";
print STDERR "$stem ($debug)\n";
}
}
close($wordfile);
######################################
## LoadRules reads a rules file and
## produces the ruleset structure.
######################################
sub LoadRules
{
my ($rulepath) = @_;
my %rules;
my $rulefile;
open($rulefile, $rulepath) or return undef;
my $i = 0;
foreach my $line (<$rulefile>)
{
$i++;
if ($line =~ /^\s*([A-Za-z]+)(\*?)(\d+)([A-Za-z]*)([>.])/)
{
my %rule;
$rule{'suffix'} = reverse $1;
$rule{'intact'} = ($2 eq '*' ? 1 : 0);
$rule{'remove'} = 1 + $3 - 1;
$rule{'append'} = $4;
$rule{'restem'} = ($5 eq '>' ? 1 : 0);
$rule{'id'} = "($i:$1$2$3$4$5)";
if ($rule{'id'} eq "($i:end0.)")
{
# encountered pseudo-rule: stop
close($rulefile);
return \%rules;
}
my $letter = substr($1, 0, 1);
$rules{$letter} = [] unless $rules{$letter};
push(@{ $rules{$letter} }, \%rule);
}
}
close($rulefile);
return \%rules;
} # end LoadRules
######################################
## IsValid returns 1 if the parameter
## is an acceptable stem, or 0 if not.
## This prevents over-stemming by
## limiting the shortest final stem.
######################################
sub IsValid
{
my ($stem) = @_;
if ($stem =~ /^[aeiou]/)
{
return (length($stem) >= 2);
}
elsif ($stem =~ /[aeiouy]/)
{
return (length($stem) >= 3);
}
return 0;
} # end IsValid
######################################
## RuleMatches returns 1 if the
## rule can be applied to the stem,
## and 0 if the rule doesn't match.
######################################
sub RuleMatches
{
my ($rule, $stem, $intact) = @_;
return 0 if (!$intact && $rule->{'intact'});
my $suffix = $rule->{'suffix'};
return ($stem =~ /$suffix$/);
} # end RuleMatches
######################################
## ApplyRule takes a rule and stem,
## and produces the new stem created
## by applying the remove and append
## parts of the rule.
######################################
sub ApplyRule
{
my ($rule, $stem) = @_;
my $result = $stem;
my $remove = $rule->{'remove'};
$result = substr($result, 0, -$remove) if $remove;
$result .= $rule->{'append'};
return $result;
} # end ApplyRule
######################################
## StemWord is the main entry point
## for the stemmer. It takes a word
## and a reference to a ruleset
## structure (see LoadRules).
######################################
sub StemWord
{
my ($stem, $rules, $debug) = @_;
$$debug = '' if $debug;
# only stem if word passes acceptability rules
return $stem unless &IsValid($stem);
$$debug = $stem if $debug;
my $intact = 1;
my $restem = 1;
while ($restem)
{
# exit loop unless we apply a continuing rule
$restem = 0;
# try each rule for stem's last letter
my $last = substr($stem, -1);
my $ruleset = $rules->{$last};
last unless $ruleset;
foreach my $rule (@$ruleset)
{
# make sure this rule matches
next unless &RuleMatches($rule, $stem, $intact);
# apply the rule, check if result is acceptable
my $result = &ApplyRule($rule, $stem);
next unless &IsValid($result);
# rule matched, replace stem and continue or exit
$stem = $result;
$intact = 0;
$$debug .= " =" . $rule->{'id'} . "=> $result" if $debug;
$restem = $rule->{'restem'};
last; # kick out to outer loop
}
}
return $stem;
} # end StemWord