-
Notifications
You must be signed in to change notification settings - Fork 62
/
trees.f90
1387 lines (1214 loc) · 48.8 KB
/
trees.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
!> \file
!> \author Chris Bradley
!> \brief Implements trees of base types.
!>
!> \section LICENSE
!>
!> Version: MPL 1.1/GPL 2.0/LGPL 2.1
!>
!> The contents of this file are subject to the Mozilla Public License
!> Version 1.1 (the "License"); you may not use this file except in
!> compliance with the License. You may obtain a copy of the License at
!> http://www.mozilla.org/MPL/
!>
!> Software distributed under the License is distributed on an "AS IS"
!> basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See the
!> License for the specific language governing rights and limitations
!> under the License.
!>
!> The Original Code is OpenCMISS
!>
!> The Initial Developer of the Original Code is University of Auckland,
!> Auckland, New Zealand, the University of Oxford, Oxford, United
!> Kingdom and King's College, London, United Kingdom. Portions created
!> by the University of Auckland, the University of Oxford and King's
!> College, London are Copyright (C) 2007-2010 by the University of
!> Auckland, the University of Oxford and King's College, London.
!> All Rights Reserved.
!>
!> Contributor(s):
!>
!> Alternatively, the contents of this file may be used under the terms of
!> either the GNU General Public License Version 2 or later (the "GPL"), or
!> the GNU Lesser General Public License Version 2.1 or later (the "LGPL"),
!> in which case the provisions of the GPL or the LGPL are applicable instead
!> of those above. If you wish to allow use of your version of this file only
!> under the terms of either the GPL or the LGPL, and not to allow others to
!> use your version of this file under the terms of the MPL, indicate your
!> decision by deleting the provisions above and replace them with the notice
!> and other provisions required by the GPL or the LGPL. If you do not delete
!> the provisions above, a recipient may use your version of this file under
!> the terms of any one of the MPL, the GPL or the LGPL.
!>
!> Implements trees of base types.
MODULE TREES
USE BaseRoutines
USE INPUT_OUTPUT
USE ISO_VARYING_STRING
USE KINDS
USE STRINGS
#include "macros.h"
IMPLICIT NONE
PRIVATE
!Module parameters
!> \addtogroup TREES_TreeNodeColourTypes TREES::TreeNodeColourTypes
!> \brief The colour of the tree nodes
!> \see TREES
!>@{
INTEGER(INTG), PARAMETER :: TREE_BLACK_NODE=0 !<The black colour type for a tree node \see TREES_TreeNodeColourTypes,TREES
INTEGER(INTG), PARAMETER :: TREE_RED_NODE=1 !<The red colour type for a tree node \see TREES_TreeNodeColourTypes,TREES
!>@}
!> \addtogroup TREES_TreeNodeInsertStatus TREES::TreeNodeInsertStatus
!> \brief The insert status for tree nodes
!> \see TREES
!>@{
INTEGER(INTG), PARAMETER :: TREE_NODE_INSERT_SUCESSFUL=1 !<Successful insert status \see TREES_TreeNodeInsertStatus,TREES
INTEGER(INTG), PARAMETER :: TREE_NODE_DUPLICATE_KEY=2 !<Duplicate key found for those trees that do not allow duplicate keys \see TREES_TreeNodeInsertStatus,TREES
!>@}
!> \addtogroup TREES_TreeInsertTypes TREES::TreeInsertTypes
!> \brief The insert type for a tree
!> \see TREES
!>@{
INTEGER(INTG), PARAMETER :: TREE_DUPLICATES_ALLOWED_TYPE=1 !<Duplicate keys allowed tree type \see TREES_TreeInsertTypes,TREES
INTEGER(INTG), PARAMETER :: TREE_NO_DUPLICATES_ALLOWED=2 !<No duplicate keys allowed tree type \see TREES_TreeInsertTypes,TREES
!>@}
!Module types
TYPE TREE_NODE_TYPE
PRIVATE
INTEGER(INTG) :: KEY !<The key for the tree node
INTEGER(INTG) :: VALUE !<The value stored at the tree node
INTEGER(INTG) :: COLOUR !<The colour of the node for the red-black tree
TYPE(TREE_NODE_TYPE), POINTER :: LEFT !<The pointer to the left daughter tree node if any
TYPE(TREE_NODE_TYPE), POINTER :: RIGHT !<The pointer to the right daughter tree node if any
TYPE(TREE_NODE_TYPE), POINTER :: PARENT !<The pointer to the parent tree node
END TYPE TREE_NODE_TYPE
TYPE TREE_TYPE
PRIVATE
LOGICAL :: TREE_FINISHED !<Is .TRUE. if the tree has finished being created, .FALSE. if not.
INTEGER(INTG) :: INSERT_TYPE !<The insert type for duplicate keys for the tree
INTEGER(INTG) :: NUMBER_IN_TREE !<The number of items currently in the tree
TYPE(TREE_NODE_TYPE), POINTER :: ROOT !<The pointer to the root of the tree
TYPE(TREE_NODE_TYPE), POINTER :: NIL !<The pointer to the nil of the tree
END TYPE TREE_TYPE
!Module variables
!Interfaces
INTERFACE Tree_CreateFinish
MODULE PROCEDURE TREE_CREATE_FINISH
END INTERFACE Tree_CreateFinish
INTERFACE Tree_CreateStart
MODULE PROCEDURE TREE_CREATE_START
END INTERFACE Tree_CreateStart
INTERFACE Tree_DetachAndDestroy
MODULE PROCEDURE TREE_DETACH_AND_DESTROY
END INTERFACE Tree_DetachAndDestroy
INTERFACE Tree_InsertTypeSet
MODULE PROCEDURE TREE_INSERT_TYPE_SET
END INTERFACE Tree_InsertTypeSet
INTERFACE Tree_ItemDelete
MODULE PROCEDURE TREE_ITEM_DELETE
END INTERFACE Tree_ItemDelete
INTERFACE Tree_ItemInsert
MODULE PROCEDURE TREE_ITEM_INSERT
END INTERFACE Tree_ItemInsert
INTERFACE Tree_NodeKeyGet
MODULE PROCEDURE TREE_NODE_KEY_GET
END INTERFACE Tree_NodeKeyGet
INTERFACE Tree_NodeValueGet
MODULE PROCEDURE TREE_NODE_VALUE_GET
END INTERFACE Tree_NodeValueGet
INTERFACE Tree_NodeValueSet
MODULE PROCEDURE TREE_NODE_VALUE_SET
END INTERFACE Tree_NodeValueSet
PUBLIC TREE_TYPE,TREE_NODE_TYPE
PUBLIC TREE_NODE_INSERT_SUCESSFUL,TREE_NODE_DUPLICATE_KEY
PUBLIC TREE_DUPLICATES_ALLOWED_TYPE,TREE_NO_DUPLICATES_ALLOWED
PUBLIC TREE_CREATE_FINISH,TREE_CREATE_START
PUBLIC Tree_CreateFinish,Tree_CreateStart
PUBLIC Tree_Destroy
PUBLIC TREE_DETACH_AND_DESTROY
PUBLIC Tree_Detach,Tree_DetachAndDestroy
PUBLIC TREE_INSERT_TYPE_SET
PUBLIC Tree_InsertTypeSet
PUBLIC TREE_ITEM_DELETE,TREE_ITEM_INSERT
PUBLIC Tree_ItemDelete,Tree_ItemInsert
PUBLIC TREE_NODE_KEY_GET
PUBLIC Tree_NodeKeyGet
PUBLIC TREE_NODE_VALUE_GET,TREE_NODE_VALUE_SET
PUBLIC Tree_NodeValueGet,Tree_NodeValueSet
PUBLIC Tree_Output
PUBLIC Tree_Search
CONTAINS
!
!================================================================================================================================
!
!>Finishes the creation of a tree created with TREE_CREATE_START \see{TREES::TREE_CREATE_START}.
SUBROUTINE TREE_CREATE_FINISH(TREE,ERR,ERROR,*)
!Argument Variables
TYPE(TREE_TYPE), POINTER :: TREE !<A pointer to the tree to finish
INTEGER(INTG), INTENT(OUT) :: ERR !<The error code
TYPE(VARYING_STRING), INTENT(OUT) :: ERROR !<The error string.
!Local Variables
ENTERS("TREE_CREATE_FINISH",ERR,ERROR,*998)
IF(ASSOCIATED(TREE)) THEN
IF(TREE%TREE_FINISHED) THEN
CALL FlagError("Tree is already finished",ERR,ERROR,*998)
ELSE
!Allocate the nil tree node
ALLOCATE(TREE%NIL,STAT=ERR)
IF(ERR/=0) CALL FlagError("Could not allocate NIL tree node",ERR,ERROR,*999)
CALL TREE_NODE_INITIALISE(TREE,TREE%NIL,ERR,ERROR,*999)
TREE%NIL%KEY=-99999999 !Set it to something identifiable for debugging
TREE%NIL%LEFT=>TREE%NIL
TREE%NIL%RIGHT=>TREE%NIL
TREE%NIL%PARENT=>TREE%NIL
!Set the root tree node to NIL
TREE%ROOT=>TREE%NIL
!Finish the tree creation
TREE%TREE_FINISHED=.TRUE.
ENDIF
ELSE
CALL FlagError("Tree is not associated",ERR,ERROR,*998)
ENDIF
EXITS("TREE_CREATE_FINISH")
RETURN
999 CALL TREE_FINALISE(TREE,ERR,ERROR,*998)
998 ERRORSEXITS("TREE_CREATE_FINISH",ERR,ERROR)
RETURN 1
END SUBROUTINE TREE_CREATE_FINISH
!
!================================================================================================================================
!
!>Starts the creation of a tree and returns a pointer to the created tree \see{TREES::TREE_CREATE_FINISH}.
SUBROUTINE TREE_CREATE_START(TREE,ERR,ERROR,*)
!Argument Variables
TYPE(TREE_TYPE), POINTER :: TREE !<A pointer to the tree to create. Must not be associated on entry.
INTEGER(INTG), INTENT(OUT) :: ERR !<The error code.
TYPE(VARYING_STRING), INTENT(OUT) :: ERROR !<The error string.
!Local Variable
ENTERS("TREE_CREATE_START",ERR,ERROR,*998)
IF(ASSOCIATED(TREE)) THEN
CALL FlagError("Tree is already associated",ERR,ERROR,*998)
ELSE
ALLOCATE(TREE,STAT=ERR)
IF(ERR/=0) CALL FlagError("Could not allocate tree",ERR,ERROR,*999)
CALL TREE_INITIALISE(TREE,ERR,ERROR,*999)
!Set Defaults
TREE%INSERT_TYPE=TREE_DUPLICATES_ALLOWED_TYPE
ENDIF
EXITS("TREE_CREATE_START")
RETURN
999 CALL TREE_FINALISE(TREE,ERR,ERROR,*998)
998 ERRORSEXITS("TREE_CREATE_START",ERR,ERROR)
RETURN 1
END SUBROUTINE TREE_CREATE_START
!
!================================================================================================================================
!
!>Destroys a tree
SUBROUTINE TREE_DESTROY(TREE,ERR,ERROR,*)
!Argument Variables
TYPE(TREE_TYPE), POINTER :: TREE !<A pointer to the tree to destroy
INTEGER(INTG), INTENT(OUT) :: ERR !<The error code
TYPE(VARYING_STRING), INTENT(OUT) :: ERROR !<The error string.
!Local Variables
ENTERS("TREE_DESTROY",ERR,ERROR,*999)
IF(ASSOCIATED(TREE)) THEN
CALL TREE_FINALISE(TREE,ERR,ERROR,*999)
ELSE
CALL FlagError("Tree is not associated",ERR,ERROR,*999)
ENDIF
EXITS("TREE_DESTROY")
RETURN
999 ERRORSEXITS("TREE_DESTROY",ERR,ERROR)
RETURN 1
END SUBROUTINE TREE_DESTROY
!
!================================================================================================================================
!
!>Detaches the tree values and returns them as a pointer to the an array
SUBROUTINE TREE_DETACH(TREE,NUMBER_IN_TREE,TREE_VALUES,ERR,ERROR,*)
!Argument Variables
TYPE(TREE_TYPE), POINTER :: TREE !<A pointer to the tree to detach
INTEGER(INTG), INTENT(OUT) :: NUMBER_IN_TREE !<On exit, the number in the array that has been detached
INTEGER(INTG), POINTER :: TREE_VALUES(:) !<On exit, a pointer to the dettached tree values. Must not be associated on entry.
INTEGER(INTG), INTENT(OUT) :: ERR !<The error code
TYPE(VARYING_STRING), INTENT(OUT) :: ERROR !<The error string.
!Local Variables
ENTERS("TREE_DETACH",ERR,ERROR,*998)
IF(ASSOCIATED(TREE)) THEN
IF(TREE%TREE_FINISHED) THEN
IF(ASSOCIATED(TREE_VALUES)) THEN
CALL FlagError("Tree values is already associated.",ERR,ERROR,*998)
ELSE
NULLIFY(TREE_VALUES)
ALLOCATE(TREE_VALUES(TREE%NUMBER_IN_TREE),STAT=ERR)
IF(ERR/=0) CALL FlagError("Could not allocate tree values.",ERR,ERROR,*999)
NUMBER_IN_TREE=0
CALL TREE_DETACH_IN_ORDER(TREE,TREE%ROOT,NUMBER_IN_TREE,TREE_VALUES,ERR,ERROR,*999)
ENDIF
ELSE
CALL FlagError("Tree has not been finished.",ERR,ERROR,*999)
ENDIF
ELSE
CALL FlagError("Tree is not associated.",ERR,ERROR,*998)
ENDIF
EXITS("TREE_DETACH")
RETURN
999 IF(ASSOCIATED(TREE_VALUES)) DEALLOCATE(TREE_VALUES)
NUMBER_IN_TREE=0
998 ERRORSEXITS("TREE_DETACH",ERR,ERROR)
RETURN 1
END SUBROUTINE TREE_DETACH
!
!================================================================================================================================
!
!>Detaches the tree values and returns them as a pointer to the an array and then destroys the tree
SUBROUTINE TREE_DETACH_AND_DESTROY(TREE,NUMBER_IN_TREE,TREE_VALUES,ERR,ERROR,*)
!Argument Variables
TYPE(TREE_TYPE), POINTER :: TREE !<A pointer to the tree to detach and destroy
INTEGER(INTG), INTENT(OUT) :: NUMBER_IN_TREE !<On exit, the number in the array that has been detached
INTEGER(INTG), POINTER :: TREE_VALUES(:) !<On exit, a pointer to the dettached tree values. Must not be associated on entry.
INTEGER(INTG), INTENT(OUT) :: ERR !<The error code
TYPE(VARYING_STRING), INTENT(OUT) :: ERROR !<The error string.
!Local Variables
ENTERS("TREE_DETACH_AND_DESTROY",ERR,ERROR,*998)
IF(ASSOCIATED(TREE)) THEN
IF(TREE%TREE_FINISHED) THEN
IF(ASSOCIATED(TREE_VALUES)) THEN
CALL FlagError("Tree values is associated",ERR,ERROR,*998)
ELSE
NULLIFY(TREE_VALUES)
ALLOCATE(TREE_VALUES(TREE%NUMBER_IN_TREE),STAT=ERR)
IF(ERR/=0) CALL FlagError("Could not allocate tree values",ERR,ERROR,*999)
NUMBER_IN_TREE=0
CALL TREE_DETACH_IN_ORDER(TREE,TREE%ROOT,NUMBER_IN_TREE,TREE_VALUES,ERR,ERROR,*999)
CALL TREE_FINALISE(TREE,ERR,ERROR,*999)
ENDIF
ELSE
CALL FlagError("Tree has not been finished",ERR,ERROR,*999)
ENDIF
ELSE
CALL FlagError("Tree is not associated",ERR,ERROR,*998)
ENDIF
EXITS("TREE_DETACH_AND_DESTROY")
RETURN
999 IF(ASSOCIATED(TREE_VALUES)) DEALLOCATE(TREE_VALUES)
NUMBER_IN_TREE=0
998 ERRORSEXITS("TREE_DETACH_AND_DESTROY",ERR,ERROR)
RETURN 1
END SUBROUTINE TREE_DETACH_AND_DESTROY
!
!================================================================================================================================
!
!>Detaches the tree values in order from the specified tree node and adds them to the tree values array
RECURSIVE SUBROUTINE TREE_DETACH_IN_ORDER(TREE,X,COUNT,TREE_VALUES,ERR,ERROR,*)
!Argument Variables
TYPE(TREE_TYPE), POINTER :: TREE !<A pointer to the tree to detach
TYPE(TREE_NODE_TYPE), POINTER :: X !<A pointer to the specified tree node to detach from
INTEGER(INTG), INTENT(INOUT) :: COUNT !<The current number in the detached tree values array
INTEGER(INTG), INTENT(INOUT) :: TREE_VALUES(:) !<The current detached tree values array
INTEGER(INTG), INTENT(OUT) :: ERR !<The error code
TYPE(VARYING_STRING), INTENT(OUT) :: ERROR !<The error string.
!Local Variables
TYPE(VARYING_STRING) :: LOCAL_ERROR
ENTERS("TREE_DETACH_IN_ORDER",ERR,ERROR,*999)
IF(ASSOCIATED(TREE)) THEN
IF(.NOT.ASSOCIATED(X,TREE%NIL)) THEN
CALL TREE_DETACH_IN_ORDER(TREE,X%LEFT,COUNT,TREE_VALUES,ERR,ERROR,*999)
COUNT=COUNT+1
IF(COUNT<=SIZE(TREE_VALUES,1)) THEN
TREE_VALUES(COUNT)=X%VALUE
ELSE
LOCAL_ERROR="The current count of the tree values ("//TRIM(NUMBER_TO_VSTRING(COUNT,"*",ERR,ERROR))// &
& ") is greater than the size of the tree values array ("// &
& TRIM(NUMBER_TO_VSTRING(SIZE(TREE_VALUES,1),"*",ERR,ERROR))//")"
CALL FlagError(LOCAL_ERROR,ERR,ERROR,*999)
ENDIF
CALL TREE_DETACH_IN_ORDER(TREE,X%RIGHT,COUNT,TREE_VALUES,ERR,ERROR,*999)
ENDIF
ELSE
CALL FlagError("Tree is not associated",ERR,ERROR,*999)
ENDIF
EXITS("TREE_DETACH_IN_ORDER")
RETURN
999 ERRORSEXITS("TREE_DETACH_IN_ORDER",ERR,ERROR)
RETURN 1
END SUBROUTINE TREE_DETACH_IN_ORDER
!
!================================================================================================================================
!
!>Finalises a tree and deallocates all memory
SUBROUTINE TREE_FINALISE(TREE,ERR,ERROR,*)
!Argument Variables
TYPE(TREE_TYPE), POINTER :: TREE !<A pointer to the tree to finalise
INTEGER(INTG), INTENT(OUT) :: ERR !<The error code
TYPE(VARYING_STRING), INTENT(OUT) :: ERROR !<The error string.
!Local Variables
ENTERS("TREE_FINALISE",ERR,ERROR,*999)
IF(ASSOCIATED(TREE)) THEN
CALL TREE_NODE_FINALISE(TREE,TREE%ROOT,ERR,ERROR,*999)
IF(ASSOCIATED(TREE%NIL)) DEALLOCATE(TREE%NIL)
DEALLOCATE(TREE)
ENDIF
EXITS("TREE_FINALISE")
RETURN
999 ERRORSEXITS("TREE_FINALISE",ERR,ERROR)
RETURN 1
END SUBROUTINE TREE_FINALISE
!
!================================================================================================================================
!
!>Initialises a tree
SUBROUTINE TREE_INITIALISE(TREE,ERR,ERROR,*)
!Argument Variables
TYPE(TREE_TYPE), POINTER :: TREE !<A pointer to the tree to initialise
INTEGER(INTG), INTENT(OUT) :: ERR !<The error code
TYPE(VARYING_STRING), INTENT(OUT) :: ERROR !<The error string.
!Local Variables
ENTERS("TREE_INITIALISE",ERR,ERROR,*999)
IF(ASSOCIATED(TREE)) THEN
TREE%TREE_FINISHED=.FALSE.
TREE%INSERT_TYPE=0
TREE%NUMBER_IN_TREE=0
NULLIFY(TREE%ROOT)
NULLIFY(TREE%NIL)
ELSE
CALL FlagError("Tree is not associated",ERR,ERROR,*999)
ENDIF
EXITS("TREE_INITIALISE")
RETURN
999 ERRORSEXITS("TREE_INITIALISE",ERR,ERROR)
RETURN 1
END SUBROUTINE TREE_INITIALISE
!
!================================================================================================================================
!
!>Sets/changes the insert type for a tree
SUBROUTINE TREE_INSERT_TYPE_SET(TREE,INSERT_TYPE,ERR,ERROR,*)
!Argument Variables
TYPE(TREE_TYPE), POINTER :: TREE !<A pointer to the tree
INTEGER(INTG), INTENT(IN) :: INSERT_TYPE !<The insert type to set \see TREES_TreeInsertTypes,TREES::TreeInsertTypes
INTEGER(INTG), INTENT(OUT) :: ERR !<The error code
TYPE(VARYING_STRING), INTENT(OUT) :: ERROR !<The error string.
!Local Variables
TYPE(VARYING_STRING) :: LOCAL_ERROR
ENTERS("TREE_INSERT_TYPE_SET",ERR,ERROR,*999)
IF(ASSOCIATED(TREE)) THEN
IF(TREE%TREE_FINISHED) THEN
CALL FlagError("Tree has been finished",ERR,ERROR,*999)
ELSE
SELECT CASE(INSERT_TYPE)
CASE(TREE_DUPLICATES_ALLOWED_TYPE)
TREE%INSERT_TYPE=TREE_DUPLICATES_ALLOWED_TYPE
CASE(TREE_NO_DUPLICATES_ALLOWED)
TREE%INSERT_TYPE=TREE_NO_DUPLICATES_ALLOWED
CASE DEFAULT
LOCAL_ERROR="The insert type of "//TRIM(NUMBER_TO_VSTRING(INSERT_TYPE,"*",ERR,ERROR))//" is invalid"
CALL FlagError(LOCAL_ERROR,ERR,ERROR,*999)
END SELECT
ENDIF
ELSE
CALL FlagError("Tree is not associated",ERR,ERROR,*999)
ENDIF
EXITS("TREE_INSERT_TYPE_SET")
RETURN
999 ERRORSEXITS("TREE_INSERT_TYPE_SET",ERR,ERROR)
RETURN 1
END SUBROUTINE TREE_INSERT_TYPE_SET
!
!================================================================================================================================
!
!>Deletes a tree node specified by a key from a tree
SUBROUTINE TREE_ITEM_DELETE(TREE,KEY,ERR,ERROR,*)
!Argument Variables
TYPE(TREE_TYPE), POINTER :: TREE !<A pointer to the Red-Black tree to delete from
INTEGER(INTG), INTENT(IN) :: KEY !<A pointer to the tree node to delete
INTEGER(INTG), INTENT(OUT) :: ERR !<The error code
TYPE(VARYING_STRING), INTENT(OUT) :: ERROR !<The error string.
!Local Variables
INTEGER(INTG) :: COMPARE_VALUE
TYPE(TREE_NODE_TYPE), POINTER :: U,V,W,X,Y,Z
TYPE(VARYING_STRING) :: LOCAL_ERROR
ENTERS("TREE_ITEM_DELETE",ERR,ERROR,*999)
IF(ASSOCIATED(TREE)) THEN
IF(TREE%TREE_FINISHED) THEN
!Try and find the key to delete
Z=>TREE%ROOT
IF(.NOT.ASSOCIATED(Z,TREE%NIL)) THEN
COMPARE_VALUE=Z%KEY-KEY
DO WHILE(COMPARE_VALUE/=0)
IF(COMPARE_VALUE>0) THEN !Z%KEY > KEY
Z=>Z%LEFT
ELSE !Z%KEY < KEY
Z=>Z%RIGHT
ENDIF
IF(ASSOCIATED(Z,TREE%NIL)) THEN
EXIT
ELSE
COMPARE_VALUE=Z%KEY-KEY
ENDIF
ENDDO
IF(COMPARE_VALUE==0) THEN
!Found the key so delete it
IF(ASSOCIATED(Z%LEFT,TREE%NIL).OR.ASSOCIATED(Z%RIGHT,TREE%NIL)) THEN
Y=>Z
ELSE
Y=>TREE_SUCCESSOR(TREE,Z,ERR,ERROR)
IF(ERR/=0) GOTO 999
ENDIF
IF(.NOT.ASSOCIATED(Y%LEFT,TREE%NIL)) THEN
X=>Y%LEFT
ELSE
X=>Y%RIGHT
ENDIF
X%PARENT=>Y%PARENT
IF(ASSOCIATED(Y%PARENT,TREE%NIL)) THEN
TREE%ROOT=>X
ELSE
IF(ASSOCIATED(Y,Y%PARENT%LEFT)) THEN
Y%PARENT%LEFT=>X
ELSE
Y%PARENT%RIGHT=>X
ENDIF
ENDIF
IF(Y%COLOUR==TREE_BLACK_NODE) THEN
!Fixup the delete to ensure the tree has red black properties
!Note: Due to Fortran restrictions on aliasing pointers in dummy arguments we need to do the fixup and rotations
!inside this routine rather than call fixup and rotate left and rotate right subroutines.
DO WHILE(.NOT.ASSOCIATED(X,TREE%ROOT).AND.X%COLOUR==TREE_BLACK_NODE)
IF(ASSOCIATED(X,X%PARENT%LEFT)) THEN
W=>X%PARENT%RIGHT
IF(W%COLOUR==TREE_RED_NODE) THEN
W%COLOUR=TREE_BLACK_NODE
X%PARENT%COLOUR=TREE_RED_NODE
!Rotate left on X->Parent
U=>X%PARENT
V=>U%RIGHT
U%RIGHT=>V%LEFT
IF(.NOT.ASSOCIATED(V%LEFT,TREE%NIL)) V%LEFT%PARENT=>U
V%PARENT=>U%PARENT
IF(ASSOCIATED(U%PARENT,TREE%NIL)) THEN
TREE%ROOT=>V
ELSE
IF(ASSOCIATED(U,U%PARENT%LEFT)) THEN
U%PARENT%LEFT=>V
ELSE
U%PARENT%RIGHT=>V
ENDIF
ENDIF
V%LEFT=>U
U%PARENT=>V
W=>X%PARENT%RIGHT
ENDIF
IF(W%LEFT%COLOUR==TREE_BLACK_NODE.AND.W%RIGHT%COLOUR==TREE_BLACK_NODE) THEN
W%COLOUR=TREE_RED_NODE
X=>X%PARENT
ELSE
IF(W%RIGHT%COLOUR==TREE_BLACK_NODE) THEN
W%LEFT%COLOUR=TREE_BLACK_NODE
W%COLOUR=TREE_RED_NODE
!Rotate right on W
U=>W
V=>U%LEFT
U%LEFT=>V%RIGHT
IF(.NOT.ASSOCIATED(V%RIGHT,TREE%NIL)) V%RIGHT%PARENT=>U
V%PARENT=>U%PARENT
IF(ASSOCIATED(V%PARENT,TREE%NIL)) THEN
TREE%ROOT=>V
ELSE
IF(ASSOCIATED(U,U%PARENT%RIGHT)) THEN
U%PARENT%RIGHT=>V
ELSE
U%PARENT%LEFT=>V
ENDIF
ENDIF
V%RIGHT=>U
U%PARENT=>V
W=>X%PARENT%RIGHT
ENDIF
W%COLOUR=X%PARENT%COLOUR
X%PARENT%COLOUR=TREE_BLACK_NODE
W%RIGHT%COLOUR=TREE_BLACK_NODE
!Rotate left on X->Parent
U=>X%PARENT
V=>U%RIGHT
U%RIGHT=>V%LEFT
IF(.NOT.ASSOCIATED(V%LEFT,TREE%NIL)) V%LEFT%PARENT=>U
V%PARENT=>U%PARENT
IF(ASSOCIATED(U%PARENT,TREE%NIL)) THEN
TREE%ROOT=>V
ELSE
IF(ASSOCIATED(U,U%PARENT%LEFT)) THEN
U%PARENT%LEFT=>V
ELSE
U%PARENT%RIGHT=>V
ENDIF
ENDIF
V%LEFT=>U
U%PARENT=>V
X=>TREE%ROOT
ENDIF
ELSE
W=>X%PARENT%LEFT
IF(W%COLOUR==TREE_RED_NODE) THEN
W%COLOUR=TREE_BLACK_NODE
X%PARENT%COLOUR=TREE_RED_NODE
!Rotate right on X->Parent
U=>X%PARENT
V=>U%LEFT
U%LEFT=>V%RIGHT
IF(.NOT.ASSOCIATED(V%RIGHT,TREE%NIL)) V%RIGHT%PARENT=>U
V%PARENT=>U%PARENT
IF(ASSOCIATED(V%PARENT,TREE%NIL)) THEN
TREE%ROOT=>V
ELSE
IF(ASSOCIATED(U,U%PARENT%RIGHT)) THEN
U%PARENT%RIGHT=>V
ELSE
U%PARENT%LEFT=>V
ENDIF
ENDIF
V%RIGHT=>U
U%PARENT=>V
W=>X%PARENT%LEFT
ENDIF
IF(W%RIGHT%COLOUR==TREE_BLACK_NODE.AND.W%LEFT%COLOUR==TREE_BLACK_NODE) THEN
W%COLOUR=TREE_RED_NODE
X=>X%PARENT
ELSE
IF(W%LEFT%COLOUR==TREE_BLACK_NODE) THEN
W%RIGHT%COLOUR=TREE_BLACK_NODE
W%COLOUR=TREE_RED_NODE
!Rotate left on W
U=>W
V=>U%RIGHT
U%RIGHT=>V%LEFT
IF(.NOT.ASSOCIATED(V%LEFT,TREE%NIL)) V%LEFT%PARENT=>U
V%PARENT=>U%PARENT
IF(ASSOCIATED(U%PARENT,TREE%NIL)) THEN
TREE%ROOT=>V
ELSE
IF(ASSOCIATED(U,U%PARENT%LEFT)) THEN
U%PARENT%LEFT=>V
ELSE
U%PARENT%RIGHT=>V
ENDIF
ENDIF
V%LEFT=>U
U%PARENT=>V
W=>X%PARENT%LEFT
ENDIF
W%COLOUR=X%PARENT%COLOUR
X%PARENT%COLOUR=TREE_BLACK_NODE
W%LEFT%COLOUR=TREE_BLACK_NODE
!Rotate right on X->Parent
U=>X%PARENT
V=>U%LEFT
U%LEFT=>V%RIGHT
IF(.NOT.ASSOCIATED(V%RIGHT,TREE%NIL)) V%RIGHT%PARENT=>U
V%PARENT=>U%PARENT
IF(ASSOCIATED(V%PARENT,TREE%NIL)) THEN
TREE%ROOT=>V
ELSE
IF(ASSOCIATED(U,U%PARENT%RIGHT)) THEN
U%PARENT%RIGHT=>V
ELSE
U%PARENT%LEFT=>V
ENDIF
ENDIF
V%RIGHT=>U
U%PARENT=>V
X=>TREE%ROOT
ENDIF
ENDIF
ENDDO
X%COLOUR=TREE_BLACK_NODE
ENDIF
IF(.NOT.ASSOCIATED(Y,Z)) THEN
Y%LEFT=>Z%LEFT
Y%RIGHT=>Z%RIGHT
Y%PARENT=>Z%PARENT
Y%COLOUR=Z%COLOUR
Z%LEFT%PARENT=>Y
Z%RIGHT%PARENT=>Y
IF(ASSOCIATED(Z,Z%PARENT%LEFT)) THEN
Z%PARENT%LEFT=>Y
ELSE
Z%PARENT%RIGHT=>Y
ENDIF
ENDIF
DEALLOCATE(Z)
TREE%NUMBER_IN_TREE=TREE%NUMBER_IN_TREE-1
ELSE
LOCAL_ERROR="Could not find the key "//TRIM(NUMBER_TO_VSTRING(KEY,"*",ERR,ERROR))//" in the tree"
CALL FlagError(LOCAL_ERROR,ERR,ERROR,*999)
ENDIF
ELSE
CALL FlagError("The tree root is NIL. Can not delete the key",ERR,ERROR,*999)
ENDIF
ELSE
CALL FlagError("The tree has not been finished",ERR,ERROR,*999)
ENDIF
ELSE
CALL FlagError("Tree is not associated",ERR,ERROR,*999)
ENDIF
EXITS("TREE_ITEM_DELETE")
RETURN
999 ERRORSEXITS("TREE_ITEM_DELETE",ERR,ERROR)
RETURN 1
END SUBROUTINE TREE_ITEM_DELETE
!
!================================================================================================================================
!
!>Inserts a tree node into a red-black tree
SUBROUTINE TREE_ITEM_INSERT(TREE,KEY,VALUE,INSERT_STATUS,ERR,ERROR,*)
!Argument Variables
TYPE(TREE_TYPE), POINTER :: TREE !<A pointer to the Red-Black tree to insert into
INTEGER(INTG), INTENT(IN) :: KEY !<The key to insert
INTEGER(INTG), INTENT(IN) :: VALUE !<The value to insert
INTEGER(INTG), INTENT(OUT) :: INSERT_STATUS !<On exit, the status of the insert \see TREES_TreeNodeInsertStatus,TREES::TreeNodeInsertStatus
INTEGER(INTG), INTENT(OUT) :: ERR !<The error code
TYPE(VARYING_STRING), INTENT(OUT) :: ERROR !<The error string.
!Local Variables
LOGICAL :: DUPLICATE_KEY
TYPE(TREE_NODE_TYPE), POINTER :: NEW_TREE_NODE,X,Y,Z
NULLIFY(NEW_TREE_NODE)
ENTERS("TREE_ITEM_INSERT",ERR,ERROR,*998)
IF(ASSOCIATED(TREE)) THEN
IF(TREE%TREE_FINISHED) THEN
!Find the position to insert
Y=>TREE%NIL
X=>TREE%ROOT
DUPLICATE_KEY=.FALSE.
DO WHILE(.NOT.ASSOCIATED(X,TREE%NIL))
Y=>X
DUPLICATE_KEY=TREE%INSERT_TYPE==TREE_NO_DUPLICATES_ALLOWED.AND.KEY==X%KEY
IF(DUPLICATE_KEY) THEN
EXIT
ELSE IF(KEY<X%KEY) THEN
X=>X%LEFT
ELSE
X=>X%RIGHT
ENDIF
ENDDO
IF(DUPLICATE_KEY) THEN
INSERT_STATUS=TREE_NODE_DUPLICATE_KEY
ELSE
!Allocate the new tree node and set its key and value
ALLOCATE(NEW_TREE_NODE,STAT=ERR)
IF(ERR/=0) CALL FlagError("Could not allocate new tree node",ERR,ERROR,*999)
CALL TREE_NODE_INITIALISE(TREE,NEW_TREE_NODE,ERR,ERROR,*999)
NEW_TREE_NODE%KEY=KEY
NEW_TREE_NODE%VALUE=VALUE
!Insert the new tree node into the tree
NEW_TREE_NODE%COLOUR=TREE_RED_NODE
NEW_TREE_NODE%LEFT=>TREE%NIL
NEW_TREE_NODE%RIGHT=>TREE%NIL
NEW_TREE_NODE%PARENT=>Y
IF(ASSOCIATED(Y,TREE%NIL)) THEN
TREE%ROOT=>NEW_TREE_NODE
ELSE
IF(NEW_TREE_NODE%KEY<Y%KEY) THEN
Y%LEFT=>NEW_TREE_NODE
ELSE
Y%RIGHT=>NEW_TREE_NODE
ENDIF
ENDIF
!Fix up the tree to keep red-black properties
!Note: Due to Fortran restrictions on aliasing pointers in dummy arguments we need to do the fixup and rotations
!inside this routine rather than call fixup and rotate left and rotate right subroutines.
Z=>NEW_TREE_NODE
DO WHILE(Z%PARENT%COLOUR==TREE_RED_NODE)
IF(ASSOCIATED(Z%PARENT,Z%PARENT%PARENT%LEFT)) THEN
Y=>Z%PARENT%PARENT%RIGHT
IF(Y%COLOUR==TREE_RED_NODE) THEN
Z%PARENT%COLOUR=TREE_BLACK_NODE
Y%COLOUR=TREE_BLACK_NODE
Z%PARENT%PARENT%COLOUR=TREE_RED_NODE
Z=>Z%PARENT%PARENT
ELSE
IF(ASSOCIATED(Z,Z%PARENT%RIGHT)) THEN
Z=>Z%PARENT
!Rotate the tree left at Z
X=>Z
Y=>X%RIGHT
X%RIGHT=>Y%LEFT
IF(.NOT.ASSOCIATED(Y%LEFT,TREE%NIL)) Y%LEFT%PARENT=>X
Y%PARENT=>X%PARENT
IF(ASSOCIATED(X%PARENT,TREE%NIL)) THEN
TREE%ROOT=>Y
ELSE
IF(ASSOCIATED(X,X%PARENT%LEFT)) THEN
X%PARENT%LEFT=>Y
ELSE
X%PARENT%RIGHT=>Y
ENDIF
ENDIF
Y%LEFT=>X
X%PARENT=>Y
ENDIF
Z%PARENT%COLOUR=TREE_BLACK_NODE
Z%PARENT%PARENT%COLOUR=TREE_RED_NODE
!Rotate the tree right at Z->Parent->Parent
X=>Z%PARENT%PARENT
Y=>X%LEFT
X%LEFT=>Y%RIGHT
IF(.NOT.ASSOCIATED(Y%RIGHT,TREE%NIL)) Y%RIGHT%PARENT=>X
Y%PARENT=>X%PARENT
IF(ASSOCIATED(X%PARENT,TREE%NIL)) THEN
TREE%ROOT=>Y
ELSE
IF(ASSOCIATED(X,X%PARENT%RIGHT)) THEN
X%PARENT%RIGHT=>Y
ELSE
X%PARENT%LEFT=>Y
ENDIF
ENDIF
Y%RIGHT=>X
X%PARENT=>Y
ENDIF
ELSE
Y=>Z%PARENT%PARENT%LEFT
IF(Y%COLOUR==TREE_RED_NODE) THEN
Z%PARENT%COLOUR=TREE_BLACK_NODE
Y%COLOUR=TREE_BLACK_NODE
Z%PARENT%PARENT%COLOUR=TREE_RED_NODE
Z=>Z%PARENT%PARENT
ELSE
IF(ASSOCIATED(Z,Z%PARENT%LEFT)) THEN
Z=>Z%PARENT
X=>Z
!Rotate the tree right at Z
Y=>X%LEFT
X%LEFT=>Y%RIGHT
IF(.NOT.ASSOCIATED(Y%RIGHT,TREE%NIL)) Y%RIGHT%PARENT=>X
Y%PARENT=>X%PARENT
IF(ASSOCIATED(X%PARENT,TREE%NIL)) THEN
TREE%ROOT=>Y
ELSE
IF(ASSOCIATED(X,X%PARENT%RIGHT)) THEN
X%PARENT%RIGHT=>Y
ELSE
X%PARENT%LEFT=>Y
ENDIF
ENDIF
Y%RIGHT=>X
X%PARENT=>Y
ENDIF
Z%PARENT%COLOUR=TREE_BLACK_NODE
Z%PARENT%PARENT%COLOUR=TREE_RED_NODE
!Rotate the tree left at Z->Parent->Parent
X=>Z%PARENT%PARENT
Y=>X%RIGHT
X%RIGHT=>Y%LEFT
IF(.NOT.ASSOCIATED(Y%LEFT,TREE%NIL)) Y%LEFT%PARENT=>X
Y%PARENT=>X%PARENT
IF(ASSOCIATED(X%PARENT,TREE%NIL)) THEN
TREE%ROOT=>Y
ELSE
IF(ASSOCIATED(X,X%PARENT%LEFT)) THEN
X%PARENT%LEFT=>Y
ELSE
X%PARENT%RIGHT=>Y
ENDIF
ENDIF
Y%LEFT=>X
X%PARENT=>Y
ENDIF
ENDIF
ENDDO
TREE%ROOT%COLOUR=TREE_BLACK_NODE
!Increment the number in the tree and indicate a successful insertion
TREE%NUMBER_IN_TREE=TREE%NUMBER_IN_TREE+1
INSERT_STATUS=TREE_NODE_INSERT_SUCESSFUL
ENDIF
ELSE
CALL FlagError("The tree has not been finished",ERR,ERROR,*998)
ENDIF
ELSE
CALL FlagError("Tree is not associated",ERR,ERROR,*998)
ENDIF
EXITS("TREE_ITEM_INSERT")
RETURN
999 IF(ASSOCIATED(NEW_TREE_NODE)) DEALLOCATE(NEW_TREE_NODE)
998 ERRORSEXITS("TREE_ITEM_INSERT",ERR,ERROR)
RETURN 1
END SUBROUTINE TREE_ITEM_INSERT
!
!================================================================================================================================
!
!>Finalises a tree node and deallocates all memory
RECURSIVE SUBROUTINE TREE_NODE_FINALISE(TREE,TREE_NODE,ERR,ERROR,*)
!Argument Variables
TYPE(TREE_TYPE), POINTER :: TREE !<A pointer to the tree containing the tree node to finalise
TYPE(TREE_NODE_TYPE), POINTER :: TREE_NODE !<A pointer to the tree node to finalise
INTEGER(INTG), INTENT(OUT) :: ERR !<The error code
TYPE(VARYING_STRING), INTENT(OUT) :: ERROR !<The error string.
!Local Variables
ENTERS("TREE_NODE_FINALISE",ERR,ERROR,*999)
IF(ASSOCIATED(TREE)) THEN
IF(.NOT.ASSOCIATED(TREE_NODE,TREE%NIL)) THEN
CALL TREE_NODE_FINALISE(TREE,TREE_NODE%LEFT,ERR,ERROR,*999)
CALL TREE_NODE_FINALISE(TREE,TREE_NODE%RIGHT,ERR,ERROR,*999)
DEALLOCATE(TREE_NODE)
ENDIF
ELSE
CALL FlagError("Tree is not associated",ERR,ERROR,*999)
ENDIF
EXITS("TREE_NODE_FINALISE")
RETURN
999 ERRORSEXITS("TREE_NODE_FINALISE",ERR,ERROR)
RETURN 1
END SUBROUTINE TREE_NODE_FINALISE
!
!================================================================================================================================
!
!>Initialises a tree node
SUBROUTINE TREE_NODE_INITIALISE(TREE,TREE_NODE,ERR,ERROR,*)
!Argument Variables
TYPE(TREE_TYPE), POINTER :: TREE !<A pointer to the tree containing the tree node to initialise
TYPE(TREE_NODE_TYPE), POINTER :: TREE_NODE !<A pointer to the tree node to initialise
INTEGER(INTG), INTENT(OUT) :: ERR !<The error code
TYPE(VARYING_STRING), INTENT(OUT) :: ERROR !<The error string.
!Local Variables
ENTERS("TREE_NODE_INITIALISE",ERR,ERROR,*999)
IF(ASSOCIATED(TREE)) THEN
IF(ASSOCIATED(TREE_NODE)) THEN
TREE_NODE%KEY=0
TREE_NODE%VALUE=0
TREE_NODE%COLOUR=TREE_BLACK_NODE
NULLIFY(TREE_NODE%LEFT)