wrap any existing import in Attribute::Handlers' injected import

Some modules using Attribute::Handlers autotie feature have their own
import method. When injecting an import method, attempt to wrap anything
that exists, either in the class directly or in a parent class.

We can't detect parent classes at injection time, because @isa may
change, and this is actually common since users of Exporter will add it
as a parent class at module runtime, while Attribute::Handlers injection
would happen first during compilation.

A better approach could involve using next::can from mro, but that also
requires Sub::Util::set_subname, and Attribute::Handlers is dual life
and currently supports 5.6.

dist/Attribute-Handlers/lib/Attribute/Handlers.pm

@@ -88,13 +88,26 @@ sub import {
 
                 if ($attr =~ /\A__CALLER__::/) {
                     no strict 'refs';
-                    *{ caller . '::import' } = sub {
-                      my $caller = caller;
-                      my $full_attr = $attr;
-                      $full_attr =~ s/__CALLER__/$caller/;
-                      eval qq{ sub $full_attr $code 1; }
-                        or die "Internal error: $@";
-
+                    my $add_import = caller;
+                    my $next = defined &{ $add_import . '::import' } && \&{ $add_import . '::import' };
+                    *{ $add_import . '::import' } = sub {
+                        my $caller = caller;
+                        my $full_attr = $attr;
+                        $full_attr =~ s/__CALLER__/$caller/;
+                        eval qq{ sub $full_attr $code 1; }
+                            or die "Internal error: $@";
+
+                        goto &$next
+                            if $next;
+                        my $uni = defined &UNIVERSAL::import && \&UNIVERSAL::import;
+                        for my $isa (@{ $add_import . '::ISA' }) {
+                            if (my $import = $isa->can('import')) {
+                                goto &$import
+                                    if $import != $uni;
+                            }
+                        }
+                        goto &$uni
+                            if $uni;
                     };
                 }
                 else {