-
Notifications
You must be signed in to change notification settings - Fork 6
/
GaussianDiffusion.jl
264 lines (229 loc) · 9.67 KB
/
GaussianDiffusion.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
"""
GaussianDiffusion(V::DataType, βs, data_shape, denoise_fn)
A Gaussian Diffusion Probalistic Model (DDPM) as introduced in "Denoising Diffusion Probabilistic Models" by Ho et. al (https://arxiv.org/abs/2006.11239).
"""
struct GaussianDiffusion{V<:AbstractVector}
num_timesteps::Int
data_shape::NTuple
denoise_fn
βs::V
αs::V
α_cumprods::V
α_cumprod_prevs::V
sqrt_α_cumprods::V
sqrt_one_minus_α_cumprods::V
sqrt_recip_α_cumprods::V
sqrt_recip_α_cumprods_minus_one::V
posterior_variance::V
posterior_log_variance_clipped::V
posterior_mean_coef1::V
posterior_mean_coef2::V
end
eltype(::Type{<:GaussianDiffusion{V}}) where {V} = V
Flux.@functor GaussianDiffusion
Flux.trainable(g::GaussianDiffusion) = (; g.denoise_fn)
function Base.show(io::IO, diffusion::GaussianDiffusion)
V = typeof(diffusion).parameters[1]
print(io, "GaussianDiffusion{$V}(")
print(io, "num_timesteps=$(diffusion.num_timesteps)")
print(io, ", data_shape=$(diffusion.data_shape)")
print(io, ", denoise_fn=$(diffusion.denoise_fn)")
num_buffers = 12
buffers_size = Base.format_bytes(Base.summarysize(diffusion.βs) * num_buffers)
print(io, ", buffers_size=$buffers_size")
print(io, ")")
end
function GaussianDiffusion(V::DataType, βs::AbstractVector, data_shape::NTuple, denoise_fn)
αs = 1 .- βs
α_cumprods = cumprod(αs)
α_cumprod_prevs = [1, (α_cumprods[1:end-1])...]
sqrt_α_cumprods = sqrt.(α_cumprods)
sqrt_one_minus_α_cumprods = sqrt.(1 .- α_cumprods)
sqrt_recip_α_cumprods = 1 ./ sqrt.(α_cumprods)
sqrt_recip_α_cumprods_minus_one = sqrt.(1 ./ α_cumprods .- 1)
posterior_variance = βs .* (1 .- α_cumprod_prevs) ./ (1 .- α_cumprods)
posterior_log_variance_clipped = log.(max.(posterior_variance, 1e-20))
posterior_mean_coef1 = βs .* sqrt.(α_cumprod_prevs) ./ (1 .- α_cumprods)
posterior_mean_coef2 = (1 .- α_cumprod_prevs) .* sqrt.(αs) ./ (1 .- α_cumprods)
GaussianDiffusion{V}(
length(βs),
data_shape,
denoise_fn,
βs,
αs,
α_cumprods,
α_cumprod_prevs,
sqrt_α_cumprods,
sqrt_one_minus_α_cumprods,
sqrt_recip_α_cumprods,
sqrt_recip_α_cumprods_minus_one,
posterior_variance,
posterior_log_variance_clipped,
posterior_mean_coef1,
posterior_mean_coef2
)
end
"""
linear_beta_schedule(num_timesteps, β_start=0.0001f0, β_end=0.02f0)
"""
function linear_beta_schedule(num_timesteps::Int, β_start=0.0001f0, β_end=0.02f0)
scale = convert(typeof(β_start), 1000 / num_timesteps)
β_start *= scale
β_end *= scale
range(β_start, β_end; length=num_timesteps)
end
"""
cosine_beta_schedule(num_timesteps, s=0.008)
Cosine schedule as proposed in "Improved Denoising Diffusion Probabilistic Models" by Nichol, Dhariwal (https://arxiv.org/abs/2102.09672)
"""
function cosine_beta_schedule(num_timesteps::Int, s=0.008)
t = range(0, num_timesteps; length=num_timesteps + 1)
α_cumprods = (cos.((t / num_timesteps .+ s) / (1 + s) * π / 2)) .^ 2
α_cumprods = α_cumprods / α_cumprods[1]
βs = 1 .- α_cumprods[2:end] ./ α_cumprods[1:(end-1)]
clamp!(βs, 0, 0.999)
βs
end
## extract input[idxs] and reshape for broadcasting across a batch.
function _extract(input, idxs::AbstractVector{Int}, shape::NTuple)
reshape(input[idxs], (repeat([1], length(shape) - 1)..., :))
end
"""
q_sample(diffusion, x_start, timesteps, noise)
q_sample(diffusion, x_start, timesteps; to_device=cpu)
The forward process ``q(x_t | x_0)``. Diffuse the data for a given number of diffusion steps.
"""
function q_sample(
diffusion::GaussianDiffusion,
x_start::AbstractArray,
timesteps::AbstractVector{Int},
noise::AbstractArray
)
coeff1 = _extract(diffusion.sqrt_α_cumprods, timesteps, size(x_start))
coeff2 = _extract(diffusion.sqrt_one_minus_α_cumprods, timesteps, size(x_start))
coeff1 .* x_start + coeff2 .* noise
end
function q_sample(
diffusion::GaussianDiffusion,
x_start::AbstractArray,
timesteps::AbstractVector{Int}
;to_device=cpu
)
T = eltype(eltype(diffusion))
noise = randn(T, size(x_start)) |> to_device
timesteps = timesteps |> to_device
q_sample(diffusion, x_start, timesteps, noise)
end
function q_sample(
diffusion::GaussianDiffusion,
x_start::AbstractArray{T,N},
timestep::Int; to_device=cpu
) where {T,N}
timesteps = fill(timestep, size(x_start, N)) |> to_device
q_sample(diffusion, x_start, timesteps; to_device=to_device)
end
"""
q_posterior_mean_variance(diffusion, x_start, x_t, timesteps)
Compute the mean and variance for the ``q_{posterior}(x_{t-1} | x_t, x_0) = q(x_t | x_{t-1}, x_0) q(x_{t-1} | x_0) / q(x_t | x_0)``
where `x_0 = x_start`.
The ``q_{posterior}`` is a Bayesian estimate of the reverse process ``p(x_{t-1} | x_{t})`` where ``x_0`` is known.
"""
function q_posterior_mean_variance(diffusion::GaussianDiffusion, x_start::AbstractArray, x_t::AbstractArray, timesteps::AbstractVector{Int})
coeff1 = _extract(diffusion.posterior_mean_coef1, timesteps, size(x_t))
coeff2 = _extract(diffusion.posterior_mean_coef2, timesteps, size(x_t))
posterior_mean = coeff1 .* x_start + coeff2 .* x_t
posterior_variance = _extract(diffusion.posterior_variance, timesteps, size(x_t))
posterior_mean, posterior_variance
end
"""
predict_start_from_noise(diffusion, x_t, timesteps, noise)
Predict an estimate for the ``x_0`` based on the forward process ``q(x_t | x_0)``.
"""
function predict_start_from_noise(diffusion::GaussianDiffusion, x_t::AbstractArray, timesteps::AbstractVector{Int}, noise::AbstractArray)
coeff1 = _extract(diffusion.sqrt_recip_α_cumprods, timesteps, size(x_t))
coeff2 = _extract(diffusion.sqrt_recip_α_cumprods_minus_one, timesteps, size(x_t))
coeff1 .* x_t - coeff2 .* noise
end
function denoise(diffusion::GaussianDiffusion, x::AbstractArray, timesteps::AbstractVector{Int})
noise = diffusion.denoise_fn(x, timesteps)
x_start = predict_start_from_noise(diffusion, x, timesteps, noise)
x_start, noise
end
"""
p_sample(diffusion, x, timesteps, noise;
clip_denoised=true, add_noise=true)
The reverse process ``p(x_{t-1} | x_t, t)``. Denoise the data by one timestep.
"""
function p_sample(
diffusion::GaussianDiffusion, x::AbstractArray, timesteps::AbstractVector{Int}, noise::AbstractArray;
clip_denoised::Bool=true, add_noise::Bool=true
)
x_start, pred_noise = denoise(diffusion, x, timesteps)
if clip_denoised
clamp!(x_start, -1, 1)
end
posterior_mean, posterior_variance = q_posterior_mean_variance(diffusion, x_start, x, timesteps)
x_prev = posterior_mean
if add_noise
x_prev += sqrt.(posterior_variance) .* noise
end
x_prev, x_start
end
"""
p_sample_loop(diffusion, shape; clip_denoised=true, to_device=cpu)
p_sample_loop(diffusion, batch_size; options...)
Generate new samples and denoise it to the first time step.
See `p_sample_loop_all` for a version which returns values for all timesteps.
"""
function p_sample_loop(diffusion::GaussianDiffusion, shape::NTuple; clip_denoised::Bool=true, to_device=cpu)
T = eltype(eltype(diffusion))
x = randn(T, shape) |> to_device
@showprogress "Sampling..." for t in diffusion.num_timesteps:-1:1
timesteps = fill(t, shape[end]) |> to_device
noise = randn(T, size(x)) |> to_device
x, x_start = p_sample(diffusion, x, timesteps, noise; clip_denoised=clip_denoised, add_noise=(t != 1))
end
x
end
function p_sample_loop(diffusion::GaussianDiffusion, batch_size::Int; options...)
p_sample_loop(diffusion, (diffusion.data_shape..., batch_size); options...)
end
"""
p_sample_loop_all(diffusion, shape; clip_denoised=true, to_device=cpu)
p_sample_loop_all(diffusion, batch_size; options...)
Generate new samples and denoise them to the first time step. Return all samples where the last dimension is time.
See `p_sample_loop` for a version which returns only the final sample.
"""
function p_sample_loop_all(diffusion::GaussianDiffusion, shape::NTuple; clip_denoised::Bool=true, to_device=cpu)
T = eltype(eltype(diffusion))
x = randn(T, shape) |> to_device
x_all = Array{T}(undef, size(x)..., 0) |> to_device
x_start_all = Array{T}(undef, size(x)..., 0) |> to_device
tdim = ndims(x_all)
@showprogress "Sampling..." for t in diffusion.num_timesteps:-1:1
timesteps = fill(t, shape[end]) |> to_device
noise = randn(T, size(x)) |> to_device
x, x_start = p_sample(diffusion, x, timesteps, noise; clip_denoised=clip_denoised, add_noise=(t != 1))
x_all = cat(x_all, x, dims=tdim)
x_start_all = cat(x_start_all, x_start, dims=tdim)
end
x_all, x_start_all
end
function p_sample_loop_all(diffusion::GaussianDiffusion, batch_size::Int=16; options...)
p_sample_loop_all(diffusion, (diffusion.data_shape..., batch_size); options...)
end
"""
p_losses(diffusion, loss, x_start, timesteps, noise)
p_losses(diffusion, loss, x_start; to_device=cpu)
Sample from ``q(x_t | x_0)`` and return the loss for the predicted noise.
"""
function p_losses(diffusion::GaussianDiffusion, loss, x_start::AbstractArray, timesteps::AbstractVector{Int}, noise::AbstractArray)
x = q_sample(diffusion, x_start, timesteps, noise)
model_out = diffusion.denoise_fn(x, timesteps)
loss(model_out, noise)
end
function p_losses(diffusion::GaussianDiffusion, loss, x_start::AbstractArray{T,N}; to_device=cpu) where {T,N}
timesteps = rand(1:diffusion.num_timesteps, size(x_start, N)) |> to_device
noise = randn(eltype(eltype(diffusion)), size(x_start)) |> to_device
p_losses(diffusion, loss, x_start, timesteps, noise)
end