-
Notifications
You must be signed in to change notification settings - Fork 20
/
ze_SpedDaNfe.prg
1125 lines (977 loc) · 59.3 KB
/
ze_SpedDaNfe.prg
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
ZE_SPEDDANFE - Documento Auxiliar da Nota Fiscal Eletrônica
Fontes originais do projeto hbnfe em https://github.com/fernandoathayde/hbnfe
Anotação (manual do usuário 6.0):
Os campos que podem ser colocados na mesma coluna são:
- “Código do Produto/Serviço” com “NCM/SH”;
- “CST” com “CFOP”;
- “CSOSN” com “CFOP”;
- “Quantidade” com “Unidade”;
- “Valor Unitário” com “Desconto”;
- “Valor Total” com “Base de Cálculo do ICMS”;
- “Base de Cálculo do ICMS por Substituição Tributária” com “Valor do ICMS por Substituição Tributária”;
- “Valor do ICMS Próprio” com “Valor do IPI”
- “Alíquota do ICMS” com “Alíquota do IPI”.
*/
#include "common.ch"
#include "hbclass.ch"
#include "harupdf.ch"
#ifndef __XHARBOUR__
#include "hbwin.ch"
#endif
#define LAYOUT_LOGO_ESQUERDA 1
#define LAYOUT_LOGO_DIREITA 2
#define LAYOUT_LOGO_EXPANDIDO 3
#define LAYOUT_NAOIMPRIME 0
#define LAYOUT_IMPRIMENORMAL 1
#define LAYOUT_IMPRIMESEGUNDA 2
#define LAYOUT_TITULO 1
#define LAYOUT_LARGURA 2
#define LAYOUT_COLUNAPDF 3
#define LAYOUT_LARGURAPDF 4
#define LAYOUT_DECIMAIS 5
#define LAYOUT_TITULO1 6
#define LAYOUT_TITULO2 7
#define LAYOUT_CONTEUDO 8
#define LAYOUT_IMPRIME 9
#define LAYOUT_CODIGO 1
#define LAYOUT_DESCRICAO 2
#define LAYOUT_NCM 3
#define LAYOUT_EAN 4
#define LAYOUT_CST 5
#define LAYOUT_CFOP 6
#define LAYOUT_UNIDADE 7
#define LAYOUT_QTD 8
#define LAYOUT_UNITARIO 9
#define LAYOUT_TOTAL 10
#define LAYOUT_DESCONTO 11
#define LAYOUT_ICMBAS 12
#define LAYOUT_ICMVAL 13
#define LAYOUT_SUBBAS 14
#define LAYOUT_SUBVAL 15
#define LAYOUT_IPIVAL 16
#define LAYOUT_ICMALI 17
#define LAYOUT_IPIALI 18
#define LAYOUT_FONTSIZE 8
CREATE CLASS hbNFeDaNFe INHERIT hbNFeDaGeral
METHOD ToPDF( cXmlNFE, cFilePDF, cXmlCancel )
METHOD Execute( cXmlNFE, cFilePDF, cXmlCancel ) INLINE ::ToPDF( cXmlNFE, cFilePDF, cXmlCancel ) // compatibilidade
METHOD BuscaDadosXML()
METHOD GeraPDF( cFilePDF )
METHOD NovaPagina()
METHOD SaltaPagina()
METHOD CabecalhoRetrato()
METHOD Destinatario()
METHOD Duplicatas()
METHOD Canhoto()
METHOD DadosImposto()
METHOD DadosTransporte()
METHOD CabecalhoProdutos()
METHOD DesenhaBoxProdutos( nLinhaFinalProd, nAlturaQuadroProdutos )
METHOD Produtos()
METHOD TotalServico()
METHOD DadosAdicionais()
METHOD ProcessaItens( cXml, nItem )
METHOD CalculaLayout()
METHOD ItensDaFolha( nFolha )
METHOD Init()
METHOD DrawTextoProduto( nCampo, nRow, nConteudo, nAlign )
METHOD DrawBoxProduto( nCampo, nRow, nHeight )
METHOD DefineColunasProdutos()
VAR cTelefoneEmitente INIT ""
VAR cSiteEmitente INIT ""
VAR cEmailEmitente INIT ""
VAR cXml
VAR cXmlCancel INIT ""
VAR cChave
VAR aIde
VAR aEmit
VAR aDest
VAR aRetirada
VAR aEntrega
VAR aICMSTotal
VAR aISSTotal
VAR aRetTrib
VAR aTransp
VAR aVeicTransp
VAR aReboque
VAR cCobranca
VAR aInfAdic
VAR aObsCont
VAR aObsFisco
VAR aExporta
VAR aCompra
VAR aInfProt
VAR aItem
VAR aItemDI
VAR aItemAdi
VAR aItemICMS
VAR aItemICMSPart
VAR aItemICMSST
VAR aItemICMSSN101
VAR aItemICMSSN102
VAR aItemICMSSN201
VAR aItemICMSSN202
VAR aItemICMSSN500
VAR aItemICMSSN900
VAR aItemIPI
VAR aItemII
VAR aItemPIS
VAR aItemPISST
VAR aItemCOFINS
VAR aItemCOFINSST
VAR aItemISSQN
VAR cFonteNFe INIT "Times"
VAR cFonteCode128 // Inserido por Anderson Camilo em 04/04/2012
VAR cFonteCode128F // Inserido por Anderson Camilo em 04/04/2012
VAR oPdf
VAR oPdfPage
VAR oPDFFontNormal
VAR oPDFFontBold
VAR nLinhaPDF
VAR nLarguraBox INIT 0.3
VAR lLaser INIT .T.
VAR cLogoFile INIT ""
VAR nLogoStyle INIT LAYOUT_LOGO_ESQUERDA
VAR nFolha
VAR cRetorno
VAR nItensFolha
VAR nLinhaFolha
VAR nLayoutTotalFolhas
VAR lLayoutEspacoDuplo INIT .T.
VAR aLayout
ENDCLASS
METHOD Init() CLASS hbNFeDaNFe
LOCAL oElement
::aLayout := Array(18)
FOR EACH oElement IN ::aLayout
oElement := Array(10)
oElement[ LAYOUT_IMPRIME ] := LAYOUT_IMPRIMENORMAL
oElement[ LAYOUT_TITULO1 ] := ""
oElement[ LAYOUT_TITULO2 ] := ""
oElement[ LAYOUT_CONTEUDO ] := { || "" }
oElement[ LAYOUT_LARGURAPDF ] := 1
NEXT
RETURN SELF
METHOD ToPDF( cXmlNFE, cFilePDF, cXmlCancel ) CLASS hbNFeDaNFe
IF Empty( cXmlNFE )
::cRetorno := "XML sem conteúdo"
RETURN ::cRetorno
ENDIF
IF ! Empty( cXmlCancel )
::cXmlCancel := cXmlCancel
ENDIF
::cXML := cXmlNFE
::cChave := SubStr( ::cXML, At( "Id=", ::cXML ) + 3 + 4, 44 )
IF ! ::BuscaDadosXML()
RETURN ::cRetorno
ENDIF
IF ! ::GeraPDF( cFilePDF )
::cRetorno := "Problema ao gerar o PDF"
RETURN ::cRetorno
ENDIF
::cRetorno := "OK"
RETURN ::cRetorno
METHOD BuscaDadosXML() CLASS hbNFeDaNFe
::aIde := XmlToHash( XmlNode( ::cXml, "ide" ), { "cUF", "cNF", "natOp", "indPag", "mod", "serie", "nNF", "dhEmi", "dhSaiEnt", "tpNF", "cMunFG", "tpImp", "tpEmis", ;
"cDV", "tpAmb", "finNFe", "procEmi", "verProc" } )
IF Empty( ::aIde[ "dhEmi" ] ) // NFE 2.0
::aIde[ "dhEmi" ] := XmlNode( XmlNode( ::cXml, "ide" ), "dEmi" )
ENDIF
//IF Empty( ::aIde[ "dhSaiEnt" ] ) // NFE 2.0
// ::aIde[ "dhSaiEnt" ] := XmlNode( XmlNode( ::cXml, "ide" ), "dSaiEnt" )
//ENDIF
::aEmit := XmlToHash( XmlNode( ::cXml, "emit" ), { "CNPJ", "CPF", "xNome", "xFant", "xLgr", "nro", "xBairro", "cMun", "xMun", "UF", "CEP", "cPais", "xPais", ;
"fone", "IE", "IEST", "IM", "CNAE", "CRT", "fone" } )
::aDest := XmlToHash( XmlNode( ::cXml, "dest" ), { "CNPJ", "CPF", "xNome", "xLgr", "nro", "xCpl", "xBairro", "cMun", "xMun", "UF", "CEP", "cPais", "xPais", "fone", "IE", "ISUF", "email" } )
::aRetirada := XmlToHash( XmlNode( ::cXml, "retirada" ), { "CNPJ", "CPF", "xLgr", "nro", "xCpl", "xBairro", "cMun", "xMun", "UF" } )
::aEntrega := XmlToHash( XmlNode( ::cXml, "entrega" ), { "CNPJ", "CPF", "xLgr", "nro", "xCpl", "xBairro", "cMun", "xMun", "UF" } )
::aICMSTotal := XmlToHash( XmlNode( ::cXml, "ICMSTot" ), { "vBC", "vICMS", "vBCST", "vST", "vProd", "vFrete", "vSeg", "vDesc", "vII", "vIPI", "vPIS", "vCOFINS", "vOutro", "vNF" } )
::aISSTotal := XmlToHash( XmlNode( ::cXml, "ISSQNtot" ), { "vServ", "vBC", "vISS", "vPIS", "vCOFINS" } )
::aRetTrib := XmlToHash( XmlNode( ::cXml, "RetTrib" ), { "vRetPIS", "vRetCOFINS", "vRetCSLL", "vBCIRRF", "vIRRF", "vBCRetPrev", "vRetPrev" } )
::aTransp := XmlToHash( XmlNode( ::cXml, "transp" ), { "modFrete", "CNPJ", "CPF", "xNome", "IE", "xEnder", "xMun", "UF", "qVol", "esp", "marca", "nVol", "pesoL", "pesoB", "nLacre" } )
::aVeicTransp := XmlToHash( XmlNode( XmlNode( ::cXml, "transp" ), "veicTransp" ), { "placa", "UF", "RNTC" } )
::aReboque := XmlToHash( XmlNode( XmlNode( ::cXml, "reboque" ), "veicTransp" ), { "placa", "UF", "RNTC" } )
::cCobranca := XmlNode( ::cXml, "cobr" )
::aInfAdic := XmlToHash( XmlNode( ::cXml, "infAdic" ), { "infAdFisco", "infCpl" } )
::aObsCont := XmlToHash( XmlNode( XmlNode( ::cXml, "infAdic" ), "obsCont" ), { "xCampo", "xTexto" } )
::aObsFisco := XmlToHash( XmlNode( XmlNode( ::cXml, "infAdic" ), "obsFisco" ), { "xCampo", "xTexto" } )
::aExporta := XmlToHash( XmlNode( XmlNode( ::cXml, "exporta" ), "infCpl" ), { "UFEmbarq", "xLocEmbarq" } )
::aCompra := XmlToHash( XmlNode( ::cXml, "compra" ), { "xNEmp", "xPed", "xCont" } )
::aInfProt := XmlToHash( iif( Empty( ::cXmlCancel ), ::cXml, ::cXmlCancel ), { "nProt", "dhRecbto", "digVal", "cStat", "xEvento", "dhRegEvento", "xMotivo" } )
::aEmit[ "xNome" ] := XmlToString( ::aEmit[ "xNome" ] )
::aDest[ "xNome" ] := XmlToString( ::aDest[ "xNome" ] )
::cTelefoneEmitente := ::FormataTelefone( ::aEmit[ "fone" ] )
::aDest[ "fone" ] := ::FormataTelefone( ::aDest[ "fone" ] )
IF ! Empty( ::aEntrega[ "xLgr" ] )
::aInfAdic[ "infCpl" ] += ";" + TrimXml( "LOCAL DE ENTREGA: " + ::aEntrega[ "xLgr" ] + " " + ::aEntrega[ "nro" ] + " " + ;
::aEntrega[ "xBairro" ] + " " + ::aEntrega[ "xMun" ] + " " + ::aEntrega[ "UF" ] )
ENDIF
IF ! Empty( ::aRetirada[ "xLgr" ] )
::aInfAdic[ "infCpl" ] += ";" + TrimXml( "LOCAL DE RETIRADA: " + ::aRetirada[ "xLgr" ] + " " + ::aRetirada[ "nro" ] + " " + ;
::aRetirada[ "xBairro" ] + " " + ::aRetirada[ "xMun" ] + " " + ::aRetirada[ "UF" ] )
ENDIF
::aInfAdic[ "infCpl" ] := StrTran( ::aInfAdic[ "infCpl" ], ";;", ";" )
::aInfAdic[ "infCpl" ] := StrTran( ::aInfAdic[ "infCpl" ], ";", Chr(13) + Chr(10) )
::aInfAdic[ "infAdFisco" ] := StrTran( ::aInfAdic[ "infAdFisco" ], ";", Chr(13) + Chr(10) )
RETURN .T.
METHOD GeraPDF( cFilePDF ) CLASS hbNFeDaNFe
::oPdf := HPDF_New()
IF ::oPdf == NIL
::cRetorno := "Falha da criação do objeto PDF"
RETURN .F.
ENDIF
HPDF_SetCompressionMode( ::oPdf, HPDF_COMP_ALL )
IF ::cFonteNFe == "Times"
::oPDFFontNormal := HPDF_GetFont( ::oPdf, "Times-Roman", "CP1252" )
::oPDFFontBold := HPDF_GetFont( ::oPdf, "Times-Bold", "CP1252" )
ELSE
::oPDFFontNormal := HPDF_GetFont( ::oPdf, "Courier", "CP1252" )
::oPDFFontBold := HPDF_GetFont( ::oPdf, "Courier-Bold", "CP1252" )
ENDIF
#ifdef __XHARBOUR__
IF ! File( "fontes\Code128bWinLarge.afm" ) .OR. ! File( "fontes\Code128bWinLarge.pfb" )
::cRetorno := "Arquivos fontes\Code128bWinLarge, nao encontrados...!"
RETURN .F.
ENDIF
::cFonteCode128 := HPDF_LoadType1FontFromFile( ::oPdf, "fontes\Code128bWinLarge.afm", "fontes\Code128bWinLarge.pfb" ) // Code 128
::cFonteCode128F := HPDF_GetFont( ::oPdf, ::cFonteCode128, "WinAnsiEncoding" )
#endif
::nFolha := 1
::NovaPagina()
// Atenção: destas duas linhas depende todo layout
HPDF_Page_SetFontAndSize( ::oPdfPage, ::oPDFFontNormal, LAYOUT_FONTSIZE )
::CalculaLayout()
::Canhoto()
::CabecalhoRetrato()
::Destinatario()
::Duplicatas()
::DadosImposto()
::DadosTransporte()
::CabecalhoProdutos()
::Produtos()
::TotalServico()
::DadosAdicionais()
::Desenvolvedor()
HPDF_SaveToFile( ::oPdf, cFilePDF )
HPDF_Free( ::oPdf )
RETURN .T.
METHOD NovaPagina() CLASS hbNFeDaNFe
LOCAL nRadiano, nAltura, nAngulo
::oPdfPage := HPDF_AddPage( ::oPdf )
HPDF_Page_SetSize( ::oPdfPage, HPDF_PAGE_SIZE_A4, HPDF_PAGE_PORTRAIT )
nAltura := HPDF_Page_GetHeight( ::oPdfPage )
::nLinhaPdf := nAltura - 8 // Margem Superior
nAngulo := 45 // A rotation of 45 degrees
nRadiano := nAngulo / 180 * 3.141592 // Calcurate the radian value
IF ::aIde[ "tpEmis" ] = "5" // Contingencia
HPDF_Page_SetFontAndSize( ::oPdfPage, ::oPDFFontBold, 30 )
HPDF_Page_BeginText( ::oPdfPage )
HPDF_Page_SetTextMatrix( ::oPdfPage, Cos( nRadiano ), Sin( nRadiano ), -Sin( nRadiano ), Cos( nRadiano ), 15, 160 )
HPDF_Page_SetRGBFill( ::oPdfPage, 0.75, 0.75, 0.75 )
HPDF_Page_ShowText( ::oPdfPage, "DANFE EM CONTINGÊNCIA. IMPRESSO EM" )
HPDF_Page_EndText( ::oPdfPage )
HPDF_Page_SetFontAndSize( ::oPdfPage, ::oPDFFontBold, 30 )
HPDF_Page_BeginText( ::oPdfPage )
HPDF_Page_SetTextMatrix( ::oPdfPage, Cos( nRadiano ), Sin( nRadiano ), -Sin( nRadiano ), Cos( nRadiano ), 15, 130 )
HPDF_Page_SetRGBFill( ::oPdfPage, 0.75, 0.75, 0.75 )
HPDF_Page_ShowText( ::oPdfPage, "DECORRÊNCIA DE PROBLEMAS TÉCNICOS." )
HPDF_Page_EndText( ::oPdfPage )
HPDF_Page_SetRGBFill( ::oPdfPage, 0, 0, 0 ) // reseta cor fontes
ENDIF
IF ::aIde[ "tpEmis" ] == "4" // DEPEC
HPDF_Page_SetFontAndSize( ::oPdfPage, ::oPDFFontBold, 30 )
HPDF_Page_BeginText( ::oPdfPage )
HPDF_Page_SetTextMatrix( ::oPdfPage, Cos( nRadiano ), Sin( nRadiano ), -Sin( nRadiano ), Cos( nRadiano ), 15, 190 )
HPDF_Page_SetRGBFill( ::oPdfPage, 0.75, 0.75, 0.75 )
HPDF_Page_ShowText( ::oPdfPage, "DANFE IMPRESSO EM CONTINGÊNCIA - DEPEC" )
HPDF_Page_EndText( ::oPdfPage )
HPDF_Page_SetFontAndSize( ::oPdfPage, ::oPDFFontBold, 30 )
HPDF_Page_BeginText( ::oPdfPage )
HPDF_Page_SetTextMatrix( ::oPdfPage, Cos( nRadiano ), Sin( nRadiano ), -Sin( nRadiano ), Cos( nRadiano ), 15, 160 )
HPDF_Page_SetRGBFill( ::oPdfPage, 0.75, 0.75, 0.75 )
HPDF_Page_ShowText( ::oPdfPage, "REGULARMENTE RECEBIDO PELA RECEITA" )
HPDF_Page_EndText( ::oPdfPage )
HPDF_Page_SetFontAndSize( ::oPdfPage, ::oPDFFontBold, 30 )
HPDF_Page_BeginText( ::oPdfPage )
HPDF_Page_SetTextMatrix( ::oPdfPage, Cos( nRadiano ), Sin( nRadiano ), -Sin( nRadiano ), Cos( nRadiano ), 15, 130 )
HPDF_Page_SetRGBFill( ::oPdfPage, 0.75, 0.75, 0.75 )
HPDF_Page_ShowText( ::oPdfPage, "FEDERAL DO BRASIL." )
HPDF_Page_EndText( ::oPdfPage )
HPDF_Page_SetRGBFill( ::oPdfPage, 0, 0, 0 ) // reseta cor fontes
ENDIF
IF ::aIde[ "tpAmb" ] == "2"
HPDF_Page_SetFontAndSize( ::oPdfPage, ::oPDFFontBold, 30 )
HPDF_Page_BeginText( ::oPdfPage )
HPDF_Page_SetTextMatrix( ::oPdfPage, Cos( nRadiano ), Sin( nRadiano ), -Sin( nRadiano ), Cos( nRadiano ), 15, 100 )
HPDF_Page_SetRGBFill( ::oPdfPage, 0.75, 0.75, 0.75 )
HPDF_Page_ShowText( ::oPdfPage, "AMBIENTE DE HOMOLOGAÇÃO - SEM VALOR FISCAL" )
HPDF_Page_EndText( ::oPdfPage )
HPDF_Page_SetRGBStroke( ::oPdfPage, 0.75, 0.75, 0.75 )
::DrawLine( 15, 95, 550, 630, 2.0 )
HPDF_Page_SetRGBStroke( ::oPdfPage, 0, 0, 0 ) // reseta cor linhas
HPDF_Page_SetRGBFill( ::oPdfPage, 0, 0, 0 ) // reseta cor fontes
ENDIF
IF ::aInfProt[ "cStat" ] $ "101,135,302" .OR. ! Empty( ::cXmlCancel )
HPDF_Page_SetFontAndSize( ::oPdfPage, ::oPDFFontBold, 30 )
HPDF_Page_BeginText( ::oPdfPage )
HPDF_Page_SetTextMatrix( ::oPdfPage, cos( nRadiano ), sin( nRadiano ), -sin( nRadiano ), cos( nRadiano ), 15, 100)
HPDF_Page_SetRGBFill(::oPdfPage, 1, 0, 0)
HPDF_Page_ShowText( ::oPdfPage, ::aInfProt[ "xEvento" ] + " " + /* ::aInfProt[ "dhRegEvento" ] ) + " " + */ ::aInfProt[ "xMotivo" ] )
HPDF_Page_EndText( ::oPdfPage)
HPDF_Page_SetRGBStroke( ::oPdfPage, 0.75, 0.75, 0.75 )
::DrawLine( 15, 95, 550, 630, 2.0 )
HPDF_Page_SetRGBStroke( ::oPdfPage, 0, 0, 0 ) // reseta cor linhas
HPDF_Page_SetRGBFill( ::oPdfPage, 0, 0, 0) // reseta cor fontes
ENDIF
RETURN NIL
METHOD SaltaPagina() CLASS hbNFeDaNFe
LOCAL nLinhaFinalProd, nAlturaQuadroProdutos
::nLinhaPdf -= 2
::TotalServico()
::DadosAdicionais()
::Desenvolvedor()
::NovaPagina()
::nFolha++
::nLinhaFolha := 1
::Canhoto()
::CabecalhoRetrato()
::CabecalhoProdutos()
nAlturaQuadroProdutos := ( ::ItensDaFolha() * LAYOUT_FONTSIZE ) + 2
nLinhaFinalProd := ::nLinhaPdf - nAlturaQuadroProdutos
::DesenhaBoxProdutos( nLinhaFinalProd, nAlturaQuadroProdutos )
RETURN NIL
METHOD Canhoto() CLASS hbNFeDaNFe
LOCAL cTexto
IF ::nFolha != 1
::nLinhaPdf -= 18
::nLinhaPdf -= 24
::nLinhaPdf -= 10
RETURN NIL
ENDIF
::DrawBox( 5, ::nLinhaPdf - 44, 585, 44, ::nLarguraBox )
cTexto := "RECEBEMOS DE " + ::aEmit[ "xNome" ] + " OS PRODUTOS CONSTANTES DA NOTA FISCAL INDICADA AO LADO,"
cTexto += " EMISSÃO " + SubStr( ::aIde[ "dhEmi" ], 9, 2 ) + "/" + SubStr( ::aIde[ "dhEmi" ], 6, 2 ) + "/" + SubStr( ::aIde[ "dhEmi" ], 1, 4 )
cTexto += " VALOR TOTAL R$ " + AllTrim( FormatNumber( Val( ::aICMSTotal[ "vNF" ] ), 15, 2 ) )
cTexto += " DESTINATÁRIO " + ::aDest[ "xNome" ]
::DrawTexto( 6, ::nLinhaPdf, 490, NIL, Upper( cTexto ), HPDF_TALIGN_LEFT, ::oPDFFontNormal, 6 )
::DrawBox( 505, ::nLinhaPdf - 44, 85, 44, ::nLarguraBox )
::DrawTexto( 506, ::nLinhaPdf - 8, 589, NIL, "NF-e", HPDF_TALIGN_CENTER, ::oPDFFontBold, 8 )
::DrawTexto( 506, ::nLinhaPdf - 20, 589, NIL, "Nº: " + Transform( StrZero( Val( ::aIde[ "nNF" ] ), 9 ), "@R 999.999.999" ), HPDF_TALIGN_CENTER, ::oPDFFontBold, 8 )
::DrawTexto( 506, ::nLinhaPdf - 32, 589, NIL, "SÉRIE " + ::aIde[ "serie" ], HPDF_TALIGN_CENTER, ::oPDFFontBold, 8 )
::nLinhaPdf -= 18
::DrawBox( 5, ::nLinhaPdf - 26, 130, 26, ::nLarguraBox )
::DrawTexto( 6, ::nLinhaPdf, 134, NIL, "DATA DE RECEBIMENTO", HPDF_TALIGN_LEFT, ::oPDFFontNormal, 6 )
::DrawBox( 135, ::nLinhaPdf - 26, 370, 26, ::nLarguraBox )
::DrawTexto( 136, ::nLinhaPdf, 470, NIL, "IDENTIFICAÇÃO E ASSINATURA DO RECEBEDOR", HPDF_TALIGN_LEFT, ::oPDFFontNormal, 6 )
::nLinhaPdf -= 24
// corte
IF ::cFonteNFe == "Times"
::DrawTexto( 5, ::nLinhaPdf, 590, NIL, Replicate( "- ", 125 ), HPDF_TALIGN_LEFT, ::oPDFFontNormal, 8 )
ELSE
::DrawTexto( 5, ::nLinhaPdf - 2, 590, NIL, Replicate( "- ", 81 ), HPDF_TALIGN_LEFT, ::oPDFFontNormal, 6 )
ENDIF
::nLinhaPdf -= 10
RETURN NIL
METHOD CabecalhoRetrato() CLASS hbNFeDaNFe
LOCAL cTexto
::DrawBox( 5, ::nLinhaPdf - 80, 585, 80, ::nLarguraBox )
// logo/dados empresa
::DrawBox( 5, ::nLinhaPdf - 80, 240, 80, ::nLarguraBox )
::DrawTexto( 6, ::nLinhaPdf, 244, NIL, "IDENTIFICAÇÃO DO EMITENTE", HPDF_TALIGN_LEFT, ::oPDFFontNormal, 6 )
IF ::cLogoFile == NIL .OR. Empty( ::cLogoFile )
::DrawTexto( 6, ::nLinhaPdf - 6, 244, NIL, Trim( MemoLine( ::aEmit[ "xNome" ], 30, 1 ) ), HPDF_TALIGN_CENTER, ::oPDFFontBold, 12 )
::DrawTexto( 6, ::nLinhaPdf - 18, 244, NIL, Trim( MemoLine( ::aEmit[ "xNome" ], 30, 2 ) ), HPDF_TALIGN_CENTER, ::oPDFFontBold, 12 )
::DrawTexto( 6, ::nLinhaPdf - 30, 244, NIL, ::aEmit[ "xLgr" ] + " " + ::aEmit[ "nro" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 6, ::nLinhaPdf - 38, 244, NIL, ::aEmit[ "xBairro" ] + " - " + Transform( ::aEmit[ "CEP" ], "@R 99999-999" ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 6, ::nLinhaPdf - 46, 244, NIL, ::aEmit[ "xMun" ] + " - " + ::aEmit[ "UF" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 6, ::nLinhaPdf - 54, 244, NIL, iif( Empty( ::cTelefoneEmitente ), "", "FONE: " + ::cTelefoneEmitente ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 6, ::nLinhaPdf - 62, 244, NIL, Trim( ::cSiteEmitente ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 6, ::nLinhaPdf - 70, 244, NIL, Trim( ::cEmailEmitente ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
ELSE
IF ::nLogoStyle == LAYOUT_LOGO_EXPANDIDO
::DrawJPEGImage( ::cLogoFile, 6, ::nLinhaPdf - ( 72 + 6 ), 238, 72 )
ELSEIF ::nLogoStyle == LAYOUT_LOGO_ESQUERDA
::DrawJPEGImage( ::cLogoFile, 6, ::nLinhaPdf - ( 60 + 6 ), 54, 48 )
HPDF_Page_SetFontAndSize( ::oPDFPage, ::oPDFFontBold, 12 )
cTexto := ::FormataMemo( ::aEmit[ "xNome" ], 180 )
::DrawTexto( 64, ::nLinhaPdf - 6, 244, NIL, MemoLine( cTexto, 1000, 1 ), HPDF_TALIGN_CENTER, ::oPDFFontBold, 12 )
::DrawTexto( 64, ::nLinhaPDF - 18, 244, NIL, MemoLine( cTexto, 1000, 2 ), HPDF_TALIGN_CENTER, ::oPDFFontBold, 12 )
::DrawTexto( 64, ::nLinhaPDF - 30, 244, NIL, MemoLine( cTexto, 1000, 3 ), HPDF_TALIGN_CENTER, ::oPDFFontBold, 12 )
::DrawTexto( 64, ::nLinhaPdf - 42, 244, NIL, ::aEmit[ "xLgr" ] + " " + ::aEmit[ "nro" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 64, ::nLinhaPdf - 50, 244, NIL, ::aEmit[ "xBairro" ] + " - " + Transform( ::aEmit[ "CEP" ], "@R 99999-999" ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 64, ::nLinhaPdf - 58, 244, NIL, ::aEmit[ "xMun" ] + " - " + ::aEmit[ "UF" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 64, ::nLinhaPdf - 66, 244, NIL, iif( Empty( ::cTelefoneEmitente ), "", "FONE: " + ::cTelefoneEmitente ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
//::DrawTexto( 50, ::nLinhaPdf - 74, 244, NIL, Trim( ::cSiteEmitente ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
//::DrawTexto( 50, ::nLinhaPdf - 82, 244, NIL, Trim( ::cEmailEmitente ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
ELSEIF ::nLogoStyle == LAYOUT_LOGO_DIREITA
::DrawJPEGImage( ::cLogoFile, 182, ::nLinhaPdf - ( 72 + 6 ), 62, 72 )
::DrawTexto( 6, ::nLinhaPdf - 6, 180, NIL, Trim( MemoLine( ::aEmit[ "xNome" ], 30, 1 ) ), HPDF_TALIGN_CENTER, ::oPDFFontBold, 12 )
::DrawTexto( 6, ::nLinhaPdf - 18, 180, NIL, Trim( MemoLine( ::aEmit[ "xNome" ], 30, 2 ) ), HPDF_TALIGN_CENTER, ::oPDFFontBold, 12 )
::DrawTexto( 6, ::nLinhaPdf - 30, 180, NIL, ::aEmit[ "xLgr" ] + " " + ::aEmit[ "nro" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 6, ::nLinhaPdf - 38, 180, NIL, ::aEmit[ "xBairro" ] + " - " + Transform( ::aEmit[ "CEP" ], "@R 99999-999" ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 6, ::nLinhaPdf - 46, 180, NIL, ::aEmit[ "xMun" ] + " - " + ::aEmit[ "UF" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 6, ::nLinhaPdf - 54, 180, NIL, iif( Empty( ::cTelefoneEmitente ), "", "FONE: " + ::cTelefoneEmitente ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 6, ::nLinhaPdf - 62, 180, NIL, Trim( ::cSiteEmitente ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 6, ::nLinhaPdf - 70, 180, NIL, Trim( ::cEmailEmitente ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
ENDIF
ENDIF
::DrawBox( 245, ::nLinhaPdf - 80, 125, 80, ::nLarguraBox )
::DrawTexto( 246, ::nLinhaPdf - 4, 369, NIL, "DANFE", HPDF_TALIGN_CENTER, ::oPDFFontBold, 12 )
::DrawTexto( 246, ::nLinhaPdf - 16, 369, NIL, "Documento Auxiliar da", HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 246, ::nLinhaPdf - 24, 369, NIL, "Nota Fiscal Eletrônica", HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 256, ::nLinhaPdf - 36, 349, NIL, "0 - ENTRADA", HPDF_TALIGN_LEFT, ::oPDFFontNormal, 8 )
::DrawTexto( 256, ::nLinhaPdf - 44, 349, NIL, "1 - SAÍDA", HPDF_TALIGN_LEFT, ::oPDFFontNormal, 8 )
// preenchimento do tipo de nf
::DrawBox( 340, ::nLinhaPdf - 52, 20, 16, ::nLarguraBox )
::DrawTexto( 341, ::nLinhaPdf - 40, 359, NIL, ::aIde[ "tpNF" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawTexto( 246, ::nLinhaPdf - 56, 369, NIL, "Nº: " + Transform( StrZero( Val( ::aIde[ "nNF" ] ), 9 ), "@R 999.999.999" ), HPDF_TALIGN_CENTER, ::oPDFFontBold, 10 )
::DrawTexto( 246, ::nLinhaPdf - 66, 369, NIL, "SÉRIE: " + ::aIde[ "serie" ] + " - FOLHA " + AllTrim( Str( ::nFolha ) ) + "/" + AllTrim( Str( ::nLayoutTotalFolhas ) ), HPDF_TALIGN_CENTER, ::oPDFFontBold, 9 )
// codigo barras
::DrawBox( 370, ::nLinhaPdf - 35, 220, 35, ::nLarguraBox )
#ifdef __XHARBOUR__
// Modificado por Anderson Camilo em 04/04/2012
// oCode128 := HPDF_LoadType1FontFromFile(::oPdf, 'fontes\Code128bWin.afm', 'fontes\Code128bWin.pfb')
// oCode128F := HPDF_GetFont( ::oPdf, oCode128, "FontSpecific" )
// ::DrawTexto( 380, ::nLinhaPdf - 8, 585, NIL, "{"+::cChave+"~", HPDF_TALIGN_CENTER, NIL, oCode128F, 8 )
// ::DrawTexto( 380, ::nLinhaPdf - 18.2, 585, NIL, "{"+::cChave+"~", HPDF_TALIGN_CENTER, NIL, oCode128F, 8 )
::DrawTexto( 380, ::nLinhaPdf - 2, 585, NIL, ::xHarbourCode128c( ::cChave ), HPDF_TALIGN_CENTER, NIL, ::cFonteCode128F, 15 )
#else
::DrawBarcode128( ::cChave, 385, ::nLinhaPdf - 32, 0.7, 30 )
#endif
// chave de acesso
::DrawBox( 370, ::nLinhaPdf - 55, 220, 55, ::nLarguraBox )
::DrawTexto( 371, ::nLinhaPdf - 36, 589, NIL, "CHAVE DE ACESSO", HPDF_TALIGN_LEFT, ::oPDFFontNormal, 6 )
IF ::cFonteNFe == "Times"
::DrawTexto( 371, ::nLinhaPdf - 44, 589, NIL, Transform( ::cChave, "@R 9999 9999 9999 9999 9999 9999 9999 9999 9999 9999 9999" ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
ELSE
::DrawTexto( 371, ::nLinhaPdf - 44, 589, NIL, Transform( ::cChave, "@R 9999 9999 9999 9999 9999 9999 9999 9999 9999 9999 9999" ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 6 )
ENDIF
// mensagem sistema sefaz
::DrawBox( 370, ::nLinhaPdf - 80, 220, 80, ::nLarguraBox )
IF Empty( ::aInfProt[ "nProt" ] )
::DrawTexto( 371, ::nLinhaPdf - 55, 589, NIL, "N F E A I N D A N Ã O F O I", HPDF_TALIGN_CENTER, ::oPDFFontBold, 8 )
::DrawTexto( 371, ::nLinhaPdf - 63, 589, NIL, "A U T O R I Z A D A P E L A", HPDF_TALIGN_CENTER, ::oPDFFontBold, 8 )
::DrawTexto( 371, ::nLinhaPdf - 71, 589, NIL, "S E F A Z (SEM VALIDADE FISCAL)", HPDF_TALIGN_CENTER, ::oPDFFontBold, 8 )
ELSE
::DrawTexto( 371, ::nLinhaPdf - 55, 589, NIL, "Consulta de autenticidade no portal nacional", HPDF_TALIGN_CENTER, ::oPDFFontBold, 8 )
::DrawTexto( 371, ::nLinhaPdf - 63, 589, NIL, "da NF-e www.nfe.fazenda.gov.br/portal ou", HPDF_TALIGN_CENTER, ::oPDFFontBold, 8 )
::DrawTexto( 371, ::nLinhaPdf - 71, 589, NIL, "no site da Sefaz Autorizadora", HPDF_TALIGN_CENTER, ::oPDFFontBold, 8 )
ENDIF
::nLinhaPdf -= 80
::DrawBoxTituloTexto( 5, ::nLinhaPdf, 365, 16, "NATUREZA DA OPERAÇÃO", ::aIde[ "natOp" ], HPDF_TALIGN_LEFT, ::oPDFFontNormal, 10 )
// PROTOCOLO
::DrawBox( 370, ::nLinhaPdf - 16, 220, 16, ::nLarguraBox )
// ::DrawTexto(371, ::nLinhaPdf - 1, 589, NIL, "PROTOCOLO DE AUTORIZAÇÃO DE USO", HPDF_TALIGN_LEFT, ::oPDFFontNormal, 5 )
IF ! Empty( ::aInfProt[ "nProt" ] )
IF ::aInfProt[ "cStat" ] == '100'
::DrawTexto( 371, ::nLinhaPdf - 1, 589, NIL, "PROTOCOLO DE AUTORIZAÇÃO DE USO", HPDF_TALIGN_LEFT, ::oPDFFontNormal, 5 )
ELSEIF ::aInfProt[ "cStat" ] == '101' .OR. ::aInfProt[ "cStat" ] == '135'
::DrawTexto( 371, ::nLinhaPdf - 1, 589, NIL, "PROTOCOLO DE HOMOLOGAÇÃO DO CANCELAMENTO", HPDF_TALIGN_LEFT, ::oPDFFontNormal, 5 )
ENDIF
IF ::cFonteNFe == "Times"
::DrawTexto( 371, ::nLinhaPdf - 6, 589, NIL, ::aInfProt[ "nProt" ] + " " + SubStr( SubStr( ::aInfProt[ "dhRecbto" ], 1, 10 ), 9, 2 ) + "/" + SubStr( SubStr( ::aInfProt[ "dhRecbto" ], 1, 10 ), 6, 2 ) + "/" + SubStr( SubStr( ::aInfProt[ "dhRecbto" ], 1, 10 ), 1, 4 ) + " " + SubStr( ::aInfProt[ "dhRecbto" ], 12, 8 ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 9 )
ELSE
::DrawTexto( 371, ::nLinhaPdf - 6, 589, NIL, ::aInfProt[ "nProt" ] + " " + SubStr( SubStr( ::aInfProt[ "dhRecbto" ], 1, 10 ), 9, 2 ) + "/" + SubStr( SubStr( ::aInfProt[ "dhRecbto" ], 1, 10 ), 6, 2 ) + "/" + SubStr( SubStr( ::aInfProt[ "dhRecbto" ], 1, 10 ), 1, 4 ) + " " + SubStr( ::aInfProt[ "dhRecbto" ], 12, 8 ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 9 )
ENDIF
ENDIF
::nLinhaPdf -= 16
::DrawBoxTituloTexto( 5, ::nLinhaPdf, 240, 16, "INSCRIÇÃO ESTADUAL", ::aEmit[ "IE" ], HPDF_TALIGN_LEFT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 245, ::nLinhaPdf, 225, 16, "INSCRIÇÃO ESTADUAL DO SUBS. TRIBUTÁRIO", "", HPDF_TALIGN_LEFT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 470, ::nLinhaPdf, 120, 16, "C.N.P.J.", Transform( ::aEmit[ "CNPJ" ], "@R 99.999.999/9999-99" ), HPDF_TALIGN_LEFT, ::oPDFFontNormal, 10 )
::nLinhaPdf -= 17
RETURN NIL
METHOD Destinatario() CLASS hbNFeDaNFe
::DrawTexto( 5, ::nLinhaPdf, 589, NIL, "DESTINATÁRIO/REMETENTE", HPDF_TALIGN_LEFT, ::oPDFFontBold, 5 )
::nLinhaPdf -= 6
::DrawBoxTituloTexto( 5, ::nLinhaPdf, 415, 16, "NOME / RAZÃO SOCIAL", ::aDest[ "xNome" ], HPDF_TALIGN_LEFT, ::oPDFFontNormal, 10 )
IF ! Empty( ::aDest[ "CNPJ" ] )
::DrawBoxTituloTexto( 420, ::nLinhaPdf, 100, 16, "CNPJ/CPF", Transform( ::aDest[ "CNPJ" ], "@R 99.999.999/9999-99" ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 9 )
ELSEIF ! Empty( ::aDest[ "CPF" ] )
::DrawBoxTituloTexto( 420, ::nLinhaPdf, 100, 16, "CNPJ/CPF", Transform( ::aDest[ "CPF" ], "@R 999.999.999-99" ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
ENDIF
::DrawBoxTituloTexto( 520, ::nLinhaPdf, 70, 16, "DATA DE EMISSÃO", ;
SubStr( ::aIde[ "dhEmi" ], 9, 2 ) + "/" + SubStr( ::aIde[ "dhEmi" ], 6, 2 ) + "/" + SubStr( ::aIde[ "dhEmi" ], 1, 4 ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
::nLinhaPdf -= 16
::DrawBoxTituloTexto( 5, ::nLinhaPdf, 265, 16, "ENDEREÇO", ::aDest[ "xLgr" ] + " " + ::aDest[ "nro" ], HPDF_TALIGN_LEFT, ::oPDFFontNormal, 8 )
::DrawBoxTituloTexto( 270, ::nLinhaPdf, 190, 16, "BAIRRO", ::aDest[ "xBairro" ], HPDF_TALIGN_LEFT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 460, ::nLinhaPdf, 60, 16, "C.E.P.", Transform( ::aDest[ "CEP" ], "@R 99999-999" ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 520, ::nLinhaPdf, 70, 16, "DATA SAIDA/ENTRADA", ;
SubStr( ::aIde[ "dhSaiEnt" ], 9, 2 ) + "/" + SubStr( ::aIde[ "dhSaiEnt" ], 6, 2 ) + "/" + SubStr( ::aIde[ "dhSaiEnt" ], 1, 4 ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
::nLinhaPdf -= 16
::DrawBoxTituloTexto( 5, ::nLinhaPdf, 245, 16, "MUNICIPIO", ::aDest[ "xMun" ], HPDF_TALIGN_LEFT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 250, ::nLinhaPdf, 30, 16, "ESTADO", ::aDest[ "UF" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 280, ::nLinhaPdf, 150, 16, "FONE/FAX", ::FormataTelefone( ::aDest[ "fone" ] ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 430, ::nLinhaPdf, 90, 16, "INSCRIÇÃO ESTADUAL", ::aDest[ "IE" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 520, ::nLinhaPdf, 70, 16, "HORA DE SAIDA", SubStr( ::aIde[ "dhSaiEnt" ], 12, 8 ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
::nLinhaPdf -= 17
RETURN NIL
METHOD Duplicatas() CLASS hbNFeDaNFe
LOCAL nICob, nItensCob, nLinhaFinalCob, nTamanhoCob
LOCAL nTamForm, aDups, nColuna, cDup, cNumero, cVencimento, cValor, nCont
IF ::nFolha != 1
RETURN NIL
ENDIF
::DrawTexto( 5, ::nLinhaPdf, 589, NIL, "FATURA/DUPLICATAS", HPDF_TALIGN_LEFT, ::oPDFFontBold, 5 )
::nLinhaPdf -= 6
IF Empty( ::cCobranca )
::DrawBox( 5, ::nLinhaPdf - 12, 585, 12, ::nLarguraBox )
IF ::aIde[ "indPag" ] == "0"
::DrawTexto( 6, ::nLinhaPdf - 1, 589, NIL, "PAGAMENTO À VISTA", HPDF_TALIGN_LEFT, ::oPDFFontNormal, 10 )
ELSEIF ::aIde[ "indPag" ] == "1"
::DrawTexto( 6, ::nLinhaPdf - 1, 589, NIL, "PAGAMENTO À PRAZO", HPDF_TALIGN_LEFT, ::oPDFFontNormal, 10 )
ELSE
::DrawTexto( 6, ::nLinhaPdf - 1, 589, NIL, "OUTROS", HPDF_TALIGN_LEFT, ::oPDFFontNormal, 10 )
ENDIF
::nLinhaPdf -= 13
RETURN NIL
ENDIF
nICob := Len( MultipleNodeToArray( ::cCobranca, "dup" ) )
IF nICob < 1
nICob := 1
ENDIF
nItensCob := Round( nIcob / 3 + 0.99, 0 )
nLinhaFinalCob := ::nLinhaPdf - ( nItensCob * 8 ) - 2
nTamanhoCob := ( nItensCob * 8 ) + 2
nTamForm := 585
FOR nCont = 0 TO 2
::DrawBox( 5 + ( ( ( nTamForm ) / 3 ) * nCont ), nLinhaFinalCob, ( ( nTamForm ) / 3 ), nTamanhoCob, ::nLarguraBox )
NEXT
nTamForm := 585
aDups := MultipleNodeToArray( ::cCobranca, "dup" )
nColuna := 1
FOR EACH cDup IN aDups
cNumero := XmlNode( cDup, "nDup" )
IF Empty( cNumero )
EXIT
ENDIF
cVencimento := XmlNode( cDup, "dVenc" )
cVencimento := SubStr( cVencimento, 9, 2 ) + "/" + SubStr( cVencimento, 6, 2 ) + "/" + SubStr( cVencimento, 1, 4 )
cValor := AllTrim( FormatNumber( Val( XmlNode( cDup, "vDup" ) ), 13, 2 ) )
::DrawTexto( 6 + ( ( ( nTamForm ) / 3 ) * ( nColuna - 1 ) ), ::nLinhaPdf - 1, 61 + ( ( ( nTamForm ) / 3 ) * ( nColuna - 1 ) ), NIL, cNumero, HPDF_TALIGN_LEFT, ::oPDFFontNormal, 8 )
::DrawTexto( 63 + ( ( ( nTamForm ) / 3 ) * ( nColuna - 1 ) ), ::nLinhaPdf - 1, 118 + ( ( ( nTamForm ) / 3 ) * ( nColuna - 1 ) ), NIL, cVencimento, HPDF_TALIGN_LEFT, ::oPDFFontNormal, 8 )
::DrawTexto( 120 + ( ( ( nTamForm ) / 3 ) * ( nColuna - 1 ) ), ::nLinhaPdf - 1, 195 + ( ( ( nTamForm ) / 3 ) * ( nColuna - 1 ) ), NIL, cValor, HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 8 )
nColuna++
IF nColuna > 3
::nLinhaPdf -= 8
nColuna := 1
ENDIF
NEXT
::nLinhaPdf -= 12
RETURN NIL
METHOD DadosImposto() CLASS hbNFeDaNFe
IF ::nFolha == 1
::DrawTexto( 5, ::nLinhaPdf, 589, NIL, "CÁLCULO DO IMPOSTO", HPDF_TALIGN_LEFT, ::oPDFFontBold, 5 )
::nLinhaPdf -= 6
::DrawBoxTituloTexto( 5, ::nLinhaPdf, 110, 16, "BASE DE CÁLCULO DO ICMS", AllTrim( FormatNumber( Val( ::aICMSTotal[ "vBC" ] ), 15, 2 ) ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 115, ::nLinhaPdf, 100, 16, "VALOR DO ICMS", AllTrim( FormatNumber( Val( ::aICMSTotal[ "vICMS" ] ), 15, 2 ) ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 215, ::nLinhaPdf, 130, 16, "BASE DE CÁLCULO DO ICMS SUBS. TRIB.", AllTrim( FormatNumber( Val( ::aICMSTotal[ "vBCST" ] ), 15, 2 ) ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 345, ::nLinhaPdf, 100, 16, "VALOR DO ICMS SUBST.", AllTrim( FormatNumber( Val( ::aICMSTotal[ "vST" ] ), 15, 2 ) ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 445, ::nLinhaPdf, 145, 16, "VALOR TOTAL DOS PRODUTOS", AllTrim( FormatNumber( Val( ::aICMSTotal[ "vProd" ] ), 15, 2 ) ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::nLinhaPdf -= 16
::DrawBoxTituloTexto( 5, ::nLinhaPdf, 88, 16, "VALOR DO FRETE", AllTrim( FormatNumber( Val( ::aICMSTotal[ "vFrete" ] ), 15, 2 ) ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 93, ::nLinhaPdf, 88, 16, "VALOR DO SEGURO", AllTrim( FormatNumber( Val( ::aICMSTotal[ "vSeg" ] ), 15, 2 ) ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 181, ::nLinhaPdf, 88, 16, "DESCONTO", AllTrim( FormatNumber( Val( ::aICMSTotal[ "vDesc" ] ), 15, 2 ) ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 269, ::nLinhaPdf, 88, 16, "OUTRAS DESP. ACESSÓRIAS", AllTrim( FormatNumber( Val( ::aICMSTotal[ "vOutro" ] ), 15, 2 ) ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 357, ::nLinhaPdf, 88, 16, "VALOR DO IPI", AllTrim( FormatNumber( Val( ::aICMSTotal[ "vIPI" ] ), 15, 2 ) ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 445, ::nLinhaPdf, 145, 16, "VALOR TOTAL DA NOTA FISCAL", AllTrim( FormatNumber( Val( ::aICMSTotal[ "vNF" ] ), 15, 2 ) ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::nLinhaPdf -= 17
ENDIF
RETURN NIL
METHOD DadosTransporte() CLASS hbNFeDaNFe
IF ::nFolha == 1
::DrawTexto( 5, ::nLinhaPdf, 589, NIL, "TRANSPORTADOR / VOLUMES TRANSPORTADOS", HPDF_TALIGN_LEFT, ::oPDFFontBold, 5 )
::nLinhaPdf -= 6
::DrawBoxTituloTexto( 5, ::nLinhaPdf, 215, 16, "NOME/RAZÃO SOCIAL", ::aTransp[ "xNome" ], HPDF_TALIGN_LEFT, ::oPDFFontNormal, 8 )
IF ::aTransp[ "modFrete" ] == "0"
::DrawBoxTituloTexto( 220, ::nLinhaPdf, 90, 16, "FRETE POR CONTA", "0-EMITENTE", HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
ELSEIF ::aTransp[ "modFrete" ] == "1"
::DrawBoxTituloTexto( 220, ::nLinhaPdf, 90, 16, "FRETE POR CONTA", "1-DESTINATARIO", HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
ELSEIF ::aTransp[ "modFrete" ] == "2"
::DrawBoxTituloTexto( 220, ::nLinhaPdf, 90, 16, "FRETE POR CONTA", "2-TERCEIROS", HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
ELSEIF ::aTransp[ "modFrete" ] == "9"
::DrawBoxTituloTexto( 220, ::nLinhaPdf, 90, 16, "FRETE POR CONTA", "9-SEM FRETE", HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
ELSE
::DrawBoxTituloTexto( 220, ::nLinhaPdf, 90, 16, "FRETE POR CONTA", "", HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
ENDIF
::DrawBoxTituloTexto( 310, ::nLinhaPdf, 110, 16, "CÓDIGO ANTT", ::aVeicTransp[ "RNTC" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
::DrawBoxTituloTexto( 420, ::nLinhaPdf, 60, 16, "PLACA DO VEÍCULO", ::aVeicTransp[ "placa" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 480, ::nLinhaPdf, 20, 16, "UF", ::aVeicTransp[ "UF" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
IF ! Empty( ::aTransp[ "CNPJ" ] )
::DrawBoxTituloTexto( 500, ::nLinhaPdf, 90, 16, "CNPJ / CPF", Transform( ::aTransp[ "CNPJ" ], "@R 99.999.999/9999-99" ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 8 )
ELSEIF ! Empty( ::aTransp[ "CPF" ] )
::DrawBoxTituloTexto( 500, ::nLinhaPdf, 90, 16, "CNPJ / CPF", Transform( ::aTransp[ "CPF" ], "@R 999.999.999-99" ), HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
ELSE
::DrawBoxTituloTexto( 500, ::nLinhaPdf, 90, 16, "CNPJ / CPF", "", HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
ENDIF
::nLinhaPdf -= 16
::DrawBoxTituloTexto( 5, ::nLinhaPdf, 265, 16, "ENDEREÇO", ::aTransp[ "xEnder" ], HPDF_TALIGN_LEFT, ::oPDFFontNormal, 8 )
::DrawBoxTituloTexto( 270, ::nLinhaPdf, 210, 16, "MUNICÍPIO", ::aTransp[ "xMun" ], HPDF_TALIGN_LEFT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 480, ::nLinhaPdf, 20, 16, "UF", ::aTransp[ "UF" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 500, ::nLinhaPdf, 90, 16, "INSCRIÇÃO ESTADUAL", ::aTransp[ "IE" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
::nLinhaPdf -= 16
::DrawBoxTituloTexto( 5, ::nLinhaPdf, 95, 16, "QUANTIDADE", LTrim( FormatNumber( Val( ::aTransp[ "qVol" ] ), 15, 0 ) ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 8 )
::DrawBoxTituloTexto( 100, ::nLinhaPdf, 100, 16, "ESPÉCIE", ::aTransp[ "esp" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 200, ::nLinhaPdf, 100, 16, "MARCA", ::aTransp[ "marca" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 300, ::nLinhaPdf, 100, 16, "NUMERAÇÃO", ::aTransp[ "nVol" ], HPDF_TALIGN_CENTER, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 400, ::nLinhaPdf, 100, 16, "PESO BRUTO", LTrim( FormatNumber( Val( ::aTransp[ "pesoB" ] ), 15, 3 ) ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 500, ::nLinhaPdf, 90, 16, "PESO LÍQUIDO", LTrim( FormatNumber( Val( ::aTransp[ "pesoL" ] ), 15, 3 ) ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::nLinhaPdf -= 17
ENDIF
RETURN NIL
METHOD CabecalhoProdutos() CLASS hbNFeDaNFe
LOCAL oElement
::DrawTexto( 5, ::nLinhaPdf, 589, NIL, "DADOS DOS PRODUTOS / SERVIÇOS", HPDF_TALIGN_LEFT, ::oPDFFontBold, 5 )
::nLinhaPdf -= LAYOUT_FONTSIZE
FOR EACH oELement IN ::aLayout
::DrawBoxProduto( oElement:__EnumIndex, ::nLinhaPdf - ( LAYOUT_FONTSIZE * 2 + 1 ), ( LAYOUT_FONTSIZE * 2 + 1 ), ::nLarguraBox )
::DrawTextoProduto( oElement:__EnumIndex, ::nLinhaPdf - 1, LAYOUT_TITULO1, HPDF_TALIGN_CENTER )
::DrawTextoProduto( oElement:__EnumIndex, ::nLinhaPdf - LAYOUT_FONTSIZE, LAYOUT_TITULO2, HPDF_TALIGN_CENTER )
NEXT
::nLinhaPdf -= LAYOUT_FONTSIZE * 2 + 1
RETURN NIL
METHOD DesenhaBoxProdutos( nLinhaFinalProd, nAlturaQuadroProdutos ) CLASS hbNFeDaNFe
LOCAL oElement
FOR EACH oElement IN ::aLayout
::DrawBoxProduto( oElement:__EnumIndex, nLinhaFinalProd, nAlturaQuadroProdutos, ::nLarguraBox )
NEXT
::nLinhaPdf -= 1
RETURN NIL
METHOD Produtos() CLASS hbNFeDaNFe
LOCAL nLinhaFinalProd, nAlturaQuadroProdutos, nItem, nNumLinha, nCont
nLinhaFinalProd := ::nLinhaPdf - ( ::ItensDaFolha() * LAYOUT_FONTSIZE ) - 2
nAlturaQuadroProdutos := ( ::ItensDaFolha() * LAYOUT_FONTSIZE ) + 2
::desenhaBoxProdutos( nLinhaFinalProd, nAlturaQuadroProdutos )
nItem := 1
::nLinhaFolha := 1
DO WHILE .T.
IF ! ::ProcessaItens( ::cXml, nItem )
EXIT
ENDIF
IF ::nLinhaFolha > ::ItensDaFolha()
::saltaPagina()
ENDIF
::aItem[ "xProd" ] := ::FormataMemo( ::aItem[ "xProd" ], ::aLayout[ LAYOUT_DESCRICAO, LAYOUT_LARGURAPDF ] - 2 )
::aItem[ "infAdProd" ] := ::FormataMemo( ::aItem[ "infAdProd" ], ::aLayout[ LAYOUT_DESCRICAO, LAYOUT_LARGURAPDF ] - 2 )
::DrawTextoProduto( LAYOUT_CODIGO, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_CENTER )
::DrawTextoProduto( LAYOUT_DESCRICAO, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_LEFT )
::DrawTextoProduto( LAYOUT_NCM, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_CENTER )
::DrawTextoProduto( LAYOUT_EAN, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_CENTER )
::DrawTextoProduto( LAYOUT_CST, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_CENTER )
::DrawTextoProduto( LAYOUT_CFOP, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_CENTER )
::DrawTextoProduto( LAYOUT_UNIDADE, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_CENTER )
::DrawTextoProduto( LAYOUT_QTD, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_RIGHT )
::DrawTextoProduto( LAYOUT_UNITARIO, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_RIGHT )
::DrawTextoProduto( LAYOUT_TOTAL, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_RIGHT )
::DrawTextoProduto( LAYOUT_DESCONTO, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_RIGHT )
::DrawTextoProduto( LAYOUT_ICMBAS, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_RIGHT )
::DrawTextoProduto( LAYOUT_ICMVAL, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_RIGHT )
::DrawTextoProduto( LAYOUT_SUBBAS, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_RIGHT )
::DrawTextoProduto( LAYOUT_SUBVAL, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_RIGHT )
::DrawTextoProduto( LAYOUT_IPIVAL, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_RIGHT )
::DrawTextoProduto( LAYOUT_ICMALI, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_RIGHT )
::DrawTextoProduto( LAYOUT_IPIALI, ::nLinhaPdf, LAYOUT_CONTEUDO, HPDF_TALIGN_RIGHT )
::nLinhaPdf -= LAYOUT_FONTSIZE
nItem++
::nLinhaFolha++
FOR nNumLinha = 2 TO MLCount( ::aItem[ "xProd" ], 1000 )
IF ::nLinhaFolha > ::ItensDaFolha()
::saltaPagina()
ENDIF
::DrawTextoProduto( LAYOUT_DESCRICAO, ::nLinhaPdf, MemoLine( ::aItem[ "xProd" ], 1000, nNumLinha ), HPDF_TALIGN_LEFT )
::nLinhaFolha++
::nLinhaPdf -= LAYOUT_FONTSIZE
NEXT
FOR nNumLinha = 1 TO MLCount( ::aItem[ "infAdProd" ], 1000 )
IF ::nLinhaFolha > ::ItensDaFolha()
::saltaPagina()
ENDIF
::DrawTextoProduto( LAYOUT_DESCRICAO, ::nLinhaPdf, MemoLine( ::aItem[ "infAdProd" ], 1000, nNumLinha ), HPDF_TALIGN_LEFT )
::nLinhaFolha++
::nLinhaPdf -= LAYOUT_FONTSIZE
NEXT
IF ::lLayoutEspacoDuplo
::nLinhaPdf -= LAYOUT_FONTSIZE
::nLinhaFolha++
ENDIF
IF ::nLinhaFolha <= ::ItensDaFolha() .AND. ! ::lLayoutEspacoDuplo
::DrawLine( 5, ::nLinhaPdf - 0.5, 590, ::nLinhaPdf - 0.5, ::nLarguraBox )
ENDIF
ENDDO
IF MLCount( ::aInfAdic[ "infCpl" ], 1000 ) > Int( 13 * 6 / LAYOUT_FONTSIZE )
::nLinhaFolha++
::nLinhaPdf -= LAYOUT_FONTSIZE
::DrawTexto( 5, ::nLinhaPdf, 589, NIL, "*CONTINUACAO INFORMAÇÕES COMPLEMENTARES*", HPDF_TALIGN_LEFT, ::oPDFFontNormal, LAYOUT_FONTSIZE )
::nLinhaFolha++
::nLinhaPdf -= LAYOUT_FONTSIZE
FOR nCont = Int( 13 * 6 / LAYOUT_FONTSIZE ) + 1 TO MLCount( ::aInfAdic[ "infCpl" ], 1000 )
IF ::nLinhaFolha > ::ItensDaFolha()
::SaltaPagina()
::DrawTexto( 5, ::nLinhaPdf, 589, NIL, "*CONTINUACAO INFORMAÇÕES COMPLEMENTARES*", HPDF_TALIGN_LEFT, ::oPDFFontNormal, LAYOUT_FONTSIZE )
::nLinhaFolha++
::nLinhaPdf -= LAYOUT_FONTSIZE
ENDIF
::DrawTexto( 5, ::nLinhaPdf, 589, NIL, MemoLine( ::aInfAdic[ "infCpl" ], 1000, nCont ), HPDF_TALIGN_LEFT, ::oPDFFontNormal, LAYOUT_FONTSIZE )
::nLinhaFolha++
::nLinhaPdf -= LAYOUT_FONTSIZE
NEXT
ENDIF
::nLinhaPdf -= ( ( ::ItensDaFolha() - ::nLinhaFolha + 1 ) * LAYOUT_FONTSIZE )
::nLinhaPdf -= 2
RETURN NIL
METHOD TotalServico() CLASS hbNFeDaNFe
IF ::nFolha == 1
IF Val( ::aISSTotal[ "vServ" ] ) > 0
::DrawTexto( 5, ::nLinhaPdf, 589, NIL, "CALCULO DO ISSQN", HPDF_TALIGN_LEFT, ::oPDFFontBold, 5 )
::nLinhaPdf -= 6
::DrawBoxTituloTexto( 5, ::nLinhaPdf, 150, 16, "INSCRIÇÃO MUNICIPAL", ::aEmit[ "IM" ], HPDF_TALIGN_LEFT, ::oPDFFontNormal, 8 )
::DrawBoxTituloTexto( 155, ::nLinhaPdf, 145, 16, "VALOR TOTAL DOS SERVIÇOS", FormatNumber( Val( ::aISSTotal[ "vServ" ] ), 15 ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 300, ::nLinhaPdf, 145, 16, "BASE DE CÁLCULO DO ISSQN", FormatNumber( Val( ::aISSTotal[ "vBC" ] ), 15 ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::DrawBoxTituloTexto( 445, ::nLinhaPdf, 145, 16, "VALOR DO ISSQN", FormatNumber( Val( ::aISSTotal[ "vISS" ] ), 15 ), HPDF_TALIGN_RIGHT, ::oPDFFontNormal, 10 )
::nLinhaPdf -= 17
ENDIF
ENDIF
RETURN NIL
METHOD DadosAdicionais() CLASS hbNFeDaNFe
LOCAL cMemo, nCont
// inf adic.fisco
IF ::nFolha == 1
cMemo := ::aInfAdic[ "infCpl" ]
::DrawTexto( 5, ::nLinhaPdf, 589, NIL, "DADOS ADICIONAIS", HPDF_TALIGN_LEFT, ::oPDFFontBold, 5 )
::nLinhaPdf -= 6
::DrawBox( 5, ::nLinhaPdf - 92, 395, 92, ::nLarguraBox )
::DrawTexto( 6, ::nLinhaPdf - 1, 399, NIL, "INFORMAÇÕES COMPLEMENTARES", HPDF_TALIGN_LEFT, ::oPDFFontNormal, LAYOUT_FONTSIZE )
::DrawBox( 400, ::nLinhaPdf - 92, 190, 92, ::nLarguraBox )
::DrawTexto( 401, ::nLinhaPdf - 1, 589, NIL, "RESERVADO AO FISCO", HPDF_TALIGN_LEFT, ::oPDFFontNormal, 6 )
::nLinhaPdf -= 7 //
::nLinhaPdf -= 4 // ESPAÇO
FOR nCont = 1 TO Min( MLCount( cMemo, 1000 ), Int( 13 * 6 / LAYOUT_FONTSIZE ) )
::DrawTexto( 6, ::nLinhaPDF - ( ( nCont - 1 ) * LAYOUT_FONTSIZE ), 399, NIL, Trim( MemoLine( cMemo, 1000, nCont ) ), HPDF_TALIGN_LEFT, ::oPDFFontNormal, LAYOUT_FONTSIZE )
NEXT
cMemo := ::FormataMemo( ::aInfAdic[ "infAdFisco" ], 186 )
FOR nCont = 1 TO Min( MLCount( cMemo, 1000 ), Int( 13 * 6 / LAYOUT_FONTSIZE ) )
::DrawTexto( 401, ::nLinhaPDF - ( ( nCont - 1 ) * LAYOUT_FONTSIZE ), 588, NIL, Trim( MemoLine( cMemo, 1000, nCont ) ), HPDF_TALIGN_LEFT, ::oPDFFontNormal, LAYOUT_FONTSIZE )
NEXT
::nLinhaPDF -= Int( 13 * 6 / LAYOUT_FONTSIZE ) * LAYOUT_FONTSIZE + 4
ENDIF
RETURN NIL
METHOD ProcessaItens( cXml, nItem ) CLASS hbNFeDaNFe
LOCAL cItem
cItem := XmlNode( cXml, [det nItem="] + AllTrim( Str( nItem ) ) + ["] )
IF Empty( cItem )
RETURN .F.
ENDIF
::aItem := XmlToHash( cItem, { "cProd", "cEAN", "xProd", "NCM", "EXTIPI", "CFOP", "uCom", "qCom", "vUnCom", "vProd", "cEANTrib", "uTrib", "qTrib", "vUnTrib", "vFrete", ;
"vSeg", "vDesc", "vOutro", "indTot", "infAdProd" } )
::aItemDI := XmlToHash( XmlNode( cItem, "DI" ), { "nDI", "dDI", "xLocDesemb", "UFDesemb", "cExportador" } )
::aItemAdi := XmlToHash( XmlNode( cItem, "adi" ), { "nAdicao", "nSeqAdic", "cFabricante", "vDescDI", "xPed", "nItemPed" } )
// todo veiculos (veicProd), medicamentos (med), armamentos (arm), combustiveis (comb)
::aItemICMS := XmlToHash( XmlNode( cItem, "ICMS" ), { "orig", "CST", "CSOSN", "vBCSTRet", "vICMSSTRet", "modBC", "pRedBC", "vBC", "pICMS", "vICMS", "motDesICMS", "modBCST", "pMVAST", "pRedBCST", "vBCST", "pICMSST", "vICMSST" } )
::aItemICMSPart := XmlToHash( XmlNode( cItem, "ICMSPart" ), { "orig", "CST", "modBC", "pRedBC", "vBC", "pICMS", "vICMS", "modBCST", "pMVAST", "pRedBCST", "vBCST", "pICMSST", "vICMSST", "pBCOp", "UFST" } )
::aItemICMSST := XmlToHash( XmlNode( cItem, "ICMSST" ), { "orig", "CST", "vBCSTRet", "vICMSSTRet", "vBCSTDest", "vICMSSTDest" } )
::aItemICMSSN101 := XmlToHash( XmlNode( cItem, "ICMSSN101" ), { "orig", "CSOSN", "pCredSN", "vCredICMSSN" } )
::aItemICMSSN102 := XmlToHash( XmlNode( cItem, "ICMSSN102" ), { "orig", "CSOSN" } )
::aItemICMSSN201 := XmlToHash( XmlNode( cItem, "ICMSSN201" ), { "orig", "CSOSN", "modBCST", "pMVAST", "pRedBCST", "vBCST", "pICMSST", "vICMSST", "pCredSN", "vCredICMSSN" } )
::aItemICMSSN202 := XmlToHash( XmlNode( cItem, "ICMSSN202" ), { "orig", "CSOSN", "modBCST", "pMVAST", "pRedBCST", "vBCST", "pICMSST", "vICMSST" } )
::aItemICMSSN500 := XmlToHash( XmlNode( cItem, "ICMSSN500" ), { "orig", "CSOSN", "vBCSTRet", "vICMSSTRet" } )
::aItemICMSSN900 := XmlToHash( XmlNode( cItem, "ICMSSN900" ), { "orig", "CSOSN", "modBC", "pRedBC", "vBC", "pICMS", "vICMS", "modBCST", "pMVAST", "pRedBCST", "vBCST", ;
"pICMSST", "vICMSST", "pCredSN", "vCredICMSSN" } )
::aItemIPI := XmlToHash( XmlNode( cItem, "IPI" ), { "clEnq", "CNPJProd", "cSelo", "qSelo", "cEnq", "CST", "vBC", "pIPI", "qUnid", "vUnid", "vIPI" } )
::aItemII := XmlToHash( XmlNode( cItem, "II" ), { "vBC", "vDespAdu", "vII", "vIOF" } )
::aItemPIS := XmlToHash( XmlNode( cItem, "PIS" ), { "CST", "vBC", "pPIS", "vPIS", "qBCProd", "vAliqProd" } )
::aItemPISST := XmlToHash( XmlNode( cItem, "PISST" ), { "vBC", "pPIS", "vPIS", "qBCProd", "vAliqProd" } )
::aItemCOFINS := XmlToHash( XmlNode( cItem, "COFINS" ), { "CST", "vBC", "pCOFINS", "vCOFINS", "qBCProd", "vAliqProd" } )
::aItemCOFINSST := XmlToHash( XmlNode( cItem, "COFINSST" ), { "vBC", "pCOFINS", "vCOFINS", "qBCProd", "vAliqProd" } )
::aItemISSQN := XmlToHash( XmlNode( cItem, "ISSQN" ), { "vBC", "vAliq", "vISSQN", "cMunFG", "cListServ", "cSitTrib" } )
::aItem[ "infAdProd" ] := StrTran( ::aItem[ "infAdProd" ], ";", Chr( 13 ) + Chr( 10 ) )
RETURN .T.
METHOD CalculaLayout() CLASS hbNFeDaNFe
LOCAL nItem, nQtdLinhas
::DefineColunasProdutos()
::aInfAdic[ "infCpl" ] := ::FormataMemo( ::aInfAdic[ "infCpl" ], 392 )
// Linhas necessárias pra imprimir ítens
nQtdLinhas := 1
nItem := 1
DO WHILE .T.
IF ! ::ProcessaItens( ::cXml, nItem )
EXIT
ENDIF
::aItem[ "xProd" ] := ::FormataMemo( ::aItem[ "xProd" ], ::aLayout[ LAYOUT_DESCRICAO, LAYOUT_LARGURAPDF ] - 2 )
nQtdLinhas += MLCount( ::aItem[ "xProd" ], 1000 )
IF Len( ::aItem[ "infAdProd" ] ) > 0
::aItem[ "infAdProd" ] := ::FormataMemo( ::aItem[ "infAdProd" ], ::aLayout[ LAYOUT_DESCRICAO, LAYOUT_LARGURAPDF ] - 2 )
nQtdLinhas += MLCount( ::aItem[ "infAdProd" ], 1000 )
ENDIF
IF ::lLayoutEspacoDuplo
nQtdLinhas += 1
ENDIF
nItem += 1
ENDDO
// Linhas extras pra informações adicionais
IF MLCount( ::ainfAdic[ "infCpl" ], 1000 ) > Int( 13 * 6 / LAYOUT_FONTSIZE )
nQtdLinhas += 2 + MLCount( ::ainfAdic[ "infCpl" ], 1000 ) - Int( 13 * 6 / LAYOUT_FONTSIZE )
ENDIF
// Total de folhas necessárias
::nLayoutTotalFolhas := 1
IF nQtdLinhas > ::ItensDaFolha( 1 )
::nLayoutTotalFolhas += Int( ( nQtdLinhas - ::ItensDaFolha( 1 ) + ::ItensDaFolha( 9 ) - 1 ) / ::ItensDaFolha( 9 ) )
ENDIF
RETURN NIL
METHOD ItensDaFolha( nFolha ) CLASS hbNFeDaNFe
LOCAL nQuadro := 630
nFolha := iif( nFolha == NIL, ::nFolha, nFolha )
IF nFolha == 1
nQuadro := 270 + ;
iif( ::lLaser, 54, 0 ) + ;
iif( Empty( ::cCobranca ), 12, 0 ) + ;
iif( Val( ::aIssTotal[ "vServ" ] ) <= 0, 24, 0 )
ENDIF
RETURN Int( nQuadro / LAYOUT_FONTSIZE )
METHOD DrawTextoProduto( nCampo, nRow, nConteudo, nAlign ) CLASS hbNFeDaNFe
LOCAL nColunaInicial, nColunaFinal, cTexto
IF ::aLayout[ nCampo, LAYOUT_IMPRIME ] != LAYOUT_NAOIMPRIME
nColunaInicial := ::aLayout[ nCampo, LAYOUT_COLUNAPDF ]
nColunaFinal := ::aLayout[ nCampo, LAYOUT_COLUNAPDF ] + ::aLayout[ nCampo, LAYOUT_LARGURAPDF ] - 2
IF ValType( nConteudo ) == "C"
cTexto := nConteudo
ELSE
cTexto := ::aLayout[ nCampo, nConteudo ]
IF nConteudo == LAYOUT_CONTEUDO
cTexto := Eval( cTexto )
ENDIF
ENDIF
IF ::aLayout[ nCampo, LAYOUT_IMPRIME ] == LAYOUT_IMPRIMESEGUNDA
nRow -= LAYOUT_FONTSIZE
ENDIF
::DrawTexto( nColunaInicial, nRow, nColunaFinal, NIL, cTexto, nAlign, ::oPDFFontNormal, LAYOUT_FONTSIZE )
ENDIF
RETURN NIL
METHOD DrawBoxProduto( nCampo, nRow, nHeight ) CLASS hbNfeDaNFe
IF ::aLayout[ nCampo, LAYOUT_IMPRIME ] == LAYOUT_IMPRIMENORMAL
::DrawBox( ::aLayout[ nCampo, LAYOUT_COLUNAPDF ] - 1, nRow, ::aLayout[ nCampo, LAYOUT_LARGURAPDF ], nHeight, ::nLarguraBox )
ENDIF
RETURN NIL
METHOD DefineColunasProdutos() CLASS hbNFeDaNFe
LOCAL oElement, nItem, nCont, nColunaFinal, nTentativa
::ProcessaItens( ::cXml, 1 ) // precisa de ::aItem pra gerar o codeblock