-
Notifications
You must be signed in to change notification settings - Fork 299
/
Interactive.mo
18245 lines (16894 loc) · 640 KB
/
Interactive.mo
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
* This file is part of OpenModelica.
*
* Copyright (c) 1998-2014, Open Source Modelica Consortium (OSMC),
* c/o Linköpings universitet, Department of Computer and Information Science,
* SE-58183 Linköping, Sweden.
*
* All rights reserved.
*
* THIS PROGRAM IS PROVIDED UNDER THE TERMS OF GPL VERSION 3 LICENSE OR
* THIS OSMC PUBLIC LICENSE (OSMC-PL) VERSION 1.2.
* ANY USE, REPRODUCTION OR DISTRIBUTION OF THIS PROGRAM CONSTITUTES
* RECIPIENT'S ACCEPTANCE OF THE OSMC PUBLIC LICENSE OR THE GPL VERSION 3,
* ACCORDING TO RECIPIENTS CHOICE.
*
* The OpenModelica software and the Open Source Modelica
* Consortium (OSMC) Public License (OSMC-PL) are obtained
* from OSMC, either from the above address,
* from the URLs: http://www.ida.liu.se/projects/OpenModelica or
* http://www.openmodelica.org, and in the OpenModelica distribution.
* GNU version 3 is obtained from: http://www.gnu.org/copyleft/gpl.html.
*
* This program is distributed WITHOUT ANY WARRANTY; without
* even the implied warranty of MERCHANTABILITY or FITNESS
* FOR A PARTICULAR PURPOSE, EXCEPT AS EXPRESSLY SET FORTH
* IN THE BY RECIPIENT SELECTED SUBSIDIARY LICENSE CONDITIONS OF OSMC-PL.
*
* See the full OSMC Public License conditions for more details.
*
*/
encapsulated package Interactive
" file: Interactive.mo
package: Interactive
description: This module contain functionality for model management,
expression evaluation, etc. in the interactive environment.
$Id: Interactive.mo 25580 2015-04-16 14:04:16Z jansilar $
This module contain functionality for model management, expression evaluation, etc.
in the interactive environment.
The module defines a symboltable used in the interactive environment containing:
- Modelica models (described using Absyn AST)
- GlobalScript.Variable bindings
- Compiled functions (so they do not need to be recompiled)
- Instantiated classes (that can be reused, not impl. yet)
- Modelica models in SCode form (to speed up instantiation. not impl. yet)"
//public imports
public import Absyn;
public import ConnectionGraph;
public import DAE;
public import FCore;
public import Global;
public import GlobalScript;
public import SCode;
public import SCodeUtil;
public import Settings;
public import Values;
// protected imports
protected import Builtin;
protected import Ceval;
protected import CevalScript;
protected import ClassInf;
protected import ClockIndexes;
protected import Config;
protected import Connect;
protected import Constants;
protected import DAEUtil;
protected import Debug;
protected import Dump;
protected import Error;
protected import ErrorExt;
protected import ExpressionDump;
protected import ExpressionSimplify;
protected import Flags;
protected import FGraph;
protected import GlobalScriptDump;
protected import GlobalScriptUtil;
protected import InnerOuter;
protected import Inst;
protected import InstUtil;
protected import InstTypes;
protected import List;
protected import Lookup;
protected import MetaUtil;
protected import Mod;
protected import Parser;
protected import Prefix;
protected import Print;
protected import Refactor;
protected import Static;
protected import StaticScript;
protected import StringUtil;
protected import System;
protected import Types;
protected import UnitAbsyn;
protected import Util;
protected import ValuesUtil;
import MetaModelica.Dangerous;
protected uniontype AnnotationType
record ICON_ANNOTATION end ICON_ANNOTATION;
record DIAGRAM_ANNOTATION end DIAGRAM_ANNOTATION;
end AnnotationType;
protected uniontype GraphicEnvCache
"Used by buildEnvForGraphicProgram to avoid excessive work."
record GRAPHIC_ENV_NO_CACHE
Absyn.Program program;
Absyn.Path modelPath;
end GRAPHIC_ENV_NO_CACHE;
record GRAPHIC_ENV_PARTIAL_CACHE
Absyn.Program program;
Absyn.Path modelPath;
FCore.Cache cache;
FCore.Graph env;
end GRAPHIC_ENV_PARTIAL_CACHE;
record GRAPHIC_ENV_FULL_CACHE
FCore.Cache cache;
FCore.Graph env;
end GRAPHIC_ENV_FULL_CACHE;
end GraphicEnvCache;
public function evaluate
"This function evaluates expressions or statements feed interactively to the compiler.
inputs: (GlobalScript.Statements, GlobalScript.SymbolTable, bool /* verbose */)
outputs: string:
The resulting string after evaluation. If an error has occurred, this string
will be empty. The error messages can be retrieved by calling print_messages_str()
in Error.mo.
GlobalScript.SymbolTable"
input GlobalScript.Statements inStatements;
input GlobalScript.SymbolTable inSymbolTable;
input Boolean inBoolean;
output String outString;
output GlobalScript.SymbolTable outSymbolTable;
algorithm
(outString,outSymbolTable) := matchcontinue (inStatements,inSymbolTable,inBoolean)
local
String res,res_1,res2,res_2;
GlobalScript.SymbolTable newst,st,newst_1;
Boolean echo,semicolon,verbose;
GlobalScript.Statement x;
list<GlobalScript.Statement> xs;
case (GlobalScript.ISTMTS(interactiveStmtLst = {x},semicolon = semicolon),st,verbose)
equation
showStatement(x, semicolon, true);
(res,newst) = evaluate2(GlobalScript.ISTMTS({x},verbose), st);
echo = getEcho();
res_1 = selectResultstr(res, semicolon, verbose, echo);
showStatement(x, semicolon, false);
then
(res_1,newst);
case (GlobalScript.ISTMTS(interactiveStmtLst = (x :: xs),semicolon = semicolon),st,verbose)
equation
showStatement(x, semicolon, true);
(res,newst) = evaluate2(GlobalScript.ISTMTS({x},semicolon), st);
echo = getEcho();
res_1 = selectResultstr(res, semicolon, verbose, echo);
showStatement(x, semicolon, false);
(res2,newst_1) = evaluate(GlobalScript.ISTMTS(xs,semicolon), newst, verbose);
res_2 = stringAppendList({res_1,res2});
then
(res_2,newst_1);
end matchcontinue;
end evaluate;
public function evaluateToStdOut
"This function evaluates expressions or statements feed interactively to the compiler.
The resulting string after evaluation is printed.
If an error has occurred, this string will be empty.
The error messages can be retrieved by calling print_messages_str() in Error.mo."
input GlobalScript.Statements inStatements;
input GlobalScript.SymbolTable inSymbolTable;
input Boolean inBoolean;
output GlobalScript.SymbolTable outSymbolTable;
algorithm
outSymbolTable := match (inStatements,inSymbolTable,inBoolean)
local
String res,res_1;
GlobalScript.SymbolTable newst,st,newst_1;
Boolean echo,semicolon,verbose;
GlobalScript.Statement x;
GlobalScript.Statements new;
list<GlobalScript.Statement> xs;
case (GlobalScript.ISTMTS(interactiveStmtLst = {x},semicolon = semicolon),st,verbose)
equation
showStatement(x, semicolon, true);
new = GlobalScript.ISTMTS({x},verbose);
(res,newst) = evaluate2(new, st);
echo = getEcho();
res_1 = selectResultstr(res, semicolon, verbose, echo);
print(res_1);
showStatement(x, semicolon, false);
then
newst;
case (GlobalScript.ISTMTS(interactiveStmtLst = (x :: xs),semicolon = semicolon),st,verbose)
equation
showStatement(x, semicolon, true);
new = GlobalScript.ISTMTS({x},semicolon);
(res,newst) = evaluate2(new, st);
echo = getEcho();
res_1 = selectResultstr(res, semicolon, verbose, echo);
print(res_1);
showStatement(x, semicolon, false);
newst_1 = evaluateToStdOut(GlobalScript.ISTMTS(xs,semicolon), newst, verbose);
then
newst_1;
end match;
end evaluateToStdOut;
public function evaluateFork
"As evaluateToStdOut, but takes the inputs as a tuple of mos-script file and symbol table.
As it is supposed to work in a thread without output, it also flushes the error-buffer since that will otherwise be lost to the void."
input tuple<String,GlobalScript.SymbolTable> inTpl;
output Boolean b;
algorithm
b := matchcontinue inTpl
local
String mosfile;
GlobalScript.Statements statements;
GlobalScript.SymbolTable st;
Absyn.Program ast;
Option<SCode.Program> explodedAst;
case ((mosfile,GlobalScript.SYMBOLTABLE(ast=ast,explodedAst=explodedAst)))
equation
setGlobalRoot(Global.instOnlyForcedFunctions, NONE()); // thread-local root that has to be set!
statements = Parser.parseexp(mosfile);
evaluateToStdOut(statements,GlobalScript.SYMBOLTABLE(ast,explodedAst,{},{},{},{}),true);
print(Error.printMessagesStr(false));
then true;
else
equation
print(Error.printMessagesStr(false));
then false;
end matchcontinue;
end evaluateFork;
protected function showStatement
input GlobalScript.Statement s;
input Boolean semicolon;
input Boolean start;
protected
Boolean testsuite;
algorithm
if not Flags.isSet(Flags.SHOW_STATEMENT) then
return;
end if;
testsuite := Config.getRunningTestsuite();
_ := matchcontinue(start, testsuite)
// running testsuite
case (true, true)
equation
print("Evaluating: " + printIstmtStr(GlobalScript.ISTMTS({s}, semicolon)) + "\n");
then
();
case (false, true) then ();
// not running testsuite, show more!
case (true, false)
equation
System.realtimeTick(ClockIndexes.RT_CLOCK_SHOW_STATEMENT);
print("Evaluating: > " + printIstmtStr(GlobalScript.ISTMTS({s}, semicolon)) + "\n");
then
();
case (false, false)
equation
print("Evaluated: < " + realString(System.realtimeTock(ClockIndexes.RT_CLOCK_SHOW_STATEMENT)) + " / " + printIstmtStr(GlobalScript.ISTMTS({s}, semicolon)) + "\n");
then
();
else ();
end matchcontinue;
end showStatement;
protected function selectResultstr
"Returns result string depending on three boolean variables
- semicolon
- verbose
- echo"
input String inString;
input Boolean inSemicolon "semicolon";
input Boolean inVerbose "verbose";
input Boolean inEcho "echo";
output String outString;
algorithm
outString := match (inString,inSemicolon,inVerbose,inEcho)
local String str;
case (_,_,_,false) then ""; // echo off always empty string
case (str,_,true,_) then str; // .. verbose on always return str
case (_,true,_,_) then ""; // ... semicolon, no resultstr
case (str,false,_,_) then str; // no semicolon
end match;
end selectResultstr;
protected function getEcho
"Return echo variable, which determines
if result should be printed or not."
output Boolean outBoolean;
algorithm
outBoolean := 0 <> Settings.getEcho();
end getEcho;
public function evaluate2
"Helper function to evaluate."
input GlobalScript.Statements inStatements;
input GlobalScript.SymbolTable inSymbolTable;
output String outString;
output GlobalScript.SymbolTable outSymbolTable;
algorithm
(outString,outSymbolTable) := matchcontinue (inStatements,inSymbolTable)
local
String str,str_1;
GlobalScript.SymbolTable st,newst,st_1;
GlobalScript.Statements stmts;
Absyn.AlgorithmItem algitem;
Boolean outres;
Absyn.Exp exp;
Boolean partialInst, gen, evalfunc, keepArrays;
SourceInfo info;
// evaluate graphical API
case ((stmts as GlobalScript.ISTMTS(interactiveStmtLst = {GlobalScript.IEXP(exp = Absyn.CALL())})),st)
equation
// adrpo: always evaluate the graphicalAPI with these options so instantiation is faster!
partialInst = System.getPartialInstantiation();
System.setPartialInstantiation(true);
gen = Flags.set(Flags.GEN, false);
evalfunc = Flags.set(Flags.EVAL_FUNC, false);
keepArrays = Flags.getConfigBool(Flags.KEEP_ARRAYS);
Flags.setConfigBool(Flags.KEEP_ARRAYS, false);
Inst.initInstHashTable();
(str,newst) = evaluateGraphicalApi(stmts, st, partialInst, gen, evalfunc, keepArrays);
str_1 = stringAppend(str, "\n");
then
(str_1,newst);
// Evaluate algorithm statements in evaluateAlgStmt()
case (GlobalScript.ISTMTS(interactiveStmtLst = {GlobalScript.IALG(algItem = (algitem as Absyn.ALGORITHMITEM()))}),st)
equation
Inst.initInstHashTable();
(str,st_1) = evaluateAlgStmt(algitem, st);
str_1 = stringAppend(str, "\n");
then
(str_1,st_1);
// Evaluate expressions in evaluate_exprToStr()
case ((GlobalScript.ISTMTS(interactiveStmtLst = {GlobalScript.IEXP(exp = exp, info = info)})),st)
equation
Inst.initInstHashTable();
(str,st_1) = evaluateExprToStr(exp, st, info);
str_1 = stringAppend(str, "\n");
then
(str_1,st_1);
end matchcontinue;
end evaluate2;
protected function evaluateAlgStmt
"This function takes an AlgorithmItem, i.e. a statement located in an
algorithm section, and a symboltable as input arguments. The statements
are recursivly evalutated and a new interactive symbol table is returned."
input Absyn.AlgorithmItem inAlgorithmItem;
input GlobalScript.SymbolTable inSymbolTable;
output String outString;
output GlobalScript.SymbolTable outSymbolTable;
algorithm
(outString,outSymbolTable) := matchcontinue (inAlgorithmItem,inSymbolTable)
local
FCore.Graph env;
DAE.Exp econd,msg_1,sexp,srexp;
DAE.Properties prop,rprop;
GlobalScript.SymbolTable st_1,st_2,st_3,st_4,st,newst;
Absyn.Exp cond,msg,exp,rexp;
Absyn.Program p;
String str,ident;
DAE.Type t;
Values.Value value;
list<DAE.Type> types;
list<String> idents;
list<Values.Value> values,valList;
list<Absyn.Exp> crefexps;
tuple<Absyn.Exp, list<Absyn.AlgorithmItem>> cond1;
list<tuple<Absyn.Exp, list<Absyn.AlgorithmItem>>> cond2,cond3,elseifexpitemlist;
list<Absyn.AlgorithmItem> algitemlist,elseitemlist;
list<GlobalScript.Variable> vars;
String iter,estr;
list<Absyn.AlgorithmItem> algItemList;
Values.Value startv, stepv, stopv;
Absyn.Exp starte, stepe, stope;
Absyn.ComponentRef cr;
FCore.Cache cache;
SourceInfo info;
Absyn.FunctionArgs fargs;
list<Absyn.Subscript> asubs;
list<DAE.Subscript> dsubs;
list<DAE.ComponentRef> crefs;
case (Absyn.ALGORITHMITEM(info=info,
algorithm_ = Absyn.ALG_NORETCALL(functionCall = Absyn.CREF_IDENT(name = "assert"),
functionArgs = Absyn.FUNCTIONARGS(args = {cond,_}))),
(st as GlobalScript.SYMBOLTABLE()))
equation
(env,st) = GlobalScriptUtil.buildEnvFromSymboltable(st);
(cache,econd,_,SOME(st_1)) = StaticScript.elabExp(FCore.emptyCache(), env, cond, true, SOME(st), true, Prefix.NOPRE(), info);
(_,Values.BOOL(true),SOME(st_2)) = CevalScript.ceval(cache,env, econd, true, SOME(st_1), Absyn.MSG(info), 0);
then
("",st_2);
case (Absyn.ALGORITHMITEM(info=info,algorithm_ = Absyn.ALG_NORETCALL(functionCall = Absyn.CREF_IDENT(name = "assert"),
functionArgs = Absyn.FUNCTIONARGS(args = {_,msg}))),
(st as GlobalScript.SYMBOLTABLE()))
equation
(env,st) = GlobalScriptUtil.buildEnvFromSymboltable(st);
(cache,msg_1,_,SOME(st_1)) = StaticScript.elabExp(FCore.emptyCache(), env, msg, true, SOME(st), true, Prefix.NOPRE(), info);
(_,Values.STRING(str),SOME(st_2)) = CevalScript.ceval(cache,env, msg_1, true, SOME(st_1), Absyn.MSG(info), 0);
then
(str,st_2);
case (Absyn.ALGORITHMITEM(info=info,algorithm_ = Absyn.ALG_NORETCALL(functionCall = cr,functionArgs = fargs)),st)
equation
(env,st) = GlobalScriptUtil.buildEnvFromSymboltable(st);
exp = Absyn.CALL(cr,fargs);
(cache,sexp,_,SOME(st_1)) = StaticScript.elabExp(FCore.emptyCache(), env, exp, true, SOME(st), true, Prefix.NOPRE(), info);
(_,_,SOME(st_2)) = CevalScript.ceval(cache, env, sexp, true, SOME(st_1), Absyn.MSG(info), 0);
then
("",st_2);
// Special case to lookup fields of records.
// SimulationResult, etc are not in the environment,
// but it's nice to be able to script them anyway
case (Absyn.ALGORITHMITEM(algorithm_ =
Absyn.ALG_ASSIGN(assignComponent =
Absyn.CREF(Absyn.CREF_IDENT(name = ident,subscripts = {})),value = Absyn.CREF(cr))),
(st as GlobalScript.SYMBOLTABLE(lstVarVal = vars)))
equation
value = getVariableValueLst(Absyn.pathToStringList(Absyn.crefToPath(cr)), vars);
str = ValuesUtil.valString(value);
t = Types.typeOfValue(value);
newst = GlobalScriptUtil.addVarToSymboltable(DAE.CREF_IDENT(ident, t, {}), value, FGraph.empty(), st);
then (str,newst);
case
(Absyn.ALGORITHMITEM(info=info,algorithm_ =
Absyn.ALG_ASSIGN(assignComponent =
Absyn.CREF(Absyn.CREF_IDENT(name = ident,subscripts = asubs)),value = exp)),
(st as GlobalScript.SYMBOLTABLE()))
equation
(env,st) = GlobalScriptUtil.buildEnvFromSymboltable(st);
(cache,sexp,DAE.PROP(_,_),SOME(st_1)) = StaticScript.elabExp(FCore.emptyCache(),env, exp, true, SOME(st),true,Prefix.NOPRE(),info);
(_,value,SOME(st_2)) = CevalScript.ceval(cache,env, sexp, true,SOME(st_1),Absyn.MSG(info),0);
(_, dsubs, _) = Static.elabSubscripts(cache, env, asubs, true, Prefix.NOPRE(), info);
t = Types.typeOfValue(value) "This type can be more specific than the elaborated type; if the dimensions are unknown...";
str = ValuesUtil.valString(value);
newst = GlobalScriptUtil.addVarToSymboltable(DAE.CREF_IDENT(ident, t, dsubs), value, env, st_2);
then
(str,newst);
// Since expressions cannot be tuples an empty string is returned
case
(Absyn.ALGORITHMITEM(info=info,algorithm_ =
Absyn.ALG_ASSIGN(assignComponent =
Absyn.TUPLE(expressions = crefexps),value = rexp)),
(st as GlobalScript.SYMBOLTABLE()))
equation
(env,st) = GlobalScriptUtil.buildEnvFromSymboltable(st);
(cache,srexp,rprop,SOME(st_1)) = StaticScript.elabExp(FCore.emptyCache(),env, rexp, true, SOME(st),true,Prefix.NOPRE(),info);
DAE.T_TUPLE(types = types) = Types.getPropType(rprop);
crefs = makeTupleCrefs(crefexps, types, env, cache, info);
(_,Values.TUPLE(values),SOME(st_2)) = CevalScript.ceval(cache, env, srexp, true, SOME(st_1), Absyn.MSG(info),0);
newst = GlobalScriptUtil.addVarsToSymboltable(crefs, values, env, st_2);
then
("",newst);
// if statement
case
(Absyn.ALGORITHMITEM(info=info,algorithm_ =
Absyn.ALG_IF(
ifExp = exp,
trueBranch = algitemlist,
elseIfAlgorithmBranch = elseifexpitemlist,
elseBranch = elseitemlist)),st)
equation
cond1 = (exp,algitemlist);
cond2 = (cond1 :: elseifexpitemlist);
cond3 = listAppend(cond2, {(Absyn.BOOL(true), elseitemlist)});
st_1 = evaluateIfStatementLst(cond3,st,info);
then
("",st_1);
// while-statement
case (Absyn.ALGORITHMITEM(info=info,algorithm_ = Absyn.ALG_WHILE(boolExpr = exp,whileBody = algitemlist)),st)
equation
(value,st_1) = evaluateExpr(exp, st, info);
st_2 = evaluateWhileStmt(value, exp, algitemlist, st_1,info);
then
("",st_2);
// for-statement, optimized case, e.g.: for i in 1:1000 loop
case (Absyn.ALGORITHMITEM(info=info,algorithm_ =
Absyn.ALG_FOR(iterators = {Absyn.ITERATOR(iter, NONE(), SOME(Absyn.RANGE(start=starte,step=NONE(), stop=stope)))},
forBody = algItemList)),st)
equation
(startv,st_1) = evaluateExpr(starte, st, info);
(stopv,st_2) = evaluateExpr(stope, st_1, info);
st_3 = evaluateForStmtRangeOpt(iter, startv, Values.INTEGER(1), stopv, algItemList, st_2);
then
("",st_3);
// for-statement, optimized case, e.g.: for i in 7.3:0.4:1000.3 loop
case (Absyn.ALGORITHMITEM(info=info,algorithm_ =
Absyn.ALG_FOR(iterators = {Absyn.ITERATOR(iter, NONE(), SOME(Absyn.RANGE(start=starte, step=SOME(stepe), stop=stope)))},
forBody = algItemList)),st)
equation
(startv,st_1) = evaluateExpr(starte, st, info);
(stepv,st_2) = evaluateExpr(stepe, st_1, info);
(stopv,st_3) = evaluateExpr(stope, st_2, info);
st_4 = evaluateForStmtRangeOpt(iter, startv, stepv, stopv, algItemList, st_3);
then
("",st_4);
// for-statement, general case
case (Absyn.ALGORITHMITEM(info=info,algorithm_ =
Absyn.ALG_FOR(iterators = {Absyn.ITERATOR(iter, NONE(), SOME(exp))},forBody = algItemList)),st)
equation
(Values.ARRAY(valueLst = valList),st_1) = evaluateExpr(exp, st, info);
st_2 = evaluateForStmt(iter, valList, algItemList, st_1);
then
("",st_2);
// for-statement - not an array type
case (Absyn.ALGORITHMITEM(info=info,algorithm_ = Absyn.ALG_FOR(iterators = {Absyn.ITERATOR(range = SOME(exp))})),st)
equation
(estr,_) = stringRepresOfExpr(exp, st);
Error.addSourceMessage(Error.NOT_ARRAY_TYPE_IN_FOR_STATEMENT, {estr}, info);
then
fail();
end matchcontinue;
end evaluateAlgStmt;
protected function evaluateForStmt
"evaluates a for-statement in an algorithm section"
input String iter "The iterator variable which will be assigned different values";
input list<Values.Value> valList "List of values that the iterator later will be assigned to";
input list<Absyn.AlgorithmItem> algItemList;
input GlobalScript.SymbolTable inSymbolTable;
output GlobalScript.SymbolTable outSymbolTable;
protected GlobalScript.SymbolTable st = inSymbolTable;
algorithm
for val in valList loop
st := GlobalScriptUtil.appendVarToSymboltable(iter, val, Types.typeOfValue(val), st);
st := evaluateAlgStmtLst(algItemList, st);
st := GlobalScriptUtil.deleteVarFromSymboltable(iter, st);
end for;
outSymbolTable := st;
end evaluateForStmt;
protected function evaluateForStmtRangeOpt
"Optimized version of for statement. In this case, we do not create a large array if
a range expression is given. E.g. for i in 1:10000 loop"
input String iter "The iterator variable which will be assigned different values";
input Values.Value startVal;
input Values.Value stepVal;
input Values.Value stopVal;
input list<Absyn.AlgorithmItem> algItems;
input GlobalScript.SymbolTable inSymbolTable;
output GlobalScript.SymbolTable st;
protected
Values.Value val;
GlobalScript.SymbolTable st2 "Introduced to avoid leaving the symbol table containing the iterator";
algorithm
st := inSymbolTable;
val := startVal;
try
while ValuesUtil.safeLessEq(val, stopVal) loop
st2 := GlobalScriptUtil.appendVarToSymboltable(iter, val, Types.typeOfValue(val), st);
st2 := evaluateAlgStmtLst(algItems, st2);
st2 := GlobalScriptUtil.deleteVarFromSymboltable(iter, st2);
val := ValuesUtil.safeIntRealOp(val, stepVal, Values.ADDOP());
st := st2;
end while;
else
// Just... ignore errors and stop the loop. Really bad, I know...
end try;
end evaluateForStmtRangeOpt;
protected function evaluateWhileStmt
"Recursively evaluates the while statement.
Note that it is tail-recursive, so we should result
in a iterative implementation."
input Values.Value inValue;
input Absyn.Exp inExp;
input list<Absyn.AlgorithmItem> inAbsynAlgorithmItemLst;
input GlobalScript.SymbolTable inSymbolTable;
input SourceInfo info;
output GlobalScript.SymbolTable outSymbolTable;
algorithm
outSymbolTable:=
matchcontinue (inValue,inExp,inAbsynAlgorithmItemLst,inSymbolTable,info)
local
GlobalScript.SymbolTable st,st_1,st_2,st_3;
Values.Value value;
Absyn.Exp exp;
list<Absyn.AlgorithmItem> algitemlst;
String estr,tstr;
DAE.Type vtype;
case (Values.BOOL(boolean = false),_,_,st,_) then st;
case (Values.BOOL(boolean = true),exp,algitemlst,st,_)
equation
st_1 = evaluateAlgStmtLst(algitemlst, st);
(value,st_2) = evaluateExpr(exp, st_1, info);
st_3 = evaluateWhileStmt(value, exp, algitemlst, st_2, info); /* Tail recursive */
then
st_3;
// An error occured when evaluating the algorithm items
case (Values.BOOL(_), _,_,st,_)
then
st;
// The condition value was not a boolean
case (value,exp,_,st,_)
equation
(estr,_) = stringRepresOfExpr(exp, st);
vtype = Types.typeOfValue(value);
tstr = Types.unparseTypeNoAttr(vtype);
Error.addSourceMessage(Error.WHILE_CONDITION_TYPE_ERROR, {estr,tstr}, info);
then
fail();
end matchcontinue;
end evaluateWhileStmt;
protected function evaluatePartOfIfStatement
"Evaluates one part of a if statement, i.e. one \"case\". If the condition is true, the algorithm items
associated with this condition are evaluated. The first argument returned is set to true if the
condition was evaluated to true. Fails if the value is not a boolean.
Note that we are sending the expression as an value, so that it does not need to be evaluated twice."
input Values.Value inValue;
input Absyn.Exp inExp;
input list<Absyn.AlgorithmItem> inAbsynAlgorithmItemLst;
input list<tuple<Absyn.Exp, list<Absyn.AlgorithmItem>>> inTplAbsynExpAbsynAlgorithmItemLstLst;
input GlobalScript.SymbolTable inSymbolTable;
input SourceInfo info;
output GlobalScript.SymbolTable outSymbolTable;
algorithm
outSymbolTable:=
matchcontinue (inValue,inExp,inAbsynAlgorithmItemLst,inTplAbsynExpAbsynAlgorithmItemLstLst,inSymbolTable,info)
local
GlobalScript.SymbolTable st_1,st;
list<Absyn.AlgorithmItem> algitemlst;
list<tuple<Absyn.Exp, list<Absyn.AlgorithmItem>>> algrest;
String estr,tstr;
DAE.Type vtype;
Values.Value value;
Absyn.Exp exp;
case (Values.BOOL(boolean = true),_,algitemlst,_,st,_)
equation
st_1 = evaluateAlgStmtLst(algitemlst, st);
then
st_1;
case (Values.BOOL(boolean = false),_,_,algrest,st,_)
equation
st_1 = evaluateIfStatementLst(algrest, st, info);
then
st_1;
// Report type error
case (value,exp,_,_,st,_)
equation
(estr,_) = stringRepresOfExpr(exp, st);
vtype = Types.typeOfValue(value);
tstr = Types.unparseTypeNoAttr(vtype);
Error.addSourceMessage(Error.IF_CONDITION_TYPE_ERROR, {estr,tstr}, info);
then
fail();
end matchcontinue;
end evaluatePartOfIfStatement;
protected function evaluateIfStatementLst
"Evaluates all parts of a if statement
(i.e. a list of exp statements)"
input list<tuple<Absyn.Exp, list<Absyn.AlgorithmItem>>> inTplAbsynExpAbsynAlgorithmItemLstLst;
input GlobalScript.SymbolTable inSymbolTable;
input SourceInfo info;
output GlobalScript.SymbolTable outSymbolTable;
algorithm
outSymbolTable:=
match (inTplAbsynExpAbsynAlgorithmItemLstLst,inSymbolTable,info)
local
GlobalScript.SymbolTable st,st_1,st_2;
Values.Value value;
Absyn.Exp exp;
list<Absyn.AlgorithmItem> algitemlst;
list<tuple<Absyn.Exp, list<Absyn.AlgorithmItem>>> algrest;
case ({},st,_) then st;
case (((exp,algitemlst) :: algrest),st,_)
equation
(value,st_1) = evaluateExpr(exp, st, info);
st_2 = evaluatePartOfIfStatement(value, exp, algitemlst, algrest, st_1, info);
then
st_2;
end match;
end evaluateIfStatementLst;
protected function evaluateAlgStmtLst
" Evaluates a list of algorithm statements"
input list<Absyn.AlgorithmItem> inAbsynAlgorithmItemLst;
input GlobalScript.SymbolTable inSymbolTable;
output GlobalScript.SymbolTable outSymbolTable;
protected
GlobalScript.SymbolTable st = inSymbolTable;
algorithm
for algitem in inAbsynAlgorithmItemLst loop
(_,st) := evaluateAlgStmt(algitem, st);
end for;
outSymbolTable := st;
end evaluateAlgStmtLst;
protected function evaluateExpr
" Evaluates an expression and returns its value.
We need to return the symbol table, since the command loadFile()
reads in data to the interactive environment.
Note that this function may fail.
Input: Absyn.Exp - Expression to be evaluated
GlobalScript.SymbolTable - The symbol table
Output: Values.Value - Resulting value of the expression"
input Absyn.Exp inExp;
input GlobalScript.SymbolTable inSymbolTable;
input SourceInfo info;
output Values.Value outValue;
output GlobalScript.SymbolTable outSymbolTable;
algorithm
(outValue,outSymbolTable):=
matchcontinue (inExp,inSymbolTable,info)
local
FCore.Graph env;
DAE.Exp sexp;
DAE.Properties prop;
GlobalScript.SymbolTable st_1,st_2,st;
Values.Value value;
Absyn.Exp exp;
Absyn.Program p;
FCore.Cache cache;
list<GlobalScript.Variable> vars;
Absyn.ComponentRef cr;
// Special case to lookup fields of records.
// SimulationResult, etc are not in the environment, but it's nice to be able to script them anyway */
case (Absyn.CREF(cr),(st as GlobalScript.SYMBOLTABLE(lstVarVal = vars)),_)
equation
value = getVariableValueLst(Absyn.pathToStringList(Absyn.crefToPath(cr)), vars);
then
(value,st);
case (exp,(st as GlobalScript.SYMBOLTABLE()),_)
equation
(env,st) = GlobalScriptUtil.buildEnvFromSymboltable(st);
(cache,sexp,_,SOME(st_1)) = StaticScript.elabExp(FCore.emptyCache(), env, exp, true, SOME(st), true, Prefix.NOPRE(), info);
(_,value,SOME(st_2)) = CevalScript.ceval(cache, env, sexp, true, SOME(st_1), Absyn.MSG(info),0);
then
(value,st_2);
end matchcontinue;
end evaluateExpr;
protected function stringRepresOfExpr
" This function returns a string representation of an expression. For example expression
33+22 will result in \"55\" and expression: \"my\" + \"string\" will result in \"\"my\"+\"string\"\". "
input Absyn.Exp exp;
input GlobalScript.SymbolTable ist;
output String estr;
output GlobalScript.SymbolTable st;
protected
FCore.Graph env;
DAE.Exp sexp;
DAE.Properties prop;
GlobalScript.SymbolTable st_1;
algorithm
(env,st) := GlobalScriptUtil.buildEnvFromSymboltable(ist);
(_,sexp,prop,SOME(st_1)) := StaticScript.elabExp(FCore.emptyCache(), env, exp, true, SOME(st), true, Prefix.NOPRE(), Absyn.dummyInfo);
(_, sexp, prop) := Ceval.cevalIfConstant(FCore.emptyCache(), env, sexp, prop, true, Absyn.dummyInfo);
estr := ExpressionDump.printExpStr(sexp);
end stringRepresOfExpr;
protected function evaluateExprToStr
" This function is similar to evaluateExpr, with the difference that it returns a string
and that it never fails. If the expression contain errors, an empty string will be returned
and the errors will be stated using Error.mo
Input: Absyn.Exp - Expression to be evaluated
GlobalScript.SymbolTable - The symbol table
Output: string - The resulting value represented as a string"
input Absyn.Exp inExp;
input GlobalScript.SymbolTable inSymbolTable;
input SourceInfo info;
output String outString;
output GlobalScript.SymbolTable outSymbolTable;
algorithm
(outString,outSymbolTable):=
matchcontinue (inExp,inSymbolTable,info)
local
Values.Value value;
GlobalScript.SymbolTable st_1,st;
String str;
Absyn.Exp exp;
case (exp,st,_)
equation
(value,st_1) = evaluateExpr(exp, st, info);
str = ValuesUtil.valString(value);
then
(str,st_1);
else ("",inSymbolTable);
end matchcontinue;
end evaluateExprToStr;
protected function makeTupleCrefs
input list<Absyn.Exp> inCrefs;
input list<DAE.Type> inTypes;
input FCore.Graph inEnv;
input FCore.Cache inCache;
input SourceInfo inInfo;
output list<DAE.ComponentRef> outCrefs;
algorithm
outCrefs := List.threadMap3(inCrefs, inTypes, makeTupleCref, inEnv, inCache, inInfo);
end makeTupleCrefs;
protected function makeTupleCref
"Translates an Absyn.CREF to a DAE.CREF_IDENT."
input Absyn.Exp inCref;
input DAE.Type inType;
input FCore.Graph inEnv;
input FCore.Cache inCache;
input SourceInfo inInfo;
output DAE.ComponentRef outCref;
algorithm
outCref := match(inCref, inType, inEnv, inCache, inInfo)
local
Absyn.Ident id;
list<Absyn.Subscript> asubs;
list<DAE.Subscript> dsubs;
String str;
case (Absyn.CREF(componentRef = Absyn.CREF_IDENT(id, asubs)), _, _, _, _)
equation
(_, dsubs, _) = Static.elabSubscripts(inCache, inEnv, asubs, true,
Prefix.NOPRE(), inInfo);
then
DAE.CREF_IDENT(id, inType, dsubs);
else
equation
str = Dump.printExpStr(inCref);
Error.addMessage(Error.INVALID_TUPLE_CONTENT, {str});
then
fail();
end match;
end makeTupleCref;
public function getTypeOfVariable
"Return the type of an interactive variable,
given a list of variables and a variable identifier."
input Absyn.Ident inIdent;
input list<GlobalScript.Variable> inVariableLst;
output DAE.Type outType;
protected
String id;
DAE.Type tp;
algorithm
for var in inVariableLst loop
GlobalScript.IVAR(varIdent = id,type_ = tp) := var;
if stringEq(inIdent, id) then
outType := tp;
return;
end if;
end for;
// did not find a type
fail();
end getTypeOfVariable;
protected function getApiFunctionNameInfo
"Returns the name of the called API function."
input GlobalScript.Statements inStmts;
output String outName;
output SourceInfo outInfo;
algorithm
GlobalScript.ISTMTS(interactiveStmtLst = {GlobalScript.IEXP(
exp = Absyn.CALL(function_ = Absyn.CREF_IDENT(name = outName)),
info = outInfo
)}) := inStmts;
end getApiFunctionNameInfo;
protected function getApiFunctionArgs
"Returns a list of arguments to the function in the interactive statement list."
input GlobalScript.Statements inStmts;
output list<Absyn.Exp> outArgs;
algorithm
outArgs := match(inStmts)
local
list<Absyn.Exp> args;
case (GlobalScript.ISTMTS(interactiveStmtLst = {GlobalScript.IEXP(exp = Absyn.CALL(functionArgs =
Absyn.FUNCTIONARGS(args = args)))})) then args;
else {};
end match;
end getApiFunctionArgs;
protected function getApiFunctionNamedArgs
"Returns a list of named arguments to the function in the interactive statement list."
input GlobalScript.Statements inStmts;
output list<Absyn.NamedArg> outArgs;
algorithm
outArgs := match(inStmts)
local list<Absyn.NamedArg> args;
case (GlobalScript.ISTMTS(interactiveStmtLst = {GlobalScript.IEXP(exp = Absyn.CALL(functionArgs =
Absyn.FUNCTIONARGS(argNames = args)))})) then args;
end match;
end getApiFunctionNamedArgs;
protected function evaluateGraphicalApi
"Evaluating graphical api.
NOTE: the graphical API is always evaluated with checkModel ON and +d=nogen,noevalfunc ON"
input GlobalScript.Statements inStatements;
input GlobalScript.SymbolTable inSymbolTable;
input Boolean isPartialInst;
input Boolean flagGen;
input Boolean flagEvalFunc;
input Boolean flagKeepArrays;
output String outResult;
output GlobalScript.SymbolTable outSymbolTable;
protected
String fn_name;
SourceInfo info;
Boolean failed = false;
algorithm
try
(outResult, outSymbolTable) :=
evaluateGraphicalApi_dispatch(inStatements, inSymbolTable);
else
failed := true;
end try;
// Reset the flags!
System.setPartialInstantiation(isPartialInst);
Flags.set(Flags.GEN, flagGen);
Flags.set(Flags.EVAL_FUNC, flagEvalFunc);
Flags.setConfigBool(Flags.KEEP_ARRAYS, flagKeepArrays);
if failed then fail(); end if;
end evaluateGraphicalApi;
protected function evaluateGraphicalApi_dispatch
"This function evaluates all primitives in the graphical api."
input GlobalScript.Statements inStatements;
input GlobalScript.SymbolTable inSymbolTable;
output String outResult;
output GlobalScript.SymbolTable outSymbolTable = inSymbolTable;
protected
String fn_name, name;
Absyn.Program old_p, p, p_1;
SCode.Program s;
list<Absyn.Exp> args, expl;
Absyn.ComponentRef cr, cr1, cr2, tp, model_, class_, old_cname, new_cname;
Absyn.ComponentRef crident, subident;
Absyn.Path path;
list<Absyn.NamedArg> nargs;
Integer n;
String cmt, variability, causality/*, isField*/;