build.gradle

buildscript {
    repositories {
        maven { url = "https://files.minecraftforge.net/maven" }
        mavenCentral()
    }
    dependencies {
        classpath group: "net.minecraftforge.gradle", name: "ForgeGradle", version: "5.1.+", changing: true
        classpath "org.spongepowered:mixingradle:0.7.+"
    }
}

apply plugin: "net.minecraftforge.gradle"
apply plugin: "eclipse"
apply plugin: "org.spongepowered.mixin"

version = project.mod_version + "-forge-" + project.minecraft_suffix
group = project.maven_group
archivesBaseName = project.mod_id

java.toolchain.languageVersion = JavaLanguageVersion.of(project.java_target)

println("Java: " + System.getProperty("java.version") + " JVM: " + System.getProperty("java.vm.version") + "(" + System.getProperty("java.vendor") + ") Arch: " + System.getProperty("os.arch"))

// Keep parameter names when compiling
compileJava.options.compilerArgs.add '-parameters'

repositories {
    maven {
        url = "https://repo.spongepowered.org/maven"
    }
}

dependencies {
    // Forge
    minecraft "net.minecraftforge:forge:${project.minecraft_version}-${project.forge_version}"

    // SpongePowered Mixin
    annotationProcessor "org.spongepowered:mixin:0.8.5:processor"
    implementation("org.spongepowered:mixin:0.8.5") {
        exclude module: "guava"
        exclude module: "commons-io"
        exclude module: "gson"
    }

    // SpongeForge
    compileOnly("org.spongepowered:spongeforge:1.12.2-2838-7.4.7") {
        transitive = false
    }
}

// Include resources generated by data generators.
sourceSets.main {
    resources.srcDir "src/generated/resources"
    // Make sure resources are available for 1.12
    output.setResourcesDir output.classesDirs.asPath
}

processResources {
    inputs.property "version", project.version

    filesMatching(["mcmod.info", "modid.mixins.json", "pack.mcmeta"]) {
        expand project.properties
    }

    exclude "**/*.pdn"

    rename "^modid.mixins.json\$", "${project.mod_id}.mixins.json"
    rename "^icon.png\$", "${project.mod_id}.png"
    rename "^accesstransformer.cfg\$", "${project.mod_id}-accesstransformer.cfg"
}

minecraft {
    mappings channel: project.mappings_channel, version: project.mappings_version

    accessTransformer = file("src/main/resources/META-INF/accesstransformer.cfg")

    String resolved_core_plugin = "${project.mod_package}.${project.coremod_package}.${project.coremod_class}"
    String resolved_core_config = "${project.mod_id}.mixins.json"

    runs {
        client {
            workingDirectory project.file("run")

            property "forge.logging.markers", "REGISTRIES"
            property "fml.coreMods.load", resolved_core_plugin

            args "--mixin", resolved_core_config

            mods {
                supermartijn642corelib {
                    source sourceSets.main
                }
                corelibtestmod {
                    source sourceSets.test
                }
            }
        }

        server {
            workingDirectory project.file("run")

            property "forge.logging.markers", "REGISTRIES"
            property "fml.coreMods.load", resolved_core_plugin

            args "--mixin", resolved_core_config

            mods {
                supermartijn642corelib {
                    source sourceSets.main
                }
                corelibtestmod {
                    source sourceSets.test
                }
            }
        }

        data {
            parent runs.client
            property "--generatorModid", project.mod_id
            property "--output", file("src/generated/resources/")
            property "--existing", file("$buildDir/data_resources")
        }
    }
}

task processSources(type: Sync) {
    from sourceSets.main.java
    into "$buildDir/sources"
    inputs.property 'version', version

    // Replace mod properties in main mod class
    Hashtable<String, String> properties = new Hashtable<>()
    project.properties.entrySet().stream()
            .filter(entry -> entry.key instanceof String && entry.value instanceof String)
            .forEach(entry -> properties.put(entry.key, entry.value))
    filesMatching(project.mod_package.replace('.', '/') + "/" + project.mod_main_class + ".java") {
        //noinspection UnnecessaryQualifiedReference
        filter(org.apache.tools.ant.filters.ReplaceTokens, tokens: properties)
    }
}

compileJava {
    source = processSources.outputs
}

mixin {
    // MixinGradle Settings
    add sourceSets.main, "${project.mod_id}.mixins.refmap.json"
}

jar {
    from {
        configurations.compileClasspath
                .filter { "mixin-0.8.2.jar" == it.name }
                .collect { it.isDirectory() ? it : zipTree(it) }
    } {
        exclude "LICENSE.txt", "META-INF/MANIFSET.MF", "META-INF/maven/**", "META-INF/*.RSA", "META-INF/*.SF"
    }

    manifest {
        attributes "FMLCorePlugin": "com.supermartijn642.core.coremod.CoreModPlugin"
        attributes "FMLCorePluginContainsFMLMod": "true"
        attributes "ForceLoadAsMod": "true"
        attributes "TweakClass": "org.spongepowered.asm.launch.MixinTweaker"
        attributes "TweakOrder": "0"
        attributes "MixinConfigs": "supermartijn642corelib.mixins.json"
    }
}

//jar.finalizedBy('reobfJar')

task javadocJar(type: Jar, dependsOn: javadoc) {
    group = "documentation"
    classifier = "javadoc"
    from javadoc.destinationDir
}

task sourcesJar(type: Jar, dependsOn: classes) {
    group = "documentation"
    classifier = 'sources'
    from sourceSets.main.allSource
}

task prepareDataResources(type: Sync) {
    from file("src/main/resources")
    into "$buildDir/data_resources"
    inputs.property "version", version

    filesMatching(["META-INF/mods.toml", "modid.mixins.json", "pack.mcmeta"]) {
        expand project.properties
    }

    exclude "**/*.pdn"

    rename "^modid.mixins.json\$", "${project.mod_id}.mixins.json"
    rename "^icon.png\$", "${project.mod_id}.png"
    rename "^accesstransformer.cfg\$", "${project.mod_id}-accesstransformer.cfg"
}

// Run prepareDataResources before prepareRunData
tasks.whenTaskAdded {
    if (it.name == "prepareRunData")
        it.dependsOn "prepareDataResources"
}

// Create task which copies from 'jar', but renames the file
tasks.register('renameJar', Copy) {
    dependsOn build
    from jar
    into 'build/renamedLibs'
    rename "_"::concat
}
jar.finalizedBy renameJar