PKGBUILD

# include global config
source ../_buildscripts/${current_repo}-${_arch}-cfg.conf

pkgname=dolphin
pkgver=${_kdever}
pkgrel=2
pkgdesc="File manager by KDE."
arch=('x86_64')
url='https://invent.kde.org/system/dolphin'
license=('LGPL')
depends=('kcmutils6' 'knewstuff6' 'kcoreaddons6' 'ki18n6' 'kdbusaddons6' 'kbookmarks6' 'kconfig6' 'kio6'
         'kparts6' 'solid6' 'kiconthemes6' 'kcompletion6' 'ktextwidgets6' 'knotifications6' 'kwindowsystem6'
         'kwidgetsaddons6' 'kuserfeedback6' 'plasma-activities' 'baloo6' 'kfilemetadata6' 'kde-cli-tools'
         'baloo-widgets' 'kio-admin')
makedepends=('extra-cmake-modules' 'kdoctools6' 'ruby')
conflicts=('dolphin6')
replaces=('dolphin6')
groups=('kde-system')
source=("$_mirror/${pkgname}-${_kdever}.tar.xz"
        'kdesu.diff'
        'dolphinui.diff'
        "https://invent.kde.org/system/dolphin/-/commit/a07f24228a94aab2bdeb3caaf7a4d694c0180ed7.diff")
md5sums=(`grep ${pkgname}-${_kdever}.tar.xz ../kde-sc.md5 | cut -d" " -f1`
         'b4f0491bacf3c9f923f2ee0810cc3576'
         'e0211cc01ceb848101e19cbd0bd95fcf'
         'ffabdc14115766fe60b5d30013738928')

prepare() {
  cd ${pkgname}-${pkgver}

  patch -p1 -i ${srcdir}/a07f24228a94aab2bdeb3caaf7a4d694c0180ed7.diff
  # set KaOS defaults
  patch -p1 -i ${srcdir}/dolphinui.diff
  #sed -i 's|dirLister->setShowingDotFiles|dirLister->setShowHiddenFiles|' src/kitemviews/kfileitemmodel.cpp
}

build() {
  cmake -B build -S ${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DKDE_INSTALL_LIBDIR=lib \
    -DBUILD_TESTING=OFF \
    -DQT_MAJOR_VERSION=6
  cmake --build build
}

package() {

  DESTDIR=${pkgdir} cmake --install build
}