fom.jl

# An implementation of FOM for the solution of the square linear system Ax = b.
#
# This method is described in
#
# Y. Saad, Krylov subspace methods for solving unsymmetric linear systems.
# Mathematics of computation, Vol. 37(155), pp. 105--126, 1981.
#
# Alexis Montoison, <alexis.montoison@polymtl.ca>
# Montreal, December 2018.

export fom, fom!

"""
    (x, stats) = fom(A, b::AbstractVector{FC};
                     memory::Int=20, M=I, N=I, ldiv::Bool=false,
                     restart::Bool=false, reorthogonalization::Bool=false,
                     atol::T=√eps(T), rtol::T=√eps(T), itmax::Int=0,
                     timemax::Float64=Inf, verbose::Int=0, history::Bool=false,
                     callback=solver->false, iostream::IO=kstdout)

`T` is an `AbstractFloat` such as `Float32`, `Float64` or `BigFloat`.
`FC` is `T` or `Complex{T}`.

    (x, stats) = fom(A, b, x0::AbstractVector; kwargs...)

FOM can be warm-started from an initial guess `x0` where `kwargs` are the same keyword arguments as above.

Solve the linear system Ax = b of size n using FOM.

FOM algorithm is based on the Arnoldi process and a Galerkin condition.

#### Input arguments

* `A`: a linear operator that models a matrix of dimension n;
* `b`: a vector of length n.

#### Optional argument

* `x0`: a vector of length n that represents an initial guess of the solution x.

#### Keyword arguments

* `memory`: if `restart = true`, the restarted version FOM(k) is used with `k = memory`. If `restart = false`, the parameter `memory` should be used as a hint of the number of iterations to limit dynamic memory allocations. Additional storage will be allocated if the number of iterations exceeds `memory`;
* `M`: linear operator that models a nonsingular matrix of size `n` used for left preconditioning;
* `N`: linear operator that models a nonsingular matrix of size `n` used for right preconditioning;
* `ldiv`: define whether the preconditioners use `ldiv!` or `mul!`;
* `restart`: restart the method after `memory` iterations;
* `reorthogonalization`: reorthogonalize the new vectors of the Krylov basis against all previous vectors;
* `atol`: absolute stopping tolerance based on the residual norm;
* `rtol`: relative stopping tolerance based on the residual norm;
* `itmax`: the maximum number of iterations. If `itmax=0`, the default number of iterations is set to `2n`;
* `timemax`: the time limit in seconds;
* `verbose`: additional details can be displayed if verbose mode is enabled (verbose > 0). Information will be displayed every `verbose` iterations;
* `history`: collect additional statistics on the run such as residual norms, or Aᴴ-residual norms;
* `callback`: function or functor called as `callback(solver)` that returns `true` if the Krylov method should terminate, and `false` otherwise;
* `iostream`: stream to which output is logged.

#### Output arguments

* `x`: a dense vector of length n;
* `stats`: statistics collected on the run in a [`SimpleStats`](@ref) structure.

#### Reference

* Y. Saad, [*Krylov subspace methods for solving unsymmetric linear systems*](https://doi.org/10.1090/S0025-5718-1981-0616364-6), Mathematics of computation, Vol. 37(155), pp. 105--126, 1981.
"""
function fom end

"""
    solver = fom!(solver::FomSolver, A, b; kwargs...)
    solver = fom!(solver::FomSolver, A, b, x0; kwargs...)

where `kwargs` are keyword arguments of [`fom`](@ref).

Note that the `memory` keyword argument is the only exception.
It's required to create a `FomSolver` and can't be changed later.

See [`FomSolver`](@ref) for more details about the `solver`.
"""
function fom! end

def_args_fom = (:(A                    ),
                :(b::AbstractVector{FC}))

def_optargs_fom = (:(x0::AbstractVector),)

