-
Notifications
You must be signed in to change notification settings - Fork 64
/
Delphinus.SetupDialog.pas
440 lines (403 loc) · 12.6 KB
/
Delphinus.SetupDialog.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
{
#########################################################
# Copyright by Alexander Benikowski #
# This unit is part of the Delphinus project hosted on #
# https://github.com/Memnarch/Delphinus #
#########################################################
}
unit Delphinus.SetupDialog;
interface
uses
Windows, Messages, SysUtils, Variants, Classes, Graphics,
Controls, Forms, Dialogs,
DN.PackageProvider.Intf,
DN.Package.Intf,
DN.Package.Version.Intf,
DN.Package.DirectoryLoader.Intf,
DN.Setup.Dependency.Resolver.Intf,
DN.Setup.Dependency.Intf,
DN.Setup.Dependency.Processor.Intf,
DN.Installer.Intf,
DN.Uninstaller.Intf,
StdCtrls,
DN.Types,
DN.Setup.Intf,
Delphinus.Forms,
ComCtrls,
ExtCtrls,
DN.ComCtrls.Helper,
ImgList
{$IFDEF CONDITIONALEXPRESSIONS}
{$IF CompilerVersion >= 29.0}
, System.ImageList
{$IFEND}
{$ENDIF};
const
CStart = WM_USER + 1;
type
TSetupDialogMode = (sdmInstall, sdmInstallDirectory, sdmUninstall, sdmUninstallDirectory, sdmUpdate);
TSetupDialog = class(TForm)
mLog: TMemo;
pcSteps: TPageControl;
tsMainPage: TTabSheet;
tsLog: TTabSheet;
btnOK: TButton;
btnCancel: TButton;
Image1: TImage;
lbNameInstallUpdate: TLabel;
cbVersion: TComboBox;
Label1: TLabel;
lbLicenseAnotation: TLabel;
Label3: TLabel;
lbLicenseType: TLabel;
btnLicense: TButton;
tsProgress: TTabSheet;
pbProgress: TProgressBar;
btnCloseProgress: TButton;
lbAction: TLabel;
btnShowLog: TButton;
ilButtons: TImageList;
btnDependencies: TButton;
cbIgnoreDependencies: TCheckBox;
procedure HandleOK(Sender: TObject);
procedure FormShow(Sender: TObject);
procedure btnLicenseClick(Sender: TObject);
procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
procedure btnShowLogClick(Sender: TObject);
procedure cbVersionChange(Sender: TObject);
procedure btnDependenciesClick(Sender: TObject);
private
{ Private declarations }
FMode: TSetupDialogMode;
FPackage: IDNPackage;
FInstalledComponentDirectory: string;
FDirectoryToInstall: string;
FSetup: IDNSetup;
FSetupIsRunning: Boolean;
FLoader: IDNPackageDirectoryLoader;
FDependencyResolver: IDNSetupDependencyResolver;
FDependencies: TArray<IDNSetupDependency>;
FDependencyCount: Integer;
FDependencyProcessor: IDNSetupDependencyProcessor;
procedure Log(const AMessage: string);
procedure HandleLogMessage(AType: TMessageType; const AMessage: string);
procedure HandleProgress(const ATask, AItem: string; AProgress, AMax: Int64);
procedure HandleDependencyProgress(const ATask, AItem: string; AProgress, AMax: Int64);
procedure InitMainPage();
procedure InitVersionSelection();
procedure Execute();
procedure SetupFinished;
function GetSelectedVersion: IDNPackageVersion;
function LoadPackage(const ADirectory: string): IDNPackage;
procedure ResolvelDependencies;
public
{ Public declarations }
constructor Create(const ASetup: IDNSetup;
const ADependencyResolver: IDNSetupDependencyResolver;
const ADependencyProcessor: IDNSetupDependencyProcessor); reintroduce;
function ExecuteInstallation(const APackage: IDNPackage): Boolean;
function ExecuteInstallationFromDirectory(const ADirectory: string): Boolean;
function ExecuteUninstallation(const APackage: IDNPackage): Boolean;
function ExecuteUninstallationFromDirectory(const ADirectory: string): Boolean;
function ExecuteUpdate(const APackage: IDNPackage): Boolean;
end;
var
SetupDialog: TSetupDialog;
implementation
uses
IOUtils,
StrUtils,
DN.JSonFile.InstalledInfo,
Delphinus.LicenseDialog,
Delphinus.Resources.Names,
Delphinus.Resources,
DN.Package.DirectoryLoader,
DN.Package,
Delphinus.DependencyDialog;
{$R *.dfm}
{ TSetupDialog }
procedure TSetupDialog.btnDependenciesClick(Sender: TObject);
var
LDialog: TDependencyDialog;
begin
LDialog := TDependencyDialog.Create(nil);
try
LDialog.Dependencies := FDependencies;
LDialog.ShowModal();
finally
LDialog.Free();
end;
end;
procedure TSetupDialog.btnLicenseClick(Sender: TObject);
var
LDialog: TLicenseDialog;
begin
LDialog := TLicenseDialog.Create(nil);
try
LDialog.Package := FPackage;
LDialog.ShowModal();
finally
LDialog.Free;
end;
end;
procedure TSetupDialog.btnShowLogClick(Sender: TObject);
begin
pcSteps.ActivePage := tsLog;
end;
procedure TSetupDialog.cbVersionChange(Sender: TObject);
begin
if cbVersion.ItemIndex > -1 then
begin
ResolvelDependencies();
end
else
begin
btnDependencies.Enabled := False;
end;
end;
constructor TSetupDialog.Create(const ASetup: IDNSetup;
const ADependencyResolver: IDNSetupDependencyResolver;
const ADependencyProcessor: IDNSetupDependencyProcessor);
begin
inherited Create(nil);
FDependencyResolver := ADependencyResolver;
FDependencyProcessor := ADependencyProcessor;
FDependencyProcessor.OnMessage := HandleLogMessage;
FDependencyProcessor.OnProgress := HandleDependencyProgress;
FSetup := ASetup;
FSetup.OnMessage := HandleLogMessage;
FSetup.OnProgress := HandleProgress;
btnLicense.ImageIndex := AddIconToImageList(ilButtons, Ico_Agreement);
btnLicense.DisabledImageIndex := AddIconToImageList(ilButtons, Ico_Agreement_Disabled);
btnDependencies.ImageIndex := AddIconToImageList(ilButtons, Ico_Dependencies);
btnDependencies.DisabledImageIndex := AddIconToImageList(ilButtons, Ico_Dependencies_Disabled);
end;
procedure TSetupDialog.Execute;
var
LThread: TThread;
LError: string;
begin
FSetupIsRunning := True;
mLog.Clear;
pbProgress.Position := 0;
pbProgress.State := pbsNormal;
pcSteps.ActivePage := tsProgress;
LThread := TThread.CreateAnonymousThread(
procedure
begin
try
if cbIgnoreDependencies.Checked or FDependencyProcessor.Execute(FDependencies) then
begin
case FMode of
sdmInstall: FSetup.Install(FPackage, GetSelectedVersion());
sdmInstallDirectory: FSetup.InstallDirectory(FDirectoryToInstall);
sdmUninstall: FSetup.Uninstall(FPackage);
sdmUninstallDirectory: FSetup.UninstallDirectory(FInstalledComponentDirectory);
sdmUpdate: FSetup.Update(FPackage, GetSelectedVersion());
end;
end;
except
on E: Exception do
LError := E.ToString;
end;
if LError <> '' then
TThread.Synchronize(nil, procedure begin HandleLogMessage(mtError, LError) end);
TThread.Synchronize(nil, SetupFinished);
end);
LThread.Start;
end;
function TSetupDialog.ExecuteInstallation(const APackage: IDNPackage): Boolean;
begin
FPackage := APackage;
FMode := sdmInstall;
Result := ShowModal() <> mrCancel;
end;
function TSetupDialog.ExecuteInstallationFromDirectory(
const ADirectory: string): Boolean;
begin
FDirectoryToInstall := ADirectory;
FMode := sdmInstallDirectory;
FPackage := LoadPackage(ADirectory);
Result := ShowModal() <> mrCancel;
end;
function TSetupDialog.ExecuteUninstallation(const APackage: IDNPackage): Boolean;
begin
FPackage := APackage;
FMode := sdmUninstall;
Result := ShowModal() <> mrCancel;;
end;
function TSetupDialog.ExecuteUninstallationFromDirectory(
const ADirectory: string): Boolean;
begin
FInstalledComponentDirectory := ADirectory;
FMode := sdmUninstallDirectory;
FPackage := LoadPackage(ADirectory);
Result := ShowModal() <> mrCancel;
end;
function TSetupDialog.ExecuteUpdate(const APackage: IDNPackage): Boolean;
begin
FPackage := APackage;
FMode := sdmUpdate;
Result := ShowModal() <> mrCancel;
end;
procedure TSetupDialog.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
CanClose := not FSetupIsRunning;
if not CanClose then
MessageDlg('You can not close the dialog while the setup is running, please wait', mtInformation, [mbOK], 0)
else if (ModalResult = mrCancel) and (pcSteps.ActivePageIndex > 0) then
ModalResult := mrOk;
end;
procedure TSetupDialog.FormShow(Sender: TObject);
begin
InitMainPage();
end;
function TSetupDialog.GetSelectedVersion: IDNPackageVersion;
begin
if Assigned(FPackage) and (cbVersion.ItemIndex > -1) then
Result := FPackage.Versions[cbVersion.ItemIndex]
else
Result := nil;
end;
procedure TSetupDialog.HandleDependencyProgress(const ATask, AItem: string;
AProgress, AMax: Int64);
begin
TThread.Queue(nil,
procedure
begin
lbAction.Caption := ATask + ' ' + AItem;
pbProgress.Position := Round(AProgress / AMax * pbProgress.Max / (FDependencyCount + 1) * FDependencyCount);
end
);
end;
procedure TSetupDialog.HandleLogMessage(AType: TMessageType;
const AMessage: string);
begin
TThread.Synchronize(nil,
procedure
begin
case AType of
mtNotification: Log(AMessage);
mtWarning: Log('Warning: ' + AMessage);
mtError:
begin
Log('Error: ' + AMessage);
pbProgress.State := pbsError;
end;
end;
end
);
end;
procedure TSetupDialog.HandleOK(Sender: TObject);
begin
Execute();
end;
procedure TSetupDialog.HandleProgress(const ATask, AItem: string; AProgress, AMax: Int64);
begin
TThread.Queue(nil,
procedure
var
LBase: Single;
LScale: Single;
LElements: Integer;
begin
lbAction.Caption := IfThen(AItem <> '', AItem, ATask);
LElements := FDependencyCount + 1;
if LElements > 1 then
begin
LBase := pbProgress.Max / LElements * FDependencyCount;
end
else
begin
LBase := 0;
end;
LScale := 1 / LElements;
pbProgress.Position := Round(LBase + (AProgress / AMax * pbProgress.Max * LScale));
end
);
end;
procedure TSetupDialog.InitMainPage;
begin
pcSteps.ActivePage := tsMainPage;
if not Assigned(FPackage) then
Exit;
case FMode of
sdmInstall, sdmInstallDirectory:
begin
btnOK.Caption := 'Install';
lbNameInstallUpdate.Caption := FPackage.Name;
lbLicenseType.Caption := FPackage.LicenseTypes;
btnLicense.Enabled := lbLicenseType.Caption <> '';
if Assigned(FPackage.Picture) then
Image1.Picture.Assign(FPackage.Picture);
InitVersionSelection();
end;
sdmUninstall, sdmUninstallDirectory:
begin
btnOK.Caption := 'Uninstall';
lbNameInstallUpdate.Caption := FPackage.Name;
lbLicenseType.Caption := FPackage.LicenseTypes;
if Assigned(FPackage.Picture) then
Image1.Picture.Assign(FPackage.Picture);
cbVersion.Enabled := False;
btnLicense.Enabled := False;
lbLicenseAnotation.Visible := False;
ResolvelDependencies();
end;
sdmUpdate:
begin
btnOK.Caption := 'Update';
lbNameInstallUpdate.Caption := FPackage.Name;
if Assigned(FPackage.Picture) then
Image1.Picture.Assign(FPackage.Picture);
InitVersionSelection();
end;
end;
end;
procedure TSetupDialog.InitVersionSelection;
var
i: Integer;
begin
cbVersion.Enabled := (FPackage.Versions.Count > 0) and (not FPackage.Versions.First.Value.IsEmpty);
for i := 0 to FPackage.Versions.Count - 1 do
begin
cbVersion.Items.Add(FPackage.Versions[i].Name);
end;
cbVersion.ItemIndex := 0;
cbVersionChange(cbVersion);
end;
function TSetupDialog.LoadPackage(const ADirectory: string): IDNPackage;
begin
if not Assigned(FLoader) then
FLoader := TDNPackageDirectoryLoader.Create();
Result := TDNPackage.Create();
FLoader.Load(ADirectory, Result);
end;
procedure TSetupDialog.Log(const AMessage: string);
begin
mLog.Lines.Add(AMessage);
end;
procedure TSetupDialog.ResolvelDependencies;
var
LDependency: IDNSetupDependency;
begin
FDependencyCount := 0;
if cbVersion.ItemIndex > -1 then
FDependencies := FDependencyResolver.Resolve(FPackage, FPackage.Versions[cbVersion.ItemIndex])
else
FDependencies := FDependencyResolver.Resolve(FPackage, FPackage.Versions.First);
for LDependency in FDependencies do
if LDependency.Action <> daNone then
Inc(FDependencyCount);
btnDependencies.Enabled := Length(FDependencies) > 0;
cbIgnoreDependencies.Enabled := btnDependencies.Enabled;
end;
procedure TSetupDialog.SetupFinished;
begin
btnCloseProgress.Enabled := True;
btnShowLog.Enabled := True;
FSetupIsRunning := False;
if FSetup.HasPendingChanges then
MessageDlg('Some changes require an IDE restart to take effect', mtInformation, [mbOK], 0);
end;
end.