build.gradle

plugins {
    id 'java'
    id "io.freefair.lombok" version "6.3.0"
    id 'com.github.johnrengelman.shadow' version "7.1.2"
    id "com.github.hierynomus.license" version "0.16.1"
}

group 'pl.asie.zima'

version = '0.9.0'
ext.revision = 'git rev-list --count HEAD'.execute().text.trim()
ext.hash = 'git rev-parse --short HEAD'.execute().text.trim()
version = "${version}-r${revision}.${hash}"

repositories {
    mavenCentral()
}

dependencies {
    implementation 'com.beust:jcommander:1.82'
    implementation 'com.github.davidmoten:word-wrap:0.1.12'
    implementation 'com.google.code.gson:gson:2.10'
    implementation 'com.google.guava:guava:32.0.1-jre'

    testImplementation(platform('org.junit:junit-bom:5.9.3'))
    testImplementation('org.junit.jupiter:junit-jupiter')
}

license {
    header = file('docs/licenses/COPYING')
    exclude "**/*.txt"
    exclude "**/asie/zima/repack/**"
}

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}

sourceSets {
    main {
        resources {
            srcDirs "src/main/resources", "docs"
        }
    }
}

jar {
    manifest {
        attributes 'Main-Class': 'pl.asie.zima.Main'
    }
}

artifacts {
    shadowJar
}

shadowJar {
    minimize()
}

build.dependsOn(shadowJar)

tasks.withType(Copy).all {
    duplicatesStrategy 'exclude'
}