def_kwargs_fom = (:(; M = I                            ),
                  :(; N = I                            ),
                  :(; ldiv::Bool = false               ),
                  :(; restart::Bool = false            ),
                  :(; reorthogonalization::Bool = false),
                  :(; atol::T = √eps(T)                ),
                  :(; rtol::T = √eps(T)                ),
                  :(; itmax::Int = 0                   ),
                  :(; timemax::Float64 = Inf           ),
                  :(; verbose::Int = 0                 ),
                  :(; history::Bool = false            ),
                  :(; callback = solver -> false       ),
                  :(; iostream::IO = kstdout           ))

def_kwargs_fom = mapreduce(extract_parameters, vcat, def_kwargs_fom)

args_fom = (:A, :b)
optargs_fom = (:x0,)
kwargs_fom = (:M, :N, :ldiv, :restart, :reorthogonalization, :atol, :rtol, :itmax, :timemax, :verbose, :history, :callback, :iostream)

@eval begin
  function fom($(def_args_fom...), $(def_optargs_fom...); memory :: Int=20, $(def_kwargs_fom...)) where {T <: AbstractFloat, FC <: FloatOrComplex{T}}
    start_time = time_ns()
    solver = FomSolver(A, b, memory)
    warm_start!(solver, $(optargs_fom...))
    elapsed_time = ktimer(start_time)
    timemax -= elapsed_time
    fom!(solver, $(args_fom...); $(kwargs_fom...))
    solver.stats.timer += elapsed_time
    return (solver.x, solver.stats)
  end

  function fom($(def_args_fom...); memory :: Int=20, $(def_kwargs_fom...)) where {T <: AbstractFloat, FC <: FloatOrComplex{T}}
    start_time = time_ns()
    solver = FomSolver(A, b, memory)
    elapsed_time = ktimer(start_time)
    timemax -= elapsed_time
    fom!(solver, $(args_fom...); $(kwargs_fom...))
    solver.stats.timer += elapsed_time
    return (solver.x, solver.stats)
  end

  function fom!(solver :: FomSolver{T,FC,S}, $(def_args_fom...); $(def_kwargs_fom...)) where {T <: AbstractFloat, FC <: FloatOrComplex{T}, S <: AbstractVector{FC}}

    # Timer
    start_time = time_ns()
    timemax_ns = 1e9 * timemax

    m, n = size(A)
    (m == solver.m && n == solver.n) || error("(solver.m, solver.n) = ($(solver.m), $(solver.n)) is inconsistent with size(A) = ($m, $n)")
    m == n || error("System must be square")
    length(b) == m || error("Inconsistent problem size")
    (verbose > 0) && @printf(iostream, "FOM: system of size %d\n", n)

    # Check M = Iₙ and N = Iₙ
    MisI = (M === I)
    NisI = (N === I)

    # Check type consistency
    eltype(A) == FC || @warn "eltype(A) ≠ $FC. This could lead to errors or additional allocations in operator-vector products."
    ktypeof(b) <: S || error("ktypeof(b) is not a subtype of $S")

    # Set up workspace.
    allocate_if(!MisI  , solver, :q , S, n)
    allocate_if(!NisI  , solver, :p , S, n)
    allocate_if(restart, solver, :Δx, S, n)
    Δx, x, w, V, z = solver.Δx, solver.x, solver.w, solver.V, solver.z
    l, U, stats = solver.l, solver.U, solver.stats
    warm_start = solver.warm_start
    rNorms = stats.residuals
    reset!(stats)
    q  = MisI ? w : solver.q
    r₀ = MisI ? w : solver.q
    xr = restart ? Δx : x

    # Initial solution x₀.
    x .= zero(FC)

    # Initial residual r₀.
    if warm_start
      mul!(w, A, Δx)
      @kaxpby!(n, one(FC), b, -one(FC), w)
      restart && @kaxpy!(n, one(FC), Δx, x)
    else
      w .= b
    end
    MisI || mulorldiv!(r₀, M, w, ldiv)  # r₀ = M(b - Ax₀)
    β = @knrm2(n, r₀)                   # β = ‖r₀‖₂

    rNorm = β
    history && push!(rNorms, β)
    ε = atol + rtol * rNorm

    if β == 0
      stats.niter = 0
      stats.solved, stats.inconsistent = true, false
      stats.timer = ktimer(start_time)
      stats.status = "x = 0 is a zero-residual solution"
      solver.warm_start = false
      return solver
    end

    mem = length(l)  # Memory
    npass = 0        # Number of pass

    iter = 0        # Cumulative number of iterations
    inner_iter = 0  # Number of iterations in a pass

    itmax == 0 && (itmax = 2*n)
    inner_itmax = itmax

    (verbose > 0) && @printf(iostream, "%5s  %5s  %7s  %7s  %5s\n", "pass", "k", "‖rₖ‖", "hₖ₊₁.ₖ", "timer")
    kdisplay(iter, verbose) && @printf(iostream, "%5d  %5d  %7.1e  %7s  %.2fs\n", npass, iter, rNorm, "✗ ✗ ✗ ✗", ktimer(start_time))

    # Tolerance for breakdown detection.
    btol = eps(T)^(3/4)

    # Stopping criterion
    breakdown = false
    solved = rNorm ≤ ε
    tired = iter ≥ itmax
    inner_tired = inner_iter ≥ inner_itmax
    status = "unknown"
    user_requested_exit = false
    overtimed = false

    while !(solved || tired || breakdown || user_requested_exit || overtimed)

      # Initialize workspace.
      nr = 0  # Number of coefficients stored in Uₖ.
      for i = 1 : mem
        V[i] .= zero(FC)  # Orthogonal basis of Kₖ(MAN, Mr₀).
      end
      l .= zero(FC)  # Lower unit triangular matrix Lₖ.
      U .= zero(FC)  # Upper triangular matrix Uₖ.
      z .= zero(FC)  # Solution of Lₖzₖ = βe₁.

      if restart
        xr .= zero(FC)  # xr === Δx when restart is set to true
        if npass ≥ 1
          mul!(w, A, x)
          @kaxpby!(n, one(FC), b, -one(FC), w)
          MisI || mulorldiv!(r₀, M, w, ldiv)
        end
      end

      # Initial ζ₁ and V₁
      β = @knrm2(n, r₀)
      z[1] = β
      @. V[1] = r₀ / rNorm

      npass = npass + 1
      inner_iter = 0
      inner_tired = false

      while !(solved || inner_tired || breakdown)

        # Update iteration index
        inner_iter = inner_iter + 1

        # Update workspace if more storage is required and restart is set to false
        if !restart && (inner_iter > mem)
          for i = 1 : inner_iter
            push!(U, zero(FC))
          end
          push!(l, zero(FC))
          push!(z, zero(FC))
        end

        # Continue the Arnoldi process.
        p = NisI ? V[inner_iter] : solver.p
        NisI || mulorldiv!(p, N, V[inner_iter], ldiv)  # p ← Nvₖ
        mul!(w, A, p)                                  # w ← ANvₖ
        MisI || mulorldiv!(q, M, w, ldiv)              # q ← MANvₖ
        for i = 1 : inner_iter
          U[nr+i] = @kdot(n, V[i], q)      # hᵢₖ = (vᵢ)ᴴq
          @kaxpy!(n, -U[nr+i], V[i], q)    # q ← q - hᵢₖvᵢ
        end

        # Reorthogonalization of the Krylov basis.
        if reorthogonalization
          for i = 1 : inner_iter
            Htmp = @kdot(n, V[i], q)
            U[nr+i] += Htmp
            @kaxpy!(n, -Htmp, V[i], q)
          end
        end

        # Compute hₖ₊₁.ₖ
        Hbis = @knrm2(n, q)  # hₖ₊₁.ₖ = ‖vₖ₊₁‖₂

        # Update the LU factorization of Hₖ.
        if inner_iter ≥ 2
          for i = 2 : inner_iter
            # uᵢ.ₖ ← hᵢ.ₖ - lᵢ.ᵢ₋₁ * uᵢ₋₁.ₖ
            U[nr+i] = U[nr+i] - l[i-1] * U[nr+i-1]
          end
          # ζₖ = -lₖ.ₖ₋₁ * ζₖ₋₁
          z[inner_iter] = - l[inner_iter-1] * z[inner_iter-1]
        end
        # lₖ₊₁.ₖ = hₖ₊₁.ₖ / uₖ.ₖ
        l[inner_iter] = Hbis / U[nr+inner_iter]

        # Update residual norm estimate.
        # ‖ M(b - Axₖ) ‖₂ = hₖ₊₁.ₖ * |ζₖ / uₖ.ₖ|
        rNorm = Hbis * abs(z[inner_iter] / U[nr+inner_iter])
        history && push!(rNorms, rNorm)

        # Update the number of coefficients in Uₖ
        nr = nr + inner_iter

        # Stopping conditions that do not depend on user input.
        # This is to guard against tolerances that are unreasonably small.
        resid_decrease_mach = (rNorm + one(T) ≤ one(T))

        # Update stopping criterion.
        user_requested_exit = callback(solver) :: Bool
        resid_decrease_lim = rNorm ≤ ε
        breakdown = Hbis ≤ btol
        solved = resid_decrease_lim || resid_decrease_mach
        inner_tired = restart ? inner_iter ≥ min(mem, inner_itmax) : inner_iter ≥ inner_itmax
        timer = time_ns() - start_time
        overtimed = timer > timemax_ns
        kdisplay(iter+inner_iter, verbose) && @printf(iostream, "%5d  %5d  %7.1e  %7.1e  %.2fs\n", npass, iter+inner_iter, rNorm, Hbis, ktimer(start_time))

        # Compute vₖ₊₁.
        if !(solved || inner_tired || breakdown || user_requested_exit || overtimed)
          if !restart && (inner_iter ≥ mem)
            push!(V, S(undef, n))
          end
          @. V[inner_iter+1] = q / Hbis  # hₖ₊₁.ₖvₖ₊₁ = q
        end
      end

      # Hₖyₖ = βe₁ ⟺ LₖUₖyₖ = βe₁ ⟺ Uₖyₖ = zₖ.
      # Compute yₖ by solving Uₖyₖ = zₖ with backward substitution.
      y = z  # yᵢ = zᵢ
      for i = inner_iter : -1 : 1
        pos = nr + i - inner_iter      # position of rᵢ.ₖ
        for j = inner_iter : -1 : i+1
          y[i] = y[i] - U[pos] * y[j]  # yᵢ ← yᵢ - uᵢⱼyⱼ
          pos = pos - j + 1            # position of rᵢ.ⱼ₋₁
        end
        y[i] = y[i] / U[pos]  # yᵢ ← yᵢ / rᵢᵢ
      end

      # Form xₖ = NVₖyₖ
      for i = 1 : inner_iter
        @kaxpy!(n, y[i], V[i], xr)
      end
      if !NisI
        solver.p .= xr
        mulorldiv!(xr, N, solver.p, ldiv)
      end
      restart && @kaxpy!(n, one(FC), xr, x)

      # Update inner_itmax, iter, tired and overtimed variables.
      inner_itmax = inner_itmax - inner_iter
      iter = iter + inner_iter
      tired = iter ≥ itmax
      timer = time_ns() - start_time
      overtimed = timer > timemax_ns
    end
    (verbose > 0) && @printf(iostream, "\n")

    # Termination status
    tired               && (status = "maximum number of iterations exceeded")
    breakdown           && (status = "inconsistent linear system")
    solved              && (status = "solution good enough given atol and rtol")
    user_requested_exit && (status = "user-requested exit")
    overtimed           && (status = "time limit exceeded")

    # Update x
    warm_start && !restart && @kaxpy!(n, one(FC), Δx, x)
    solver.warm_start = false

    # Update stats
    stats.niter = iter
    stats.solved = solved
    stats.inconsistent = !solved && breakdown
    stats.timer = ktimer(start_time)
    stats.status = status
    return solver
  end
end