-
Notifications
You must be signed in to change notification settings - Fork 16
/
Windows.MSVC.toolchain.cmake
207 lines (176 loc) · 10 KB
/
Windows.MSVC.toolchain.cmake
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
#----------------------------------------------------------------------------------------------------------------------
# MIT License
#
# Copyright (c) 2021 Mark Schofield
#
# Permission is hereby granted, free of charge, to any person obtaining a copy
# of this software and associated documentation files (the "Software"), to deal
# in the Software without restriction, including without limitation the rights
# to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
# copies of the Software, and to permit persons to whom the Software is
# furnished to do so, subject to the following conditions:
#
# The above copyright notice and this permission notice shall be included in all
# copies or substantial portions of the Software.
#
# THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
# IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
# FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
# AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
# LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
# OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
# SOFTWARE.
#----------------------------------------------------------------------------------------------------------------------
#
# This CMake toolchain file configures a CMake, non-'Visual Studio Generator' build to use
# the MSVC compilers and tools.
#
# The following variables can be used to configure the behavior of this toolchain file:
#
# | CMake Variable | Description |
# |---------------------------------------------|--------------------------------------------------------------------------------------------------------------------------|
# | CMAKE_SYSTEM_VERSION | The version of the operating system for which CMake is to build. Defaults to the host version. |
# | CMAKE_SYSTEM_PROCESSOR | The processor to compiler for. One of 'x86', 'x64'/'AMD64', 'arm', 'arm64'. Defaults to ${CMAKE_HOST_SYSTEM_PROCESSOR}. |
# | CMAKE_VS_VERSION_RANGE | A verson range for VS instances to find. For example, '[16.0,17.0)' will find versions '16.*'. Defaults to '[16.0,17.0)' |
# | CMAKE_VS_VERSION_PRERELEASE | Whether 'prerelease' versions of Visual Studio should be considered. Defaults to 'OFF' |
# | CMAKE_VS_PRODUCTS | One or more Visual Studio Product IDs to consider. Defaults to '*' |
# | CMAKE_VS_PLATFORM_TOOLSET_VERSION | The version of the MSVC toolset to use. For example, 14.29.30133. Defaults to the highest available. |
# | CMAKE_VS_PLATFORM_TOOLSET_HOST_ARCHITECTURE | The architecture of the toolset to use. Defaults to 'x64'. |
# | CMAKE_WINDOWS_KITS_10_DIR | The location of the root of the Windows Kits 10 directory. |
# | VS_EXPERIMENTAL_MODULE | Whether experimental module support should be enabled.
# | VS_USE_SPECTRE_MITIGATION_RUNTIME | Whether the compiler should link with a runtime that uses 'Spectre' mitigations. Defaults to 'OFF'. |
#
# The toolchain file will set the following variables:
#
# | CMake Variable | Description |
# |---------------------------------------------|-------------------------------------------------------------------------------------------------------|
# | CMAKE_C_COMPILER | The path to the C compiler to use. |
# | CMAKE_CXX_COMPILER | The path to the C++ compiler to use. |
# | CMAKE_MT | The path to the 'mt.exe' tool to use. |
# | CMAKE_RC_COMPILER | The path tp the 'rc.exe' tool to use. |
# | CMAKE_SYSTEM_NAME | Windows |
# | WIN32 | 1 |
# | MSVC | 1 |
# | MSVC_VERSION | The '<major><minor>' version of the C++ compiler being used. For example, '1929' |
#
# Resources:
# <https://cmake.org/cmake/help/latest/manual/cmake-toolchains.7.html>
#
cmake_minimum_required(VERSION 3.20)
include_guard()
if(NOT (CMAKE_HOST_SYSTEM_NAME STREQUAL Windows))
return()
endif()
set(UNUSED ${CMAKE_TOOLCHAIN_FILE}) # Note: only to prevent cmake unused variable warninig
set(CMAKE_SYSTEM_NAME Windows)
set(CMAKE_TRY_COMPILE_PLATFORM_VARIABLES
CMAKE_SYSTEM_PROCESSOR
CMAKE_CROSSCOMPILING
CMAKE_VS_VERSION_PRERELEASE
CMAKE_VS_VERSION_RANGE
CMAKE_VS_PRODUCTS
CMAKE_VS_PLATFORM_TOOLSET_HOST_ARCHITECTURE
VS_INSTALLATION_VERSION
VS_INSTALLATION_PATH
)
set(CMAKE_CROSSCOMPILING TRUE)
set(WIN32 1)
set(MSVC 1)
include("${CMAKE_CURRENT_LIST_DIR}/VSWhere.cmake")
if(NOT CMAKE_SYSTEM_PROCESSOR)
set(CMAKE_SYSTEM_PROCESSOR ${CMAKE_HOST_SYSTEM_PROCESSOR})
endif()
if(NOT CMAKE_VS_VERSION_RANGE)
set(CMAKE_VS_VERSION_RANGE "[16.0,)")
endif()
if(NOT CMAKE_VS_VERSION_PRERELEASE)
set(CMAKE_VS_VERSION_PRERELEASE OFF)
endif()
if(NOT CMAKE_VS_PRODUCTS)
set(CMAKE_VS_PRODUCTS "*")
endif()
if(NOT CMAKE_VS_PLATFORM_TOOLSET_HOST_ARCHITECTURE)
set(CMAKE_VS_PLATFORM_TOOLSET_HOST_ARCHITECTURE x64)
endif()
if(NOT VS_USE_SPECTRE_MITIGATION_RUNTIME)
set(VS_USE_SPECTRE_MITIGATION_RUNTIME OFF)
endif()
# Find Visual Studio
#
findVisualStudio(
VERSION ${CMAKE_VS_VERSION_RANGE}
PRERELEASE ${CMAKE_VS_VERSION_PRERELEASE}
PRODUCTS ${CMAKE_VS_PRODUCTS}
PROPERTIES
installationVersion VS_INSTALLATION_VERSION
installationPath VS_INSTALLATION_PATH
)
message(VERBOSE "VS_INSTALLATION_VERSION = ${VS_INSTALLATION_VERSION}")
message(VERBOSE "VS_INSTALLATION_PATH = ${VS_INSTALLATION_PATH}")
if(NOT VS_INSTALLATION_PATH)
message(FATAL_ERROR "Unable to find Visual Studio")
endif()
cmake_path(NORMAL_PATH VS_INSTALLATION_PATH)
set(VS_MSVC_PATH "${VS_INSTALLATION_PATH}/VC/Tools/MSVC")
if(NOT VS_PLATFORM_TOOLSET_VERSION)
file(GLOB VS_TOOLSET_VERSIONS RELATIVE ${VS_MSVC_PATH} ${VS_MSVC_PATH}/*)
list(SORT VS_TOOLSET_VERSIONS COMPARE NATURAL ORDER DESCENDING)
list(POP_FRONT VS_TOOLSET_VERSIONS VS_TOOLSET_VERSION)
endif()
set(VS_TOOLSET_PATH "${VS_INSTALLATION_PATH}/VC/Tools/MSVC/${VS_TOOLSET_VERSION}")
# Set the tooling variables, include_directories and link_directories
#
function(getMsvcVersion COMPILER MSVC_VERSION_OUTPUT)
execute_process(
COMMAND "${COMPILER}" -Bv
ERROR_VARIABLE COMPILER_OUTPUT
OUTPUT_QUIET
)
if(COMPILER_OUTPUT MATCHES "cl.exe.*(([0-9]+)\\.([0-9]+)\\.([0-9]+)(\\.([0-9]+))?)")
set(COMPILER_VERSION ${CMAKE_MATCH_1})
set(COMPILER_VERSION_MAJOR ${CMAKE_MATCH_2})
set(COMPILER_VERSION_MINOR ${CMAKE_MATCH_3})
endif()
set(${MSVC_VERSION_OUTPUT} "${COMPILER_VERSION_MAJOR}${COMPILER_VERSION_MINOR}" PARENT_SCOPE)
endfunction()
# Map CMAKE_SYSTEM_PROCESSOR values to CMAKE_VS_PLATFORM_TOOLSET_ARCHITECTURE that identifies the tools that should
# be used to produce code for the CMAKE_SYSTEM_PROCESSOR.
if((CMAKE_SYSTEM_PROCESSOR STREQUAL AMD64) OR (CMAKE_SYSTEM_PROCESSOR STREQUAL x64))
set(CMAKE_VS_PLATFORM_TOOLSET_ARCHITECTURE x64)
elseif((CMAKE_SYSTEM_PROCESSOR STREQUAL arm)
OR (CMAKE_SYSTEM_PROCESSOR STREQUAL arm64)
OR (CMAKE_SYSTEM_PROCESSOR STREQUAL x86))
set(CMAKE_VS_PLATFORM_TOOLSET_ARCHITECTURE ${CMAKE_SYSTEM_PROCESSOR})
else()
message(FATAL_ERROR "Unable identify compiler architecture for CMAKE_SYSTEM_PROCESSOR ${CMAKE_SYSTEM_PROCESSOR}")
endif()
set(CMAKE_CXX_COMPILER "${VS_TOOLSET_PATH}/bin/Host${CMAKE_VS_PLATFORM_TOOLSET_HOST_ARCHITECTURE}/${CMAKE_VS_PLATFORM_TOOLSET_ARCHITECTURE}/cl.exe")
set(CMAKE_C_COMPILER "${VS_TOOLSET_PATH}/bin/Host${CMAKE_VS_PLATFORM_TOOLSET_HOST_ARCHITECTURE}/${CMAKE_VS_PLATFORM_TOOLSET_ARCHITECTURE}/cl.exe")
if(CMAKE_SYSTEM_PROCESSOR STREQUAL arm)
set(CMAKE_CXX_FLAGS_INIT "${CMAKE_CXX_FLAGS_INIT} /EHsc")
endif()
getMsvcVersion(${CMAKE_CXX_COMPILER} MSVC_VERSION)
if(NOT MSVC_VERSION)
message(FATAL_ERROR "Unable to obtain the compiler version from: ${CMAKE_CXX_COMPILER}")
endif()
# Compiler
foreach(LANG C CXX RC)
list(APPEND CMAKE_${LANG}_STANDARD_INCLUDE_DIRECTORIES "${VS_TOOLSET_PATH}/ATLMFC/include")
list(APPEND CMAKE_${LANG}_STANDARD_INCLUDE_DIRECTORIES "${VS_TOOLSET_PATH}/include")
endforeach()
if(VS_USE_SPECTRE_MITIGATION_RUNTIME)
set(TOOLCHAIN_SPECTRE_TOKEN "/spectre")
else()
set(TOOLCHAIN_SPECTRE_TOKEN)
endif()
link_directories("${VS_TOOLSET_PATH}/ATLMFC/lib${TOOLCHAIN_SPECTRE_TOKEN}/${CMAKE_VS_PLATFORM_TOOLSET_ARCHITECTURE}")
link_directories("${VS_TOOLSET_PATH}/lib${TOOLCHAIN_SPECTRE_TOKEN}/${CMAKE_VS_PLATFORM_TOOLSET_ARCHITECTURE}")
link_directories("${VS_TOOLSET_PATH}/lib/x86/store/references")
# Module support
if(VS_EXPERIMENTAL_MODULE)
set(CMAKE_CXX_FLAGS_INIT "${CMAKE_CXX_FLAGS_INIT} /experimental:module")
set(CMAKE_CXX_FLAGS_INIT "${CMAKE_CXX_FLAGS_INIT} /stdIfcDir \"${VS_TOOLSET_PATH}/ifc/${CMAKE_VS_PLATFORM_TOOLSET_ARCHITECTURE}\"")
endif()
# Windows Kits
include("${CMAKE_CURRENT_LIST_DIR}/Windows.Kits.cmake")
set(TOOLCHAIN_SPECTRE_TOKEN)