-
Notifications
You must be signed in to change notification settings - Fork 86
/
PeerMetric.hs
271 lines (235 loc) · 7.52 KB
/
PeerMetric.hs
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
{-# LANGUAGE BangPatterns #-}
{-# LANGUAGE GADTs #-}
{-# LANGUAGE NamedFieldPuns #-}
{-# LANGUAGE RankNTypes #-}
{-# LANGUAGE ScopedTypeVariables #-}
module Ouroboros.Network.PeerSelection.PeerMetric
( -- * Peer metrics
PeerMetrics
, newPeerMetric
-- * Metric calculations
, upstreamyness
, fetchynessBytes
, fetchynessBlocks
-- * Tracers
, headerMetricTracer
, fetchedMetricTracer
-- * Metrics reporters
, ReportPeerMetrics (..)
, nullMetric
, reportMetric
-- * Internals
-- only exported for testing purposes
, SlotMetric
, newPeerMetric'
) where
import Control.Monad.Class.MonadSTM.Strict
import Control.Monad.Class.MonadTime
import Control.Tracer (Tracer (..), contramap, nullTracer)
import Data.IntPSQ (IntPSQ)
import qualified Data.IntPSQ as Pq
import Data.Map.Strict (Map)
import qualified Data.Map.Strict as Map
import Cardano.Slotting.Slot (SlotNo (..))
import Ouroboros.Network.DeltaQ (SizeInBytes)
import Ouroboros.Network.NodeToNode (ConnectionId (..))
import Ouroboros.Network.PeerSelection.PeerMetric.Type
-- The maximum numbers of slots we will store data for.
-- On some chains sometimes this corresponds to 1h
-- worth of metrics *sighs*.
maxEntriesToTrack :: Int
maxEntriesToTrack = 180
type SlotMetric p = IntPSQ SlotNo (p, Time)
-- | Mutable peer metrics state accessible via 'STM'.
--
newtype PeerMetrics m p = PeerMetrics {
peerMetricsVar :: StrictTVar m (PeerMetricsState p)
}
-- | Internal state
--
data PeerMetricsState p = PeerMetricsState {
headerMetrics :: SlotMetric p
, fetchedMetrics :: SlotMetric (p, SizeInBytes)
}
newPeerMetric
:: MonadSTM m
=> m (PeerMetrics m p)
newPeerMetric = newPeerMetric' Pq.empty Pq.empty
newPeerMetric'
:: MonadSTM m
=> SlotMetric p
-> SlotMetric (p, SizeInBytes)
-> m (PeerMetrics m p)
newPeerMetric' headerMetrics fetchedMetrics =
PeerMetrics <$> newTVarIO PeerMetricsState {
headerMetrics,
fetchedMetrics
}
reportMetric
:: forall m p.
( MonadSTM m )
=> PeerMetrics m p
-> ReportPeerMetrics m (ConnectionId p)
reportMetric peerMetrics =
ReportPeerMetrics (headerMetricTracer peerMetrics)
(fetchedMetricTracer peerMetrics)
nullMetric
:: MonadSTM m
=> ReportPeerMetrics m p
nullMetric =
ReportPeerMetrics nullTracer nullTracer
slotMetricKey :: SlotNo -> Int
slotMetricKey (SlotNo s) = fromIntegral s
-- | Tracer which updates header metrics (upstreameness).
--
headerMetricTracer
:: forall m p.
( MonadSTM m )
=> PeerMetrics m p
-> Tracer (STM m) (TraceLabelPeer (ConnectionId p) (SlotNo, Time))
headerMetricTracer PeerMetrics{peerMetricsVar} =
(\(TraceLabelPeer con d) -> TraceLabelPeer (remoteAddress con) d)
`contramap`
metricsTracer
(headerMetrics <$> readTVar peerMetricsVar)
(\headerMetrics -> modifyTVar peerMetricsVar
(\metrics -> metrics { headerMetrics }))
-- | Tracer which updates fetched metrics (fetchyness).
--
fetchedMetricTracer
:: forall m p.
( MonadSTM m )
=> PeerMetrics m p
-> Tracer (STM m) (TraceLabelPeer (ConnectionId p)
( SizeInBytes
, SlotNo
, Time
))
fetchedMetricTracer PeerMetrics{peerMetricsVar} =
(\(TraceLabelPeer con (bytes, slot, time)) ->
TraceLabelPeer (remoteAddress con, bytes) (slot, time))
`contramap`
metricsTracer
(fetchedMetrics <$> readTVar peerMetricsVar)
(\fetchedMetrics -> modifyTVar peerMetricsVar
(\metrics -> metrics { fetchedMetrics }))
metricsTracer
:: forall m p. ( MonadSTM m )
=> STM m (SlotMetric p) -- ^ read metrics
-> (SlotMetric p -> STM m ()) -- ^ update metrics
-> Tracer (STM m) (TraceLabelPeer p (SlotNo, Time))
metricsTracer getMetrics writeMetrics = Tracer $ \(TraceLabelPeer !peer (!slot, !time)) -> do
metrics <- getMetrics
case Pq.lookup (slotMetricKey slot) metrics of
Nothing -> do
let metrics' = Pq.insert (slotMetricKey slot) slot (peer, time) metrics
if Pq.size metrics' > maxEntriesToTrack
then
case Pq.minView metrics' of
Nothing -> error "impossible empty pq" -- We just inserted an element!
Just (_, minSlotNo, _, metrics'') ->
if minSlotNo == slot
then return ()
else writeMetrics metrics''
else writeMetrics metrics'
Just (_, (_, oldTime)) ->
if oldTime <= time
then return ()
else writeMetrics (Pq.insert (slotMetricKey slot) slot (peer, time) metrics)
--
-- Metrics
--
-- * upstreameness
-- * fetchyness by blocks
-- * fetchyness by bytes
--
-- | Returns a Map which counts the number of times a given peer was the first
-- to present us with a block/header.
--
upstreamyness
:: forall p m.
MonadSTM m
=> Ord p
=> PeerMetrics m p
-> STM m (Map p Int)
upstreamyness PeerMetrics {peerMetricsVar} =
upstreamynessImpl <$> readTVar peerMetricsVar
upstreamynessImpl
:: forall p.
Ord p
=> PeerMetricsState p
-> Map p Int
upstreamynessImpl PeerMetricsState { headerMetrics } =
Pq.fold' count Map.empty headerMetrics
where
count :: Int
-> SlotNo
-> (p,Time)
-> Map p Int
-> Map p Int
count _ _ (peer,_) m =
Map.alter fn peer m
where
fn :: Maybe Int -> Maybe Int
fn Nothing = Just 1
fn (Just c) = Just $! c + 1
-- | Returns a Map which counts the number of bytes downloaded for a given
-- peer.
--
fetchynessBytes
:: forall p m.
MonadSTM m
=> Ord p
=> PeerMetrics m p
-> STM m (Map p Int)
fetchynessBytes PeerMetrics {peerMetricsVar} =
fetchynessBytesImpl <$> readTVar peerMetricsVar
fetchynessBytesImpl
:: forall p.
Ord p
=> PeerMetricsState p
-> Map p Int
fetchynessBytesImpl PeerMetricsState { fetchedMetrics } =
Pq.fold' count Map.empty fetchedMetrics
where
count :: Int
-> SlotNo
-> ((p, SizeInBytes), Time)
-> Map p Int
-> Map p Int
count _ _ ((peer, bytes),_) m =
Map.alter fn peer m
where
fn :: Maybe Int -> Maybe Int
fn Nothing = Just $ fromIntegral bytes
fn (Just oldBytes) = Just $! oldBytes + fromIntegral bytes
-- | Returns a Map which counts the number of times a given peer was the first
-- we downloaded a block from.
--
fetchynessBlocks
:: forall p m.
MonadSTM m
=> Ord p
=> PeerMetrics m p
-> STM m (Map p Int)
fetchynessBlocks PeerMetrics {peerMetricsVar} =
fetchynessBlocksImpl <$> readTVar peerMetricsVar
fetchynessBlocksImpl
:: forall p.
Ord p
=> PeerMetricsState p
-> Map p Int
fetchynessBlocksImpl PeerMetricsState { fetchedMetrics } =
Pq.fold' count Map.empty fetchedMetrics
where
count :: Int
-> SlotNo
-> ((p, SizeInBytes), Time)
-> Map p Int
-> Map p Int
count _ _ ((peer, _),_) m =
Map.alter fn peer m
where
fn :: Maybe Int -> Maybe Int
fn Nothing = Just 1
fn (Just c) = Just $! c + 1