/
CryptHash.ahk
147 lines (132 loc) · 7.09 KB
/
CryptHash.ahk
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
/*
Encripta datos en el algoritmo especificado.
Parámetros:
Binary : Una dirección de memoria o una cadena.
Length : La longitud de Binary. Este parámetro puede ser 0 si Binary es una cadena.
Algorithm: El algoritmo utilizado para encriptar los datos. Este parámetro puede ser una de las siguientes cadenas:
MD2, MD4, MD5, SHA1, SHA256, SHA384, SHA512 (https://msdn.microsoft.com/en-us/library/windows/desktop/aa375534(v=vs.85).aspx)
MAC : El proveedor realizará el algoritmo de código de autenticación de mensajes basado en hash (HMAC) con el algoritmo de hash especificado. Si este valor es de tipo entero y es 0, no se utiliza.
Return:
Si la función falla, devuelve una cadena vacía y ErrorLevel se establece en el código de error.
Códigos de error:
https://msdn.microsoft.com/en-us/library/cc704588.aspx.
Ejemplos:
MsgBox(CryptHash('Hola Mundo!', 0, 'SHA512'))
MsgBox(CryptHash(&(B:=FileRead('*c ' . (F:=FileSelect()))), FileGetSize(F), 'MD5'))
*/
CryptHash(Binary, Length, Algorithm, MAC := 0)
{
Local R, hAlgorithm, ObjectLength, BytesCopied, HashObject, Secret, Buffer, HashDigestLength, Data, Hash
, pSecret := sSecret := 0
, UseMAC := Type(MAC) == 'Integer' && MAC == 0 ? FALSE : TRUE
; https://msdn.microsoft.com/en-us/library/windows/desktop/aa375479(v=vs.85).aspx
R := DllCall('Bcrypt.dll\BCryptOpenAlgorithmProvider', 'PtrP', hAlgorithm ;phAlgorithm
, 'Str' , Format('{:U}', Algorithm) ;pszAlgId
, 'Ptr' , 0 ;pszAlgId
, 'UInt', UseMAC ? 8 : 0 ;pszImplementation --> BCRYPT_ALG_HANDLE_HMAC_FLAG : 0
, 'UInt') ;ReturnType
If (R)
{
ErrorLevel := Format('0x{:08X}', R)
Return ('')
}
; https://msdn.microsoft.com/en-us/library/windows/desktop/aa375464(v=vs.85).aspx
R := DllCall('Bcrypt.dll\BCryptGetProperty', 'Ptr' , hAlgorithm ;hObject
, 'Str' , 'ObjectLength' ;pszProperty
, 'UIntP', ObjectLength ;pbOutput
, 'UInt' , 4 ;cbOutput
, 'UIntP', BytesCopied ;pcbResult
, 'UInt' , 0 ;dwFlags
, 'UInt') ;ReturnType
If (R)
{
DllCall('Bcrypt.dll\BCryptCloseAlgorithmProvider', 'Ptr', hAlgorithm, 'UInt', 0)
ErrorLevel := Format('0x{:08X}', R)
Return ('')
}
; https://msdn.microsoft.com/en-us/library/windows/desktop/aa375383(v=vs.85).aspx
VarSetCapacity(HashObject, ObjectLength)
If (UseMAC)
{
VarSetCapacity(Secret, sSecret := StrPut(MAC, 'UTF-8') - 1)
StrPut(MAC, pSecret := &Secret, sSecret, 'UTF-8')
}
R := DllCall('Bcrypt.dll\BCryptCreateHash', 'Ptr' , hAlgorithm ;hAlgorithm
, 'PtrP', hHash ;phHash
, 'UPtr', &HashObject ;pbHashObject
, 'UInt', ObjectLength ;cbHashObject
, 'Ptr' , pSecret ;pbSecret
, 'UInt', sSecret ;cbSecret
, 'UInt', 0 ;dwFlags
, 'UInt') ;ReturnType
If (R)
{
DllCall('Bcrypt.dll\BCryptCloseAlgorithmProvider', 'Ptr', hAlgorithm, 'UInt', 0)
ErrorLevel := Format('0x{:08X}', R)
Return ('')
}
; https://msdn.microsoft.com/en-us/library/windows/desktop/aa375468(v=vs.85).aspx
If (Type(Binary) == 'String')
{
If (Binary == '')
{
DllCall('Bcrypt.dll\BCryptDestroyHash', 'Ptr', hHash)
DllCall('Bcrypt.dll\BCryptCloseAlgorithmProvider', 'Ptr', hAlgorithm, 'UInt', 0)
ErrorLevel := -1
Return ('')
}
If (Length)
Binary := SubStr(Binary, 1, Length)
VarSetCapacity(Buffer
, Length := StrPut(Binary, 'UTF-8') - 1)
StrPut(Binary, &Buffer, Length, 'UTF-8')
Binary := &Buffer
}
R := DllCall('Bcrypt.dll\BCryptHashData', 'Ptr' , hHash ;hHash
, 'UPtr', Binary ;pbInput
, 'UInt', Length ;cbInput
, 'UInt', 0 ;dwFlags
, 'UInt') ;ReturnType
If (R)
{
DllCall('Bcrypt.dll\BCryptDestroyHash', 'Ptr', hHash)
DllCall('Bcrypt.dll\BCryptCloseAlgorithmProvider', 'Ptr', hAlgorithm, 'UInt', 0)
ErrorLevel := Format('0x{:08X}', R)
Return ('')
}
; https://msdn.microsoft.com/en-us/library/windows/desktop/aa375464(v=vs.85).aspx
R := DllCall('Bcrypt.dll\BCryptGetProperty', 'Ptr' , hAlgorithm ;hObject
, 'Str' , 'HashDigestLength' ;pszProperty
, 'UIntP', HashDigestLength ;pbOutput
, 'UInt' , 4 ;cbOutput
, 'UIntP', BytesCopied ;pcbResult
, 'UInt' , 0 ;dwFlags
, 'UInt') ;ReturnType
If (R)
{
DllCall('Bcrypt.dll\BCryptDestroyHash', 'Ptr', hHash)
DllCall('Bcrypt.dll\BCryptCloseAlgorithmProvider', 'Ptr', hAlgorithm, 'UInt', 0)
ErrorLevel := Format('0x{:08X}', R)
Return ('')
}
; https://msdn.microsoft.com/en-us/library/windows/desktop/aa375443(v=vs.85).aspx
VarSetCapacity(Data, HashDigestLength)
R := DllCall('Bcrypt.dll\BCryptFinishHash', 'Ptr' , hHash ;hHash
, 'UPtr', &Data ;pbOutput
, 'UInt', HashDigestLength ;cbOutput
, 'UInt', 0 ;dwFlags
, 'UInt') ;ReturnType
If (R)
{
DllCall('Bcrypt.dll\BCryptDestroyHash', 'Ptr', hHash)
DllCall('Bcrypt.dll\BCryptCloseAlgorithmProvider', 'Ptr', hAlgorithm, 'UInt', 0)
ErrorLevel := Format('0x{:08X}', R)
Return ('')
}
Loop (HashDigestLength)
Hash .= Format('{:02X}', NumGet(&Data + A_Index - 1, 'UChar'))
DllCall('Bcrypt.dll\BCryptDestroyHash', 'Ptr', hHash)
DllCall('Bcrypt.dll\BCryptCloseAlgorithmProvider', 'Ptr', hAlgorithm, 'UInt', 0)
ErrorLevel := 0
Return (Hash)
}