forked from ocaml/opam
/
opamMisc.ml
288 lines (233 loc) · 6.74 KB
/
opamMisc.ml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
(***********************************************************************)
(* *)
(* Copyright 2012 OCamlPro *)
(* Copyright 2012 INRIA *)
(* *)
(* All rights reserved. This file is distributed under the terms of *)
(* the GNU Public License version 3.0. *)
(* *)
(* OPAM is distributed in the hope that it will be useful, *)
(* but WITHOUT ANY WARRANTY; without even the implied warranty of *)
(* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the *)
(* GNU General Public License for more details. *)
(* *)
(***********************************************************************)
module type SET = sig
include Set.S
val map: (elt -> elt) -> t -> t
val choose_one : t -> elt
val of_list: elt list -> t
val to_string: t -> string
val find: (elt -> bool) -> t -> elt
end
module type MAP = sig
include Map.S
val to_string: ('a -> string) -> 'a t -> string
val values: 'a t -> 'a list
val keys: 'a t -> key list
val union: ('a -> 'a -> 'a) -> 'a t -> 'a t -> 'a t
val of_list: (key * 'a) list -> 'a t
end
module type ABSTRACT = sig
type t
val of_string: string -> t
val to_string: t -> string
module Set: SET with type elt = t
module Map: MAP with type key = t
end
module type OrderedType = sig
include Set.OrderedType
val to_string: t -> string
end
let string_of_list f = function
| [] -> "{}"
| l -> Printf.sprintf "{ %s }" (String.concat ", " (List.map f l))
module Set = struct
module Make (O : OrderedType) = struct
module S = Set.Make(O)
include S
let choose_one s =
match elements s with
| [x] -> x
| [] -> raise Not_found
| _ -> invalid_arg "choose_one"
let of_list l =
List.fold_left (fun set e -> add e set) empty l
let to_string s =
let l = fold (fun nv l -> O.to_string nv :: l) s [] in
string_of_list (fun x -> x) l
let map f t =
of_list (List.map f (elements t))
let find fn s =
choose (filter fn s)
end
end
module Map = struct
module Make (O : OrderedType) = struct
module M = Map.Make(O)
include M
let values map = List.map snd (bindings map)
let keys map = List.map fst (bindings map)
let union f m1 m2 =
M.fold (fun k v m ->
if M.mem k m then
M.add k (f v (M.find k m)) (M.remove k m)
else
M.add k v m
) m1 m2
let to_string string_of_value m =
let s (k,v) = Printf.sprintf "%s:%s" (O.to_string k) (string_of_value v) in
let l = fold (fun k v l -> s (k,v)::l) m [] in
string_of_list (fun x -> x) l
let of_list l =
List.fold_left (fun map (k,v) -> add k v map) empty l
end
end
module Base = struct
type t = string
let of_string x = x
let to_string x = x
module O = struct
type t = string
let to_string = to_string
let compare = compare
end
module Set = Set.Make(O)
module Map = Map.Make(O)
end
let filter_map f l =
let rec loop accu = function
| [] -> List.rev accu
| h :: t ->
match f h with
| None -> loop accu t
| Some x -> loop (x::accu) t in
loop [] l
module OInt = struct
type t = int
let compare = compare
let to_string = string_of_int
end
module IntMap = Map.Make(OInt)
module IntSet = Set.Make(OInt)
module OString = struct
type t = string
let compare = compare
let to_string x = x
end
module StringSet = Set.Make(OString)
module StringMap = Map.Make(OString)
module OP = struct
let (|>) f g x = g (f x)
let finally f clean =
let safe_clean () =
try clean ()
with _ -> () in
let result =
try f ()
with e ->
safe_clean ();
raise e in
safe_clean ();
result
end
let strip str =
let p = ref 0 in
let l = String.length str in
let fn = function
| ' ' | '\t' | '\r' | '\n' -> true
| _ -> false in
while !p < l && fn (String.unsafe_get str !p) do
incr p;
done;
let p = !p in
let l = ref (l - 1) in
while !l >= p && fn (String.unsafe_get str !l) do
decr l;
done;
String.sub str p (!l - p + 1)
let starts_with ~prefix s =
String.length s >= String.length prefix
&& String.sub s 0 (String.length prefix) = prefix
let ends_with ~suffix s =
String.length s >= String.length suffix
&& String.sub s (String.length s - String.length suffix) (String.length suffix) = suffix
let remove_prefix ~prefix s =
if starts_with ~prefix s then
Some (String.sub s (String.length prefix) (String.length s - String.length prefix))
else
None
let cut_at_aux fn s sep =
try
let i = fn s sep in
let name = String.sub s 0 i in
let version = String.sub s (i+1) (String.length s - i - 1) in
Some (name, version)
with _ ->
None
let cut_at = cut_at_aux String.index
let rcut_at = cut_at_aux String.rindex
let contains s c =
try let _ = String.index s c in true
with Not_found -> false
let split s c =
Pcre.split ~rex:(Re_perl.compile (Re.char c)) s
(* Remove from a ':' separated list of string the one with the given prefix *)
let reset_env_value ~prefix v =
let v = split v ':' in
List.filter (fun v -> not (starts_with ~prefix v)) v
(* if rsync -arv return 4 lines, this means that no files have changed *)
let rsync_trim = function
| [] -> []
| _ :: t ->
match List.rev t with
| _ :: _ :: _ :: l -> List.filter ((<>) "./") l
| _ -> []
let exact_match re s =
try
let subs = Re.exec re s in
let subs = Array.to_list (Re.get_all_ofs subs) in
let n = String.length s in
let subs = List.filter (fun (s,e) -> s=0 && e=n) subs in
List.length subs > 0
with Not_found ->
false
(* XXX: not optimized *)
let insert comp x l =
let rec aux = function
| [] -> [x]
| h::t when comp h x < 0 -> h::aux t
| l -> x :: l in
aux l
let env = lazy (
let e = Unix.environment () in
List.map (fun s ->
match cut_at s '=' with
| None -> s, ""
| Some p -> p
) (Array.to_list e)
)
let getenv n =
List.assoc n (Lazy.force env)
let env () = Lazy.force env
let indent_left s nb =
let nb = nb - String.length s in
if nb <= 0 then
s
else
s ^ String.make nb ' '
let indent_right s nb =
let nb = nb - String.length s in
if nb <= 0 then
s
else
String.make nb ' ' ^ s
let sub_at n s =
if String.length s <= n then
s
else
String.sub s 0 n
let git_of_string a =
match cut_at a '#' with
| None -> a, None
| Some (a,c) -> a, Some c