-
Notifications
You must be signed in to change notification settings - Fork 270
/
IntelliJPlugin.groovy
480 lines (440 loc) · 26.5 KB
/
IntelliJPlugin.groovy
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
package org.jetbrains.intellij
import com.jetbrains.plugin.structure.intellij.version.IdeVersion
import org.gradle.api.GradleException
import org.gradle.api.Plugin
import org.gradle.api.Project
import org.gradle.api.artifacts.Configuration
import org.gradle.api.artifacts.Dependency
import org.gradle.api.file.DuplicatesStrategy
import org.gradle.api.internal.artifacts.publish.ArchivePublishArtifact
import org.gradle.api.internal.plugins.DefaultArtifactPublicationSet
import org.gradle.api.logging.Logging
import org.gradle.api.plugins.JavaPlugin
import org.gradle.api.tasks.SourceSet
import org.gradle.api.tasks.bundling.Zip
import org.gradle.api.tasks.compile.AbstractCompile
import org.gradle.api.tasks.testing.Test
import org.gradle.internal.jvm.Jvm
import org.gradle.jvm.tasks.Jar
import org.gradle.language.jvm.tasks.ProcessResources
import org.gradle.tooling.BuildException
import org.jetbrains.annotations.NotNull
import org.jetbrains.intellij.dependency.IdeaDependencyManager
import org.jetbrains.intellij.dependency.PluginDependency
import org.jetbrains.intellij.dependency.PluginDependencyManager
import org.jetbrains.intellij.dependency.PluginProjectDependency
import org.jetbrains.intellij.jbre.JbreResolver
import org.jetbrains.intellij.tasks.*
class IntelliJPlugin implements Plugin<Project> {
public static final GROUP_NAME = "intellij"
public static final EXTENSION_NAME = "intellij"
public static final String DEFAULT_SANDBOX = 'idea-sandbox'
public static final String PATCH_PLUGIN_XML_TASK_NAME = "patchPluginXml"
public static final String PLUGIN_XML_DIR_NAME = "patchedPluginXmlFiles"
public static final String PREPARE_SANDBOX_TASK_NAME = "prepareSandbox"
public static final String PREPARE_TESTING_SANDBOX_TASK_NAME = "prepareTestingSandbox"
public static final String VERIFY_PLUGIN_TASK_NAME = "verifyPlugin"
public static final String RUN_IDE_TASK_NAME = "runIde"
public static final String BUILD_PLUGIN_TASK_NAME = "buildPlugin"
public static final String PUBLISH_PLUGIN_TASK_NAME = "publishPlugin"
public static final String IDEA_CONFIGURATION_NAME = "idea"
public static final String IDEA_PLUGINS_CONFIGURATION_NAME = "ideaPlugins"
public static final LOG = Logging.getLogger(IntelliJPlugin)
public static final String DEFAULT_IDEA_VERSION = "LATEST-EAP-SNAPSHOT"
public static final String DEFAULT_INTELLIJ_REPO = 'https://cache-redirector.jetbrains.com/intellij-repository'
public static final String DEFAULT_JBRE_REPO = 'https://cache-redirector.jetbrains.com/intellij-jdk'
public static final String DEFAULT_INTELLIJ_PLUGINS_REPO = 'https://plugins.jetbrains.com'
@Override
void apply(Project project) {
def javaPlugin = project.getPlugins().apply(JavaPlugin)
def intellijExtension = project.extensions.create(EXTENSION_NAME, IntelliJPluginExtension) as IntelliJPluginExtension
intellijExtension.with {
pluginName = project.name
sandboxDirectory = new File(project.buildDir, DEFAULT_SANDBOX).absolutePath
downloadSources = !System.getenv().containsKey('CI')
}
configureConfigurations(project, javaPlugin)
configureTasks(project, intellijExtension)
}
private static void configureConfigurations(@NotNull Project project, @NotNull JavaPlugin javaPlugin) {
def idea = project.configurations.create(IDEA_CONFIGURATION_NAME)
def ideaPlugins = project.configurations.create(IDEA_PLUGINS_CONFIGURATION_NAME)
if (javaPlugin.hasProperty('COMPILE_ONLY_CONFIGURATION_NAME')) {
project.configurations.getByName(JavaPlugin.COMPILE_ONLY_CONFIGURATION_NAME).extendsFrom idea, ideaPlugins
project.configurations.getByName(JavaPlugin.TEST_COMPILE_CONFIGURATION_NAME).extendsFrom idea, ideaPlugins
} else {
project.configurations.getByName(JavaPlugin.COMPILE_CONFIGURATION_NAME).extendsFrom idea, ideaPlugins
}
}
private static def configureTasks(@NotNull Project project, @NotNull IntelliJPluginExtension extension) {
LOG.info("Configuring IntelliJ IDEA gradle plugin")
configurePatchPluginXmlTask(project, extension)
configurePrepareSandboxTasks(project, extension)
configurePluginVerificationTask(project)
configureRunIdeaTask(project, extension)
configureBuildPluginTask(project)
configurePublishPluginTask(project, extension)
configureProcessResources(project)
configureInstrumentation(project, extension)
configureDependencyExtensions(project, extension)
assert !project.state.executed : "afterEvaluate is a no-op for an executed project"
project.afterEvaluate { configureProjectAfterEvaluate(it, extension) }
}
private static void configureProjectAfterEvaluate(@NotNull Project project,
@NotNull IntelliJPluginExtension extension) {
for (def subproject : project.subprojects) {
def subprojectExtension = subproject.extensions.findByType(IntelliJPluginExtension)
if (subprojectExtension) {
configureProjectAfterEvaluate(subproject, subprojectExtension)
}
}
configureIntellijDependency(project, extension)
configurePluginDependencies(project, extension)
configureTestTasks(project, extension)
}
private static void configureDependencyExtensions(@NotNull Project project,
@NotNull IntelliJPluginExtension extension) {
project.dependencies.ext.intellij = { Closure filter = {} ->
def dependency = extension.ideaDependency
if (dependency == null || dependency.jarFiles == null || dependency.jarFiles.empty) {
throw new GradleException('intellij is not (yet) configured. Please note that you should configure intellij dependencies in the afterEvaluate block')
}
project.files(dependency.jarFiles).asFileTree.matching(filter)
}
project.dependencies.ext.intellijPlugin = { String plugin, Closure filter = {} ->
def pluginDep = extension.pluginDependencies.find { it.id == plugin }
if (pluginDep == null || pluginDep.jarFiles == null || pluginDep.jarFiles.empty) {
throw new GradleException("intellij plugin '$plugin' is not (yet) configured or not found. Please note that you should specify plugins in the intellij.plugins property and configure dependencies to them in the afterEvaluate block")
}
project.files(pluginDep.jarFiles).asFileTree.matching(filter)
}
project.dependencies.ext.intellijPlugins = { String... plugins ->
def selectedPlugins = new HashSet<PluginDependency>()
def invalidPlugins = []
for (pluginName in plugins) {
def plugin = extension.pluginDependencies.find { it.id == pluginName }
if (plugin == null || plugin.jarFiles == null || plugin.jarFiles.empty) {
invalidPlugins.add(pluginName)
}
else {
selectedPlugins.add(plugin)
}
}
if (!invalidPlugins.empty) {
throw new GradleException("intellij plugins $invalidPlugins are not (yet) configured or not found. Please note that you should specify plugins in the intellij.plugins property and configure dependencies to them in the afterEvaluate block")
}
project.files(selectedPlugins.collect { it.jarFiles })
}
project.dependencies.ext.intellijExtra = { String extra, Closure filter = {} ->
def dependency = extension.ideaDependency
def extraDep = dependency != null ? dependency.extraDependencies.find { it.name == extra } : null
if (extraDep == null || extraDep.jarFiles == null || extraDep.jarFiles.empty) {
throw new GradleException("intellij extra artefact '$extra' is not (yet) configured or not found. Please note that you should specify extra dependencies in the intellij.extraDependencies property and configure dependencies to them in the afterEvaluate block")
}
project.files(extraDep.jarFiles).asFileTree.matching(filter)
}
}
private static void configureIntellijDependency(@NotNull Project project,
@NotNull IntelliJPluginExtension extension) {
LOG.info("Configuring IntelliJ IDEA dependency")
def resolver = new IdeaDependencyManager(extension.intellijRepo ?: DEFAULT_INTELLIJ_REPO)
def ideaDependency
if (extension.localPath != null) {
if (extension.version != null) {
LOG.warn("Both `localPath` and `version` specified, second would be ignored")
}
LOG.info("Using path to locally installed IDE: '${extension.localPath}'")
ideaDependency = resolver.resolveLocal(project, extension.localPath, extension.localSourcesPath)
} else {
LOG.info("Using IDE from remote repository")
def version = extension.version ?: DEFAULT_IDEA_VERSION
ideaDependency = resolver.resolveRemote(project, version, extension.type, extension.downloadSources,
extension.extraDependencies)
}
extension.ideaDependency = ideaDependency
if (extension.configureDefaultDependencies) {
LOG.info("IntelliJ IDEA ${ideaDependency.buildNumber} is used for building")
resolver.register(project, ideaDependency, IDEA_CONFIGURATION_NAME)
if (!ideaDependency.extraDependencies.empty) {
LOG.info("Note: IntelliJ IDEA ${ideaDependency.buildNumber} extra dependencies (${ideaDependency.extraDependencies}) should be applied manually")
}
def toolsJar = Jvm.current().toolsJar
if (toolsJar) {
project.dependencies.add(JavaPlugin.RUNTIME_CONFIGURATION_NAME, project.files(toolsJar))
}
}
else {
LOG.info("IntelliJ IDEA ${ideaDependency.buildNumber} dependencies are applied manually")
}
}
private static void configurePluginDependencies(@NotNull Project project,
@NotNull IntelliJPluginExtension extension) {
LOG.info("Configuring IntelliJ IDEA plugin dependencies")
def ideVersion = IdeVersion.createIdeVersion(extension.ideaDependency.buildNumber)
def resolver = new PluginDependencyManager(project.gradle.gradleUserHomeDir.absolutePath, extension.ideaDependency, extension.pluginsRepo)
extension.plugins.each {
LOG.info("Configuring IntelliJ plugin $it")
if (it instanceof Project) {
project.dependencies.add(IDEA_PLUGINS_CONFIGURATION_NAME, it)
if (it.state.executed) {
configureProjectPluginDependency(project, it, extension)
} else {
it.afterEvaluate {
configureProjectPluginDependency(project, it, extension)
}
}
} else {
def (pluginId, pluginVersion, channel) = Utils.parsePluginDependencyString(it.toString())
if (!pluginId) {
throw new BuildException("Failed to resolve plugin $it", null)
}
def plugin = resolver.resolve(pluginId, pluginVersion, channel)
if (plugin == null) {
throw new BuildException("Failed to resolve plugin $it", null)
}
if (ideVersion != null && !plugin.isCompatible(ideVersion)) {
throw new BuildException("Plugin $it is not compatible to ${ideVersion.asString()}", null)
}
if (extension.configureDefaultDependencies) {
resolver.register(project, plugin, plugin.builtin ? IDEA_CONFIGURATION_NAME : IDEA_PLUGINS_CONFIGURATION_NAME)
}
extension.pluginDependencies.add(plugin)
project.tasks.withType(PrepareSandboxTask).each {
it.configureExternalPlugin(plugin)
}
}
}
}
private static void configureProjectPluginDependency(@NotNull Project project,
@NotNull Project dependency,
@NotNull IntelliJPluginExtension extension) {
if (dependency.plugins.findPlugin(IntelliJPlugin) == null) {
throw new BuildException("Cannot use $dependency as a plugin dependency. IntelliJ Plugin is not found." + dependency.plugins, null)
}
def pluginDependency = new PluginProjectDependency(dependency)
extension.pluginDependencies.add(pluginDependency)
def dependencySandboxTask = dependency.tasks.findByName(PREPARE_SANDBOX_TASK_NAME)
project.tasks.withType(PrepareSandboxTask).each {
it.dependsOn(dependencySandboxTask)
it.configureCompositePlugin(pluginDependency)
}
}
private static void configurePatchPluginXmlTask(@NotNull Project project,
@NotNull IntelliJPluginExtension extension) {
LOG.info("Configuring patch plugin.xml task")
project.tasks.create(PATCH_PLUGIN_XML_TASK_NAME, PatchPluginXmlTask).with {
group = GROUP_NAME
description = "Patch plugin xml files with corresponding since/until build numbers and version attributes"
conventionMapping('version', { project.version?.toString() })
conventionMapping('pluginXmlFiles', { Utils.sourcePluginXmlFiles(project) })
conventionMapping('destinationDir', { new File(project.buildDir, PLUGIN_XML_DIR_NAME) })
conventionMapping('sinceBuild', {
if (extension.updateSinceUntilBuild) {
def ideVersion = IdeVersion.createIdeVersion(extension.ideaDependency.buildNumber)
return "$ideVersion.baselineVersion.$ideVersion.build".toString()
}
})
conventionMapping('untilBuild', {
if (extension.updateSinceUntilBuild) {
def ideVersion = IdeVersion.createIdeVersion(extension.ideaDependency.buildNumber)
return extension.sameSinceUntilBuild ? "${getSinceBuild()}.*".toString()
: "$ideVersion.baselineVersion.*".toString()
}
})
}
}
private static void configurePrepareSandboxTasks(@NotNull Project project,
@NotNull IntelliJPluginExtension extension) {
configurePrepareSandboxTask(project, extension, false)
configurePrepareSandboxTask(project, extension, true)
}
private static void configurePrepareSandboxTask(@NotNull Project project,
@NotNull IntelliJPluginExtension extension,
boolean inTest) {
LOG.info("Configuring prepare IntelliJ sandbox task")
def taskName = inTest ? PREPARE_TESTING_SANDBOX_TASK_NAME : PREPARE_SANDBOX_TASK_NAME
project.tasks.create(taskName, PrepareSandboxTask).with {
group = GROUP_NAME
description = "Prepare sandbox directory with installed plugin and its dependencies."
conventionMapping('pluginName', { extension.pluginName })
conventionMapping('pluginJar', { (project.tasks.findByName(JavaPlugin.JAR_TASK_NAME) as Jar).archivePath })
conventionMapping('destinationDir', { project.file(Utils.pluginsDir(extension.sandboxDirectory, inTest)) })
conventionMapping('configDirectory', { project.file(Utils.configDir(extension.sandboxDirectory, inTest)) })
conventionMapping('librariesToIgnore', { project.files(extension.ideaDependency.jarFiles) })
conventionMapping('pluginDependencies', { extension.pluginDependencies })
dependsOn(JavaPlugin.JAR_TASK_NAME)
}
}
private static void configurePluginVerificationTask(@NotNull Project project) {
LOG.info("Configuring plugin verification task")
project.tasks.create(VERIFY_PLUGIN_TASK_NAME, VerifyPluginTask).with {
group = GROUP_NAME
description = "Verifies built plugin."
conventionMapping('pluginDirectory', {
def prepareSandboxTask = project.tasks.findByName(PREPARE_SANDBOX_TASK_NAME) as PrepareSandboxTask
new File(prepareSandboxTask.getDestinationDir(), prepareSandboxTask.getPluginName())
})
dependsOn { project.getTasksByName(PREPARE_SANDBOX_TASK_NAME, false) }
}
}
private static void configureRunIdeaTask(@NotNull Project project, @NotNull IntelliJPluginExtension extension) {
LOG.info("Configuring run IntelliJ task")
project.tasks.create(RUN_IDE_TASK_NAME, RunIdeTask)
//noinspection GroovyAssignabilityCheck
project.tasks.withType(RunIdeTask) { RunIdeTask task ->
task.group = GROUP_NAME
task.description = "Runs Intellij IDEA with installed plugin."
task.conventionMapping.map("ideaDirectory", { Utils.ideaSdkDirectory(extension) })
task.conventionMapping.map("systemProperties", { extension.systemProperties })
task.conventionMapping.map("requiredPluginIds", { Utils.getPluginIds(project) })
task.conventionMapping.map("configDirectory", {
(project.tasks.findByName(PREPARE_SANDBOX_TASK_NAME) as PrepareSandboxTask).getConfigDirectory()
})
task.conventionMapping.map("pluginsDirectory", {
(project.tasks.findByName(PREPARE_SANDBOX_TASK_NAME) as PrepareSandboxTask).getDestinationDir()
})
task.conventionMapping.map("systemDirectory", {
project.file(Utils.systemDir(extension.sandboxDirectory, false))
})
task.conventionMapping("executable", {
def jbreResolver = new JbreResolver(project)
def jbreVersion = task.getJbreVersion()
if (jbreVersion != null) {
def jbre = jbreResolver.resolve(jbreVersion)
if (jbre != null) {
return jbre.javaExecutable
}
LOG.warn("Cannot resolve JBRE $jbreVersion. Falling back to builtin JBRE.")
}
def builtinJbreVersion = Utils.getBuiltinJbreVersion(Utils.ideaSdkDirectory(extension))
if (builtinJbreVersion != null) {
def builtinJbre = jbreResolver.resolve(builtinJbreVersion)
if (builtinJbre != null) {
return builtinJbre.javaExecutable
}
LOG.warn("Cannot resolve builtin JBRE $builtinJbreVersion. Falling local Java.")
}
return Jvm.current().javaExecutable.absolutePath
})
task.dependsOn(PREPARE_SANDBOX_TASK_NAME)
}
}
private static void configureInstrumentation(@NotNull Project project, @NotNull IntelliJPluginExtension extension) {
LOG.info("Configuring IntelliJ compile tasks")
project.sourceSets.all { SourceSet sourceSet ->
def instrumentTask = project.tasks.create(sourceSet.getTaskName('instrument', 'code'), IntelliJInstrumentCodeTask)
instrumentTask.sourceSet = sourceSet
instrumentTask.with {
dependsOn sourceSet.classesTaskName
onlyIf { extension.instrumentCode && it.getJavac2().exists() }
conventionMapping('ideaDependency', { extension.ideaDependency })
conventionMapping('javac2', { project.file("$extension.ideaDependency.classes/lib/javac2.jar") })
conventionMapping('outputDir', {
def output = sourceSet.output
def classesDir = output.hasProperty('classesDirs') ?
output.classesDirs.first() :
output.classesDir
new File(classesDir.parentFile, "${sourceSet.name}-instrumented")
})
}
def updateTask = project.tasks.create('post' + instrumentTask.name.capitalize())
updateTask.with {
dependsOn instrumentTask
onlyIf { extension.instrumentCode && instrumentTask.getJavac2().exists() }
doLast {
def sourceSetOutput = sourceSet.output
def oldClassesDir = sourceSetOutput.hasProperty("classesDirs") ?
sourceSetOutput.classesDirs :
sourceSetOutput.classesDir
// Set the classes dir to the new one with the instrumented classes
if (sourceSetOutput.hasProperty("classesDirs"))
sourceSetOutput.classesDirs.from = instrumentTask.outputDir else
sourceSetOutput.classesDir = instrumentTask.outputDir
if (sourceSet.name == SourceSet.MAIN_SOURCE_SET_NAME) {
// When we change the output classes directory, Gradle will automatically configure
// the test compile tasks to use the instrumented classes. Normally this is fine,
// however, it causes problems for Kotlin projects:
// The "internal" modifier can be used to restrict access to the same module.
// To make it possible to use internal methods from the main source set in test classes,
// the Kotlin Gradle plugin adds the original output directory of the Java task
// as "friendly directory" which makes it possible to access internal members
// of the main module.
// This fails when we change the classes dir. The easiest fix is to prepend the
// classes from the "friendly directory" to the compile classpath.
AbstractCompile testCompile = project.tasks.findByName('compileTestKotlin') as AbstractCompile
if (testCompile) {
testCompile.classpath = project.files(oldClassesDir, testCompile.classpath)
}
}
}
}
// Ensure that our task is invoked when the source set is built
sourceSet.compiledBy(updateTask)
}
}
private static void configureTestTasks(@NotNull Project project, @NotNull IntelliJPluginExtension extension) {
LOG.info("Configuring IntelliJ tests tasks")
project.tasks.withType(Test).each {
def configDirectory = project.file(Utils.configDir(extension.sandboxDirectory, true))
def systemDirectory = project.file(Utils.systemDir(extension.sandboxDirectory, true))
def pluginsDirectory = project.file(Utils.pluginsDir(extension.sandboxDirectory, true))
it.enableAssertions = true
it.systemProperties(extension.systemProperties)
it.systemProperties(Utils.getIdeaSystemProperties(configDirectory, systemDirectory, pluginsDirectory, Utils.getPluginIds(project)))
it.jvmArgs = Utils.getIdeaJvmArgs(it, it.jvmArgs, Utils.ideaSdkDirectory(extension))
it.classpath += project.files("$extension.ideaDependency.classes/lib/resources.jar",
"$extension.ideaDependency.classes/lib/idea.jar")
it.outputs.dir(systemDirectory)
it.outputs.dir(configDirectory)
it.dependsOn(project.getTasksByName(PREPARE_TESTING_SANDBOX_TASK_NAME, false))
}
}
private static void configureBuildPluginTask(@NotNull Project project) {
LOG.info("Configuring building IntelliJ IDEA plugin task")
def prepareSandboxTask = project.tasks.findByName(PREPARE_SANDBOX_TASK_NAME) as PrepareSandboxTask
Zip zip = project.tasks.create(BUILD_PLUGIN_TASK_NAME, Zip).with {
description = "Bundles the project as a distribution."
group = GROUP_NAME
from { "${prepareSandboxTask.getDestinationDir()}/${prepareSandboxTask.getPluginName()}" }
into { prepareSandboxTask.getPluginName() }
dependsOn(prepareSandboxTask)
conventionMapping.map('baseName', { prepareSandboxTask.getPluginName() })
it
}
Configuration archivesConfiguration = project.configurations.getByName(Dependency.ARCHIVES_CONFIGURATION)
if (archivesConfiguration) {
ArchivePublishArtifact zipArtifact = new ArchivePublishArtifact(zip)
archivesConfiguration.getArtifacts().add(zipArtifact)
project.getExtensions().getByType(DefaultArtifactPublicationSet.class).addCandidate(zipArtifact)
project.getComponents().add(new IntelliJPluginLibrary())
}
}
private static void configurePublishPluginTask(@NotNull Project project,
@NotNull IntelliJPluginExtension extension) {
LOG.info("Configuring publishing IntelliJ IDEA plugin task")
project.tasks.create(PUBLISH_PLUGIN_TASK_NAME, PublishTask).with {
group = GROUP_NAME
description = "Publish plugin distribution on plugins.jetbrains.com."
conventionMapping('username', { extension.publish.username })
conventionMapping('password', { extension.publish.password })
conventionMapping('channels', { extension.publish.channels })
conventionMapping('distributionFile', {
def buildPluginTask = project.tasks.findByName(BUILD_PLUGIN_TASK_NAME) as Zip
def distributionFile = buildPluginTask?.archivePath
return distributionFile?.exists() ? distributionFile : null
})
dependsOn { project.getTasksByName(BUILD_PLUGIN_TASK_NAME, false) }
dependsOn { project.getTasksByName(VERIFY_PLUGIN_TASK_NAME, false) }
}
}
private static void configureProcessResources(@NotNull Project project) {
LOG.info("Configuring IntelliJ resources task")
def processResourcesTask = project.tasks.findByName(JavaPlugin.PROCESS_RESOURCES_TASK_NAME) as ProcessResources
if (processResourcesTask) {
processResourcesTask.from(project.tasks.findByName(PATCH_PLUGIN_XML_TASK_NAME)) {
into("META-INF")
duplicatesStrategy = DuplicatesStrategy.INCLUDE
}
}
}
}