forked from gradle/gradle
/
build.gradle.kts
57 lines (49 loc) · 1.55 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
plugins {
`java-library`
}
repositories {
mavenCentral()
}
// tag::test_dependency[]
dependencies {
testImplementation("junit:junit:4.13")
testImplementation(project(":producer"))
}
// end::test_dependency[]
// tag::ask-for-instrumented-classes[]
configurations {
testRuntimeClasspath {
attributes {
attribute(LibraryElements.LIBRARY_ELEMENTS_ATTRIBUTE, objects.named(LibraryElements::class.java, "instrumented-jar"))
}
}
}
// end::ask-for-instrumented-classes[]
// tag::compatibility-rule-use[]
dependencies {
attributesSchema {
attribute(LibraryElements.LIBRARY_ELEMENTS_ATTRIBUTE) {
compatibilityRules.add(InstrumentedJarsRule::class.java)
}
}
}
// end::compatibility-rule-use[]
// tag::compatibility-rule[]
abstract class InstrumentedJarsRule: AttributeCompatibilityRule<LibraryElements> {
override fun execute(details: CompatibilityCheckDetails<LibraryElements>) = details.run {
if (consumerValue?.name == "instrumented-jar" && producerValue?.name == "jar") {
compatible()
}
}
}
// end::compatibility-rule[]
tasks.register("showTestClasspath") {
val testCompileClasspath: FileCollection = configurations.testCompileClasspath.get()
val testRuntimeClasspath: FileCollection = configurations.testRuntimeClasspath.get()
inputs.files(testCompileClasspath)
inputs.files(testRuntimeClasspath)
doLast {
println(testCompileClasspath.files.map(File::getName))
println(testRuntimeClasspath.files.map(File::getName))
}
}