-
Notifications
You must be signed in to change notification settings - Fork 86
/
BigLedgerPeers.hs
236 lines (206 loc) · 10.1 KB
/
BigLedgerPeers.hs
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
{-# LANGUAGE FlexibleContexts #-}
{-# LANGUAGE NamedFieldPuns #-}
{-# LANGUAGE ScopedTypeVariables #-}
module Ouroboros.Network.PeerSelection.Governor.BigLedgerPeers
( belowTarget
, aboveTarget
) where
import Data.Map.Strict qualified as Map
import Data.Set (Set)
import Data.Set qualified as Set
import GHC.Stack (HasCallStack)
import Control.Applicative (Alternative)
import Control.Concurrent.JobPool (Job (..))
import Control.Exception (SomeException)
import Control.Monad.Class.MonadSTM
import Control.Monad.Class.MonadTime.SI
import Ouroboros.Network.PeerSelection.Bootstrap (requiresBootstrapPeers)
import Ouroboros.Network.PeerSelection.Governor.Types
import Ouroboros.Network.PeerSelection.LedgerPeers (LedgerPeersKind (..))
import Ouroboros.Network.PeerSelection.PeerAdvertise (PeerAdvertise (..))
import Ouroboros.Network.PeerSelection.PublicRootPeers (PublicRootPeers)
import Ouroboros.Network.PeerSelection.PublicRootPeers qualified as PublicRootPeers
import Ouroboros.Network.PeerSelection.State.EstablishedPeers qualified as EstablishedPeers
import Ouroboros.Network.PeerSelection.State.KnownPeers qualified as KnownPeers
import Ouroboros.Network.PeerSelection.State.LocalRootPeers qualified as LocalRootPeers
belowTarget :: (MonadSTM m, Ord peeraddr)
=> PeerSelectionActions peeraddr peerconn m
-> Time
-> PeerSelectionState peeraddr peerconn
-> Guarded (STM m) (TimedDecision m peeraddr peerconn)
belowTarget actions
blockedAt
st@PeerSelectionState {
publicRootPeers,
bigLedgerPeerRetryTime,
inProgressBigLedgerPeersReq,
targets = PeerSelectionTargets {
targetNumberOfKnownBigLedgerPeers
},
ledgerStateJudgement,
bootstrapPeersFlag
}
-- Are we in a sensitive state? We shouldn't attempt to fetch ledger peers
-- in a sensitive state since we only want to connect to trustable peers.
| not (requiresBootstrapPeers bootstrapPeersFlag ledgerStateJudgement)
-- Do we need more big ledger peers?
, maxExtraBigLedgerPeers > 0
, not inProgressBigLedgerPeersReq
, blockedAt >= bigLedgerPeerRetryTime
= Guarded Nothing $
return $ \_now -> Decision {
decisionTrace = [TraceBigLedgerPeersRequest
targetNumberOfKnownBigLedgerPeers
numBigLedgerPeers],
decisionState = st { inProgressBigLedgerPeersReq = True },
decisionJobs = [jobReqBigLedgerPeers actions maxExtraBigLedgerPeers]
}
| otherwise
= GuardedSkip Nothing
where
numBigLedgerPeers = Set.size (PublicRootPeers.getBigLedgerPeers publicRootPeers)
maxExtraBigLedgerPeers = targetNumberOfKnownBigLedgerPeers
- numBigLedgerPeers
jobReqBigLedgerPeers :: forall m peeraddr peerconn.
(MonadSTM m, Ord peeraddr)
=> PeerSelectionActions peeraddr peerconn m
-> Int
-> Job () m (Completion m peeraddr peerconn)
jobReqBigLedgerPeers PeerSelectionActions{ requestPublicRootPeers }
numExtraAllowed =
Job job (return . handler) () "reqBigLedgerPeers"
where
handler :: SomeException -> Completion m peeraddr peerconn
handler e =
Completion $ \st now ->
-- This is a failure, so move the backoff counter one in the failure
-- direction (negative) and schedule the next retry time accordingly.
-- We use an exponential backoff strategy. The max retry time of 2^8
-- seconds is just over 4 minutes.
let bigLedgerPeerBackoffs' :: Int
bigLedgerPeerBackoffs' = (bigLedgerPeerBackoffs st `min` 0) - 1
bigLedgerPeerRetryDiffTime' :: DiffTime
bigLedgerPeerRetryDiffTime' = 2 ^ (abs bigLedgerPeerBackoffs' `min` 8)
bigLedgerPeerRetryTime' :: Time
bigLedgerPeerRetryTime' = addTime bigLedgerPeerRetryDiffTime' now
in Decision {
decisionTrace = [TraceBigLedgerPeersFailure
e
bigLedgerPeerBackoffs'
bigLedgerPeerRetryDiffTime'],
decisionState = st {
inProgressPublicRootsReq = False,
publicRootBackoffs = bigLedgerPeerBackoffs',
publicRootRetryTime = bigLedgerPeerRetryTime'
},
decisionJobs = []
}
job :: m (Completion m peeraddr peerconn)
job = do
(results, ttl) <- requestPublicRootPeers BigLedgerPeers numExtraAllowed
return $ Completion $ \st now ->
let -- We make sure the set of big ledger peers disjoint from the sum
-- of local, public and ledger peers.
newPeers :: PublicRootPeers peeraddr
newPeers = results
`PublicRootPeers.difference`
( LocalRootPeers.keysSet (localRootPeers st)
<> PublicRootPeers.toSet (publicRootPeers st))
newPeersSet = PublicRootPeers.toSet newPeers
publicRootPeers' = publicRootPeers st <> newPeers
knownPeers'
= KnownPeers.insert
(Map.fromSet (\_ -> ( Nothing
-- the peer sharing flag will be
-- updated once we negotiate
-- the connection
, Just DoNotAdvertisePeer
))
newPeersSet)
(knownPeers st)
-- We got a successful response to our request, but if we're still
-- below target we're going to want to try again at some point.
-- If we made progress towards our target then we will retry at the
-- suggested ttl. But if we did not make progress then we want to
-- follow an exponential backoff strategy. The max retry time of 2^8
-- seconds is just over four minutes.
bigLedgerPeerBackoffs' :: Int
bigLedgerPeerBackoffs'
| PublicRootPeers.null newPeers = (bigLedgerPeerBackoffs st `max` 0) + 1
| otherwise = 0
bigLedgerPeerRetryDiffTime :: DiffTime
bigLedgerPeerRetryDiffTime
| bigLedgerPeerBackoffs' == 0
= ttl
| otherwise = 2^(bigLedgerPeerBackoffs' `min` 8)
bigLedgerPeerRetryTime :: Time
bigLedgerPeerRetryTime = bigLedgerPeerRetryDiffTime `addTime` now
in Decision {
decisionTrace = [TraceBigLedgerPeersResults
newPeersSet
bigLedgerPeerBackoffs'
bigLedgerPeerRetryDiffTime],
decisionState = st {
publicRootPeers = publicRootPeers',
knownPeers = knownPeers',
bigLedgerPeerBackoffs = bigLedgerPeerBackoffs',
bigLedgerPeerRetryTime = bigLedgerPeerRetryTime,
inProgressBigLedgerPeersReq = False
},
decisionJobs = []
}
aboveTarget :: forall m peeraddr peerconn.
(Alternative (STM m), MonadSTM m, Ord peeraddr, HasCallStack)
=> MkGuardedDecision peeraddr peerconn m
aboveTarget PeerSelectionPolicy {policyPickColdPeersToForget}
st@PeerSelectionState {
publicRootPeers,
knownPeers,
establishedPeers,
inProgressPromoteCold,
targets = PeerSelectionTargets {
targetNumberOfKnownBigLedgerPeers
}
}
-- Are we above the target for number of known big ledger peers
| numKnownBigLedgerPeers > targetNumberOfKnownBigLedgerPeers
-- Are there any cold big ledger peers we could pick to forget?
, numKnownBigLedgerPeers > numEstablishedBigLedgerPeers
, let availableToForget :: Set peeraddr
availableToForget = bigLedgerPeersSet
Set.\\ establishedBigLedgerPeers
Set.\\ inProgressPromoteCold
, not (Set.null availableToForget)
= Guarded Nothing $ do
let numPeersCanForget = numKnownBigLedgerPeers
- targetNumberOfKnownBigLedgerPeers
selectedToForget <- pickPeers st
policyPickColdPeersToForget
availableToForget
numPeersCanForget
return $ \_now ->
let knownPeers' = KnownPeers.delete selectedToForget knownPeers
publicRootPeers' = PublicRootPeers.difference publicRootPeers selectedToForget
in Decision {
decisionTrace = [TraceForgetBigLedgerPeers
targetNumberOfKnownBigLedgerPeers
numKnownBigLedgerPeers
selectedToForget
],
decisionState = st { knownPeers = knownPeers',
publicRootPeers = publicRootPeers'
},
decisionJobs = []
}
| otherwise
= GuardedSkip Nothing
where
bigLedgerPeersSet = PublicRootPeers.getBigLedgerPeers publicRootPeers
numKnownBigLedgerPeers :: Int
numKnownBigLedgerPeers = Set.size bigLedgerPeersSet
establishedBigLedgerPeers :: Set peeraddr
establishedBigLedgerPeers = EstablishedPeers.toSet establishedPeers
`Set.intersection`
bigLedgerPeersSet
numEstablishedBigLedgerPeers :: Int
numEstablishedBigLedgerPeers = Set.size establishedBigLedgerPeers