/
dci_normal.jl
185 lines (164 loc) · 5.03 KB
/
dci_normal.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
"""
normal_step!(nlp, x, cx, Jx, fx, ∇fx, λ, ℓxλ, ∇ℓxλ, dualnorm, primalnorm, ρmax, ϵp, max_eval, max_time, max_iter, meta, workspace)
Normal step: find `z` such that `||h(z)|| ≤ ρ` where `` is the trust-cylinder radius.
# Output
- `z`, `cz`, `fz`, `ℓzλ`, `∇ℓzλ`: the new iterate, and updated evaluations.
- `ρ`: updated trust-cylinder radius.
- `primalnorm`, `dualnorm`: updated primal and dual feasibility norms.
- `status`: Computation status. The possible outcomes are: `:init_success`, `:success`, `:max_eval`, `:max_time`, `:max_iter`, `:unknown_tired`, `:infeasible`, `:unknown`.
"""
function normal_step!(
nlp::AbstractNLPModel,
x::AbstractVector{T},
cx::AbstractVector{T},
Jx,
fx::T,
∇fx::AbstractVector{T},
λ::AbstractVector{T},
ℓxλ::T,
∇ℓxλ::AbstractVector{T},
dualnorm::T,
primalnorm::T, #norm(cx)
ρmax::T,
ϵp::T,
max_eval,
max_time,
max_iter,
meta::MetaDCI,
workspace::DCIWorkspace,
verbose::Bool,
) where {T}
#assign z variable:
workspace.z .= x
workspace.cz .= cx
workspace.∇fz .= ∇fx
Jz, fz, ℓzλ = Jx, fx, ℓxλ
norm∇fz = norm(∇fx) #can be avoided if we use dualnorm
workspace.∇ℓzλ .= ∇ℓxλ
z, cz, ∇fz, ∇ℓzλ = workspace.z, workspace.cz, workspace.∇fz, workspace.∇ℓzλ
infeasible = false
restoration = false
tired = false
start_time = time()
eltime = 0.0
#Initialize ρ at x
ρ = compute_ρ(dualnorm, primalnorm, norm∇fz, ρmax, ϵp, 0, meta)
done_with_normal_step = primalnorm ≤ ρ
iter_normal_step = 0
while !done_with_normal_step
#primalnorm = norm(cz)
z, cz, primalnorm, Jz, normal_status = eval(meta.feas_step)(
nlp,
z,
cz,
primalnorm,
Jz,
ρ,
ϵp,
meta,
workspace,
verbose,
max_eval = max_eval,
max_time = max_time,
)
fz, ∇fz = objgrad!(nlp, z, ∇fz)
norm∇fz = norm(∇fz) #can be avoided if we use dualnorm
compute_lx!(Jz, ∇fz, λ, meta)
ℓzλ = fz + dot(λ, cz)
mul!(workspace.Jtv, Jz', λ)
∇ℓzλ .= ∇fz .+ workspace.Jtv
dualnorm = norm(∇ℓzλ)
#update rho
iter_normal_step += 1
ρ = compute_ρ(dualnorm, primalnorm, norm∇fz, ρmax, ϵp, iter_normal_step, meta)
eltime = time() - start_time
verbose && @info log_row(
Any[
"N",
iter_normal_step,
neval_obj(nlp) + neval_cons(nlp),
fz,
ℓzλ,
dualnorm,
primalnorm,
ρmax,
ρ,
normal_status,
Float64,
Float64,
eltime,
],
)
many_evals = neval_obj(nlp) + neval_cons(nlp) > max_eval
tired = many_evals || eltime > max_time || iter_normal_step > max_iter
infeasible = normal_status == :infeasible
if infeasible && !restoration && !(primalnorm ≤ ρ || tired)
#Enter restoration phase to avoid infeasible stationary points.
#Heuristic that forces a random move from z
restoration, infeasible = true, false
perturbation_length = min(primalnorm, √ϵp) / norm(z) #sqrt(ϵp)/norm(z)
z .+= (2 * rand(T, nlp.meta.nvar) .- one(T)) * perturbation_length
cons_norhs!(nlp, z, cz)
Jz = jac_op!(nlp, z, workspace.Jv, workspace.Jtv) # workspace.Jx
primalnorm = norm(cz)
ρ = compute_ρ(dualnorm, primalnorm, norm∇fz, ρmax, ϵp, 0, meta)
end
done_with_normal_step = primalnorm ≤ ρ || tired || infeasible
end
status = if primalnorm ≤ ρ && iter_normal_step == 0
:init_success
elseif primalnorm ≤ ρ
:success
elseif tired
if neval_obj(nlp) + neval_cons(nlp) > max_eval
:max_eval
elseif eltime > max_time
:max_time
elseif iter_normal_step > max_iter
:max_iter
else
:unknown_tired
end
elseif infeasible
:infeasible
else
:unknown
end
return z, cz, fz, ℓzλ, ∇ℓzλ, ρ, primalnorm, dualnorm, status
end
"""
compute_ρ(dualnorm, primalnorm, norm∇fx, ρmax, ϵ, iter, meta::MetaDCI)
compute_ρ(dualnorm, primalnorm, norm∇fx, ρmax, ϵ, iter, p1, p2)
Update and return the trust-cylinder radius `ρ`.
Theory asks for ngp ρmax 10^-4 < ρ <= ngp ρmax
There are no evaluations of functions here.
`ρ = O(‖g_p(z)‖)` and in the paper `ρ = ν n_p(z) ρ_max` with `n_p(z) = norm(g_p(z)) / (norm(g(z)) + 1)`.
"""
function compute_ρ(dualnorm, primalnorm, norm∇fx, ρmax, ϵ, iter, meta::MetaDCI)
p1, p2 = meta.compρ_p1, meta.compρ_p2
return compute_ρ(dualnorm, primalnorm, norm∇fx, ρmax, ϵ, iter, p1, p2)
end
# T.M., 2021 Feb. 5th: what if dualnorm is excessively small ?
# Feb. 8th: don't let ρ decrease too crazy
function compute_ρ(
dualnorm::T,
primalnorm::T,
norm∇fx::T,
ρmax::T,
ϵ::T, #ctol
iter::Integer,
p1::Real,
p2::Real,
) where {T}
if iter > 100
return p1 * ρmax
end
ngp = dualnorm / (norm∇fx + 1)
ρ = max(min(ngp, p1) * ρmax, ϵ) # max(min(ngp/ρmax, p1) * ρmax, ϵ)
if ρ ≤ ϵ && primalnorm > 100 * ϵ
ρ = primalnorm * p2 #/ 10
#elseif ngp ≤ 5ϵ
# ρ = ϵ
end
return ρ
end