forked from coil-kt/coil
-
Notifications
You must be signed in to change notification settings - Fork 0
/
build.gradle.kts
217 lines (195 loc) · 7.3 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
import coil3.enableComposeMetrics
import coil3.groupId
import coil3.publicModules
import coil3.versionName
import com.diffplug.gradle.spotless.SpotlessExtension
import com.diffplug.gradle.spotless.SpotlessExtensionPredeclare
import dev.drewhamilton.poko.gradle.PokoPluginExtension
import kotlinx.validation.ApiValidationExtension
import org.jetbrains.compose.ComposeExtension
import org.jetbrains.compose.experimental.dsl.ExperimentalExtension
import org.jetbrains.dokka.gradle.DokkaMultiModuleTask
import org.jetbrains.dokka.gradle.DokkaTaskPartial
import org.jetbrains.kotlin.gradle.dsl.JvmTarget
import org.jetbrains.kotlin.gradle.dsl.KotlinMultiplatformExtension
import org.jetbrains.kotlin.gradle.plugin.KotlinPlatformType
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
import org.jetbrains.kotlin.gradle.tasks.KotlinJvmCompile
buildscript {
repositories {
google()
mavenCentral()
}
dependencies {
classpath(libs.gradlePlugin.android)
classpath(libs.gradlePlugin.atomicFu)
classpath(libs.gradlePlugin.jetbrainsCompose)
classpath(libs.gradlePlugin.kotlin)
classpath(libs.gradlePlugin.mavenPublish)
classpath(libs.gradlePlugin.paparazzi)
classpath(libs.gradlePlugin.roborazzi)
}
}
plugins {
alias(libs.plugins.baselineProfile) apply false
alias(libs.plugins.binaryCompatibility)
alias(libs.plugins.dokka)
alias(libs.plugins.poko) apply false
alias(libs.plugins.spotless)
}
extensions.configure<ApiValidationExtension> {
ignoredProjects += project.subprojects.mapNotNull { project ->
if (project.name in publicModules) null else project.name
}
}
tasks.withType<DokkaMultiModuleTask>().configureEach {
outputDirectory = layout.projectDirectory.dir("docs/api")
}
allprojects {
repositories {
google()
mavenCentral()
}
// Necessary to publish to Maven.
group = groupId
version = versionName
// Target JVM 8.
tasks.withType<JavaCompile>().configureEach {
sourceCompatibility = JavaVersion.VERSION_1_8.toString()
targetCompatibility = JavaVersion.VERSION_1_8.toString()
options.compilerArgs = options.compilerArgs + "-Xlint:-options"
}
tasks.withType<KotlinJvmCompile>().configureEach {
compilerOptions.jvmTarget = JvmTarget.JVM_1_8
}
tasks.withType<DokkaTaskPartial>().configureEach {
dokkaSourceSets.configureEach {
jdkVersion = 8
failOnWarning = true
skipDeprecated = true
suppressInheritedMembers = true
externalDocumentationLink(
url = "https://developer.android.com/reference/",
)
externalDocumentationLink(
url = "https://kotlinlang.org/api/kotlinx.coroutines/",
)
externalDocumentationLink(
url = "https://square.github.io/okio/3.x/okio/",
packageListUrl = "https://square.github.io/okio/3.x/okio/okio/package-list",
)
externalDocumentationLink(
url = "https://jetbrains.github.io/skiko/",
packageListUrl = "https://jetbrains.github.io/skiko/skiko/package-list",
)
externalDocumentationLink(
url = "https://api.ktor.io/",
)
}
}
dependencies {
modules {
module("org.jetbrains.kotlin:kotlin-stdlib-jdk7") {
replacedBy("org.jetbrains.kotlin:kotlin-stdlib")
}
module("org.jetbrains.kotlin:kotlin-stdlib-jdk8") {
replacedBy("org.jetbrains.kotlin:kotlin-stdlib")
}
}
}
// Uninstall test APKs after running instrumentation tests.
tasks.configureEach {
if (name == "connectedDebugAndroidTest") {
finalizedBy("uninstallDebugAndroidTest")
}
}
apply(plugin = "com.diffplug.spotless")
val configureSpotless: SpotlessExtension.() -> Unit = {
kotlin {
target("**/*.kt", "**/*.kts")
ktlint(libs.versions.ktlint.get())
endWithNewline()
indentWithSpaces()
trimTrailingWhitespace()
}
}
if (project === rootProject) {
spotless { predeclareDeps() }
extensions.configure<SpotlessExtensionPredeclare>(configureSpotless)
} else {
extensions.configure(configureSpotless)
}
plugins.withId("org.jetbrains.compose") {
extensions.configure<ComposeExtension> {
kotlinCompilerPlugin = libs.jetbrains.compose.compiler.get().toString()
extensions.configure<ExperimentalExtension> {
web.application {}
}
}
}
plugins.withId("dev.drewhamilton.poko") {
extensions.configure<PokoPluginExtension> {
pokoAnnotation = "coil3.annotation.Data"
}
}
if (enableComposeMetrics && name in publicModules) {
plugins.withId("org.jetbrains.compose") {
tasks.withType<KotlinCompile> {
val outputDir = layout.buildDirectory.dir("composeMetrics").get().asFile.path
compilerOptions.freeCompilerArgs.addAll(
"-P", "$composePlugin:metricsDestination=$outputDir",
"-P", "$composePlugin:reportsDestination=$outputDir",
)
}
}
}
plugins.withId("org.jetbrains.compose") {
tasks.withType<KotlinCompile> {
val outputDir = rootDir.resolve("coil-core/compose_compiler_config.conf").path
compilerOptions.freeCompilerArgs.addAll(
"-P", "$composePlugin:stabilityConfigurationPath=$outputDir",
)
}
}
applyOkioJsTestWorkaround()
}
// https://github.com/square/okio/issues/1163
fun Project.applyOkioJsTestWorkaround() {
plugins.withId("org.jetbrains.kotlin.multiplatform") {
val applyNodePolyfillPlugin by lazy {
tasks.register("applyNodePolyfillPlugin") {
val applyPluginFile = projectDir
.resolve("webpack.config.d/applyNodePolyfillPlugin.js")
onlyIf {
!applyPluginFile.exists()
}
doLast {
applyPluginFile.parentFile.mkdirs()
applyPluginFile.writeText(
"""
const NodePolyfillPlugin = require("node-polyfill-webpack-plugin");
config.plugins.push(new NodePolyfillPlugin());
""".trimIndent(),
)
}
}
}
extensions.configure<KotlinMultiplatformExtension> {
sourceSets {
targets.configureEach {
compilations.configureEach {
if (platformType == KotlinPlatformType.js && name == "test") {
tasks
.getByName(compileKotlinTaskName)
.dependsOn(applyNodePolyfillPlugin)
dependencies {
implementation(devNpm("node-polyfill-webpack-plugin", "^2.0.1"))
}
}
}
}
}
}
}
}
private val composePlugin = "plugin:androidx.compose.compiler.plugins.kotlin"