Analyse dateTime/Period/date/time elements

[nir-r]

Requirment
Allow for temporal analysis by extracting relevant paths into a file and then analyzing it in the dashboard.

Implementation
All relevant dateTime/Period/date/time elements (from base or profiles) will be listed in an auxiliary file.
Currently, only elements defined in the base will be included.

• Create paths file with the following attributes
• path (resourceType.path)
• Create a target file with the following attributes
• DateTime
• resource ID
• resourceType

https://hl7.org/fhir/R4/datatypes.html#dateTime:~:text=3%5B0%2D1%5D))%3F)%3F-,dateTime,-A%20date%2C%20date

[nir-r]

/*List dateTime/Period/date/time elements in server-supported resources*/
(
  /*List all supported resources*/
   $SupportedResourceTypes := $capabilities().rest.resource[type in ['Patient','Practitioner','PractitionerRole','Observation','Encounter','Procedure']].type /*remove [] filtering on prod*/;

  /*For each supported resource, list date/time/period elements*/
    $elements := $SupportedResourceTypes.$getSnapshot($).snapshot.element[type.code='dateTime' or type.code='date' or type.code='time' or type.code='Period'].{
      'resourceType': $substringBefore(path,".")
      ,'path': path
      ,'elementPath' : $substringAfter(path,$substringBefore(path,".") & '.')
      ,'id':id
      ,"dataType": type.code
      };

  /*List relevant (date/time/period elements) paths*/
    $writeFile($elements,'DateTimeElements.json')
)

[nir-r]

/*Extract dateTime/Period/date/time elements from the sample and write to a target file by type*/
(
  $DateTimeElements := $readFile('DateTimeElements.json');

  $SampledResources := $readFile('SampledResources.json');

  $ElementsValues := $DateTimeElements@$dte.($SampledResources[resourceType=$dte.resourceType].(
      $instance := $;
      $value := $eval($dte.elementPath);
      $value#$i.{
      'resourceType': $instance.resourceType
      ,'id': $instance.id
      ,'path': $dte.path
      ,'dataType' : $dte.dataType
      ,'index': $i
      ,'value': $
      }
    ));
  
  $ElementsValues^(dataType,id,path,index)
)

[nir-r]

/*Extract dateTime/Period/date/time elements from the sample and write to a target file by type*/
(
  $DateTimeElements := $readFile('DateTimeElements.json');

  $SampledResources := $readFile('SampledResources.json');

  $ElementsValues := $DateTimeElements@$dte.($SampledResources[resourceType=$dte.resourceType].{
    'resourceType': resourceType
    ,'id': id
    ,'path': $dte.path
    ,'dataType' : $dte.dataType
    ,'value': $eval($dte.elementPath)
    });
  
  $ElementsValues.value#$i.{
    'resourceType': %.resourceType
    ,'id': %.id
    ,'path': %.path
    ,'dataType' : %.dataType
    ,'index' : $i 
    ,'value': $
    }
)
```
/*Extract dateTime/Period/date/time elements from the sample and write to a target file by type*/
(
  $DateTimeElements := $readFile('DateTimeElements.json');

  $SampledResources := $readFile('SampledResources.json');

  $ElementsValues := $DateTimeElements@$dte.($SampledResources[resourceType=$dte.resourceType].{
    'resourceType': resourceType
    ,'id': id
    ,'path': $dte.path
    ,'dataType' : $dte.dataType
    ,'value': $eval($dte.elementPath)
    });
  
  $ElementsValues.value#$i.{
    'resourceType': %.resourceType
    ,'id': %.id
    ,'path': %.path
    ,'dataType' : %.dataType
    ,'index' : $i 
    ,'value': $
    }
)