build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven { url 'https://plugins.gradle.org/m2/' }
    }
    dependencies {
        // force a more recent spring since some nebula plugins were bringing an older version
        // before springboot plugins had any saying
        classpath "org.springframework:spring-core:5.2.8.RELEASE"
    }
}

plugins {
    id 'nebula.netflixoss' version '9.1.0'
    id 'nebula.ospackage' version '8.5.6'
    id "com.google.osdetector" version "1.7.0"
}

ext.useMavenLocal = project.hasProperty('useMavenLocal') ? project.getProperty('useMavenLocal').toBoolean() : false
ext.integrationTestScope = project.hasProperty('integrationTestScope') ? project.getProperty('integrationTestScope') : ""

allprojects {
    apply plugin: 'nebula.dependency-lock'
    apply plugin: 'idea'

    if (useMavenLocal) {
        repositories {
            mavenLocal()
        }
    }

    repositories {
        mavenCentral()
        maven { url 'https://artifactory-oss.prod.netflix.net/artifactory/maven-oss-candidates' }
    }
}

subprojects {
    buildscript {
        repositories {
            mavenCentral()
            maven { url 'https://plugins.gradle.org/m2/' }
        }
        dependencies {
            classpath "org.springframework:spring-core:5.2.8.RELEASE"
        }
    }

    group "com.netflix.titus"

    apply plugin: 'java'
    apply plugin: 'jacoco'
    apply plugin: 'nebula.netflixoss'

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    ext {
        titusApiDefinitionsVersion = '0.0.3-rc.18'

        springVersion = '5.2.11.RELEASE'
        springSecurityVersion = '5.3.6.RELEASE'
        springBootVersion = '2.3.6.RELEASE'
        springCloudVersion = '2.2.6.RELEASE'
        springReactor = '3.4.2'
        springReactorAdapter = '3.3.3.RELEASE'
        springReactorNetty = '1.0.3'

        awsSdkVersion = '1.11.+'
        javaxElVersion = '3.+'
        javaxInjectVersion = '1'
        guavaVersion = '25.1-jre'
        servletVersion = '3.1.0'
        rxJava = '1.+'
        hdrhistogramVersion = '2.1.+'
        hsqldbVersion = '2.4.+'
        apacheCommonsCliVersion = '1.3.+'
        archaius2Version = '2.3.+'
        eurekaVersion = '1.+'
        numerusVersion = '1.1'
        snappyVersion = '1.1.+'
        jacksonVersion = '2.10.+'
        slf4jVersion = '1.7.0'
        cliParserVersion = '1.1.1'
        curatorVersion = '2.13.+'
        governatorVersion = '1.15.+'
        jettyVersion = '9.2.12.v20150709'
        jerseyVersion = '1.19.+'
        jooqVersion = '3.11.+'
        spectatorVersion = '0.59.+'
        postgresqlVersion = '42.2.9'
        protobufVersion = '3.7.+'
        protobufVersionOSAware = protobufVersion
        grpcVersion = '1.39.+'
        grpcVersionOSAware = grpcVersion
        if (osdetector.os == "osx") {
            protobufVersionOSAware += ':osx-x86_64'
            grpcVersionOSAware += ':osx-x86_64'
        }
        protobufJavaUtilVersion = '3.5.+'
        googleTruthVersion = '0.34' // pinned to avoid a transitive dependency on guava > 20.x
        swaggerVersion = '1.5.12'
        jsonVersion = '20140107'
        guiceVersion = '4.1.+'
        hibernateValidatorVersion = '6.2.+'
        runtimeHealthVersion = '1.1.+'
        configMagicVersion = '0.11'
        swaggerUiVersion = '2.1.4'
        okHttpVersion = '3.+'
        cassandraDriverVersion = '3.3.+'
        commonsCliVersion = '1.3.+'
        caffeineVersion = '2.6.+'
        rxJavaInteropVersion = '0.13.+'
        kubernetesClientVersion = '12.0.+' // Major release in support of Kubernetes 1.20.x
        fabric8ioKubeClient = '5.8.+' // Check compatibility at: https://github.com/fabric8io/kubernetes-client#kubernetes-compatibility-matrix
        commonsMath3Version = '3.6.1'
        friggaVersion = '0.+'
        pcollectionsVersion = '3.1.4'

        // Test
        junitVersion = '4.+'
        mockitoVersion = '3.3.3'
        hamcrestVersion = '1.3'
        awaitilityVersion = '1.7.0'
        assertjVersion = '3.8.0'
        cassandraUnitVersion = '3.1.1.0'
        mockServerVersion = '3.10.4'
        javaslangVersion = '2.0.6'
        jnaVersion = '5.9+'
    }

    tasks.withType(JavaCompile) {
        options.compilerArgs << '-parameters'
    }

    tasks.withType(Javadoc).all {
        enabled = false
    }

    // There is some clean up in our transitive dependencies that we need to do here.
    configurations.all {
        exclude group: 'netflix', module: 'SRWrapper'
        exclude group: 'org.apache.ant', module: 'ant'
        exclude group: 'org.apache.cxf', module: 'cxf'
        exclude group: 'javax.servlet', module: 'servlet-api'
        exclude group: 'org.mortbay.jetty', module: 'servlet-api'
        // Superceded by governator-api
        exclude group: 'com.netflix.governator', module: 'governator-annotations'

        resolutionStrategy {
            force "com.google.guava:guava:${guavaVersion}"
        }

        // We need to exclude logback as it clashes with other logging engines.
        exclude group: 'ch.qos.logback', module: 'logback-classic'
        exclude group: 'ch.qos.logback', module: 'logback-core'

        // Conflicts by SpringBoot
        exclude group: 'com.vaadin.external.google', module: 'android-json'

        // Provided by jakarta.validation:jakarta.validation-api
        exclude group: 'javax.validation', module: 'validation-api'
    }

    dependencies {
        compile "org.slf4j:slf4j-api:${slf4jVersion}"
        runtime "org.slf4j:slf4j-log4j12:${slf4jVersion}"

        testCompile "junit:junit-dep:${junitVersion}"
        testCompile "org.mockito:mockito-core:${mockitoVersion}"
        testCompile "org.hamcrest:hamcrest-core:${hamcrestVersion}"
        testCompile "com.jayway.awaitility:awaitility:${awaitilityVersion}"
        testCompile "io.projectreactor:reactor-test:${springReactor}"
        testCompile "org.assertj:assertj-core:${assertjVersion}"
        testCompile "net.java.dev.jna:jna:${jnaVersion}"
    }

    def processorTarget = Runtime.runtime.availableProcessors().intdiv(2) ?: 1

    test {
        maxParallelForks = processorTarget

        useJUnit {
            excludeCategories 'com.netflix.titus.testkit.junit.category.IntegrationTest', 'com.netflix.titus.testkit.junit.category.IntegrationNotParallelizableTest',
                    'com.netflix.titus.testkit.junit.category.RemoteIntegrationTest'
        }

        reports {
            junitXml.enabled = true
            html.enabled = true
        }

        testLogging {
            events "failed"
            exceptionFormat "full"
            showExceptions true
            showStackTraces true
            showCauses true
        }
    }

    task integrationTest(type: Test) {
        maxParallelForks = processorTarget
        shouldRunAfter test

        if ("excludeMaster".equalsIgnoreCase(integrationTestScope)) {
            exclude 'com/netflix/titus/master/integration/**/*'
        } else if ("onlyMaster1".equalsIgnoreCase(integrationTestScope)) {
            include 'com/netflix/titus/master/integration/**/*'
            exclude 'com/netflix/titus/master/integration/v3/job/basic/**/*', 'com/netflix/titus/master/integration/v3/job/other/**/*'
        } else if ("onlyMaster2".equalsIgnoreCase(integrationTestScope)) {
            include 'com/netflix/titus/master/integration/v3/job/basic/**/*'
        } else if ("onlyMaster3".equalsIgnoreCase(integrationTestScope)) {
            include 'com/netflix/titus/master/integration/v3/job/other/**/*'
        }

        useJUnit {
            includeCategories 'com.netflix.titus.testkit.junit.category.IntegrationTest'
        }

        reports {
            junitXml.enabled = true
            html.enabled = true
        }

        testLogging {
            events "failed"
            exceptionFormat "full"
            showExceptions true
            showStackTraces true
            showCauses true
        }
    }

    task integrationNotParallelizableTest(type: Test) {
        maxParallelForks = 1
        shouldRunAfter test

        useJUnit {
            includeCategories 'com.netflix.titus.testkit.junit.category.IntegrationNotParallelizableTest'
        }

        reports {
            junitXml.enabled = true
            html.enabled = true
        }

        testLogging {
            events "failed"
            exceptionFormat "full"
            showExceptions true
            showStackTraces true
            showCauses true
        }
    }

    task remoteIntegrationTest(type: Test) {
        maxParallelForks = processorTarget
        shouldRunAfter test

        useJUnit {
            includeCategories 'com.netflix.titus.testkit.junit.category.RemoteIntegrationTest'
        }

        reports {
            junitXml.enabled = true
            html.enabled = true
        }

        testLogging {
            events "failed"
            exceptionFormat "full"
            showExceptions true
            showStackTraces true
            showCauses true
        }
    }

    task testAll {
        dependsOn 'test'
        dependsOn 'integrationTest'
        dependsOn 'integrationNotParallelizableTest'
    }

    task buildScriptDependencies(type: org.gradle.api.tasks.diagnostics.DependencyReportTask) {
        configurations = project.buildscript.configurations
    }

    task dependenciesForAll(type: DependencyReportTask) {}
}



dependencyLock {
    includeTransitives = true
}