/
Static.mo
12956 lines (12104 loc) · 503 KB
/
Static.mo
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/*
* This file is part of OpenModelica.
*
* Copyright (c) 1998-CurrentYear, Linköping University,
* Department of Computer and Information Science,
* SE-58183 Linköping, Sweden.
*
* All rights reserved.
*
* THIS PROGRAM IS PROVIDED UNDER THE TERMS OF GPL VERSION 3
* AND THIS OSMC PUBLIC LICENSE (OSMC-PL).
* ANY USE, REPRODUCTION OR DISTRIBUTION OF THIS PROGRAM CONSTITUTES RECIPIENT'S
* ACCEPTANCE OF THE OSMC PUBLIC LICENSE.
*
* The OpenModelica software and the Open Source Modelica
* Consortium (OSMC) Public License (OSMC-PL) are obtained
* from Linköping University, either from the above address,
* from the URLs: http://www.ida.liu.se/projects/OpenModelica or
* http://www.openmodelica.org, and in the OpenModelica distribution.
* GNU version 3 is obtained from: http://www.gnu.org/copyleft/gpl.html.
*
* This program is distributed WITHOUT ANY WARRANTY; without
* even the implied warranty of MERCHANTABILITY or FITNESS
* FOR A PARTICULAR PURPOSE, EXCEPT AS EXPRESSLY SET FORTH
* IN THE BY RECIPIENT SELECTED SUBSIDIARY LICENSE CONDITIONS
* OF OSMC-PL.
*
* See the full OSMC Public License conditions for more details.
*
*/
encapsulated package Static
" file: Static.mo
package: Static
description: Static analysis of expressions
RCS: $Id$
This module does static analysis on expressions.
The analyzed expressions are built using the
constructors in the `Exp\' module from expressions defined in \'Absyn\'.
Also, a set of properties of the expressions is calculated during analysis.
Properties of expressions include type information and a boolean indicating if the
expression is constant or not.
If the expression is constant, the \'Ceval\' module is used to evaluate the expression
value. A value of an expression is described using the \'Values\' module.
The main function in this module is evalExp which takes an Absyn.Exp and transform it
into an DAE.Exp, while performing type checking and automatic type conversions, etc.
To determine types of builtin functions and operators, the module also contain an elaboration
handler for functions and operators. This function is called elabBuiltinHandler.
NOTE: These functions should only determine the type and properties of the builtin functions and
operators and not evaluate them. Constant evaluation is performed by the Ceval module.
The module also contain a function for deoverloading of operators, in the \'deoverload\' function.
It transforms operators like \'+\' to its specific form, ADD, ADD_ARR, etc.
Interactive function calls are also given their types by elabExp, which calls
elabCallInteractive.
Elaboration for functions involve checking the types of the arguments by filling slots of the
argument list with first positional and then named arguments to find a matching function. The
details of this mechanism can be found in the Modelica specification.
The elaboration also contain function deoverloading which will be added to Modelica in the future."
public import Absyn;
public import DAE;
public import Env;
public import Interactive;
public import MetaUtil;
public import RTOpts;
public import SCode;
public import SCodeUtil;
public import Values;
public import Prefix;
public import Util;
public type Ident = String;
public
uniontype Slot
record SLOT
DAE.FuncArg an "An argument to a function" ;
Boolean slotFilled "True if the slot has been filled, i.e. argument has been given a value" ;
Option<DAE.Exp> expExpOption;
list<DAE.Dimension> typesArrayDimLst;
end SLOT;
end Slot;
protected import Ceval;
protected import ClassInf;
protected import ComponentReference;
protected import Connect;
protected import Debug;
protected import Dump;
protected import Error;
protected import ErrorExt;
protected import Expression;
protected import ExpressionDump;
protected import ExpressionSimplify;
protected import Inline;
protected import Inst;
protected import InnerOuter;
protected import Lookup;
protected import Mod;
protected import ModUtil;
protected import OptManager;
protected import Patternm;
protected import Print;
protected import System;
protected import Types;
protected import ValuesUtil;
protected import DAEUtil;
protected import PrefixUtil;
protected import CevalScript;
protected import VarTransform;
public function elabExpList "Expression elaboration of Absyn.Exp list, i.e. lists of expressions."
input Env.Cache inCache;
input Env.Env inEnv;
input list<Absyn.Exp> inAbsynExpLst;
input Boolean inImplicit;
input Option<Interactive.InteractiveSymbolTable> inInteractiveInteractiveSymbolTableOption;
input Boolean performVectorization;
input Prefix.Prefix inPrefix;
input Absyn.Info info;
output Env.Cache outCache;
output list<DAE.Exp> outExpExpLst;
output list<DAE.Properties> outTypesPropertiesLst;
output Option<Interactive.InteractiveSymbolTable> outInteractiveInteractiveSymbolTableOption;
algorithm
(outCache,outExpExpLst,outTypesPropertiesLst,outInteractiveInteractiveSymbolTableOption):=
match (inCache,inEnv,inAbsynExpLst,inImplicit,inInteractiveInteractiveSymbolTableOption,performVectorization,inPrefix,info)
local
Boolean impl;
Option<Interactive.InteractiveSymbolTable> st,st_1,st_2;
DAE.Exp exp;
DAE.Properties p;
list<DAE.Exp> exps;
list<DAE.Properties> props;
list<Env.Frame> env;
Absyn.Exp e;
list<Absyn.Exp> rest;
Env.Cache cache;
Boolean doVect;
Prefix.Prefix pre;
case (cache,_,{},impl,st,doVect,_,_) then (cache,{},{},st);
case (cache,env,(e :: rest),impl,st,doVect,pre,info)
equation
(cache,exp,p,st_1) = elabExp(cache,env, e, impl, st,doVect,pre,info);
(cache,exps,props,st_2) = elabExpList(cache,env, rest, impl, st_1,doVect,pre,info);
then
(cache,(exp :: exps),(p :: props),st_2);
end match;
end elabExpList;
public function elabExpListList
"function: elabExpListList
Expression elaboration of lists of lists of expressions.
Used in for instance matrices, etc."
input Env.Cache inCache;
input Env.Env inEnv;
input list<list<Absyn.Exp>> inAbsynExpLstLst;
input Boolean inBoolean;
input Option<Interactive.InteractiveSymbolTable> inInteractiveInteractiveSymbolTableOption;
input Boolean performVectorization;
input Prefix.Prefix inPrefix;
input Absyn.Info info;
output Env.Cache outCache;
output list<list<DAE.Exp>> outExpExpLstLst;
output list<list<DAE.Properties>> outTypesPropertiesLstLst;
output Option<Interactive.InteractiveSymbolTable> outInteractiveInteractiveSymbolTableOption;
algorithm
(outCache,outExpExpLstLst,outTypesPropertiesLstLst,outInteractiveInteractiveSymbolTableOption):=
match (inCache,inEnv,inAbsynExpLstLst,inBoolean,inInteractiveInteractiveSymbolTableOption,performVectorization,inPrefix,info)
local
Boolean impl;
Option<Interactive.InteractiveSymbolTable> st,st_1,st_2;
list<DAE.Exp> exp;
list<DAE.Properties> p;
list<list<DAE.Exp>> exps;
list<list<DAE.Properties>> props;
list<Env.Frame> env;
list<Absyn.Exp> e;
list<list<Absyn.Exp>> rest;
Env.Cache cache;
Boolean doVect;
Prefix.Prefix pre;
case (cache,_,{},impl,st,doVect,_,_) then (cache,{},{},st);
case (cache,env,(e :: rest),impl,st,doVect,pre,info)
equation
(cache,exp,p,st_1) = elabExpList(cache,env, e, impl, st,doVect,pre,info);
(cache,exps,props,st_2) = elabExpListList(cache,env, rest, impl, st_1,doVect,pre,info);
then
(cache,(exp :: exps),(p :: props),st_2);
end match;
end elabExpListList;
protected function elabExpOptAndMatchType "
elabExp, but for Option<Absyn.Exp>,DAE.Type => Option<DAE.Exp>"
input Env.Cache inCache;
input Env.Env inEnv;
input Option<Absyn.Exp> oExp;
input DAE.Type defaultType;
input Boolean inBoolean;
input Option<Interactive.InteractiveSymbolTable> inSt;
input Boolean performVectorization;
input Prefix.Prefix inPrefix;
input Absyn.Info info;
output Env.Cache cache;
output Option<DAE.Exp> outExp;
output DAE.Properties prop;
output Option<Interactive.InteractiveSymbolTable> st;
algorithm
(cache,outExp,prop,st) := match (inCache,inEnv,oExp,defaultType,inBoolean,inSt,performVectorization,inPrefix,info)
local
Absyn.Exp inExp;
DAE.Exp exp;
case (_,_,SOME(inExp),_,_,_,_,_,_)
equation
(cache,exp,prop,st) = elabExp(inCache,inEnv,inExp,inBoolean,inSt,performVectorization,inPrefix,info);
(exp,prop) = Types.matchProp(exp,prop,DAE.PROP(defaultType,DAE.C_CONST()),true);
then (cache,SOME(exp),prop,st);
else (inCache,NONE(),DAE.PROP(defaultType,DAE.C_CONST()),inSt);
end match;
end elabExpOptAndMatchType;
public function elabExp "
function: elabExp
Static analysis of expressions means finding out the properties of
the expression. These properties are described by the
`DAE.Properties\' type, and include the type and the variability of the
expression. This function performs analysis, and returns an
`DAE.Exp\' and the properties."
input Env.Cache inCache;
input Env.Env inEnv;
input Absyn.Exp inExp;
input Boolean inImplicit;
input Option<Interactive.InteractiveSymbolTable> inInteractiveInteractiveSymbolTableOption;
input Boolean performVectorization;
input Prefix.Prefix inPrefix;
input Absyn.Info info;
output Env.Cache outCache;
output DAE.Exp outExp;
output DAE.Properties outProperties;
output Option<Interactive.InteractiveSymbolTable> st;
algorithm
(outCache,outExp,outProperties,st) := elabExp2(inCache,inEnv,inExp,inImplicit,inInteractiveInteractiveSymbolTableOption,performVectorization,inPrefix,info,Error.getNumErrorMessages());
end elabExp;
protected function elabExp2 "
function: elabExp
Static analysis of expressions means finding out the properties of
the expression. These properties are described by the
`DAE.Properties\' type, and include the type and the variability of the
expression. This function performs analysis, and returns an
`DAE.Exp\' and the properties."
input Env.Cache inCache;
input Env.Env inEnv;
input Absyn.Exp inExp;
input Boolean inImplicit;
input Option<Interactive.InteractiveSymbolTable> inInteractiveInteractiveSymbolTableOption;
input Boolean performVectorization;
input Prefix.Prefix inPrefix;
input Absyn.Info info;
input Integer numErrorMessages;
output Env.Cache outCache;
output DAE.Exp outExp;
output DAE.Properties outProperties;
output Option<Interactive.InteractiveSymbolTable> outInteractiveInteractiveSymbolTableOption;
algorithm
(outCache,outExp,outProperties,outInteractiveInteractiveSymbolTableOption):=
matchcontinue (inCache,inEnv,inExp,inImplicit,inInteractiveInteractiveSymbolTableOption,performVectorization,inPrefix,info,numErrorMessages)
local
Boolean impl,a,b,havereal,doVect;
Integer l,i,nmax;
Real r;
String expstr,str1,str2,s,msg;
DAE.Dimension dim1,dim2;
Option<Interactive.InteractiveSymbolTable> st,st_1,st_2,st_3;
DAE.Exp exp,e1_1,e2_1,e1_2,e2_2,exp_1,e_1,e_2,e3_1,mexp,mexp_1,arrexp;
DAE.Properties prop,prop1,prop2,prop3;
list<Env.Frame> env;
Absyn.ComponentRef cr,fn;
DAE.Type t,t1,t2,arrtp,rtype,t_1,t_2,tp,ty;
DAE.Const c1,c2,c,const;
list<tuple<DAE.Operator, list<tuple<DAE.TType, Option<Absyn.Path>>>, tuple<DAE.TType, Option<Absyn.Path>>>> ops;
DAE.Operator op_1;
Absyn.Exp e,e1,e2,e3;
Absyn.Operator op;
list<Absyn.Exp> args,es;
list<Absyn.NamedArg> nargs;
list<DAE.Exp> es_1;
list<DAE.Properties> props,propList;
list<tuple<DAE.TType, Option<Absyn.Path>>> types,tps_2;
list<DAE.TupleConst> consts;
DAE.ExpType at,tp_1;
list<list<DAE.Properties>> tps;
list<list<tuple<DAE.TType, Option<Absyn.Path>>>> tps_1;
Env.Cache cache;
Absyn.ForIterators iterators;
Prefix.Prefix pre;
list<list<Absyn.Exp>> ess;
list<list<DAE.Exp>> dess;
Absyn.CodeNode cn;
list<DAE.Type> typeList;
list<DAE.Const> constList;
/* uncomment for debuging
case (cache,_,inExp,impl,st,doVect,_,info)
equation
print("Static.elabExp: " +& Dump.dumpExpStr(inExp) +& "\n");
then
fail();
*/
// The types below should contain the default values of the attributes of the builtin
// types. But since they are default, we can leave them out for now, unit=\"\" is not
// that interesting to find out.
case (cache,_,Absyn.INTEGER(value = i),impl,st,doVect,_,info,_)
then (cache,DAE.ICONST(i),DAE.PROP(DAE.T_INTEGER_DEFAULT,DAE.C_CONST()),st);
case (cache,_,Absyn.REAL(value = r),impl,st,doVect,_,info,_)
then
(cache,DAE.RCONST(r),DAE.PROP(DAE.T_REAL_DEFAULT,DAE.C_CONST()),st);
case (cache,_,Absyn.STRING(value = s),impl,st,doVect,_,info,_)
equation
s = System.unescapedString(s);
then
(cache,DAE.SCONST(s),DAE.PROP(DAE.T_STRING_DEFAULT,DAE.C_CONST()),st);
case (cache,_,Absyn.BOOL(value = b),impl,st,doVect,_,info,_)
then
(cache,DAE.BCONST(b),DAE.PROP(DAE.T_BOOL_DEFAULT,DAE.C_CONST()),st);
case (cache,_,Absyn.END(),impl,st,doVect,_,info,_)
then (cache,DAE.END(),DAE.PROP(DAE.T_INTEGER_DEFAULT,DAE.C_CONST()),st);
case (cache,env,Absyn.CREF(componentRef = cr),impl,st,doVect,pre,info,_) // BoschRexroth specifics
equation
false = OptManager.getOption("cevalEquation");
(cache,SOME((exp,prop as DAE.PROP(ty,DAE.C_PARAM()),_))) = elabCref(cache,env, cr, impl, doVect, pre, info);
then
(cache,exp,DAE.PROP(ty,DAE.C_VAR()),st);
case (cache,env,Absyn.CREF(componentRef = cr),impl,st,doVect,pre,info,_)
equation
(cache,SOME((exp,prop,_))) = elabCref(cache,env, cr, impl,doVect,pre,info);
then
(cache,exp,prop,st);
case (cache,env,(e as Absyn.BINARY(exp1 = e1,op = op,exp2 = e2)),impl,st,doVect,pre,info,_) /* Binary and unary operations */
equation
(cache,e1_1,DAE.PROP(t1,c1),st_1) = elabExp(cache,env, e1, impl, st,doVect,pre,info);
(cache,e2_1,DAE.PROP(t2,c2),st_2) = elabExp(cache,env, e2, impl, st_1,doVect,pre,info);
c = Types.constAnd(c1, c2);
(cache,ops) = operators(cache,op, env, t1, t2);
(op_1,{e1_2,e2_2},rtype) = deoverload(ops,{(e1_1,t1),(e2_1,t2)},e,pre,info);
exp_1 = replaceOperatorWithFcall(DAE.BINARY(e1_2,op_1,e2_2), c);
(exp_1,_) = ExpressionSimplify.simplify(exp_1);
prop = DAE.PROP(rtype,c);
then
(cache,exp_1,prop,st_2);
case (cache,env,(e as Absyn.UNARY(op = op,exp = e1)),impl,st,doVect,pre,info,_)
equation
(cache,e_1,DAE.PROP(t,c),st_1) = elabExp(cache,env,e1,impl,st,doVect,pre,info);
(cache,ops) = operators(cache,op, env, t, (DAE.T_NOTYPE(),NONE()));
(op_1,{e_2},rtype) = deoverload(ops,{(e_1,t)},e,pre,info);
exp_1 = replaceOperatorWithFcall(DAE.UNARY(op_1,e_2), c);
prop = DAE.PROP(rtype,c);
then
(cache,exp_1,prop,st_1);
case (cache,env,(e as Absyn.LBINARY(exp1 = e1,op = op,exp2 = e2)),impl,st,doVect,pre,info,_)
equation
(cache,e1_1,DAE.PROP(t1,c1),st_1) = elabExp(cache,env, e1, impl, st,doVect,pre,info) "Logical binary expressions" ;
(cache,e2_1,DAE.PROP(t2,c2),st_2) = elabExp(cache,env, e2, impl, st_1,doVect,pre,info);
c = Types.constAnd(c1, c2);
(cache,ops) = operators(cache,op, env, t1, t2);
(op_1,{e1_2,e2_2},rtype) = deoverload(ops, {(e1_1,t1),(e2_1,t2)},e,pre,info);
exp_1 = replaceOperatorWithFcall(DAE.LBINARY(e1_2,op_1,e2_2), c);
prop = DAE.PROP(rtype,c);
then
(cache,exp_1,prop,st_2);
case (cache,env,(e as Absyn.LUNARY(op = op,exp = e1)),impl,st,doVect,pre,info,_)
equation
(cache,e_1,DAE.PROP(t,c),st_1) = elabExp(cache,env,e1,impl,st,doVect,pre,info) "Logical unary expressions" ;
(cache,ops) = operators(cache,op, env, t, (DAE.T_NOTYPE(),NONE()));
(op_1,{e_2},rtype) = deoverload(ops, {(e_1,t)},e,pre,info);
exp_1 = replaceOperatorWithFcall(DAE.LUNARY(op_1,e_2), c);
prop = DAE.PROP(rtype,c);
then
(cache,exp_1,prop,st_1);
case (cache,env,(e as Absyn.RELATION(exp1 = e1,op = op,exp2 = e2)),impl,st,doVect,pre,info,_)
equation
(cache,e1_1,DAE.PROP(t1,c1),st_1) = elabExp(cache,env, e1, impl, st,doVect,pre,info) "Relations, e.g. a < b" ;
(cache,e2_1,DAE.PROP(t2,c2),st_2) = elabExp(cache,env, e2, impl, st_1,doVect,pre,info);
c = Types.constAnd(c1, c2);
(cache,ops) = operators(cache,op, env, t1, t2);
(op_1,{e1_2,e2_2},rtype) = deoverload(ops,{(e1_1,t1),(e2_1,t2)},e,pre,info);
exp_1 = replaceOperatorWithFcall(DAE.RELATION(e1_2,op_1,e2_2,-1,NONE()), c);
prop = DAE.PROP(rtype,c);
warnUnsafeRelations(env,c,t1,t2,e1_2,e2_2,op_1,pre);
then
(cache,exp_1,prop,st_2);
case (cache,env,e as Absyn.IFEXP(ifExp = _),impl,st,doVect,pre,info,_) /* Conditional expressions */
equation
Absyn.IFEXP(ifExp = e1,trueBranch = e2,elseBranch = e3) = Absyn.canonIfExp(e);
(cache,e1_1,prop1,st_1) = elabExp(cache,env, e1, impl, st,doVect,pre,info) "if expressions";
(cache,e_1,prop,st_2) = elabIfExp(cache,env,e1_1,prop1,e2,e3,impl,st,doVect,pre,info);
then
(cache,e_1,prop,st_2);
// adrpo: deal with DynamicSelect(literalExp, dynamicExp) by returning literalExp only!
case (cache,env,Absyn.CALL(function_ = Absyn.CREF_IDENT("DynamicSelect",_),functionArgs = Absyn.FUNCTIONARGS(args = (e1 :: _),argNames = _)),impl,st,doVect,pre,info,_)
equation
(cache,e_1,prop,st_1) = elabExp(cache,env, e1, impl, st, doVect, pre, info);
then
(cache,e_1,prop,st_1);
/*--------------------------------*/
/* Part of MetaModelica extension. KS */
case (cache,env,Absyn.CALL(function_ = Absyn.CREF_IDENT("SOME",_),functionArgs = Absyn.FUNCTIONARGS(args = (e1 :: _),argNames = _)),impl,st,doVect,pre,info,_)
equation
true = RTOpts.acceptMetaModelicaGrammar();
(cache,e_1,prop,st_1) = elabExp(cache,env, e1, impl, st,doVect,pre,info);
t = Types.getPropType(prop);
(e_1,t) = Types.matchType(e_1,t,DAE.T_BOXED_DEFAULT,true);
e_1 = DAE.META_OPTION(SOME(e_1));
c = Types.propAllConst(prop);
prop1 = DAE.PROP((DAE.T_METAOPTION(t),NONE()),c);
then
(cache,e_1,prop1,st);
case (cache,env,Absyn.CALL(function_ = Absyn.CREF_IDENT("NONE",_),functionArgs = Absyn.FUNCTIONARGS(args = {},argNames = _)),impl,st,doVect,_,info,_)
equation
true = RTOpts.acceptMetaModelicaGrammar();
e_1 = DAE.META_OPTION(NONE());
prop1 = DAE.PROP((DAE.T_METAOPTION((DAE.T_NOTYPE(),NONE())),NONE()),DAE.C_CONST());
then
(cache,e_1,prop1,st);
case (cache,env,Absyn.CALL(function_ = fn,functionArgs = Absyn.FUNCTIONARGS(args = args,argNames = nargs)),impl,st,doVect,pre,info,_)
equation
Debug.fprintln("sei", "elab_exp CALL...") "Function calls PA. Only positional arguments are elaborated for now. TODO: Implement elaboration of named arguments." ;
(cache,e_1,prop,st_1) = elabCall(cache,env, fn, args, nargs, impl, st,pre,info,Error.getNumErrorMessages());
c = Types.propAllConst(prop);
(e_1,_) = ExpressionSimplify.simplify(e_1);
Debug.fprintln("sei", "elab_exp CALL done");
then
(cache,e_1,prop,st_1);
// stefan
case (cache,env,e1 as Absyn.PARTEVALFUNCTION(function_ = _),impl,st,doVect,pre,info,_)
equation
(cache,e1_1,prop,st_1) = elabPartEvalFunction(cache,env,e1,st,impl,doVect,pre,info);
then
(cache,e1_1,prop,st_1);
case (cache,env,Absyn.TUPLE(expressions = es),impl,st,doVect,pre,info,_) /* PR. Get the properties for each expression in the tuple.
Each expression has its own constflag.
*/
equation
(cache,es_1,props) = elabTuple(cache,env,es,impl,doVect,pre,info) "Tuple function calls" ;
(types,consts) = splitProps(props);
then
(cache,DAE.TUPLE(es_1),DAE.PROP_TUPLE((DAE.T_TUPLE(types),NONE()),DAE.TUPLE_CONST(consts)),st);
case (cache,env,Absyn.CALL(function_ = fn,functionArgs = Absyn.FOR_ITER_FARG(exp = e, iterators=iterators)),impl,st,doVect,pre,info,_) /* Array-related expressions Elab reduction expressions, including array() constructor */
equation
(cache,e_1,prop,st_1) = elabCallReduction(cache,env, fn, e, iterators, impl, st,doVect,pre,info);
c = Types.propAllConst(prop);
then
(cache,e_1,prop,st_1);
case (cache, env, Absyn.RANGE(start = _), impl, st, doVect, pre, info, _)
equation
(cache, e_1, prop, st_1) = elabRange(cache, env, inExp, impl, st, doVect, pre, info);
then
(cache, e_1, prop, st_1);
// Part of the MetaModelica extension. This eliminates elab_array failed failtraces when using the empty list. sjoelund
case (cache,env,Absyn.ARRAY({}),impl,st,doVect,pre,info,_)
equation
true = RTOpts.acceptMetaModelicaGrammar();
(cache,exp,prop,st) = elabExp(cache,env,Absyn.LIST({}),impl,st,doVect,pre,info);
then (cache,exp,prop,st);
case (cache,env,Absyn.ARRAY(arrayExp = es),impl,st,doVect,pre,info,_)
equation
(cache,es_1,DAE.PROP(t,const)) = elabArray(cache,env, es, impl, st,doVect,pre,info) "array expressions, e.g. {1,2,3}" ;
l = listLength(es_1);
arrtp = (DAE.T_ARRAY(DAE.DIM_INTEGER(l),t),NONE());
at = Types.elabType(arrtp);
a = Types.isArray(t);
a = boolNot(a); // scalar = !array
arrexp = DAE.ARRAY(at,a,es_1);
(arrexp,arrtp) = MetaUtil.tryToConvertArrayToList(arrexp,arrtp) "converts types that cannot be arrays into lists";
arrexp = tryToConvertArrayToMatrix(arrexp);
then
(cache,arrexp,DAE.PROP(arrtp,const),st);
case (cache,env,Absyn.MATRIX(matrix = ess),impl,st,doVect,pre,info,_)
equation
(cache,dess,tps,_) = elabExpListList(cache, env, ess, impl, st,doVect,pre,info) "matrix expressions, e.g. {1,0;0,1} with elements of simple type." ;
tps_1 = Util.listListMap(tps, Types.getPropType);
tps_2 = Util.listFlatten(tps_1);
nmax = matrixConstrMaxDim(tps_2);
havereal = Types.containReal(tps_2);
(cache,mexp,DAE.PROP(t,c),dim1,dim2)
= elabMatrixSemi(cache,env, dess, tps, impl, st, havereal, nmax,doVect,pre,info);
mexp = Util.if_(havereal,DAE.CAST(DAE.ET_ARRAY(DAE.ET_REAL(),{dim1,dim2}),mexp),mexp);
(mexp,_) = ExpressionSimplify.simplify1(mexp); // to propagate cast down to scalar elts
mexp_1 = elabMatrixToMatrixExp(mexp);
t_1 = Types.unliftArray(t);
t_2 = Types.unliftArray(t_1) "All elts promoted to matrix, therefore unlifting" ;
then
(cache,mexp_1,DAE.PROP((DAE.T_ARRAY(dim1,(DAE.T_ARRAY(dim2,t_2),NONE())),NONE()),c),st);
case (cache,env,Absyn.CODE(code = cn),impl,st,doVect,_,info,_)
equation
tp = elabCodeType(env, cn) "Code expressions" ;
tp_1 = Types.elabType(tp);
then
(cache,DAE.CODE(cn,tp_1),DAE.PROP(tp,DAE.C_CONST()),st);
//-------------------------------------
// Part of the MetaModelica extension. KS
case (cache,env,Absyn.ARRAY(es),impl,st,doVect,pre,info,_)
equation
true = RTOpts.acceptMetaModelicaGrammar();
(cache,exp,prop,st) = elabExp(cache,env,Absyn.LIST(es),impl,st,doVect,pre,info);
then (cache,exp,prop,st);
case (cache,env,Absyn.CONS(e1,e2),impl,st,doVect,pre,info,_)
equation
{e1,e2} = MetaUtil.transformArrayNodesToListNodes({e1,e2},{});
(cache,e1_1,prop1,st_1) = elabExp(cache,env, e1, impl, st,doVect,pre,info);
(cache,e2_1,DAE.PROP((DAE.T_LIST(t2),_),c2),st_1) = elabExp(cache,env, e2, impl, st,doVect,pre,info);
t1 = Types.getPropType(prop1);
c1 = Types.propAllConst(prop1);
t = Types.superType(Types.boxIfUnboxedType(t1),Types.boxIfUnboxedType(t2));
(e1_1,_) = Types.matchType(e1_1, t1, t, true);
(e2_1,_) = Types.matchType(e2_1, (DAE.T_LIST(t2),NONE()), (DAE.T_LIST(t),NONE()), true);
exp = DAE.CONS(e1_1,e2_1);
c = Types.constAnd(c1,c2);
prop = DAE.PROP((DAE.T_LIST(t),NONE()),c);
then (cache,exp,prop,st);
case (cache,env,e as Absyn.CONS(e1,e2),impl,st,doVect,pre,info,_)
equation
{e1,e2} = MetaUtil.transformArrayNodesToListNodes({e1,e2},{});
(cache,e1_1,prop1,st_1) = elabExp(cache,env, e1, impl, st,doVect,pre,info);
(cache,e2_1,DAE.PROP(t2 as (DAE.T_LIST(_),_),c2),st_1) = elabExp(cache,env, e2, impl, st,doVect,pre,info);
expstr = Dump.printExpStr(e);
str1 = Types.unparseType(Types.getPropType(prop1));
str2 = Types.unparseType(t2);
Error.addSourceMessage(Error.META_CONS_TYPE_MATCH, {expstr,str1,str2}, info);
then fail();
// The Absyn.LIST() node is used for list expressions that are
// transformed from Absyn.ARRAY()
case (cache,env,Absyn.LIST({}),impl,st,doVect,_,info,_)
equation
t = DAE.T_LIST_DEFAULT;
prop = DAE.PROP(t,DAE.C_CONST());
then (cache,DAE.LIST({}),prop,st);
case (cache,env,Absyn.LIST(es),impl,st,doVect,pre,info,_)
equation
(cache,es_1,propList,st_2) = elabExpList(cache,env, es, impl, st,doVect,pre,info);
typeList = Util.listMap(propList, Types.getPropType);
constList = Types.getConstList(propList);
c = Util.listFold(constList, Types.constAnd, DAE.C_CONST());
t = Types.boxIfUnboxedType(Util.listReduce(typeList, Types.superType));
es_1 = Types.matchTypes(es_1, typeList, t, true);
prop = DAE.PROP((DAE.T_LIST(t),NONE()),c);
then (cache,DAE.LIST(es_1),prop,st_2);
// ----------------------------------
// Pattern matching has its own module that handles match expressions
case (cache,env,e as Absyn.MATCHEXP(matchTy = _),impl,st,doVect,pre,info,numErrorMessages)
equation
(cache,exp,prop,st) = Patternm.elabMatchExpression(cache,env,e,impl,st,doVect,pre,info,numErrorMessages);
then (cache,exp,prop,st);
case (cache,env,e,_,_,_,pre,info,numErrorMessages)
equation
true = numErrorMessages == Error.getNumErrorMessages();
msg = Dump.printExpStr(e);
Error.addSourceMessage(Error.GENERIC_ELAB_EXPRESSION,{msg},info);
/* FAILTRACE REMOVE
true = RTOpts.debugFlag("failtrace");
Debug.fprint("failtrace", "- Static.elabExp failed: ");
Debug.traceln(Dump.printExpStr(e));
Debug.traceln(" Scope: " +& Env.printEnvPathStr(env));
Debug.traceln(" Prefix: " +& PrefixUtil.printPrefixStr(pre));
//Debug.traceln("\n env : ");
//Debug.traceln(Env.printEnvStr(env));
//Debug.traceln("\n----------------------- FINISHED ENV ------------------------\n");
*/
then
fail();
end matchcontinue;
end elabExp2;
protected function elabIfExp
"Elaborates an if-expression. If one of the branches can not be elaborated and
the condition is parameter or constant; it is evaluated and the correct branch is selected.
This is a dirty hack to make MSL CombiTable models work!
Note: Because of this, the function has to rollback or delete an ErrorExt checkpoint."
input Env.Cache cache;
input Env.Env env;
input DAE.Exp condExp;
input DAE.Properties condProp;
input Absyn.Exp trueExp;
input Absyn.Exp falseExp;
input Boolean impl;
input Option<Interactive.InteractiveSymbolTable> st;
input Boolean vect;
input Prefix.Prefix pre;
input Absyn.Info info;
output Env.Cache outCache;
output DAE.Exp outExp;
output DAE.Properties prop;
output Option<Interactive.InteractiveSymbolTable> outSt;
algorithm
(outCache,outExp,prop,outSt) := matchcontinue (cache,env,condExp,condProp,trueExp,falseExp,impl,st,vect,pre,info)
local
DAE.Exp etrueExp,efalseExp;
DAE.Properties trueProp,falseProp;
Boolean b;
case (cache,env,condExp,condProp,trueExp,falseExp,impl,st,vect,pre,info)
equation
ErrorExt.setCheckpoint("Static.elabExp:IFEXP");
(cache,etrueExp,trueProp,st) = elabExp(cache,env,trueExp,impl,st,vect,pre,info);
(cache,efalseExp,falseProp,st) = elabExp(cache,env,falseExp,impl,st,vect,pre,info);
(cache,outExp,prop) = makeIfexp(cache,env,condExp,condProp,etrueExp,trueProp,efalseExp,falseProp,impl,st,pre);
ErrorExt.delCheckpoint("Static.elabExp:IFEXP");
then (cache,outExp,prop,st);
case (cache,env,condExp,condProp,trueExp,falseExp,impl,st,vect,pre,info)
equation
ErrorExt.setCheckpoint("Static.elabExp:IFEXP:HACK") "Extra rollback point so we get the regular error message only once if the hack fails";
true = Types.isParameterOrConstant(Types.propAllConst(condProp));
(cache,Values.BOOL(b),_) = Ceval.ceval(cache,env,condExp,impl,NONE(),NONE(),Ceval.MSG());
(cache,outExp,prop,st) = elabExp(cache,env,Util.if_(b,trueExp,falseExp),impl,st,vect,pre,info);
ErrorExt.delCheckpoint("Static.elabExp:IFEXP:HACK");
ErrorExt.rollBack("Static.elabExp:IFEXP");
then (cache,outExp,prop,st);
else
equation
ErrorExt.rollBack("Static.elabExp:IFEXP:HACK");
ErrorExt.delCheckpoint("Static.elabExp:IFEXP");
then fail();
end matchcontinue;
end elabIfExp;
// Part of MetaModelica extension
public function elabListExp "function: elabListExp
Function that elaborates the MetaModelica list type,
for instance list<Integer>.
This is used by Inst.mo when handling a var := {...} statement
"
input Env.Cache inCache;
input Env.Env inEnv;
input list<Absyn.Exp> inExpList;
input DAE.Properties inProp;
input Boolean inBoolean;
input Option<Interactive.InteractiveSymbolTable> inInteractiveInteractiveSymbolTableOption;
input Boolean performVectorization;
input Prefix.Prefix inPrefix;
input Absyn.Info info;
output Env.Cache outCache;
output DAE.Exp outExp;
output DAE.Properties outProperties;
output Option<Interactive.InteractiveSymbolTable> outInteractiveInteractiveSymbolTableOption;
algorithm
(outCache,outExp,outProperties,outInteractiveInteractiveSymbolTableOption) :=
matchcontinue (inCache,inEnv,inExpList,inProp,inBoolean,inInteractiveInteractiveSymbolTableOption,performVectorization,inPrefix,info)
local
Env.Cache cache;
Env.Env env;
Boolean impl,doVect;
Option<Interactive.InteractiveSymbolTable> st;
DAE.Properties prop;
DAE.Const c;
Prefix.Prefix pre;
list<Absyn.Exp> expList;
list<DAE.Exp> expExpList;
DAE.Type t;
list<Boolean> boolList;
list<DAE.Properties> propList;
list<DAE.Type> typeList;
DAE.ExpType t2;
case (cache,env,{},prop,_,st,_,_,info) then (cache,DAE.LIST({}),prop,st);
case (cache,env,expList,prop as DAE.PROP((DAE.T_LIST(t),_),c),impl,st,doVect,pre,info)
equation
(cache,expExpList,propList,st) = elabExpList(cache,env,expList,impl,st,doVect,pre,info);
typeList = Util.listMap(propList, Types.getPropType);
(expExpList, t) = Types.listMatchSuperType(expExpList, typeList, true);
then
(cache,DAE.LIST(expExpList),DAE.PROP((DAE.T_LIST(t),NONE()),c),st);
case (_,_,_,_,_,_,_,_,_)
equation
Debug.fprintln("failtrace", "- elabListExp failed, non-matching args in list constructor?");
then
fail();
end matchcontinue;
end elabListExp;
/* ------------------------------- */
public function fromEquationsToAlgAssignments "function: fromEquationsToAlgAssignments
Converts equations to algorithm assignments.
Matchcontinue expressions may contain statements that you won't find
in a normal equation section. For instance:
case(...)
local
equation
(var1,_,MYREC(...)) = func(...);
fail();
then 1;
"
input list<Absyn.EquationItem> eqsIn;
input list<Absyn.AlgorithmItem> accList;
input Env.Cache cache;
input Env.Env env;
input Prefix.Prefix inPrefix;
output Env.Cache outCache;
output list<Absyn.AlgorithmItem> algsOut;
algorithm
(outCache,algsOut) :=
match (eqsIn,accList,cache,env,inPrefix)
local
list<Absyn.AlgorithmItem> localAccList;
Env.Cache localCache;
Env.Env localEnv;
Prefix.Prefix pre;
Option<Absyn.Comment> comment;
Absyn.Info info;
Absyn.Equation first;
list<Absyn.EquationItem> rest;
list<Absyn.AlgorithmItem> alg;
case ({},localAccList,localCache,localEnv,_) then (localCache,listReverse(localAccList));
case (Absyn.EQUATIONITEM(equation_ = first, comment = comment, info = info) :: rest,localAccList,localCache,localEnv,pre)
equation
(localCache,alg) = fromEquationToAlgAssignment(first,comment,info,localCache,localEnv,pre);
(localCache,localAccList) = fromEquationsToAlgAssignments(rest,listAppend(alg,localAccList),localCache,localEnv,pre);
then (localCache,localAccList);
end match;
end fromEquationsToAlgAssignments;
protected function fromEquationBranchesToAlgBranches
"Converts equations to algorithm assignments."
input list<tuple<Absyn.Exp,list<Absyn.EquationItem>>> eqsIn;
input list<tuple<Absyn.Exp,list<Absyn.AlgorithmItem>>> accList;
input Env.Cache cache;
input Env.Env env;
input Prefix.Prefix inPrefix;
output Env.Cache outCache;
output list<tuple<Absyn.Exp,list<Absyn.AlgorithmItem>>> algsOut;
algorithm
(outCache,algsOut) :=
match (eqsIn,accList,cache,env,inPrefix)
local
list<tuple<Absyn.Exp,list<Absyn.AlgorithmItem>>> localAccList;
list<tuple<Absyn.Exp,list<Absyn.EquationItem>>> rest;
Env.Cache localCache;
Env.Env localEnv;
Prefix.Prefix pre;
Absyn.Exp e;
list<Absyn.AlgorithmItem> algs;
list<Absyn.EquationItem> eqs;
case ({},localAccList,localCache,localEnv,_) then (localCache,listReverse(localAccList));
case ((e,eqs)::rest,localAccList,localCache,localEnv,pre)
equation
(localCache,algs) = fromEquationsToAlgAssignments(eqs,{},localCache,localEnv,pre);
(localCache,localAccList) = fromEquationBranchesToAlgBranches(rest,(e,algs)::localAccList,localCache,localEnv,pre);
then (localCache,localAccList);
end match;
end fromEquationBranchesToAlgBranches;
protected function fromEquationToAlgAssignment "function: fromEquationToAlgAssignment"
input Absyn.Equation eq;
input Option<Absyn.Comment> comment;
input Absyn.Info info;
input Env.Cache cache;
input Env.Env env;
input Prefix.Prefix inPrefix;
output Env.Cache outCache;
output list<Absyn.AlgorithmItem> algStatement;
algorithm
(outCache,algStatement) := matchcontinue (eq,comment,info,cache,env,inPrefix)
local
Env.Cache localCache;
Prefix.Prefix pre;
String str,strLeft,strRight;
Absyn.Exp left,right,e;
Absyn.AlgorithmItem algItem,algItem1,algItem2;
Absyn.Equation eq2;
Option<Absyn.Comment> comment2;
Absyn.Info info2;
Absyn.AlgorithmItem res;
Absyn.ComponentRef cref;
Absyn.FunctionArgs fargs;
list<Absyn.AlgorithmItem> algs, algTrueItems, algElseItems;
list<tuple<Absyn.Exp,list<Absyn.AlgorithmItem>>> algBranches;
list<Absyn.EquationItem> eqTrueItems, eqElseItems;
list<tuple<Absyn.Exp,list<Absyn.EquationItem>>> eqBranches;
case (Absyn.EQ_EQUALS(Absyn.CREF(Absyn.CREF_IDENT(strLeft,{})),Absyn.CREF(Absyn.CREF_IDENT(strRight,{}))),comment,info,localCache,_,_)
equation
true = strLeft ==& strRight;
// match x case x then ... produces equation x = x; we save a bit of time by removing it here :)
then (localCache,{});
// The syntax n>=0 = true; is also used
case (Absyn.EQ_EQUALS(left,Absyn.BOOL(true)),comment,info,localCache,_,_)
equation
failure(Absyn.CREF(_) = left); // If lhs is a CREF, it should be an assignment
algItem1 = Absyn.ALGORITHMITEM(Absyn.ALG_THROW(),comment,info);
algItem2 = Absyn.ALGORITHMITEM(Absyn.ALG_IF(Absyn.LUNARY(Absyn.NOT(),left),{algItem1},{},{}),comment,info);
then (localCache,{algItem2});
case (Absyn.EQ_EQUALS(left,Absyn.BOOL(false)),comment,info,localCache,_,_)
equation
failure(Absyn.CREF(_) = left); // If lhs is a CREF, it should be an assignment
algItem1 = Absyn.ALGORITHMITEM(Absyn.ALG_THROW(),comment,info);
algItem2 = Absyn.ALGORITHMITEM(Absyn.ALG_IF(left,{algItem1},{},{}),comment,info);
then (localCache,{algItem2});
case (Absyn.EQ_NORETCALL(Absyn.CREF_IDENT("fail",_),_),comment,info,localCache,_,_)
equation
algItem = Absyn.ALGORITHMITEM(Absyn.ALG_THROW(),comment,info);
then (localCache,{algItem});
case (Absyn.EQ_NORETCALL(cref,fargs),comment,info,localCache,_,_)
equation
algItem = Absyn.ALGORITHMITEM(Absyn.ALG_NORETCALL(cref,fargs),comment,info);
then (localCache,{algItem});
case (Absyn.EQ_EQUALS(left,right),comment,info,localCache,_,_)
equation
algItem = Absyn.ALGORITHMITEM(Absyn.ALG_ASSIGN(left,right),comment,info);
then (localCache,{algItem});
case (Absyn.EQ_FAILURE(Absyn.EQUATIONITEM(eq2,comment2,info2)),comment,info,cache,env,pre)
equation
(cache,algs) = fromEquationToAlgAssignment(eq2,comment2,info2,cache,env,pre);
res = Absyn.ALGORITHMITEM(Absyn.ALG_FAILURE(algs),comment,info);
then (cache,{res});
case (Absyn.EQ_IF(ifExp = e, equationTrueItems = eqTrueItems, elseIfBranches = eqBranches, equationElseItems = eqElseItems),comment,info,cache,env,pre)
equation
(cache,algTrueItems) = fromEquationsToAlgAssignments(eqTrueItems,{},cache,env,pre);
(cache,algElseItems) = fromEquationsToAlgAssignments(eqElseItems,{},cache,env,pre);
(cache,algBranches) = fromEquationBranchesToAlgBranches(eqBranches,{},cache,env,pre);
res = Absyn.ALGORITHMITEM(Absyn.ALG_IF(e, algTrueItems, algBranches, algElseItems),comment,info);
then (cache,{res});
case (eq,_,info,_,_,_)
equation
str = Dump.equationName(eq);
Error.addSourceMessage(Error.META_MATCH_EQUATION_FORBIDDEN, {str}, info);
then fail();
end matchcontinue;
end fromEquationToAlgAssignment;
protected function elabMatrixGetDimensions "function: elabMatrixGetDimensions
Helper function to elab_exp (MATRIX). Calculates the dimensions of the
matrix by investigating the elaborated expression.
"
input DAE.Exp inExp;
output Integer outInteger1;
output Integer outInteger2;
algorithm
(outInteger1,outInteger2):=
matchcontinue (inExp)
local
Integer dim1,dim2;
list<DAE.Exp> lst2,lst;
case (DAE.ARRAY(array = lst))
equation
dim1 = listLength(lst);
(DAE.ARRAY(array = lst2) :: _) = lst;
dim2 = listLength(lst2);
then
(dim1,dim2);
end matchcontinue;
end elabMatrixGetDimensions;
protected function elabMatrixToMatrixExp "function: elabMatrixToMatrixExp
Convert an array expression (which is a matrix or higher dim.) to
a matrix expression (using MATRIX).
"
input DAE.Exp inExp;
output DAE.Exp outExp;
algorithm
outExp:=
matchcontinue (inExp)
local
list<list<tuple<DAE.Exp, Boolean>>> mexpl;
DAE.ExpType a;
Boolean at;
Integer d1;
list<DAE.Exp> expl;
DAE.Exp e;
case (DAE.ARRAY(ty = a,scalar = at,array = expl))
equation
mexpl = elabMatrixToMatrixExp2(expl);
d1 = listLength(mexpl);
then
DAE.MATRIX(a,d1,mexpl);
case (e) then e; /* if fails, skip conversion, use generic array expression as is. */
end matchcontinue;
end elabMatrixToMatrixExp;
protected function elabMatrixToMatrixExp2 "function: elabMatrixToMatrixExp2
Helper function to elab_matrix_to_matrix_exp
"
input list<DAE.Exp> inExpExpLst;
output list<list<tuple<DAE.Exp, Boolean>>> outTplExpExpBooleanLstLst;
algorithm
(outTplExpExpBooleanLstLst):=
match (inExpExpLst)
local
list<tuple<DAE.Exp, Boolean>> expl_1;
list<list<tuple<DAE.Exp, Boolean>>> es_1;
DAE.ExpType a;
Boolean at;
list<DAE.Exp> expl,es;
case ({}) then {};
case ((DAE.ARRAY(ty = a,scalar = at,array = expl) :: es))
equation
expl_1 = elabMatrixToMatrixExp3(expl);
es_1 = elabMatrixToMatrixExp2(es);
then
expl_1 :: es_1;
end match;
end elabMatrixToMatrixExp2;
protected function elabMatrixToMatrixExp3
input list<DAE.Exp> inExpExpLst;
output list<tuple<DAE.Exp, Boolean>> outTplExpExpBooleanLst;
algorithm
outTplExpExpBooleanLst:=
match (inExpExpLst)
local
DAE.ExpType tp;
Boolean scalar;
Ident s;
list<tuple<DAE.Exp, Boolean>> es_1;
DAE.Exp e;
list<DAE.Exp> es;
case ({}) then {};
case ((e :: es))
equation
tp = Expression.typeof(e);
scalar = Expression.typeBuiltin(tp);
es_1 = elabMatrixToMatrixExp3(es);
then
((e,scalar) :: es_1);
end match;
end elabMatrixToMatrixExp3;
protected function matrixConstrMaxDim "function: matrixConstrMaxDim
Helper function to elab_exp (MATRIX).
Determines the maximum dimension of the array arguments to the matrix
constructor as.
max(2, ndims(A), ndims(B), ndims(C),..) for matrix constructor arguments
A, B, C, ...
"
input list<DAE.Type> inTypesTypeLst;
output Integer outInteger;
algorithm
outInteger:=
matchcontinue (inTypesTypeLst)
local
Integer tn,tn2,res;
tuple<DAE.TType, Option<Absyn.Path>> t;
list<tuple<DAE.TType, Option<Absyn.Path>>> ts;
case ({}) then 2;
case ((t :: ts))
equation
tn = Types.numberOfDimensions(t);
tn2 = matrixConstrMaxDim(ts);
res = intMax(tn, tn2);
then
res;
case (_)
equation
Debug.fprint("failtrace", "-matrix_constr_max_dim failed\n");
then