forked from pharo-project/pharo
/
AthensDemoMorph.class.st
448 lines (366 loc) · 9.5 KB
/
AthensDemoMorph.class.st
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
"
Demos for Athens, just run:
AthensDemoMorph example
You can find an implementation of each figure in
corresponding #figure<#>: method
"
Class {
#name : #AthensDemoMorph,
#superclass : #Morph,
#instVars : [
'surface',
'current',
'frame',
'pharoLogo',
'esugBallon'
],
#category : #'Athens-Examples-Demos'
}
{ #category : #examples }
AthensDemoMorph class >> example [
| demo model window |
demo := self new openInWorld.
(model := DynamicComposablePresenter new)
instantiatePresenters: #(backButton ButtonPresenter forwardButton ButtonPresenter).
model backButton
label: 'Previous Figure';
action: [ demo prevFigure ].
model forwardButton
label: 'Next Figure';
action: [ demo nextFigure ].
window := model
openWithSpecLayout:
(SpecLayout composed
newColumn: [ :c |
c add: #backButton.
c add: #forwardButton ];
yourself).
window title: 'Athens demos' translated
]
{ #category : #utilities }
AthensDemoMorph class >> roundedRectanglePathOn: aCanvas [
^ aCanvas createPath: [:builder |
builder
absolute;
moveTo: 70@100;
lineTo: 330@100;
cwArcTo: 350@120 angle: 90 degreesToRadians;
lineTo: 350@280;
cwArcTo: 330@300 angle: 90 degreesToRadians;
lineTo: 70@300;
cwArcTo: 50@280 angle: 90 degreesToRadians;
lineTo: 50@120;
cwArcTo: 70@100 angle: 90 degreesToRadians ]
]
{ #category : #accessing }
AthensDemoMorph >> backColor [
^ Color white
]
{ #category : #accessing }
AthensDemoMorph >> carColor [
^ Color veryVeryLightGray
]
{ #category : #accessing }
AthensDemoMorph >> chasisDecoratorColor [
^ Color black
]
{ #category : #accessing }
AthensDemoMorph >> chasisLineColor [
^ Color white
]
{ #category : #accessing }
AthensDemoMorph >> coloredCarColor [
^ Color red
]
{ #category : #accessing }
AthensDemoMorph >> defaultExtent [
^ 400@400
]
{ #category : #drawing }
AthensDemoMorph >> drawBackgroundOn: aCanvas [
aCanvas
setPaint: Color veryLightGray;
drawShape: (0 @ 0 extent: 1 @ 1)
]
{ #category : #drawing }
AthensDemoMorph >> drawCarOn: aCanvas [
| p stroke wheel decorator |
"chasis"
p := aCanvas createPath: [:b |
b
moveTo: 0.3@0.3 ;
lineTo: 0.4@0;
curveVia: 0.1@0 to: 0.1@0.1;
lineTo: 0@0.2;
curveVia: 0@0.1 to: -0.1@0.1;
lineTo: -0.4@0;
curveVia: -0.1@0 to: (0.1@0.1) negated;
lineTo: 0@0.2 negated ;
curveVia: 0@0.1 negated to: 0.1@0.1 negated ].
aCanvas
setPaint: self coloredCarColor;
drawShape: p.
stroke := aCanvas setStrokePaint: self wheelColor.
stroke width: 0.01.
aCanvas draw.
"wheels"
wheel := aCanvas createPath:[:b|
b
moveTo: 0.3@0.3;
cwArcTo: 0.15@0 angle: Float halfPi ;
moveTo: 0.1@0;
cwArcTo: 0.15@0 angle: Float halfPi ;
moveTo: 0.0@0.4;
cwArcTo: 0.15 negated@0 angle: Float halfPi;
moveTo: -0.1@0;
cwArcTo: 0.15 negated@0 angle: Float halfPi ].
aCanvas
setPaint: self wheelColor;
drawShape: wheel.
"chasis decorator"
decorator := aCanvas createPath:[:b|
b
moveTo: 0.2@0.45;
lineTo: 0.225@0 ;
cwArcTo: 0.15@0 angle: Float halfPi ;
lineTo: 0.225@0;
lineTo: 0@0.1 ;
lineTo: -0.225@ 0;
cwArcTo: -0.15@0 angle: Float halfPi ;
lineTo: -0.225@ 0 ;
lineTo: 0@0.1 negated].
stroke := aCanvas setStrokePaint: self chasisDecoratorColor.
stroke width: 0.01.
aCanvas drawShape: decorator.
aCanvas setPaint: self chasisLineColor.
aCanvas draw
]
{ #category : #drawing }
AthensDemoMorph >> drawOn: aCanvas [
self render.
aCanvas
drawImage: surface asForm at: self bounds origin
]
{ #category : #figures }
AthensDemoMorph >> figure10: aCanvas [
| ellipsePath patternPaint rectangle |
ellipsePath := aCanvas createPath: [ :builder |
builder
moveTo: 0@200;
cwArcTo: 240@0 angle: Float pi;
cwArcTo: -240@0 angle: Float pi ].
aCanvas setPaint: Color black.
aCanvas drawShape: ellipsePath.
rectangle := 250@40 extent: 140@300.
aCanvas drawShape: rectangle.
aCanvas paintTransform loadIdentity.
aCanvas paintTransform scaleBy: ((frame/100) sin abs) * 5.
aCanvas paintTransform rotateByDegrees: (frame/100) sin * 360.
patternPaint := aCanvas setPaint: pharoLogo.
patternPaint setExtend: #Repeat.
aCanvas drawShape: ellipsePath.
aCanvas setPaint: patternPaint.
patternPaint setExtend: #Reflect.
aCanvas drawShape: rectangle
]
{ #category : #figures }
AthensDemoMorph >> figure1: aCanvas [
aCanvas
setPaint: self carColor;
drawShape: (50@100 extent: 300@200)
]
{ #category : #figures }
AthensDemoMorph >> figure2: aCanvas [
| path |
path := aCanvas createPath: [:builder |
builder
absolute;
moveTo: 70@100;
lineTo: 330@100;
cwArcTo: 350@120 angle: 90 degreesToRadians;
lineTo: 350@280;
cwArcTo: 330@300 angle: 90 degreesToRadians;
lineTo: 70@300;
cwArcTo: 50@280 angle: 90 degreesToRadians;
lineTo: 50@120;
cwArcTo: 70@100 angle: 90 degreesToRadians ].
aCanvas
setPaint: self carColor;
drawShape: path
]
{ #category : #figures }
AthensDemoMorph >> figure3: aCanvas [
| path |
path := aCanvas createPath: [:builder |
builder
relative;
moveTo: 0.3@0.3 ;
lineTo: 0.4@0;
curveVia: 0.1@0 to: 0.1@0.1;
lineTo: 0@0.2;
curveVia: 0@0.1 to: -0.1@0.1;
lineTo: -0.4@0;
curveVia: -0.1@0 to: (-0.1@ -0.1);
lineTo: 0@ -0.2 ;
curveVia: 0@ -0.1 to: 0.1@ -0.1 ].
aCanvas pathTransform scaleBy: self extent.
aCanvas
setPaint: self carColor;
drawShape: path
]
{ #category : #figures }
AthensDemoMorph >> figure4: aCanvas [
| path stroke |
path := self class roundedRectanglePathOn: aCanvas.
aCanvas setShape: path.
aCanvas setPaint: self carColor.
aCanvas draw.
stroke := aCanvas setStrokePaint: Color black.
stroke width: 3.
aCanvas draw
]
{ #category : #figures }
AthensDemoMorph >> figure5: aCanvas [
| wheels |
self figure4: aCanvas.
wheels := aCanvas createPath: [:builder |
builder
moveTo: 100@100;
cwArcTo: 60@0 angle: 90 degreesToRadians;
moveTo: 80@0;
cwArcTo: 60@0 angle: 90 degreesToRadians;
moveTo: 0.0@200;
cwArcTo: -60@0 angle: 90 degreesToRadians;
moveTo: -80@0;
cwArcTo: -60@0 angle: 90 degreesToRadians ].
aCanvas
setPaint: self wheelColor;
drawShape: wheels
]
{ #category : #figures }
AthensDemoMorph >> figure6: aCanvas [
| linearGradient |
self figure5: aCanvas.
linearGradient :=
aCanvas surface createLinearGradient: {
0 -> self coloredCarColor .
0.25 -> self coloredCarColor muchLighter.
0.5 -> Color white.
0.75 -> (self coloredCarColor muchLighter ).
1 -> (self coloredCarColor alpha: 0)
}
start: 0@100
stop: 0@300.
aCanvas setShape: (self class roundedRectanglePathOn: aCanvas).
aCanvas setPaint: linearGradient.
aCanvas draw
]
{ #category : #figures }
AthensDemoMorph >> figure7: aCanvas [
| pt |
self drawBackgroundOn: aCanvas.
pt := aCanvas pathTransform.
pt restoreAfter:[
pt scaleBy: self extent .
self drawCarOn: aCanvas.
pt scaleBy: 0.25@0.25.
self drawCarOn: aCanvas.
pt translateBy: 2@0; rotateByDegrees: 35.
self drawCarOn: aCanvas ]
]
{ #category : #figures }
AthensDemoMorph >> figure8: aCanvas [
| pt |
pt := aCanvas pathTransform.
pt restoreAfter:[
pt scaleBy: self extent.
self drawBackgroundOn: aCanvas.
pt scaleBy: (frame/100) sin abs.
self drawCarOn: aCanvas.
pt scaleBy: 0.25@0.2.5.
self drawCarOn: aCanvas.
pt translateBy: 2@0; rotateByDegrees: 35.
self drawCarOn: aCanvas ]
]
{ #category : #figures }
AthensDemoMorph >> figure9: aCanvas [
| ellipsePath patternPaint |
ellipsePath := aCanvas createPath: [ :builder |
builder
moveTo: 10@200;
cwArcTo: 360@0 angle: Float pi ;
lineTo: -100@180;
lineTo: -150@ -0;
lineTo: -110@ -180].
aCanvas setPaint: Color black.
aCanvas drawShape: ellipsePath.
aCanvas paintTransform loadIdentity.
aCanvas paintTransform scaleBy: ((frame/200) sin abs)*3.
patternPaint := aCanvas setPaint: esugBallon .
patternPaint setExtend: #None.
aCanvas draw
]
{ #category : #accessing }
AthensDemoMorph >> figures [
^ #(
figure1:
figure2:
figure3:
figure4:
figure5:
figure6:
figure7:
figure8:
figure9:
figure10:
)
]
{ #category : #initialization }
AthensDemoMorph >> initialize [
| ref loadFileFailBlock|
super initialize.
self extent: self defaultExtent.
self color: self backColor.
surface := AthensCairoSurface extent: self extent.
current := 1.
frame := 0.
loadFileFailBlock:= AthensCairoSurface fromForm:(Form fromDisplay: (0@0 extent:(300@150))).
ref := 'Pharo.png' asFileReference.
pharoLogo := AthensCairoSurface createFromFile: ref fullName ifFailed: [ loadFileFailBlock ].
ref := 'esug-balloon.png' asFileReference.
esugBallon := AthensCairoSurface createFromFile: ref fullName ifFailed: [ loadFileFailBlock ].
self startStepping
]
{ #category : #accessing }
AthensDemoMorph >> nextFigure [
current := current + 1.
current > self figures size ifTrue: [ current := 1 ].
]
{ #category : #accessing }
AthensDemoMorph >> prevFigure [
current := current - 1.
current < 1 ifTrue: [ current := self figures size ].
]
{ #category : #drawing }
AthensDemoMorph >> render [
surface drawDuring: [:canvas |
surface clear.
canvas pathTransform loadIdentity.
canvas setPaint: Color lightGray;
drawShape: (0@0 corner: self extent).
self perform: (self figures at: current) with: canvas
].
]
{ #category : #'stepping and presenter' }
AthensDemoMorph >> step [
frame := frame + 1.
self changed
]
{ #category : #'model - stepping' }
AthensDemoMorph >> stepTime [
^ 0
]
{ #category : #drawing }
AthensDemoMorph >> wheelColor [
^ Color brown darker
]