/
K2Structured.jl
234 lines (215 loc) · 5.04 KB
/
K2Structured.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
export K2StructuredParams
"""
Type to use the K2 formulation with a structured Krylov method, using the package
[`Krylov.jl`](https://github.com/JuliaSmoothOptimizers/Krylov.jl).
This only works for solving Linear Problems.
The outer constructor
K2StructuredParams(; uplo = :L, kmethod = :trimr, rhs_scale = true,
atol0 = 1.0e-4, rtol0 = 1.0e-4,
atol_min = 1.0e-10, rtol_min = 1.0e-10,
ρ_min = 1e2 * sqrt(eps()), δ_min = 1e2 * sqrt(eps()),
itmax = 0, mem = 20)
creates a [`RipQP.SolverParams`](@ref).
The available methods are:
- `:tricg`
- `:trimr`
- `:gpmr`
The `mem` argument sould be used only with `gpmr`.
"""
mutable struct K2StructuredParams{T} <: AugmentedParams{T}
uplo::Symbol
kmethod::Symbol
rhs_scale::Bool
atol0::T
rtol0::T
atol_min::T
rtol_min::T
ρ_min::T
δ_min::T
itmax::Int
mem::Int
end
function K2StructuredParams{T}(;
uplo::Symbol = :L,
kmethod::Symbol = :trimr,
rhs_scale::Bool = true,
atol0::T = eps(T)^(1 / 4),
rtol0::T = eps(T)^(1 / 4),
atol_min::T = sqrt(eps(T)),
rtol_min::T = sqrt(eps(T)),
ρ_min::T = T(1e2 * sqrt(eps(T))),
δ_min::T = T(1e2 * sqrt(eps(T))),
itmax::Int = 0,
mem::Int = 20,
) where {T <: Real}
return K2StructuredParams(
uplo,
kmethod,
rhs_scale,
atol0,
rtol0,
atol_min,
rtol_min,
ρ_min,
δ_min,
itmax,
mem,
)
end
K2StructuredParams(; kwargs...) = K2StructuredParams{Float64}(; kwargs...)
mutable struct PreallocatedDataK2Structured{T <: Real, S, Ksol <: KrylovSolver} <:
PreallocatedDataAugmentedKrylovStructured{T, S}
E::S # temporary top-left diagonal
invE::S
ξ1::S
ξ2::S
rhs_scale::Bool
regu::Regularization{T}
KS::Ksol
kiter::Int
atol::T
rtol::T
atol_min::T
rtol_min::T
itmax::Int
end
function PreallocatedData(
sp::K2StructuredParams,
fd::QM_FloatData{T},
id::QM_IntData,
itd::IterData{T},
pt::Point{T},
iconf::InputConfig{Tconf},
) where {T <: Real, Tconf <: Real}
# init Regularization values
E = similar(fd.c, id.nvar)
if iconf.mode == :mono
regu =
Regularization(T(sqrt(eps()) * 1e5), T(sqrt(eps()) * 1e5), T(sp.ρ_min), T(sp.δ_min), :classic)
E .= T(1.0e0) / 2
else
regu = Regularization(
T(sqrt(eps()) * 1e5),
T(sqrt(eps()) * 1e5),
T(sqrt(eps(T)) * 1e0),
T(sqrt(eps(T)) * 1e0),
:classic,
)
E .= T(1.0e-2)
end
if regu.δ_min == zero(T) # gsp for gpmr
regu.δ = zero(T)
end
invE = similar(E)
invE .= one(T) ./ E
ξ1 = similar(fd.c, id.nvar)
ξ2 = similar(fd.c, id.ncon)
KS = init_Ksolver(fd.A', fd.b, sp)
return PreallocatedDataK2Structured(
E,
invE,
ξ1,
ξ2,
sp.rhs_scale,
regu,
KS,
0,
T(sp.atol0),
T(sp.rtol0),
T(sp.atol_min),
T(sp.rtol_min),
sp.itmax,
)
end
function update_kresiduals_history!(
res::AbstractResiduals{T},
E::AbstractVector{T},
A::Union{AbstractMatrix{T}, AbstractLinearOperator{T}},
δ::T,
solx::AbstractVector{T},
soly::AbstractVector{T},
ξ1::AbstractVector{T},
ξ2::AbstractVector{T},
nvar::Int,
) where {T <: Real}
if typeof(res) <: ResidualsHistory
@views mul!(res.Kres[1:nvar], A', soly)
@. res.Kres[1:nvar] += -E * solx - ξ1
@views mul!(res.Kres[(nvar + 1):end], A, solx)
@. res.Kres[(nvar + 1):end] += δ * soly - ξ2
end
end
function solver!(
dd::AbstractVector{T},
pad::PreallocatedDataK2Structured{T},
dda::DescentDirectionAllocs{T},
pt::Point{T},
itd::IterData{T},
fd::Abstract_QM_FloatData{T},
id::QM_IntData,
res::AbstractResiduals{T},
cnts::Counters,
step::Symbol,
) where {T <: Real}
pad.ξ1 .= @views step == :init ? fd.c : dd[1:(id.nvar)]
pad.ξ2 .= @views (step == :init && all(dd[(id.nvar + 1):end] .== zero(T))) ? one(T) :
dd[(id.nvar + 1):end]
if pad.rhs_scale
rhsNorm = sqrt(norm(pad.ξ1)^2 + norm(pad.ξ2)^2)
pad.ξ1 ./= rhsNorm
pad.ξ2 ./= rhsNorm
end
(step !== :cc) && (pad.kiter = 0)
ksolve!(
pad.KS,
fd.A',
pad.ξ1,
pad.ξ2,
Diagonal(pad.invE),
(one(T) / pad.regu.δ) .* I,
verbose = 0,
atol = pad.atol,
rtol = pad.rtol,
gsp = (pad.regu.δ == zero(T)),
itmax = pad.itmax,
)
update_kresiduals_history!(
res,
pad.E,
fd.A,
pad.regu.δ,
pad.KS.x,
pad.KS.y,
pad.ξ1,
pad.ξ2,
id.nvar,
)
pad.kiter += niterations(pad.KS)
if pad.rhs_scale
kunscale!(pad.KS.x, rhsNorm)
kunscale!(pad.KS.y, rhsNorm)
end
dd[1:(id.nvar)] .= pad.KS.x
dd[(id.nvar + 1):end] .= pad.KS.y
return 0
end
function update_pad!(
pad::PreallocatedDataK2Structured{T},
dda::DescentDirectionAllocs{T},
pt::Point{T},
itd::IterData{T},
fd::Abstract_QM_FloatData{T},
id::QM_IntData,
res::AbstractResiduals{T},
cnts::Counters,
) where {T <: Real}
if cnts.k != 0
update_regu!(pad.regu)
end
update_krylov_tol!(pad)
pad.E .= pad.regu.ρ
@. pad.E[id.ilow] += pt.s_l / itd.x_m_lvar
@. pad.E[id.iupp] += pt.s_u / itd.uvar_m_x
@. pad.invE = one(T) / pad.E
return 0
end