This repository has been archived by the owner on May 18, 2019. It is now read-only.
/
NFRecord.mo
185 lines (162 loc) · 5.9 KB
/
NFRecord.mo
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
/*
* This file is part of OpenModelica.
*
* Copyright (c) 1998-2014, Open Source Modelica Consortium (OSMC),
* c/o Linköpings universitet, Department of Computer and Information Science,
* SE-58183 Linköping, Sweden.
*
* All rights reserved.
*
* THIS PROGRAM IS PROVIDED UNDER THE TERMS OF GPL VERSION 3 LICENSE OR
* THIS OSMC PUBLIC LICENSE (OSMC-PL) VERSION 1.2.
* ANY USE, REPRODUCTION OR DISTRIBUTION OF THIS PROGRAM CONSTITUTES
* RECIPIENT'S ACCEPTANCE OF THE OSMC PUBLIC LICENSE OR THE GPL VERSION 3,
* ACCORDING TO RECIPIENTS CHOICE.
*
* The OpenModelica software and the Open Source Modelica
* Consortium (OSMC) Public License (OSMC-PL) are obtained
* from OSMC, either from the above address,
* from the URLs: http://www.ida.liu.se/projects/OpenModelica or
* http://www.openmodelica.org, and in the OpenModelica distribution.
* GNU version 3 is obtained from: http://www.gnu.org/copyleft/gpl.html.
*
* This program is distributed WITHOUT ANY WARRANTY; without
* even the implied warranty of MERCHANTABILITY or FITNESS
* FOR A PARTICULAR PURPOSE, EXCEPT AS EXPRESSLY SET FORTH
* IN THE BY RECIPIENT SELECTED SUBSIDIARY LICENSE CONDITIONS OF OSMC-PL.
*
* See the full OSMC Public License conditions for more details.
*
*/
encapsulated package NFRecord
" file: NFRecord.mo
package: NFRecord
description: package for handling records.
Functions used by NFInst for handling records.
"
import NFBinding.Binding;
import NFClass.Class;
import NFComponent.Component;
import Dimension = NFDimension;
import Expression = NFExpression;
import NFExpression.CallAttributes;
import NFInstNode.InstNode;
import NFInstNode.InstNodeType;
import Type = NFType;
import Subscript = NFSubscript;
protected
import Inst = NFInst;
import List;
import Lookup = NFLookup;
import TypeCheck = NFTypeCheck;
import Types;
import Typing = NFTyping;
import NFInstUtil;
import NFPrefixes.Variability;
import NFPrefixes.Visibility;
import NFFunction.Function;
import NFClassTree.ClassTree;
import ComplexType = NFComplexType;
import ComponentRef = NFComponentRef;
import ErrorExt;
import NFFunction.FunctionStatus;
public
function instDefaultConstructor
input Absyn.Path path;
input output InstNode node;
input SourceInfo info;
protected
list<InstNode> inputs, locals;
DAE.FunctionAttributes attr;
Pointer<FunctionStatus> status;
InstNode ctor_node, out_rec;
Component out_comp;
Class ctor_cls;
InstNode ty_node;
algorithm
// The node we get is usually a record instance, with applied modifiers and so on.
// So the first thing we do is to create a "pure" instance of the record.
// TODO: The lookup will fail for records declared in redeclare modifiers,
// since the parent will be the class scope of the modifier instead of
// the element being modified. In that case we just reinstantiate the
// record completely, but this probably isn't entirely correct. We
// should make the expanded but not fully instantiated class available
// here somehow.
try
ctor_node := Lookup.lookupLocalSimpleName(InstNode.name(node), InstNode.classScope(InstNode.parent(node)));
true := referenceEq(InstNode.definition(node), InstNode.definition(ctor_node));
else
ctor_node := InstNode.replaceClass(Class.NOT_INSTANTIATED(), node);
end try;
ctor_node := Inst.instantiate(ctor_node);
Inst.instExpressions(ctor_node);
// Collect the record fields.
(inputs, locals) := collectRecordParams(ctor_node);
// Create the output record element, using the instance created above as both parent and type.
out_comp := Component.UNTYPED_COMPONENT(ctor_node, listArray({}),
NFBinding.EMPTY_BINDING, NFBinding.EMPTY_BINDING,
NFComponent.OUTPUT_ATTR, NONE(), false, Absyn.dummyInfo);
out_rec := InstNode.fromComponent("$out" + InstNode.name(ctor_node), out_comp, ctor_node);
// Make a record constructor class and create a node for the constructor.
ctor_cls := Class.makeRecordConstructor(inputs, locals, out_rec);
ctor_node := InstNode.replaceClass(ctor_cls, ctor_node);
// Create the constructor function and add it to the function cache.
attr := DAE.FUNCTION_ATTRIBUTES_DEFAULT;
status := Pointer.create(FunctionStatus.INITIAL);
InstNode.cacheAddFunc(node, Function.FUNCTION(path, ctor_node, inputs,
{out_rec}, locals, {}, Type.UNKNOWN(), attr, {}, status, Pointer.create(0)), false);
end instDefaultConstructor;
function collectRecordParams
input InstNode recNode;
output list<InstNode> inputs = {};
output list<InstNode> locals = {};
protected
array<InstNode> comps;
array<Mutable<InstNode>> pcomps;
ClassTree tree;
algorithm
tree := Class.classTree(InstNode.getClass(recNode));
() := match tree
case ClassTree.FLAT_TREE(components = comps)
algorithm
for i in arrayLength(comps):-1:1 loop
(inputs, locals) := collectRecordParam(comps[i], inputs, locals);
end for;
then
();
case ClassTree.INSTANTIATED_TREE(components = pcomps)
algorithm
for i in arrayLength(pcomps):-1:1 loop
(inputs, locals) := collectRecordParam(Mutable.access(pcomps[i]), inputs, locals);
end for;
then
();
else
algorithm
Error.assertion(false, getInstanceName() + " got non-instantiated function", sourceInfo());
then
fail();
end match;
end collectRecordParams;
function collectRecordParam
input InstNode component;
input output list<InstNode> inputs;
input output list<InstNode> locals;
protected
Component comp;
algorithm
if InstNode.isEmpty(component) then
return;
end if;
if InstNode.isProtected(component) then
locals := component :: locals;
end if;
comp := InstNode.component(component);
if Component.isConst(comp) and Component.hasBinding(comp) then
locals := component :: locals;
else
inputs := component :: inputs;
end if;
end collectRecordParam;
annotation(__OpenModelica_Interface="frontend");
end NFRecord;