/
NFStatement.mo
322 lines (277 loc) · 8.06 KB
/
NFStatement.mo
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
/*
* This file is part of OpenModelica.
*
* Copyright (c) 1998-2014, Open Source Modelica Consortium (OSMC),
* c/o Linköpings universitet, Department of Computer and Information Science,
* SE-58183 Linköping, Sweden.
*
* All rights reserved.
*
* THIS PROGRAM IS PROVIDED UNDER THE TERMS OF GPL VERSION 3 LICENSE OR
* THIS OSMC PUBLIC LICENSE (OSMC-PL) VERSION 1.2.
* ANY USE, REPRODUCTION OR DISTRIBUTION OF THIS PROGRAM CONSTITUTES
* RECIPIENT'S ACCEPTANCE OF THE OSMC PUBLIC LICENSE OR THE GPL VERSION 3,
* ACCORDING TO RECIPIENTS CHOICE.
*
* The OpenModelica software and the Open Source Modelica
* Consortium (OSMC) Public License (OSMC-PL) are obtained
* from OSMC, either from the above address,
* from the URLs: http://www.ida.liu.se/projects/OpenModelica or
* http://www.openmodelica.org, and in the OpenModelica distribution.
* GNU version 3 is obtained from: http://www.gnu.org/copyleft/gpl.html.
*
* This program is distributed WITHOUT ANY WARRANTY; without
* even the implied warranty of MERCHANTABILITY or FITNESS
* FOR A PARTICULAR PURPOSE, EXCEPT AS EXPRESSLY SET FORTH
* IN THE BY RECIPIENT SELECTED SUBSIDIARY LICENSE CONDITIONS OF OSMC-PL.
*
* See the full OSMC Public License conditions for more details.
*
*/
encapsulated uniontype NFStatement
import Absyn;
import Type = NFType;
import Expression = NFExpression;
import NFInstNode.InstNode;
protected
import Statement = NFStatement;
public
record ASSIGNMENT
Expression lhs "The asignee";
Expression rhs "The expression";
SourceInfo info;
end ASSIGNMENT;
record FUNCTION_ARRAY_INIT "Used to mark in which order local array variables in functions should be initialized"
String name;
Type ty;
SourceInfo info;
end FUNCTION_ARRAY_INIT;
record FOR
InstNode iterator;
list<Statement> body "The body of the for loop.";
SourceInfo info;
end FOR;
record IF
list<tuple<Expression, list<Statement>>> branches
"List of branches, where each branch is a tuple of a condition and a body.";
SourceInfo info;
end IF;
record WHEN
list<tuple<Expression, list<Statement>>> branches
"List of branches, where each branch is a tuple of a condition and a body.";
SourceInfo info;
end WHEN;
record ASSERT
Expression condition "The assert condition.";
Expression message "The message to display if the assert fails.";
Expression level;
SourceInfo info;
end ASSERT;
record TERMINATE
Expression message "The message to display if the terminate triggers.";
SourceInfo info;
end TERMINATE;
record NORETCALL
Expression exp;
SourceInfo info;
end NORETCALL;
record WHILE
Expression condition;
list<Statement> body;
SourceInfo info;
end WHILE;
record RETURN
SourceInfo info;
end RETURN;
record BREAK
SourceInfo info;
end BREAK;
record FAILURE
list<Statement> body;
SourceInfo info;
end FAILURE;
function info
input Statement stmt;
output SourceInfo info;
algorithm
info := match stmt
case ASSIGNMENT() then stmt.info;
case FUNCTION_ARRAY_INIT() then stmt.info;
case FOR() then stmt.info;
case IF() then stmt.info;
case WHEN() then stmt.info;
case ASSERT() then stmt.info;
case TERMINATE() then stmt.info;
case NORETCALL() then stmt.info;
case WHILE() then stmt.info;
case RETURN() then stmt.info;
case BREAK() then stmt.info;
case FAILURE() then stmt.info;
end match;
end info;
function mapExpListList
input output list<list<Statement>> stmtl;
input MapFunc func;
partial function MapFunc
input output Expression exp;
end MapFunc;
algorithm
stmtl := list(mapExpList(s, func) for s in stmtl);
end mapExpListList;
function mapExpList
input output list<Statement> stmtl;
input MapFunc func;
partial function MapFunc
input output Expression exp;
end MapFunc;
algorithm
stmtl := list(mapExp(s, func) for s in stmtl);
end mapExpList;
function mapExp
input output Statement stmt;
input MapFunc func;
partial function MapFunc
input output Expression exp;
end MapFunc;
algorithm
stmt := match stmt
local
Expression e1, e2, e3;
case ASSIGNMENT()
algorithm
e1 := func(stmt.lhs);
e2 := func(stmt.rhs);
then
if referenceEq(e1, stmt.lhs) and referenceEq(e2, stmt.rhs) then
stmt else ASSIGNMENT(e1, e2, stmt.info);
case FOR()
algorithm
stmt.body := mapExpList(stmt.body, func);
then
stmt;
case IF()
algorithm
stmt.branches := list(
(func(Util.tuple21(b)), mapExpList(Util.tuple22(b), func)) for b in stmt.branches);
then
stmt;
case WHEN()
algorithm
stmt.branches := list(
(func(Util.tuple21(b)), mapExpList(Util.tuple22(b), func)) for b in stmt.branches);
then
stmt;
case ASSERT()
algorithm
e1 := func(stmt.condition);
e2 := func(stmt.message);
e3 := func(stmt.level);
then
if referenceEq(e1, stmt.condition) and referenceEq(e2, stmt.message) and
referenceEq(e3, stmt.level) then stmt else ASSERT(e1, e2, e3, stmt.info);
case TERMINATE()
algorithm
e1 := func(stmt.message);
then
if referenceEq(e1, stmt.message) then stmt else TERMINATE(e1, stmt.info);
case NORETCALL()
algorithm
e1 := func(stmt.exp);
then
if referenceEq(e1, stmt.exp) then stmt else NORETCALL(e1, stmt.info);
case WHILE()
then WHILE(func(stmt.condition), mapExpList(stmt.body, func), stmt.info);
else stmt;
end match;
end mapExp;
function foldExpListList<ArgT>
input list<list<Statement>> stmt;
input FoldFunc func;
input output ArgT arg;
partial function FoldFunc
input Expression exp;
input output ArgT arg;
end FoldFunc;
algorithm
for s in stmt loop
arg := foldExpList(s, func, arg);
end for;
end foldExpListList;
function foldExpList<ArgT>
input list<Statement> stmt;
input FoldFunc func;
input output ArgT arg;
partial function FoldFunc
input Expression exp;
input output ArgT arg;
end FoldFunc;
algorithm
for s in stmt loop
arg := foldExp(s, func, arg);
end for;
end foldExpList;
function foldExp<ArgT>
input Statement stmt;
input FoldFunc func;
input output ArgT arg;
partial function FoldFunc
input Expression exp;
input output ArgT arg;
end FoldFunc;
algorithm
() := match stmt
case Statement.ASSIGNMENT()
algorithm
arg := func(stmt.lhs, arg);
arg := func(stmt.rhs, arg);
then
();
case Statement.FOR()
algorithm
arg := foldExpList(stmt.body, func, arg);
then
();
case Statement.IF()
algorithm
for b in stmt.branches loop
arg := func(Util.tuple21(b), arg);
arg := foldExpList(Util.tuple22(b), func, arg);
end for;
then
();
case Statement.WHEN()
algorithm
for b in stmt.branches loop
arg := func(Util.tuple21(b), arg);
arg := foldExpList(Util.tuple22(b), func, arg);
end for;
then
();
case Statement.ASSERT()
algorithm
arg := func(stmt.condition, arg);
arg := func(stmt.message, arg);
arg := func(stmt.level, arg);
then
();
case Statement.TERMINATE()
algorithm
arg := func(stmt.message, arg);
then
();
case Statement.NORETCALL()
algorithm
arg := func(stmt.exp, arg);
then
();
case Statement.WHILE()
algorithm
arg := func(stmt.condition, arg);
arg := foldExpList(stmt.body, func, arg);
then
();
else ();
end match;
end foldExp;
annotation(__OpenModelica_Interface="frontend");
end NFStatement;