-
-
Notifications
You must be signed in to change notification settings - Fork 3
/
build.gradle
183 lines (154 loc) · 4.82 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
buildscript {
repositories {
mavenCentral()
}
dependencies {
classpath("com.guardsquare:proguard-gradle:${project.proguard_version}") {
exclude(group: "com.android.tools.build")
}
}
}
plugins {
id 'fabric-loom' version '1.4-SNAPSHOT'
id 'maven-publish'
id "com.matthewprenger.cursegradle" version '1.4.0'
id "com.modrinth.minotaur" version '2.3.1'
id 'com.github.johnrengelman.shadow' version '7.1.2'
}
version = project.mod_version
group = project.maven_group
def ENV = System.getenv()
def RELEASE_NAME = "${version}"
def RELEASE_FILE = "${buildDir}/tmp/${archivesBaseName}-${version}-shadowed.jar"
@SuppressWarnings('GrMethodMayBeStatic')
def getChangeLog() {
return ""
}
repositories {
maven { url "https://maven.shedaniel.me/" }
maven { url "https://jitpack.io" }
}
dependencies {
minecraft "com.mojang:minecraft:${project.minecraft_version}"
mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
}
processResources {
inputs.property "version", project.version
filteringCharset "UTF-8"
filesMatching("fabric.mod.json") {
expand "version": project.version
}
}
def targetJavaVersion = 17
tasks.withType(JavaCompile).configureEach {
it.options.encoding = "UTF-8"
if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
it.options.release = targetJavaVersion
}
}
java {
def javaVersion = JavaVersion.toVersion(targetJavaVersion)
if (JavaVersion.current() < javaVersion) {
toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
}
archivesBaseName = project.archives_base_name
withSourcesJar()
}
jar {
from("LICENSE") {
rename { "${it}_${project.archivesBaseName}" }
}
}
shadowJar {
archiveClassifier.set("shadowed")
configurations = [project.configurations.shadow]
}
//noinspection UnnecessaryQualifiedReference
task proguardJar(type: proguard.gradle.ProGuardTask, dependsOn: shadowJar) {
Map<String, String> MODULE_INFO_CLASS_FILTER = new HashMap<String, String>(1) {{ put("filter", "!module-info.class") }}
// NOTE: The "code/allocation/variable" optimisation (see: https://www.guardsquare.com/manual/configuration/optimizations) breaks remapJar.
configuration("proguard-rules.pro")
libraryjars(
new HashMap<String, String>(2) {{
putAll(MODULE_INFO_CLASS_FILTER)
put("jarfilter", "!**.jar")
}},
fileTree("${System.getenv("JAVA_HOME")}/jmods").matching { include("java.base.jmod") }.getSingleFile()
)
libraryjars(MODULE_INFO_CLASS_FILTER, project.configurations.runtimeClasspath )
File shadowedJar = shadowJar.archiveFile.get().asFile
injars(shadowedJar)
outjars("${buildDir}/tmp/${shadowedJar.getName()}")
}
remapJar {
dependsOn(proguardJar)
inputFile.set(proguardJar.outJarFileCollection.singleFile)
}
curseforge {
if (ENV.CURSEFORGE_API_KEY) {
apiKey = ENV.CURSEFORGE_API_KEY
}
project {
id = project.curseforge_id
changelog = getChangeLog()
releaseType = "release"
addGameVersion "1.20.3"
addGameVersion "Fabric"
mainArtifact(file(RELEASE_FILE)) {
displayName = RELEASE_NAME
relations {
requiredDependency 'fabric-api'
}
}
afterEvaluate {
uploadTask.dependsOn("remapJar")
}
}
options {
forgeGradleIntegration = false
}
}
//Modrinth publishing
modrinth {
if (ENV.MODRINTH_TOKEN) {
token = ENV.MODRINTH_TOKEN
}
projectId = project.modrinth_id
versionNumber = project.mod_version
uploadFile = remapJar
gameVersions = [project.minecraft_version]
loaders = ['fabric']
versionType = "release"
dependencies {
required.project("fabric-api")
}
}
// configure the maven publication
publishing {
publications {
mavenJava(MavenPublication) {
// add all the jars that should be included when publishing to maven
artifact(remapJar) {
builtBy remapJar
}
artifact(sourcesJar) {
builtBy remapSourcesJar
}
}
}
// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
repositories {
maven {
url "https://maven.cafeteria.dev/releases"
credentials {
username = System.getenv().mcdUsername
password = System.getenv().mcdPassword
}
authentication {
basic(BasicAuthentication)
}
}
}
}